[Résolu] Position graphique du curseur sur Synedit

label bouger

synedit 1
left 1,100
top 1,150
on_mouse_move 1,bouger

END

bouger:
   off_mouse_move 1
   caption 0,"x="+str$(mouse_x_position(1))+" /y="+str$(mouse_x_position(1))
   on_mouse_move 1,bouger
return

' Panoramic 0.9.27i5

'   ===========================================================================================
'   =  Title  : GetCaretPos
'   =
'   =  Author : Silverman
'   =
'   =  Date   : Février 2016
'   =
'   =  Version: 1.0
'   ===========================================================================================
'   Comments  : Obtenir les coordonnées du curseur dans un memo/synedit en coordonnées souris
'   ===========================================================================================


' Attention au type de données:( plus d'info ici : https://msdn.microsoft.com/en-us/library/cc230318.aspx )
'
'    LONG = 4 bytes ---> entier signé, donc la variable de stockage d'un LONG se termine par %(x%,y%,...)
'
'    pointeur : DWORD
'    DWORD=4 bytes non signé; ce type n'existe pas en Panoramic, mais on peut le remplacer par
'    un LONG à condition qu'il soit toujours positif. Ex. de DWORD: lpPoint_ptr%
'
' lpPoint$ = structure POINT; détail ici : https://msdn.microsoft.com/fr-fr/library/windows/desktop/dd162805%28v=vs.85%29.aspx
'
' les valeurs retournées dans la structure POINT sont : 2 LONG
'
' Caret Functions; détail ici : https://msdn.microsoft.com/fr-fr/library/windows/desktop/ff468799%28v=vs.85%29.aspx
'
'
' 07/2021 : adapté le code à la commande peek32


label affichage
dim i
dim bool%,lpPoint$,lpPoint_ptr%,x%,y%

' créer un buffer pour 2 LONG(donc 8 bytes) nuls
lpPoint$=string$(8,chr$(0))

alpha 1

synedit 10 : left 10,250
for i=1 to 100
   item_add 10,"0123456"
next i
set_focus 10

timer 5
timer_interval 5,125 : on_timer 5,affichage

dll_on "user32"
peek_reverse


END
affichage:
 timer_off 5
   '
   lpPoint_ptr%=peek32(adr(lpPoint$))
   bool%=dll_call1("GetCaretPos",lpPoint_ptr%)
  
   ' copie les valeurs des coordonnées souris contenu dans le buffer, dans les variables x% et y%
   COPY_LONG(adr(x%),lpPoint_ptr%,0)
   COPY_LONG(adr(y%),lpPoint_ptr%,4)

   ' affichage du résultat
   caption 1,"X = "+str$(x%)+"          Y = "+str$(y%)

 timer_on 5
return

' LES SUBs *********************************************************************
sub COPY_LONG(adr_destination%,adr_source%,buffer_position%)
' LONG = 4 BYTEs
' adr_destination%  = adresse destination
' adr_source%       = adresse adr_source
' copie un LONG, –2147483648 < LONG < 2147483647
   poke adr_destination%,peek(adr_source%+buffer_position%)
   poke adr_destination%+1,peek(adr_source%+1+buffer_position%)
   poke adr_destination%+2,peek(adr_source%+2+buffer_position%)
   poke adr_destination%+3,peek(adr_source%+3+buffer_position%)
end_sub