Création d'une application avec Panoramic_Editor

' hexify.bas
'
' This utility converts any binary file into a TXT file containing an hexadecimal dump
' of the binary file, with lines containing BlockSize%*2 characters.
' This kind of file can easyly be included into a Panoramic Application EXE file.
' Thus, any binary file can be used, not only TXT, JPG and BMP files.
' Please use the ExtractFiles procedure from the test_application.bas file to rebuild
' the binary files on program startup - see this program for documentation.

label opn, ext

dim f$, fout$, no%, no1%, no2%, ext$, buf$, siz%, siz0%
dim BlockSize% : BlockSize% = 512

no% = no% + 1 : main_menu no% : no1% = no%
  no% = no% + 1 : sub_menu no% : no2% = no% : parent no%,no1% : caption no%,"Files"
    no% = no% + 1 : sub_menu no% : parent no%,no2% : caption no%,"Open" : on_click no%,opn
    no% = no% + 1 : sub_menu no% : parent no%,no2% : caption no%,"-"
    no% = no% + 1 : sub_menu no% : parent no%,no2% : caption no%,"Exit" : on_click no%,ext
  
open_dialog 100
progress_bar 101 : top 101,40 : left 101,10 : width 101,width_client(0)-20

end

opn:
  ' ask for file to convert
  f$ = file_name$(100)
  if f$="_" then return
  if file_exists(f$)=0
    message "File not found"
    return
  end_if
  ' build TXT file name
  ext$ = file_extract_extension$(f$)
  fout$ = left$(f$,len(f$)-len(ext$))+".txt"
  ' get binary file size
  filebin_open_read 1,f$
  siz% = filebin_size(1)
  if siz%=0
    message "File is empty"
    filebin_close 1
    return
  end_if
  ' check if file exists
  if file_exists(fout$)=1
    if message_confirmation_yes_no("Output file already exists. Replace ?")<>1
      filebin_close 1
      return
    end_if
    file_delete fout$
  end_if
  
  ' conversion loop
  file_open_write 2,fout$
  siz0% = siz%
  max 101,siz0%
  ' do as many full block reads as possible
  while siz%>=BlockSize%
    position 101,siz0%-siz%
    buf$ = filebin_hexa_read$(1,BlockSize%)
    file_writeln 2,buf$
    siz% = siz% - BlockSize%
  end_while
  ' eventually, do a final partial block
  if siz%>0
    position 101,siz0%
    buf$ = filebin_hexa_read$(1,siz%)
    file_writeln 2,buf$
  end_if
  ' done
  position 101,siz0%  
  filebin_close 1
  file_close 2
  message "File created:"+chr$(13)+chr$(10)+fout$
  position 101,0
  return
  
ext:
  terminate
  

' test_application.bas
'
' This program is for demonstration purposes only.
' It show how to include any binary file into a Panoramic Application EXE file.
' Using the hexify utility, any binary file can be converted to an hexa dump
' in TXT format. Same file name, but *.TXT extension. Thus, the file will be
' flawlessly integrated into the application.
' As many binary files as required may be included in the same way.
' A supplemental TXT file must be supplied, giving the index of all included
' binary files, in the following format:
'   index file name: IndexOfIncludedFiles.txt
'   index file content:
'     first line: #IndexOfIncludedFiles
'     followed by 2 lines for each binary file. The first of them is the name
'     of the hexified TXT file, without path. The second of them is the target
'     file name, eventually including the destination path
' Example:
'    #IndexOfIncludedFiles       <=== first line as identifyer
'    KGFdll.txt                  <=== name of the hexified TXT file
'    KGF.dll                     <=== name of the resulting binary  output file
'    ...

dim res%, vers$, KGF$
KGF$ = "KGF.dll"

if file_exists(KGF$)=0 then ExtractFiles()
message "Ready..."

end

