Enigme : combien y a-t-il de carrés ?

Bonsoir à tous !

Voici quelques lignes de codes pour poser le problème :

Code:: DIM a%
BORDER_SMALL 0
COLOR 0,0,0,0
WIDTH 0,550
HEIGHT 0,630

PICTURE 1
LEFT 1,(WIDTH_CLIENT(0)-401)/2
TOP 1,LEFT(1)
WIDTH 1,401
HEIGHT 1,401
COLOR 1,255,210,64
2D_TARGET_IS 1
2D_FILL_OFF
2D_PEN_WIDTH 3
2D_PEN_COLOR 0,0,255
2D_LINE 0,0,0,400
2D_LINE 100,0,100,400
2D_LINE 200,0,200,400
2D_LINE 300,0,300,400
2D_LINE 400,0,400,400
2D_LINE 0,0,400,0
2D_LINE 0,100,400,100
2D_LINE 0,200,400,200
2D_LINE 0,300,400,300
2D_LINE 0,400,400,400
2D_RECTANGLE 250,50,351,151
2D_RECTANGLE 150,150,251,251
2D_RECTANGLE 50,250,151,351

ALPHA 2
TOP 2,500
LEFT 2,550
FONT_COLOR 2,250,250,250
FONT_SIZE 2,20
CAPTION 2,"Combien y a-t-il de carrés ?"

FOR a% = 550 TO 100 STEP -1
LEFT 2,a%
PAUSE 20
NEXT a%

END

... Et la question : combien y a-t-il de carrés ? scratch

Merci pour votre participation et vos réponses !

Bon comptage !

Voici ma réponse

Considérons que le plus petit carré est de côté ½.
On en trouve 16
Considérons ensuite les carrés dont le côté est 1 :
Il y en 4*4 = 16 plus 3 de la diagonale, ça fait 19
Les carrés de côté 2 sont au nombre de 12
Les carrés de côté 3 sont au nombre de 4
Et pour terminer, il y a un seul carré de cote 4
Soit, au total, il y a, (si je suis encore capable de bien compter)
16+19+12+4+1 = 52

Edité une troisième fois pour correction

Nombre de messages : 2693 Date d'inscription : 13/09/2009

Eh, j'ai compté 50 carrés !
scratch

Bonjour à tous !

Papydall et Jjn4, merci de votre participation. Vous n'êtes pas loin... mais ce n'est pas le bon résultat.

D’autres paroramiciens veulent tenter leur chance ?

Je donnerai la solution un peu plus tard, le temps de la rédiger en Panoramic…

52 c'est mon dernier mot. affraid

Voilà ! Un, deux, trois , ... cinquante-deux , adjugé !

Encore merci Papydall et JJN4 pour votre participation.

Papydall et Jjn4 sont ex aequo !
... mais aucun n'a trouvé la bonne réponse scratch

La bonne réponse est :

Code:: LABEL soluce
BORDER_SMALL 0
COLOR 0,190,190,190
WIDTH 0,550
HEIGHT 0,620

PICTURE 1
LEFT 1,(WIDTH_CLIENT(0)-403)/2
TOP 1,75
WIDTH 1,403
HEIGHT 1,403
COLOR 1,255,210,64
2D_TARGET_IS 1
2D_FILL_OFF
2D_PEN_WIDTH 3
2D_PEN_COLOR 127,127,127

2D_RECTANGLE 1,1,202,202
2D_RECTANGLE 101,1,302,202
2D_RECTANGLE 201,1,402,202
2D_RECTANGLE 1,101,202,302
2D_RECTANGLE 101,101,302,302
2D_RECTANGLE 201,101,402,302
2D_RECTANGLE 1,201,202,402
2D_RECTANGLE 101,201,302,402
2D_RECTANGLE 201,201,402,402

2D_RECTANGLE 251,51,352,152
2D_RECTANGLE 151,151,252,252
2D_RECTANGLE 51,251,152,352

ALPHA 2
TOP 2,25
LEFT 2,105
FONT_COLOR 2,0,0,0
FONT_SIZE 2,20
CAPTION 2,"Combien y a-t-il de carrés ?"

ALPHA 3
TOP 3,500
LEFT 3,125
FONT_COLOR 3,0,0,0
FONT_SIZE 3,20
HIDE 3

BUTTON 4
TOP 4,500
LEFT 4,230
CAPTION 4,"Solution"
ON_CLICK 4,soluce

END

soluce:
   solution()
RETURN

