Racine carrée d’un nombre par l’algorithme de Héron

Code:: rem ============================================================================
rem Extraction de la racine carrée d’un nombre par l’algorithme de Héron
rem ============================================================================

print " Racine carrée (ALGO) de 121 = " + str$(Racine_Carree(121))
print " Racine carrée (PANO) de 121 = " + str$(sqr(121))

end
rem ============================================================================
' Calcul de la racine carrée par l'algorithme de Héron d'Alexandrie
' Cet algorithme donne très vite un grand nombre de décimales correctes.
' C'est un algo d'une efficacité exceptionnelle
FNC Racine_Carree(n)
dim_local x,x1,i,epsilon
epsilon = power(10,0-10)
x = 1 : ' Valeur arbitraire de départ
repeat
x1 = x
x = 0.5 * (x + (n/x))
until abs(x-x1) < epsilon
result x
END_FNC
rem ============================================================================

AVAST me demande d'attendre 159 mn parce que j'ai découvert un fichier très rare qui peut être nocif.

Je recommencerai demain.

Bonne soirée Papydall Very Happy

Autre algorithme pour l'extraction de la racine carrée.
Calcul de la racine carrée par soustractions successives

Code:: rem ============================================================================
rem Calcul de la racine carrée par soustractions successives
rem ============================================================================

print "La racine carrée de 16 est : " + str$(Racine_Carree_Par_Soustraction(16))
print "La racine carrée de 106 est : " + str$(Racine_Carree_Par_Soustraction(106))

end
rem ============================================================================
FNC Racine_Carree_Par_Soustraction(n)
   dim_local x,i, ns
   x = n : i = 1 : ns = 0
   repeat
   x = x - i
   ns = ns + 1
   i = i + 2
   until x <= 0
   if x = 0
   result ns : ' Résultat exact
   else
   result ns-1 : ' Résultat à 1 près par défaut
   end_if
END_FNC
rem ============================================================================

@ Ouf_ca_passe

Et aussi d'une manière générale:

Code:: print racine_(2,15625)
end
' n=2 pour racine carré, 3 pour racine cubique, etc...
FNC Racine_(n,A)
dim_local x,oldx
x = A/n : ' Valeur arbitraire de départ
repeat
oldx=x
x = (1/n) * ((n-1)*x + (A/power(x,n-1)))
until abs(x-oldx)<0.0000001
result x
END_FNC

Bonsoir à tous Smile

Absent depuis un moment, pour cause de décès dans ma famille.

Bonsoir Papydall,

pour la méthode par l'algorithme de Héron, essaye ceci:

Code:: print " Racine carrée (ALGO) de 121 = " + str$(Racine_Carree(121))
print " Racine carrée (PANO) de 121 = " + str$(sqr(121))]

Je n'ai pas cherché d'autres anomalies. Il y en a peut-être, qui sait?
Pour moi, cet algorithme n'est pas fiable à 100%

A+ Wink

Mes condoléances à toi et à ta famille, Bignono

Bignono a écrit:: Pour moi, cet algorithme n'est pas fiable à 100%

Si, si !
L’algorithme est exceptionnellement efficace !
Je l’ai montré sur un cas particulier pour une boucle de seulement 5 itérations.
Voici le bon code

Code:: rem ============================================================================
rem Extraction de la racine carrée d’un nombre par l’algorithme de Héron
rem ============================================================================

print " Racine carrée (ALGO) de 123456789 = " + str$(Racine_Carree(123456789))
print " Racine carrée (PANO) de 123456789 = " + str$(sqr(123456789))

end
rem ============================================================================
' Calcul de la racine carrée par l'algorithme de Héron d'Alexandrie
' Cet algorithme donne très vite un grand nombre de décimales correctes.
' C'est un algo d'une efficacité exceptionnelle
FNC Racine_Carree(n)
   dim_local x,x1,i,epsilon
   epsilon = power(10,0-10)
   x = 1 : ' Valeur arbitraire de départ
   repeat
   x1 = x
   x = 0.5 * (x + (n/x))
   until abs(x-x1) < epsilon
   result x
END_FNC
rem ============================================================================

Après que AVAST a contrôlé que mon téléchargement de la dernière mouture de PANORAMIC.exe était inoffensif (j'ai du mal à abandonner le subjonctif pour le mode indicatif après 65 ans d'usage),
j'ai constaté, sans surprise, que vos codes passaient parfaitement.

C'est beau l'INSTRUCTION. Smile

» Méthode manuelle d'extraction de la racine carrée
» Chercher un algorithme
» Comment déterminer le nombre de chiffres d'un nombre naturel
» Tracé : Triangle, Carrée, Dents de scie, Sinusoïde redressée
» algorithme de classement