sub ExtractFiles()
  dim_local s$, fincluded$, foutput$, nobj%, n%
  
  nobj% = 1
  while object_exists(nobj%)=1
    nobj% = nobj% + 1
  end_while
  dlist nobj%
  file_load nobj%,"IndexOfIncludedFiles.txt"
  
  n% = 1
  s$ = item_read$(nobj%,n%)
  if s$<>"#IndexOfIncludedFiles"
    message "Invalid index file"
    delete nobj%
    exit_sub
  end_if
  
  while n%<count(nobj%)
    n% = n% + 1
    fincluded$ = item_read$(nobj%,n%)
    n% = n% + 1
    foutput$ = item_read$(nobj%,n%)
    
    file_open_read 1,fincluded$
    filebin_open_write 2,foutput$
      while file_eof(1)=0
        file_readln 1,s$
        filebin_hexa_write 2,len(s$)/2,s$
      end_while
    filebin_close 2
    file_close 1
  end_while  
  delete nobj%
end_sub

position 101,siz0%  .

' ExeResourceManager.bas


label open, exit

dim no%, no1%, no2%, no_open%, no_names%
dim f$, ext$, a%, an%, k%, s$, buf%(256), PEheader%, v%, SectionCount%
dim ResourceSection%, SectionOffset%, SizeOfResources%, PointerToResources%
dim ResourceNameEntries%, ResourceIdEntries%, RCDATApointer%
dim PointerToRCDATA%, RcDataResourceNameEntries%, RcDataResourceIdEntries%

no% = no% + 1 : main_menu no% : no1% = no%
  no% = no% + 1 : sub_menu no% : no2% = no% : parent no%,no1% : caption no%,"Files"
    no% = no% + 1 : sub_menu no% : parent no%,no2% : caption no%,"Open" : on_click no%,open
    no% = no% + 1 : sub_menu no% : parent no%,no2% : caption no%,"-"
    no% = no% + 1 : sub_menu no% : parent no%,no2% : caption no%,"Exit" : on_click no%,exit
   
no% = no% + 1 : open_dialog no% : no_open% = no%
  filter no%,"EXE or DLL files|*.exe;*.dll"
no% = no% + 1 : list no% : no_names% = no%
  top no%,10 : left no%,10 : width no%,300 : height no%,200 
                                           
caption 0,"ExeResourceManager"   


end
   
open:
  f$ = file_name$(no_open%)
  if f$="_" then return
  if file_exists(f$)=0
    message "File not found"
    return
  end_if
  ext$ = lower$(file_extract_extension$(f$))
  if (ext$<>".exe") and (ext$<>".dll")
    message "Wrong file type (EXE or DLL)"
    return
  end_if
 
  AnalyzeExeFile()
  if CheckIfFileIsIncluded("IndexOfIncludedFiles.txt")=1
    message "Le fichier index est bien présent"
  else
    message "Le fichier index est absent"
  end_if
  return
 
exit:
  terminate
 
 
 