SUB solution()
   CAPTION 3,"Comptage des carrés..."
   HIDE 4
   SHOW 3
   PAUSE 1200
   LEFT 3,190
   comptage(1,1,402,402,"1")
   comptage(1,1,102,102,"2")
   comptage(101,1,202,102,"3")
   comptage(201,1,302,102,"4")
   comptage(301,1,402,102,"5")
   comptage(1,101,102,202,"6")
   comptage(101,101,202,202,"7")
   comptage(201,101,302,202,"8")
   comptage(301,101,402,202,"9")
   comptage(1,201,102,302,"A")
   comptage(101,201,202,302,"B")
   comptage(201,201,302,302,"C")
   comptage(301,201,402,302,"D")
   comptage(1,301,102,402,"E")
   comptage(101,301,202,402,"F")
   comptage(201,301,302,402,"10")
   comptage(301,301,402,402,"11")
   comptage(1,1,202,202,"12")
   comptage(101,1,302,202,"13")
   comptage(201,1,402,202,"14")
   comptage(1,101,202,302,"15")
   comptage(101,101,302,302,"16")
   comptage(201,101,402,302,"17")
   comptage(1,201,202,402,"18")
   comptage(101,201,302,402,"19")
   comptage(201,201,402,402,"1A")
   comptage(1,1,302,302,"1B")
   comptage(101,1,402,302,"1C")
   comptage(1,101,302,402,"1D")
   comptage(101,101,402,402,"1E")
   comptage(251,51,352,152,"1F")
   comptage(151,151,252,252,"20")
   comptage(51,251,152,352,"21")
   comptage(251,51,302,102,"22")
   comptage(301,51,352,102,"23")
   comptage(201,101,252,152,"24")
   comptage(251,101,302,152,"25")
   comptage(301,101,352,152,"26")
   comptage(151,151,202,202,"27")
   comptage(201,151,252,202,"28")
   comptage(251,151,302,202,"29")
   comptage(101,201,152,252,"2A")
   comptage(151,201,202,252,"2B")
   comptage(201,201,252,252,"2C")
   comptage(51,251,102,302,"2D")
   comptage(101,251,152,302,"2E")
   comptage(151,251,202,302,"2F")
   comptage(51,301,102,352,"30")
   comptage(101,301,152,352,"31")
   comptage(101,101,252,252,"32")
   comptage(151,151,302,302,"33")
   pause 1000
   LEFT 3,150
   CAPTION 3,"Il y a "+STR$(HEX("33"))+" carrés ! ;-)"
END_SUB

SUB comptage(x1,y1,x2,y2,n$)
   CAPTION 3,"comptage : "+STR$(HEX(n$))
   2D_PEN_COLOR 0,0,0
   2D_RECTANGLE x1,y1,x2,y2
   PAUSE 401
   2D_PEN_COLOR 255,255,255
   2D_RECTANGLE x1,y1,x2,y2
   pause 401
   2D_PEN_COLOR 0,0,0
   2D_RECTANGLE x1,y1,x2,y2
   PAUSE 401
   2D_PEN_COLOR 127,127,127
   2D_RECTANGLE x1,y1,x2,y2
END_SUB

Bonne soirée à tous !

EDIT :

Papydall a écrit:: Les carrés de côté 2 sont au nombre de 12

=> Ils ne sont que 9, soit 3 de trop, ce qui fait 52-3=49
+ 2 carrés de 1.5 de coté, ce qui donne au final 49+2=51

Merci Marc pour la solution.
En effet, Papydall s’est fait trop vieux pour savoir bien compter ! Embarassed

J’ai entamé une solution sœur de la tienne, mais suffisamment tordue que j’ai abandonné.
A titre d’info, voici le début …

Code:: rem ============================================================================
label Afficher
DIM a%
dim compteur,p
compteur = 0 : p = 1000
BORDER_SMALL 0 : COLOR 0,0,0,0 : WIDTH 0,550+200 : HEIGHT 0,650

PICTURE 1 : print_target_is 1 : font_color 1,255,255,255 : font_bold 1
LEFT 1,(WIDTH_CLIENT(0)-601)/2 : TOP 1,LEFT(1) : WIDTH 1,401 : HEIGHT 1,401
COLOR 1,255,210,64 : 2D_TARGET_IS 1 : 2D_FILL_OFF : 2D_PEN_WIDTH 3 : 2D_PEN_COLOR 0,0,255

Grille() : pause 1000

ALPHA 2 : TOP 2,20 : LEFT 2,100 : FONT_COLOR 2,250,250,250 : FONT_SIZE 2,20
CAPTION 2,"Combien y a-t-il de carrés ?"
alpha 3 : top 3,550 : left 3,150 : font_color 3,255,0,0 : font_size 3,20
button 5 : top 5,500 : left 5,100 : width 5,300 : height 5,50 : font_bold 5 : font_size 5,14
caption 5,"Afficher la solution" : on_click 5,Afficher
alpha 8 : top 8,100 : left 8,500 : font_color 8,255,255,0
font_bold 8 : font_size 8,10

END
rem ============================================================================
Afficher:
   inactive 5 : Afficher_Solution()
return
rem ============================================================================
SUB Grille()
2D_FILL_OFF : 2D_PEN_WIDTH 3 : 2D_PEN_COLOR 0,0,255

   2D_LINE 0,0,0,400
   2D_LINE 100,0,100,400
   2D_LINE 200,0,200,400
   2D_LINE 300,0,300,400
   2D_LINE 400,0,400,400
   2D_LINE 0,0,400,0
   2D_LINE 0,100,400,100
   2D_LINE 0,200,400,200
   2D_LINE 0,300,400,300
   2D_LINE 0,400,400,400
   2D_RECTANGLE 250,50,351,151
   2D_RECTANGLE 150,150,251,251
   2D_RECTANGLE 50,250,151,351
END_SUB
rem ============================================================================
SUB Afficher_Solution()
   2d_flood 255,55,255,0,0 : compteur = compteur + 1 : caption 3,str$(compteur)
   print_locate 255,55 : print compteur : pause p
   2d_flood 305,55,255,0,0 : compteur = compteur + 1 : caption 3,str$(compteur)
   print_locate 305,55 : print compteur : pause p
   2d_flood 255,105,255,0,0 : compteur = compteur + 1 : caption 3,str$(compteur)
   print_locate 255,105 : print compteur : pause p
   2d_flood 305,105,255,0,0 : compteur = compteur + 1 : caption 3,str$(compteur)
   print_locate 305,105 : print compteur : pause p

   2d_flood 155,155,255,0,0 : compteur = compteur + 1 : caption 3,str$(compteur)
   print_locate 155,155 : print compteur : pause p
   2d_flood 205,155,255,0,0 : compteur = compteur + 1 : caption 3,str$(compteur)
   print_locate 205,155 : print compteur : pause p
   2d_flood 155,205,255,0,0 : compteur = compteur + 1 : caption 3,str$(compteur)
   print_locate 155,205 : print compteur : pause p
   2d_flood 205,205,255,0,0 : compteur = compteur + 1 : caption 3,str$(compteur)
   print_locate 205,205 : print compteur : pause p

   2d_flood 55,255,255,0,0 : compteur = compteur + 1 : caption 3,str$(compteur)
   print_locate 55,255 : print compteur : pause p
   2d_flood 105,255,255,0,0 : compteur = compteur + 1 : caption 3,str$(compteur)
   print_locate 105,255 : print compteur : pause p
   2d_flood 55,305,255,0,0 : compteur = compteur + 1 : caption 3,str$(compteur)
   print_locate 55,305 : print compteur : pause p
   2d_flood 105,305,255,0,0 : compteur = compteur + 1 : caption 3,str$(compteur)
   print_locate 105,305 : print compteur : pause p

   caption 8,"Solution : 12 + ..."
   pause 2000 : cls : COLOR 1,255,210,64 : Grille() : compteur = 0 : hide 3
   Cote_1()
END_SUB
rem ============================================================================
SUB Cote_1()
   show 3
   2d_flood 5,5,255,0,0 : compteur = compteur + 1 : caption 3,str$(compteur)
   print_locate 5,5 : print compteur : pause p
   2d_flood 105,5,255,0,0 : compteur = compteur + 1 : caption 3,str$(compteur) : pause p
   print_locate 105,5 : print compteur : pause p
   2d_flood 205,5,255,0,0 : compteur = compteur + 1 : caption 3,str$(compteur) : pause p
   2d_flood 255,55,255,0,0
   print_locate 205,5 : print compteur : pause p
   2d_flood 305,5,255,0,0 : compteur = compteur + 1 : caption 3,str$(compteur) : pause p
   2d_flood 305,55,255,0,0
   print_locate 305,5 : print compteur : pause p

   2d_flood 5,105,255,0,0 : compteur = compteur + 1 : caption 3,str$(compteur)
   print_locate 5,105 : print compteur : pause p
   2d_flood 105,105,255,0,0 : compteur = compteur + 1 : caption 3,str$(compteur)
   2d_flood 155,155,255,0,0
   print_locate 105,105 : print compteur : pause p

   2d_flood 205,105,255,0,0 : compteur = compteur + 1 : caption 3,str$(compteur)
   2d_flood 255,105,255,0,0 : 2d_flood 255,155,255,0,0 : 2d_flood 355,105,255,0,0
   2d_flood 205,155,255,0,0
   print_locate 205,105 : print compteur : pause p

   2d_flood 305,105,255,0,0 : compteur = compteur + 1 : caption 3,str$(compteur)
   print_locate 305,105 : print compteur : pause p
   caption 3,str$(compteur) + " ... j'abandonne !"
   ' etc ....