sub AnalyzeExeFile()
  filebin_open_read 1,f$                  : ' open the selected EXE or DLL file
 
  ' at offset hex("3C") is located the length of the MS-DOS header.
  ' this is also the start offset for the PE header
  a% = Read32(hex("3C"))

  ' at this point, there must be the PE signature (letters PE followed by 2 zero bytes)
  v% = Read32(a%)
  if v%<>hex("00004550")
    message "Invalid EXE or DLL file"
    filebin_close 1                          : ' close the file
    exit_sub
  end_if
  PEheader% = a% + 4                        : ' skip the PE signature to point to the PE header
 
  ' at offset 2 of the PEheader, there is the section count as 16 bit number
  SectionCount% = Read16(PEheader%+2)

  ' at offset 16 of the PEheader, there is the size of the optional header as 16 bit number
  v% = Read16(PEheader%+16)

  ' now, point after the header (20 bytes) and after the optional header (v% bytes)
  a% = PEheader% + 20 + v%
 
  ' here is the section table - 40 bytes of section header for each section.
  ' the first 8 bytes are the ASCII section name:
  ResourceSection% = 0
  for k%=1 to SectionCount%
    s$ = ReadString$(a%,8)
    if s$=".rsrc"
      ResourceSection% = k%
      SectionOffset% = a%
    end_if
    a% = a% + 40
  next k%
  if ResourceSection%=0
    message "Resource section .rsrc not found"
    filebin_close 1                          : ' close the file
    exit_sub
  end_if

  ' here, the resource section header is identified.
  ' at offset 16, there is the 32 bit section size
  ' at offset 20, there is the 32 bit section pointer
  SizeOfResources% = Read32(SectionOffset%+16)
  PointerToResources% = Read32(SectionOffset%+20) 
 
  ' PointerToResources% contains the pointer to the resource directory table header
  ' at offset 12, there is the 16 bit number of name entries
  ' at offset 14, there is the 16 bit number of ID entries
  ResourceNameEntries% = Read16(PointerToResources%+12)
  ResourceIdEntries% = Read16(PointerToResources%+14)
 
  if ResourceNameEntries%>0
    a% = PointerToResources% + 16
    RCDATApointer% = 0
    for k%=1 to ResourceNameEntries%
      an% = PointerToResources% + bin_and(Read32(a%),hex("0FFFFFFF"))
      s$ = ReadUnicodeString$(an%)
      if s$="RCDATA"
        RCDATApointer% = Read32(a%+4)
      end_if
      a% = a% + 8
    next k%
  end_if
  if RCDATApointer%=0
    message "RCDATA section not found"
    filebin_close 1                          : ' close the file
    exit_sub
  end_if
 
  ' here, RCDATApointer% contains the pointer to the data for the RCDATA section.
  ' if high bit is set, this is an offset to a resource directory entry,
  '  otherwise, it is just an offset to the data.
  if bin_and(RCDATApointer%,hex("80000000"))=0
    ' actually not used... 
  else  : ' here, we have an offset to lower level resource directory header
    PointerToRCDATA% = PointerToResources% + bin_and(RCDATApointer%,hex("0FFFFFFF"))   
    ' at offset 12, there is the 16 bit number of name entries
    ' at offset 14, there is the 16 bit number of ID entries
    RcDataResourceNameEntries% = Read16(PointerToRCDATA%+12)
    RcDataResourceIdEntries% = Read16(PointerToRCDATA%+14)

    if RcDataResourceNameEntries%=0
      message "No included resource file"
      filebin_close 1                          : ' close the file
      exit_sub
    end_if
    ' here, the names entries indicate the included files for the applciation
    a% = PointerToRCDATA%+16
    clear no_names%
    for k%=1 to RcDataResourceNameEntries%
      an% = PointerToResources% + bin_and(Read32(a%),hex("0FFFFFFF"))
      s$ = ReadUnicodeString$(an%)
      ' here we have the names of the included resource files
      item_add no_names%,s$ 
      a% = a% + 8
    next k%
   
  end_if         
 
 
  filebin_close 1                          : ' close the file
end_sub
 
' this function reads a 32 bit word from the specified offset and returns its value 
fnc Read32(offset%)
  filebin_position 1,offset%
  filebin_block_read 1,4,buf%(0)
  result ((buf%(3)*256+buf%(2))*256+buf%(1))*256+buf%(0)
end_fnc

' this function reads a 16 bit word from the specified offset and returns its value 
fnc Read16(offset%)
  filebin_position 1,offset%
  filebin_block_read 1,2,buf%(0)
  result buf%(1)*256+buf%(0)
end_fnc

' this function reads a n byte string from the specified offset and returns the string
fnc ReadString$(offset%,n%)
  dim_local i%, s$, c%
  filebin_position 1,offset%
  s$ = ""
  for i%=1 to n%
    c% = filebin_read(1)
    if c%<>0 then s$ = s$ + chr$(c%)
  next i%
  result s$
end_fnc

' this function reads a Unicode resource name string from the specified offset and returns it as ASCII string
fnc ReadUnicodeString$(offset%)
  dim_local s$, c%, n%, i%
  s$ = ""
  n% = Read16(offset%)
  for i%=1 to n%
    c% = filebin_read(1)
    s$ = s$ + chr$(c%)
    c% = filebin_read(1)    : ' skip the Unicode extension unsused in Panoramic !
  next i%
  result s$
end_fnc

fnc CheckIfFileIsIncluded(file$)
  dim_local res%, i%
  res% = 0
  if count(no_names%)=0 then exit_fnc
  for i%=1 to count(no_names%)
    if item_read$(no_names%,i%)=upper$(file$) then res% = 1
  next i%
  result res%
end_fnc