END_SUB
rem ============================================================================

Citation :: Papydall s’est fait trop vieux pour savoir bien compter !

Je n’ai pas fait mieux : après avoir trouvé différents résultats erronés, ce sont mes enfants qui m’ont donné la solution !

Pour animer le forum, je me suis dit que j’allais poser ce casse-tête en langage Panoramic.
Je voulais l’adapter sous Android, mais le petit bug de P4A ne permet pas de dessiner pour l'instant comme il faut.

Merci pour ton source, même s’il est inachevé. C’est sympa !

@JJN4 : Hé, le martien ! Redonne le carré que tu as mis dans ta soucoupe: je sais très bien qu'il y en avait 51 lol!

Bonne nuit à tous ! Sleep

J'arrive un peu tard, mais voici ma solution de dénombrement des carrés, c'est purement mathématique! Very Happy

Code:: WIDTH 0,550
HEIGHT 0,630

dim x,y,dist,carre,tmp,total,pas_a_pas
dim pts(500,500)

' liste des sommets des carrés de tailles 100
for x=100 to 500 step 100
   for y=100 to 500 step 100
   2d_circle x,y,5
   pts(x,y)=1
   next y
next x

' liste des sommets des carrés de tailles 50
for x=350 to 450 step 50
   for y=150 to 250 step 50
   2d_circle x,y,5
   pts(x,y)=1
   next y
next x

for x=250 to 350 step 50
   for y=250 to 350 step 50
   2d_circle x,y,5
   pts(x,y)=1
   next y
next x

for x=150 to 250 step 50
   for y=350 to 450 step 50
   2d_circle x,y,5
   pts(x,y)=1
   next y
next x

' résolution
x=100 : y=100 : dist=0 : tmp = 400 : carre=0 : total=0
'
pas_a_pas=0 :' mettre à 1 pour visualiser une taille de carré en particulier
'
repeat
   if pas_a_pas=1
   ' tailles de carré possibles: 50, 100, 150, 200, 300, 400
   dist=50 : tmp=dist
   else
   dist=dist+50
   end_if
   carre=0
   ' compter tous les carrés de taille "dist"
   for x=100 to 500 step 50
   for y=100 to 500 step 50
   if IN_ARRAY(x,y)=1
   if IN_ARRAY(x+dist,y)=1
   if IN_ARRAY(x+dist,y+dist)=1
   if IN_ARRAY(x,y+dist)=1
   carre = carre + 1
   2D_PEN_COLOR int(rnd(200)),int(rnd(200)),int(rnd(200))
   2d_line x,y,x+dist,y
   2d_line x+dist,y,x+dist,y+dist
   2d_line x+dist,y+dist,x,y+dist
   2d_line x,y+dist,x,y
   if pas_a_pas=1 then message str$(carre)
   end_if
   end_if
   end_if
   end_if
   next y
   next x
   print carre," carré(s) de taille ",dist
   total = total + carre
until dist=tmp
'
print : print "total = ",total," carres"

END
fnc IN_ARRAY(a,b)
   result 0
   if a>99 and a<501
   if b>99 and b<501
   result pts(a,b)
   end_if
   end_if
end_fnc

Nombre de messages : 2693 Date d'inscription : 13/09/2009

Marc a écrit:: Hé, le martien ! Redonne le carré que tu as mis dans ta soucoupe: je sais très bien qu'il y en avait 51

Eh eh, je l'ai fait discrètement disparaître dans ma manche et après hop, volatilisé !
Du coup, il n'y en a plus que 50 comme j'avais dit !
Malin le martien !
lol!

JJN4 a écrit:: Eh eh, je l'ai fait discrètement disparaître dans ma manche et après hop, volatilisé !

Tu ne l’aurais pas mangé par hasard ?

Enigme : combien y a-t-il de carrés ? W10

@Silverman
Merci et bravo Silverman ! cheers

Ton programme est splendide, très carré !
Merci de ta participation !

Nombre de messages : 2693 Date d'inscription : 13/09/2009

Pas sympa, ce Marc, quand même !
Vous avez vu ça ?
Cet enragé m'a mis la tête au carré !
lol!

» Carrés disséqués
» Défi2 = les moindres carrés
» Sauriez-vous compter les carrés ?
» La clé de l'énigme
» L’énigme d’Einstein.