FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC

Développement d'applications avec le langage Panoramic
 
AccueilAccueil  FAQFAQ  RechercherRechercher  S'enregistrerS'enregistrer  MembresMembres  GroupesGroupes  Connexion  
Derniers sujets
» Demande pour Jack concernant PanExpress
par Jack Aujourd'hui à 7:48

» Calculatrice
par papydall Hier à 22:54

» EPP_V01 éditeur pour Panoramic
par Minibug Mer 19 Sep 2018 - 21:03

» [RESOLU] Quelle ligne est sélectionnée dans SYNEDIT ?
par Jean Claude Mer 19 Sep 2018 - 21:02

» PanExpress : l'éditeur Panoramic avec création d'objet
par Minibug Mer 19 Sep 2018 - 15:58

» Planétarium virtuel.
par Pedro Alvarez Mer 19 Sep 2018 - 9:28

» Petit coucou en passant !
par Minibug Dim 16 Sep 2018 - 15:03

» bug SEVERE fnc+sub : variables globales corrompus
par silverman Dim 16 Sep 2018 - 13:38

» Verrouiller un form en avant plan
par silverman Dim 16 Sep 2018 - 12:50

» Fin de l'aventure.
par Pedro Alvarez Sam 15 Sep 2018 - 18:16

» Demande d'explications Sur File_Write & File_writeln
par Jack Sam 15 Sep 2018 - 17:26

» MEMO avec des possibilités de commande
par Oscaribout Mer 12 Sep 2018 - 1:06

» La théorie du chaos
par jean_debord Mar 11 Sep 2018 - 9:30

» Orbites de l’ensemble de Mandelbrot
par Jean Claude Lun 10 Sep 2018 - 21:08

» Version instantanée V 0.9.29i2 du 4/09/2018
par silverman Mer 5 Sep 2018 - 10:15

Navigation
 Portail
 Index
 Membres
 Profil
 FAQ
 Rechercher
Rechercher
 
 

Résultats par :
 
Rechercher Recherche avancée
Septembre 2018
LunMarMerJeuVenSamDim
     12
3456789
10111213141516
17181920212223
24252627282930
CalendrierCalendrier

Partagez | 
 

 Bandit manchot

Aller en bas 
AuteurMessage
jjn4

avatar

Nombre de messages : 1761
Date d'inscription : 13/09/2009

MessageSujet: Bandit manchot   Jeu 9 Fév 2017 - 15:46

Les fins de mois sont difficiles ?
Qu'à cela ne tienne,
voici la solution à vos problèmes !
Code:
rem ' Bandimanchoramic - le Bandit manchot - par jjn4 - le 08/02/2017 =========
   rem Variables du bloc de roulettes -----------------------------------------
      dim LC$(20) : rem Listes des Couleurs selon les 20 possibilités
      dim LS$(20) : rem Listes des Symboles selon les 20 possibilités
      dim QF%(20) : rem Quel Format est utilisé selon les 20 possibilités
      dim QP%(20) : rem Quelle Police utilisée selon les 20 possibilités
   rem Variables du bloc de mise en jeu des pièces ----------------------------
      dim STM% : rem Somme Totale Misée
   rem Variables du bloc de réceptacle des pièces -----------------------------
      dim MC% : rem Montant de la Cagnotte
   rem Variables du bloc de commandes du style de jeu -------------------------
      dim QSJ% : rem Quel style de jeu a été choisi
   rem Variables du bloc d`affichage des combinaisons gagnantes ---------------
      dim QC%(20,3) : rem Quelles Couleurs sont utilisées selon ls combinaisons
      dim QG%(20,3) : rem Quels Gains sont attendus selon les combinaisons
      dim QS$(20,3) : rem Quels Symboles sont utilisés selon les combinaisons
   rem Variables du bloc des commentaires et autres ---------------------------
      dim MG% : rem Montant du meilleur Gain
      dim MP% : rem Meilleur Pactole ou cagnotte
      dim TRJ$(40) : rem Texte des Règles du Jeu
      dim TCD$(32) : rem Textes des Commentaires Divers
   rem Variables provenant des datas ------------------------------------------
      dim DC%(7,3) : rem Définitions des Couleurs utilisées
      dim DP$(4) : rem Définitions des Polices utilisées
   rem Autres variables -------------------------------------------------------
      dim BIS% : rem Recommencer la simulation
      dim V1M% , V2M% , V3M% , V4M$ , V5M% : rem Variables à utilisation variée
      dim VO% , VO1% : rem Vitesse de l`Ordinateur
   label clic : rem Redirection de tous les on-click

rem form0 =====================================================================
   width 0,1365
   height 0,720
   caption 0,"   Bandit-manchot - par jjn4 - Ver-080217.1.0"
   VO1%=number_ticks

rem Construction du cache de départ ===========================================
   form 2
      width 2,1365
      height 2,720
      caption 2,"   Bandit-manchot - Suspens..."
   panel 3 : rem Indicateur du titre en attente -------------------------------
      parent 3,2
      left 3,480
      top 3,250
      width 3,400
      height 3,80
      font_bold 3
      font_size 3,20
      font_name 3,"Arial"
      caption 3,"B A N D I T   M A N C H O T"

rem Lecture des datas =========================================================
   for V1M% = 1 to 7
      for V2M% = 1 to 3
         read DC%(V1M%,V2M%)
      next V2M%
   next V1M%
   for V1M% = 1 to 4
      read DP$(V1M%)
   next V1M%
   for V1M% = 1 to 20
      read LS$(V1M%)
      read LC$(V1M%)
      read QP%(V1M%)
      read QF%(V1M%)
      for V2M% = 1 to 3
         read QC%(V1M%,V2M%)
         read QS$(V1M%,V2M%)
         read QG%(V1M%,V2M%)
      next V2M%
   next V1M%
   for V1M% = 1 to 40
      read TRJ$(v1M%)
   next V1M%
   for V1M% = 1 to 32
      read TCD$(V1M%)
      read V4M$
      TCD$(V1M%)=TCD$(V1M%)+chr$(13)+V4M$
   next V1M%

rem Prise en compte de l`enregistrement des données ===========================
   MC%=200
   MP%=200
   if file_exists("Bandimancho.txt")=1
      file_open_read 1,"Bandimancho.txt"
         file_readln 1,MC%
         file_readln 1,MG%
         file_readln 1,MP%
      file_close 1
   end_if
  
rem Construction des sprites ==================================================
   picture 5
      width 5,92 : rem Dessin du grigri ---------------------------------------
      height 5,105
      color 5,240,240,240
      2d_target_is 5
      2d_pen_color 90,190,15
      2d_fill_color 90,190,15
      2d_circle 12,40,12
      2d_circle 20,26,12
      2d_circle 48,15,12
      2d_circle 63,17,12
      2d_circle 80,44,12
      2d_circle 75,57,12
      2d_circle 41,79,12
      2d_circle 27,74,12
      2d_line 30,20,41,47
      2d_line 12,51,41,47
      2d_line 36,15,45,43
      2d_line 68,27,45,43
      2d_line 74,33,48,49
      2d_line 66,65,48,48
      2d_line 52,75,44,52
      2d_line 22,63,44,52
      2d_flood 33,42,90,190,15
      2d_flood 50,32,90,190,15
      2d_flood 60,50,90,190,15
      2d_flood 40,62,90,190,15
      2d_pen_width 3
      2d_line 41,47,49,49
      2d_line 45,43,44,53
      2d_pen_width 5
      2d_poly_from 50,85
      2d_poly_to 54,93
      2d_poly_to 60,99
      2d_poly_to 70,106
      file_save 5,"Grigri.bmp"
      width 5,44 : rem Dessin de l`indication Pas-de-grigri -------------------
      height 5,49
      color 5,240,240,240
      2d_fill_color 240,240,240
      print_target_is 5
      print_locate 5,8
      print "Pas de"
      print_locate 8,23
      print "grigri"
      file_save 5,"Pas-grigri.bmp"
      width 5,105 : rem Dessin d`un Euro --------------------------------------
      height 5,105
      color 5,0,0,0
      2d_fill_color 255,220,85
      2d_pen_color 150,150,150
      2d_pen_width 1
      2d_circle 52,52,52
      2d_circle 52,52,49
      2d_fill_color 230,230,230
      2d_circle 52,52,36
      font_size 5,38
      font_name 5,"Times New Roman"
      font_color 5,150,150,150
      print_locate 33,23
      print "1"
      font_size 5,8
      print_locate 57,46
      print "EURO"
      for V1M% = 1 to 6
         2d_line 62+V1M%*4,13+V1M%*3,62+V1M%*4,90-V1M%*3
      next V1M%
      file_save 5,"Un-Euro.bmp"
      width 5,115 : rem Dessin de deux Euro -----------------------------------
      height 5,115
      color 5,0,0,0
      2d_fill_color 230,230,230
      2d_pen_color 150,150,150
      2d_circle 57,57,55
      2d_circle 57,57,52
      2d_fill_color 255,220,85
      2d_circle 57,57,37
      font_size 5,38
      font_color 5,120,170,170
      print_locate 37,27
      print "2"
      font_size 5,8
      print_locate 64,51
      print "EURO"
      2d_pen_color 120,170,170
      for V1M% = 1 to 6
         2d_line 68+V1M%*4,18+V1M%*3,68+V1M%*4,95-V1M%*3
      next V1M%
      file_save 5,"Deux-Euro.bmp"
      width 5,375 : rem Dessin du fond de mise de 5€ maximum ------------------
      height 5,115
      color 5,255,255,255
      font_color 5,0,0,255
      2d_fill_color 255,255,255
      font_size 5,40
      font_name 5,"Arial"
      print_locate 20,20
      print "5 € maximum"
      font_size 5,8
      font_color 5,255,0,0
      print_locate 1,1
      print "Vider"
      file_save 5,"Fond-bandit.bmp"
      width 5,700 : rem Dessin du réceptacle de la monnaie --------------------
      height 5,160
      color 5,0,0,0
      2d_pen_color 200,200,255
      2d_fill_color 200,200,255
      2d_rectangle 0,70,701,161
      2d_fill_off
      2d_circle 34,36,35
      2d_circle 666,36,35
      2d_flood 5,65,200,200,255
      2d_flood 695,65,200,200,255
      2d_pen_color 0,0,0
      2d_fill_color 0,0,0
      2d_rectangle 36,70,666,1
      2d_rectangle 0,35,700,0
      file_save 5,"Réceptacle.bmp"
      hide 5

rem Construction du bloc de roulettes =========================================
   panel 10 : rem Bloc de la base des roulettes -------------------------------
      left 10,10
      top 10,10
      width 10,315
      height 10,280
   for V1M% = 1 to 4 : rem Construction des 3 roulettes et celle en + ---------
      edit V1M%*10+10 : rem Objets-système n° 30, 40 et 50 et 20 en + ---------
         parent V1M%*10+10,10
         left V1M%*10+10,V1M%*101-190
         top V1M%*10+10,10
         width V1M%*10+10,92
         height V1M%*10+10,192
         font_size V1M%*10+10,110
         font_name V1M%*10+10,"Arial"
         text V1M%*10+10,"7"
   next V1M%
   hide 20
   panel 60 : rem Cache du haut des roulettes ---------------------------------
      parent 60,10
      width 60,315
      height 60,10
   panel 70 : rem Cache du bas des roulettes ----------------------------------
      parent 70,10
      top 70,182
      width 70,315
      height 70,98
   button 80 : rem Bouton jouer -----------------------------------------------
      parent 80,70
      left 80,10
      top 80,10
      width 80,295
      height 80,78
      font_bold 80
      font_size 80,40
      font_name 80,"Arial"
      caption 80,"Jouer"
      inactive 80
      on_click 80,clic
      
rem Construction du bloc de mise en jeu des pièces ============================
   panel 100 : rem Bloc de la base des mises en jeu ---------------------------
      left 100,335
      top 100,10
      width 100,395
      height 100,280
   scene2d 110 : rem Base de la sortie des pièces -----------------------------
      parent 110,100
      left 110,10
      top 110,10
      width 110,375
      height 110,115
      file_load 110,"Fond-bandit.bmp"
      on_click 110,clic
   sprite 10 : rem Dessin de la pièce d`un Euro -------------------------------
      sprite_file_load 10,"Un-Euro.bmp"
      sprite_position 10,7,115
   sprite 20 : rem Dessin
      sprite_file_load 20,"Deux-Euro.bmp"
      sprite_position 20,131,115
   sprite 30 : rem Dessin de la 2° pièce de deux Euro -------------------------
      sprite_file_load 30,"Deux-Euro.bmp"
      sprite_position 30,260,115
   for V1M% = 1 to 3 : rem Bouton de sortie des pièces ------------------------
      button V1M%*10+110 : rem Objets-système n° 120, 130 et 140 --------------
         parent V1M%*10+110,100
         left V1M%*10+110,V1M%*130-120
         top V1M%*10+110,130
         width V1M%*10+110,115
         height V1M%*10+110,70
         font_bold V1M%*10+110
         font_size V1M%*10+110,30
         font_name V1M%*10+110,"Arial"
         caption V1M%*10+110,"2 €"
         on_click V1M%*10+110,clic
   next V1M%
   caption 120,"1 €"
   panel 150 : rem Affichage du résulat de la mise ----------------------------
      parent 150,100
      left 150,10
      top 150,210
      width 150,375
      height 150,60
      color 150,255,255,0
   alpha 160 : rem Titre de la somme misée ------------------------------------
      parent 160,150
      left 160,40
      top 160,10
      font_bold 160
      font_size 160,24
      font_name 160,"Arial"
      caption 160,"Votre mise :"
   alpha 170 : rem Somme misée ------------------------------------------------
      parent 170,150
      left 170,260
      top 170,10
      font_bold 170
      font_size 170,24
      font_name 170,"Arial"
   alpha 180 : rem Précision sur l`unité monétaire ----------------------------
      parent 180,150
      left 180,315
      top 180,10
      font_bold 180
      font_size 180,24
      font_name 180,"Arial"
      caption 180,"€"
   panel 190 : rem Invitation à miser -----------------------------------------
      parent 190,100
      left 190,10
      top 190,210
      width 190,375
      height 190,60
      color 190,255,255,0
      font_bold 190
      font_size 190,20
      font_name 190,"Arial"
      caption 190,"Combien misez-vous ?"

rem Construction du réceptacle des pièces =====================================
   panel 200 : rem Bloc de la base du réceptacle ------------------------------
      left 200,10
      top 200,300
      width 200,720
      height 200,180
   scene2d 210 : rem Fond du réceptacle ---------------------------------------
      parent 210,200
      left 210,10
      top 210,10
      width 210,700
      height 210,160
      sprite_target_is 210
   sprite 40 : rem Pièces de 1 Euro qui tombent -------------------------------
      sprite_file_load 40,"Un-Euro.bmp"
      sprite_position 40,200,-120
   sprite 50 : rem Pièces de 2 Euro qui tombent -------------------------------
      sprite_file_load 50,"Deux-Euro.bmp"
      sprite_position 50,500,-120
   sprite 60 : rem Bec du réceptacle ------------------------------------------
      sprite_file_load 60,"Réceptacle.bmp"
   panel 220 : rem Base de l`indication de la cagnotte ------------------------
      parent 220,200
      left 220,100
      top 220,90
      width 220,535
      height 220,70
      color 220,0,0,255
   alpha 230 : rem Titre de la cagnotte ---------------------------------------
      parent 230,220
      left 230,20
      top 230,15
      font_bold 230
      font_size 230,24
      font_name 230,"Arial"
      font_color 230,255,255,255
      caption 230,"Votre cagnotte :"
   alpha 240 : rem Montant de la cagnotte -------------------------------------
      parent 240,220
      left 240,400-len(str$(MC%))*12
      top 240,15
      font_bold 240
      font_size 240,24
      font_name 240,"Arial"
      font_color 240,255,255,255
      caption 240,MC%
   alpha 250 : rem Indication de l`unité monétaire ----------------------------
      parent 250,220
      left 250,480
      top 250,15
      font_bold 250
      font_size 250,24
      font_name 250,"Arial"
      font_color 250,255,255,255
      caption 250,"€"
      
rem Construction du bloc de commandes des styles de jeu =======================
   panel 290 : rem Bloc de la base des commandes de style de jeu --------------
      left 290,740
      top 290,10
      width 290,598
      height 290,470
   for V1M% = 1 to 5 : rem Ombre des faux-boutons -----------------------------
      for V2M% = 1 to 4 : rem Objets-système n° 300 à 490 ---------------------
         alpha (V1M%-1)*40+V2M%*10+290                : rem 300  310  320  330
            parent (V1M%-1)*40+V2M%*10+290,290        : rem 340  350  360  370
            left (V1M%-1)*40+V2M%*10+290,147*V2M%-137 : rem 380  390  400  410
            top (V1M%-1)*40+V2M%*10+290,V1M%*92-82    : rem 420  430  440  450
            width (V1M%-1)*40+V2M%*10+290,137         : rem 460  470  480  490
            height (V1M%-1)*40+V2M%*10+290,82
            color (V1M%-1)*40+V2M%*10+290,200,200,200
         V5M%=(V1M%-1)*40+V2M%*10+490
         panel V5M% : rem Objets-système n° 500 à 690 -------------------------
            parent V5M%,290
            left V5M%,147*V2M%-137                    : rem 500  510  520  530
            top V5M%,V1M%*92-82                       : rem 540  550  560  570
            width V5M%,135                            : rem 580  590  600  610
            height V5M%,80                            : rem 620  630  640  650
            font_size V5M%,50                         : rem 660  670  680  690
            font_name V5M%,DP$(QP%((V1M%-1)*4+V2M%))
            V3M%=QC%((V1M%-1)*4+V2M%,1)
            font_color V5M%,DC%(V3M%,1),DC%(V3M%,2),DC%(V3M%,3)
            caption V5M%,left$(LS$((V1M%-1)*4+V2M%),1)
            on_click V5M%,clic
      next V2M%
   next V1M%
   color 500,255,255,0
  
rem Construction de l`affichage des combinaisons gagnantes ====================
   panel 700 : rem Bloc de la base des combinaisons gagnantes -----------------
      left 700,10
      top 700,490
      width 700,720
      height 700,180
   for V1M% = 1 to 3 : rem Affichage des alphas pour la couleur ---------------
      alpha V1M%*100+610 : rem Objets-système n° 710  720  730 ----------------
         parent V1M%*100+610,700
         left V1M%*100+610,20
         top V1M%*100+610,V1M%*57-37
      for V2M% = 1 to 3 : rem Affichage des combinaisons gagnantes ------------
         panel V1M%*100+V2M%*10+610 : rem Objets-système n° 720 à 940 ---------
            parent V1M%*100+V2M%*10+610,700                : rem 720  730  740
            left V1M%*100+V2M%*10+610,V2M%*60-50           : rem 820  830  840
            top V1M%*100+V2M%*10+610,V1M%*57-47            : rem 920  930  940
            width V1M%*100+V2M%*10+610,50
            height V1M%*100+V2M%*10+610,47
            font_size V1M%*100+V2M%*10+610,30
            caption V1M%*100+V2M%*10+610,"7"
      next V2M%
      panel V1M%*100+650 : rem Objets-système n° 750  850  950 ----------------
         parent V1M%*100+650,700
         left V1M%*100+650,190
         top V1M%*100+650,V1M%*57-47
         width V1M%*100+650,370
         height V1M%*100+650,47
         font_bold V1M%*100+650
         font_size V1M%*100+650,30
         font_name V1M%*100+650,"Arial"
         caption V1M%*100+650," =    votre mise    x "
      panel V1M%*100+660 : rem Objets-système n° 760  860  960 ----------------
         parent V1M%*100+660,700
         left V1M%*100+660,570
         top V1M%*100+660,V1M%*57-47
         width V1M%*100+660,140
         height V1M%*100+660,47
         color V1M%*100+660,255,255,0
         font_bold V1M%*100+660
         font_size V1M%*100+660,28
         font_name V1M%*100+660,"Arial"
         on_click V1M%*100+660,clic
   next V1M%

rem Construction du bloc de commentaires scores et commandes ==================
   panel 1000 : rem Bloc de la base des commentaires scores et commandes ------
      left 1000,740
      top 1000,490
      width 1000,598
      height 1000,180
   panel 1010 : rem Base de la zone des commentaires --------------------------
      parent 1010,1000
      left 1010,10
      top 1010,10
      width 1010,578
      height 1010,70
      color 1010,255,255,0
   alpha 1020 : rem Commentaires ----------------------------------------------
      parent 1020,1010
      left 1020,10
      top 1020,7
      font_size 1020,18
      font_name 1020,"Arial"
      caption 1020,"Bienvenue dans le jeu"
      V1M%=int(rnd(10))+1
      if V1M%=1
         V4M$="Avez-vous lu le scénario et les règles du jeu ?"+chr$(13)
         V4M$=V4M$+"C'est toujours utile ( Cliquez sur AIDE )"
         caption 1020,V4M$
      end_if
   for V1M% = 1 to 3 : rem Affichage des 3 annotations sur l`utilité ----------
      alpha V1M%*10+1020 : rem Objets-système n° 1030  1040  1050 -------------
         parent V1M%*10+1020,1000
         left V1M%*10+1020,V1M%*142-90
         top V1M%*10+1020,88
         font_color V1M%*10+1020,255,0,0
   next V1M%
   caption 1030,"     Votre"+chr$(13)+"meilleur gain"
   caption 1040,"Votre meilleure"+chr$(13)+"    cagnotte"
   caption 1050,"Votre porte"+chr$(13)+"  bonheur"
   panel 1060 : rem Affichage de la base du meilleur gain ---------------------
      parent 1060,1000
      left 1060,10
      top 1060,120
      width 1060,130
      height 1060,50
      color 1060,0,0,0
   alpha 1070 : rem Affichage du montant du gain ------------------------------
      parent 1070,1060
      left 1070,40
      top 1070,7
      font_size 1070,24
      font_name 1070,"Arial"
      font_color 1070,255,255,255
      if MG%>0
         caption 1070,MG%
      end_if
   alpha 1080 : rem Indication de l`unité monétaire ---------------------------
      parent 1080,1060
      left 1080,105
      top 1080,7
      font_size 1080,24
      font_name 1080,"Arial"
      font_color 1080,255,255,255
      caption 1080,"€"
   panel 1090 : rem Affichage de la base de la meilleure cagnotte -------------
      parent 1090,1000
      left 1090,145
      top 1090,120
      width 1090,185
      height 1090,50
      color 1090,0,0,0
   alpha 1100 : rem Affichage de montant de la meilleure cagnotte -------------
      parent 1100,1090
      left 1100,50
      top 1100,7
      font_size 1090,24
      font_name 1100,"Arial"
      font_color 1100,255,255,255
      caption 1100,MP%
   alpha 1110 : rem Affichage de l`unité monétaire ----------------------------
      parent 1110,1090
      left 1110,160
      top 1110,7
      font_size 1110,24
      font_name 1110,"Arial"
      font_color 1110,255,255,255
      caption 1110,"€"
   panel 1120 : rem Base du grigri --------------------------------------------
      parent 1120,1000
      left 1120,340
      top 1120,120
      width 1120,45
      height 1120,50
   picture 1130 : rem Indication pas de grigri --------------------------------
      parent 1130,1120
      width 1130,44
      height 1130,49
      stretch_on 1130
      file_load 1130,"Pas-grigri.bmp"
      on_click 1130,clic
   picture 1140 : rem Support du grigri ---------------------------------------
      parent 1140,1120
      hide 1140
      width 1140,44
      height 1140,49
      stretch_on 1140
      file_load 1140,"Grigri.bmp"
      on_click 1140,clic
   button 1150 : rem Bouton d`aide --------------------------------------------
      parent 1150,1000
      left 1150,395
      top 1150,85
      width 1150,95
      height 1150,85
      font_bold 1150
      font_size 1150,18
      font_name 1150,"Arial"
      caption 1150,"Aide"
      on_click 1150,clic
   button 1160 : rem Bouton quitter -------------------------------------------
      parent 1160,1000
      left 1160,493
      top 1160,85
      width 1160,95
      height 1160,85
      font_bold 1160
      font_size 1160,18
      font_name 1160,"Arial"
      caption 1160,"Quitter"
      on_click 1160,clic
      
rem Fin de préparation de jeu =================================================
   midi_on
   midi_volume 127
   QSJ%=1
   gains()
   VO%=number_ticks
   VO%=int((VO%-VO1%)/1000)+1
   hide 2

end : rem ' Début des routines ================================================

sub aide() : rem Précision du scénario et des règles du jeu ===================
   dim_local v1ai%
   V4M$="C'est bien de connaître comment ça marche,"+chr$(13)
   V4M$=V4M$+"autant savoir où on met les pieds."
   caption 1020,V4M$
   couleur()
   V4M$=""
   application_title "   Scénario et règles du jeu du Bandit-manchot"
   for v1ai% = 1 to 20
      if left$(TRJ$(v1ai%*2-1),3)="   " and v1ai%>1
         V4M$=V4M$+chr$(13)
      end_if
      V4M$=V4M$+TRJ$(v1ai%*2-1)+TRJ$(v1ai%*2)+chr$(13)
   next v1ai%
   message V4M$
end_sub

sub annule() : rem Annule la mise en jeu ======================================
   dim_local v1an% , v2an , v3an%
   v3an%=int(rnd(2))+1
   midi_instrument 108
   for v1an% = 1 to 3
      if sprite_y_position(v1an%*10)<50
         for v2an = 0 to 120 step 10
            sprite_y_position v1an%*10,v2an
            pause 1
         next v2an
         if number_click=110
            caption 1020,TCD$(v3an%+10)
            couleur()
            midi_play 70,10
         end_if
      end_if
   next v1an%
   show 190
   inactive 80
   for v1an% = 1 to 3
      active v1an%*10+110
   next v1an%
   STM%=0
end_sub

sub bis1() : rem Première partie de la remise à zéro ==========================
   if BIS%=0
      BIS%=1
   else
      BIS%=0
   end_if
end_sub

sub bis2() : rem Deuxième partie de la remise à zéro ==========================
   if BIS%=1
      BIS%=2
   else
      BIS%=0
   end_if
end_sub

sub bis3() : rem Troisième partie de la remise à zéro =========================
   dim_local v1bi%
   if BIS%=2
      BIS%=0
      V4M$="Par ce biais, vous pouvez annuler tous vos essais et recommencer"
      V4M$=V4M$+chr$(13)+"la simulation telle qu'elle était au début avec "
      V4M$=V4M$+"les 200 € de départ."+chr$(13)
      V4M$=V4M$+"Cela correspond-il bien à votre demande ?"
      v1bi%=message_confirmation_yes_no(V4M$)
      if v1bi%=1
         caption 240,"200"
         caption 1070,""
         caption 1100,"200"
         milieu()
         caption 1020,"Allez, on recommence tout depuis le début !"
         couleur()
         file_open_write 1,"Bandimancho.txt"
            file_writeln 1,"200"
            file_writeln 1,"0"
            file_writeln 1,"200"
         file_close 1
      end_if
      set_focus 1150
   else
      BIS%=0
   end_if
end_sub

sub bloque() : rem Bloque toutes les entrées autres que boutons ===============
   dim_local v1bl%
   inactive 110
   for v1bl% = 500 to 690 step 10
      inactive v1bl%
   next v1bl%
   for v1bl% = 1 to 3
      inactive v1bl%*100+660
   next v1bl%
   inactive 1130
   inactive 1140
end_sub

clic: : rem Redirection de tous les on-click ==================================
   select number_click
      case 80 : jouer()
      case 110 : annule()
      case 120 : mise()
      case 130 : mise()
      case 140 : mise()
      case 760 : bis1()
      case 860 : bis2()
      case 960 : bis3()
      case 1130 : grigri()
      case 1140 : grigri()
      case 1150 : aide()
      case 1160 : quitter()
   end_select
   if number_click>495 and number_click<695
      choix()
   end_if
return

sub choix() : rem Choix d`un autre style de jeu ===============================
   dim_local v1ch% , v2ch%
   bloque()
   midi_instrument 115
   midi_play 90,10
   hide number_click-200
   pause 100
   show number_click-200
   for v1ch% = 500 to 690 step 10
      color v1ch%,240,240,240
   next v1ch%
   color number_click,255,255,0
   QSJ%=(number_click/10)-49
   for v1ch% = 1 to 3
      text v1ch%*10+20,left$(LS$(QSJ%),1)
   next v1ch%
   for v1ch% = 1 to 4
      font_name v1ch%*10+10,DP$(QP%(QSJ%))
      v2ch%=val(mid$(LC$(QSJ%),1,1))
      font_color v1ch%*10+10,DC%(v2ch%,1),DC%(v2ch%,2),DC%(v2ch%,3)
      font_size v1ch%*10+10,QF%(QSJ%)
      height v1ch%*10+10,192
   next v1ch%
   v1ch%=int(rnd(10))+1
   caption 1020,TCD$(v1ch%+12)
   couleur()
   gains()
   debloque()
end_sub

sub couleur() : rem Change la couleur des commentaires et du fond =============
   dim_local v1co%
   v1co%=int(rnd(7))+1
   font_color 1020,DC%(v1co%,1),DC%(v1co%,2),DC%(v1co%,3)
   if DC%(v1co%,2)=0
      color 1010,255,255,0
      color 1020,255,255,0
   else
      color 1010,0,0,0
      color 1020,0,0,0
   end_if
end_sub

sub debloque() : rem Débloque toutes les entrées (sauf boutons) ===============
   dim_local v1de%
   active 110
   for v1de% = 500 to 690 step 10
      active v1de%
   next v1de%
   for v1de% = 1 to 3
      active v1de%*100+660
   next v1de%
   active 1130
   active 1140
end_sub

rem Début des datas ===========================================================
   rem Datas des couleurs -----------------------------------------------------
   data 0 , 0 , 0 , 255 , 0 , 0 , 255 , 125 , 0 , 0 , 255 , 0
   data 0 , 0 , 255 , 150 , 0 , 255 , 255 , 120 , 255
   rem Datas des polices utilisées --------------------------------------------
   data "Arial" , "Symbol" , "Webdings" , "Wingdings"
   rem Datas des caractéristiques utilisées dans chaque police ----------------
   rem Arial ------------------------------------------------------------------
   data "7471777471747" , "1111111111111" , 1 , 110
   data 1 , "7" , 4 , 1 , "4" , 100 , 1 , "1" , 250
   data "7777777" , "5354535" , 1 , 110
   data 5 , "7" , 5 , 3 , "7" , 50 , 4 , "7" , 350
   data "abacadaeafaiakaxanaoaparasatauaeauaeauae"
   data "1111111111111111111111111111111111111111" , 1 , 110
   data 1 , "a" , 8 , 1 , "e" , 1000 , 1 , "u" , 2400
   data "aaaaaaaaaaa" , "52545357575" , 1 , 110
   data 5 , "a" , 6 , 7 , "a" , 170 , 4 , "a" , 1400
   data "€$€£€$€ƒ€$€£€$€§" , "1111111111111111" , 1 , 110
   data 1 , "€" , 8 , 1 , "$" , 60 , 1 , "£" , 500
   rem Symbol -----------------------------------------------------------------
   data "©§¨©¨©§¨©§©©§©" , "21222212212212" , 2 , 90
   data 2 , "©" , 10 , 1 , "§", 50, 2 , "¨" , 100
   data "¥ºÑ¥'¥Îº¥" , "111111111" , 2 , 90
   data 1 , "¥" , 10 , 1 , "º" , 100 , 1 , "'" , 1000
   data "lJlgl¡lxzx" , "5453525676" , 2 , 90
   data 5 , "l" , 15 , 6 , "x" , 125 , 2 , "¡" , 1000
   rem Webdings ---------------------------------------------------------------
   data "ÿõÿÿõÿÿõÿÿöÿÿÿÿÿöÿÿÿõ" , "535535535515555515553" , 3 , 70
   data 5 , "ÿ" , 3 , 3 , "õ" , 140 , 1 , "ö" , 1200
   data "JHJSJMJHJP" , "5653525654" , 3 , 70
   data 5 , "J" , 8 , 6 , "H" , 125 , 2 , "M" , 1000
   data "†‡†&†&†ˆ" , "31323235" , 3 , 70
   data 3 , "†" , 8 , 2 , "&" , 64 , 1 , "‡" , 666
   data "bTbjbfbhbŽbjb" , "7374727176747" , 3 , 70
   data 7 , "b" , 7 , 4 , "j" , 280 , 3 , "T" , 2000
   data "eÏe‘eÑe“e“e" , "26232425252" , 3 , 70
   data 2 , "e" , 7 , 5 , "“" , 170 , 3 , "‘" , 1400
   data "µâµ¹µãµâµ" , "131516131" , 3 , 70
   data 1 , "µ" , 6 , 3 , "â" , 125 , 6 , "ã" , 750
   data "˜l˜d˜l˜=˜" , "545654535" , 3 , 70
   data 5 , "˜" , 6 , 4 , "l" , 100 , 6 , "d" , 800
   data "”ƒ”ƒ”””„”" , "575755515" , 3 , 70
   data 5 , "”" , 4 , 7 , "ƒ" , 100 , 1 , "„" , 800
   rem Wingdings --------------------------------------------------------------
   data "IBICIIIIIGIBI" , "7374777772737" , 4 , 80
   data 7 , "I" , 3 , 3 , "B" , 300 , 2 , "G" , 3000
   data "6O6O6N6'" , "63636162" , 4 , 90
   data 6 , "6" , 8 , 3 , "O" , 80 , 1 , "N" , 800
   data "[¥[][v[¯[¥[" , "12131615121" , 4 , 80
   data 1 , "[" , 7 , 2 , "¥" , 170 , 3 , "]" , 1400
   data "b\b\–š–b\b" , "1111111111" , 4 , 70
   data 1 , "b" , 16 , 1 , "" , 40 , 1 , "–" , 130
   rem Texte de l`aide --------------------------------------------------------
   data "   La consécration que vous attendiez depuis si longtemps "
   data "vous a enfin touché de son aile divine : vous avez hérité"
   data "de votre grand-oncle Alfred (un parent lointain que vous ne "
   data "connaissiez pas et qui était parti faire fortune en Amérique)"
   data "qui vous a laissé toute sa fortune, soit 200 Euros (une fois "
   data "soustrait toutes les déductions fiscales)."
   data "   Le grand projet de votre enfance, que vous aviez presque "
   data "oublié, est alors à nouveau, pour vous, à l'ordre du jour :"
   data "vous acheter la voiture de vos rêves, c'est-à-dire une "
   data "Ferrari, une Cadillac ou une Rolls-Royce."
   data "   Cependant, renseignements pris, vous constatez que votre "
   data "héritage est un peu insuffisant pour un tel projet. C'est"
   data "alors qu'une idée absolument lumineuse vous est venue à "
   data "l'esprit : aller dans une maison de jeu avec votre pactole"
   data "pour arrondir votre fortune et pouvoir ainsi vous offrir la "
   data "voiture de vos rêves. Cette idée vous paraît même tellement"
   data "remarquable que vous vous étonnez que personne ne l'ait "
   data "jamais eue avant vous."
   data "   Un ami à qui vous avez parlé de vos intentions, et que "
   data "vous tenez pour avisé, vous a cependant conseillé de vous"
   data "entraîner d'abord sur un logiciel de simulation, avant de "
   data "vous lancer dans une telle aventure avec une expérience"
   data "insuffisante, au risque de vous retrouver complètement "
   data "plumé en un temps record."
   data "   Vous ne pensez pas du tout qu'une telle déveine puisse "
   data "jamais vous arriver. Malgré cela, vous décidez de suivre le"
   data "conseil de votre ami, histoire de mettre toutes les chances "
   data "de votre côté. De toute façon, vous avez toujours avec vous"
   data "votre grigri favori. Et voici le programme qui va vous "
   data "permettre de tester vos chances de faire fortune."
   data "   Le fonctionnement de ce logiciel est tout à fait simple "
   data "et intuitif. Il ne demande donc guère d'explication et tout"
   data "le monde peut y jouer aisément. Deux petits détails sont "
   data "cependant à préciser :"
   data "- Si vous avez misé plus que vous ne le souhaitiez, vous "
   data "pouvez annuler la mise en cliquant sur les pièces."
   data "- Si la somme que vous devez à la banque de jeu atteint des "
   data "abîmes absolument insondables, cliquez successivement"
   data "sur les trois nombres colorés en jaune, dans l'ordre, pour "
   data "recommencer la simulation.              Bonne chance !"
   rem Commentaires du bloc de roulettes --------------------------------------
   data "Ca y est," , "les jeux sont faits..."
   data "Croisez les doigts," , "ça va marcher !"
   data "Ah, on ne peut pas gagner" , "à tous les coups."
   data "La chance tourne..." , ""
   data "La prochaine fois, peut-être." , ""
   data "Il faut persévérer pour gagner !" , ""
   data "Commencer par perdre," , "c'est le début de la fortune..."
   data "Allez, tout n'est pas perdu !" , ""
   rem Commentaires du bloc de mise -------------------------------------------
   data "Ah, ah, cette fois," , "ça va être du sérieux !"
   data "Pour gagner," , "il faut commencer par investir."
   data "Oui, réfléchissons d'abord bien" , "à la stratégie !"
   data "Voyons, qu'est-ce qui est" , "le plus rentable ?"
   rem Commentaires du bloc de styles de jeu ----------------------------------
   data "Trouvez le style de jeu" , "qui vous convient le mieux."
   data "Certains styles de jeu permettent" , "de gagner plus que d'autres."
   data "N'hésitez pas à changer de style de jeu" , "quand vous vous lassez !"
   data "Lettres, chiffres, symboles," , "couleurs, il y a de tout, ici !"
   data "Découvrez à quel symbole" , "se rattache le mieux votre chance."
   data "Vous avez raison, il ne faut pas" , "s'acharner sur un style de jeu."
   data "Eh ben dis-donc, il y a des styles" , "de jeu qui rapportent un max !"
   data "Eh, il y a des styles de jeu" , "que vous n'avez pas essayés !"
   data "Vous avez essayé le style de jeu" , "du bouton d'à côté ?"
   data "Le style de jeu, ça peut être" , "le secret de la réussite !"
   rem Commentaires des grigris positifs --------------------------------------
   data "Beaucoup de gens ne se séparent" , "jamais de leur grigri."
   data "Les grigris, y'a que ça de vrai !" , ""
   data "Ah, les bons vieux grigris," , "il n'y a rien de plus efficace !"
   data "Le monde entier tourne autour des grigris." , ""
   data "Eh, le trèfle à quatre feuille," , "c'est le meilleur des grigris !"
   rem Commentaires des grigris négatifs --------------------------------------
   data "Et puis zut, c'est la bonne étoile" , "qui compte, pas les grigris !"
   data "C'est vrai, les grigris font" , "quelquefois l'effet inverse."
   data "Non, pas de grigri, cette fois-ci !" , ""
   data "Oui, c'est vrai que les grigris," , "ça marche quand ça a le temps !"
   data "Dans le fond, les grigris," , "est-ce vraiment important ?"
rem Fin des datas

sub gains() : rem Affichage des gains possibles ===============================
   dim_local v1gi% , v2gi% , v3gi% , v4gi%
   for v1gi% = 1 to 3
      for v2gi% = 1 to 3
         v4gi%=v1gi%*100+v2gi%*10+610
         font_name v4gi%,DP$(QP%(QSJ%))
         caption v4gi%,QS$(QSJ%,v1gi%)
         v3gi%=QC%(QSJ%,v1gi%)
         font_color v4gi%,DC%(v3gi%,1),DC%(v3gi%,2),DC%(v3gi%,3)
      next v2gi%
      caption v1gi%*100+660,QG%(QSJ%,v1gi%)
   next v1gi%
end_sub

sub gagne(cga%) : rem Le joueur gagne des pièces qui tombent ==================
   dim_local v1ga% , v2ga , v3ga% , v4ga%
   midi_instrument 10
   cga%=int(cga%/2)+1
   if cga%>40
      cga%=40
   end_if
   for v1ga% = 1 to cga%
      v3ga%=int(rnd(2))+1
      v4ga%=int(rnd(450))+81
      sprite_x_position v3ga%*10+30,v4ga%
      for v2ga = -120 to 80 step VO%*2
         sprite_y_position v3ga%*10+30,v2ga
      next v2ga
      midi_play int(rnd(2))*2+74,10
   next v1ga%
end_sub

sub grigri() : rem Apparition et disparition du grigri ========================
   dim_local v1gr%
   bloque()
   midi_instrument 123
   v1gr%=int(rnd(5))+1
   if show(1140)=1
      hide 1140
      caption 1020,TCD$(v1gr%+27)
      midi_play 40,10
   else
      show 1140
      caption 1020,TCD$(v1gr%+22)
      midi_play 80,10
   end_if
   couleur()
   debloque()
end_sub

sub jouer() : rem Le joueur lance les roulettes ===============================
   dim_local v1jo% , v2jo% , v3jo% , v4jo% , v5jo% , v6jo% , v7jo
   bloque()
   midi_instrument 115
   for v1jo% = 1 to 3
      inactive v1jo%*10+110
   next v1jo%
   hide 190
   inactive 80
   caption 240,val(caption$(240))-STM%
   milieu()
   v1jo%=int(rnd(2))+1
   caption 1020,TCD$(v1jo%)
   couleur()
   show 20
   for v1jo% = 1 to 3 : rem Rotation des 3 roulettes --------------------------
      midi_play 75,10
      left 20,(v1jo%-1)*101+12
      v6jo%=int(rnd(len(LS$(QSJ%))))+int(rnd(11))+5
      if v1jo%=3
         if text$(30)<>text$(40)
            v6jo%=7
         end_if
      end_if
      for v3jo% = 1 to v6jo% : rem Durée de la rotation de chaque roulette ----
         v4jo%=v4jo%+1
         if v4jo%>len(LS$(QSJ%))
            v4jo%=1
         end_if
         top 20,192
         height 20,192
         height v1jo%*10+20,192
         text 20,mid$(LS$(QSJ%),v4jo%,1)
         v5jo%=val(mid$(LC$(QSJ%),v4jo%,1))
         caption v1jo%*100+610,v5jo%
         font_color 20,DC%(v5jo%,1),DC%(v5jo%,2),DC%(v5jo%,3)
         for v7jo = 202 to 10 step 0-VO%*2
            top v1jo%*10+20,v7jo-202
            top 20,v7jo
            display
         next v7jo
         text v1jo%*10+20,text$(20)
         font_color v1jo%*10+20,DC%(v5jo%,1),DC%(v5jo%,2),DC%(v5jo%,3)
         top v1jo%*10+20,10
         height v1jo%*10+20,192
      next v3jo%
   next v1jo%
   display
   rem Détection des gains possibles ------------------------------------------
   if text$(30)=text$(40) and text$(40)=text$(50)
      if val(caption$(710))=val(caption$(810))
         if val(caption$(810))=val(caption$(910))
            for v1jo% = 1 to 3
               if text$(30)=QS$(QSJ%,v1jo%)
                  if val(caption$(710))=QC%(QSJ%,v1jo%)
                     v2jo%=v1jo%
                     exit_for
                  end_if
               end_if
            next v1jo%
         end_if
      end_if
   end_if
   if v2jo%>0 : rem Réponse aux gains -----------------------------------------
      v1jo%=STM%*QG%(QSJ%,v2jo%)
      V4M$="Vous gagnez  "+str$(STM%)+" €  X  "+str$(QG%(QSJ%,v2jo%))
      V4M$=V4M$+"  =  "+str$(v1jo%)+" €, bravo !"
      caption 1020,V4M$
      couleur()
      gagne(v1jo%)
      caption 240,val(caption$(240))+v1jo%
      v3jo%=0
      if caption$(1070)<>""
         v3jo%=val(caption$(1070))
      end_if
      if v1jo%>v3jo%
         caption 1070,v1jo%
      end_if
      v3jo%=val(caption$(1100))
      v4jo%=val(caption$(240))
      if v4jo%>v3jo%
         caption 1100,v4jo%
      end_if
      milieu()
   else : rem Réponse aux non-gains -------------------------------------------
      v3jo%=int(rnd(6))+1
      caption 1020,TCD$(v3jo%+2)
      couleur()
      midi_instrument 91
      midi_play 58,6
   end_if
   file_open_write 1,"Bandimancho.txt"
      file_writeln 1,val(caption$(240))
      if caption$(1070)<>""
         file_writeln 1,val(caption$(1070))
      else
         file_writeln 1,"0"
      end_if
      file_writeln 1,val(caption$(1100))
   file_close 1
   annule()
   debloque()
end_sub

sub milieu() : rem Placement des compteurs au milieu ==========================
   left 240,400-len(str$(MC%))*12
   if caption$(1070)<>""
      if val(caption$(1070))>999
         left 1070,10
      else
         left 1070,40
      end_if
   end_if
   if val(caption$(1100))>99999
      left 1100,10
   else
      left 1100,50
   end_if
end_sub

sub mise() : rem Le joueur met des pièces en jeu ==============================
   dim_local v1mi% , v2mi , v3mi%
   v1mi%=(number_click/10)-11
   midi_instrument 108
   for v2mi = 120 to 0 step -10
      sprite_y_position v1mi%*10,v2mi
      pause 1
   next v2mi
   if STM%=0
      v3mi%=int(rnd(2))+1
      caption 1020,TCD$(v3mi%+8)
      couleur()
   end_if
   if v1mi%=3
      v1mi%=2
   end_if
   STM%=STM%+v1mi%
   caption 170,STM%
   inactive number_click
   active 80
   if STM%=5
      hide 190
   end_if
   midi_play 60,10
end_sub

sub quitter() : rem Arrêt du jeu ==============================================
   dim_local v1qu%
   V4M$="Attendez, la chance peut tourner,"+chr$(13)
   V4M$=V4M$+"ce n'est pas le moment d'abandonner !"+chr$(13)
   V4M$=V4M$+"Vous voulez vraiment partir ?"
   v1qu%=message_confirmation_yes_no(V4M$)
   if v1qu%=1
      midi_off
      file_delete "Grigri.bmp"
      file_delete "Pas-grigri.bmp"
      file_delete "Un-Euro.bmp"
      file_delete "Deux-Euro.bmp"
      file_delete "Fond-bandit.bmp"
      file_delete "Réceptacle.bmp"
      terminate
   end_if
end_sub
Amusez-vous bien !
Laughing Laughing Laughing alien alien jocolor geek rendeer
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://jjn4.e-monsite.com
papydall

avatar

Nombre de messages : 5991
Age : 68
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: Bandit manchot   Jeu 9 Fév 2017 - 16:37

BRAVO JJN4 !!!!
Comme d’habitude, original, clair et instructif.

NB : pour ne pas me ruiner, j’ai quitté, honteux d’avoir perdu une bonne part de « me fortune ».
J’y reviendrai pour ma vengeance !
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
Jean Claude

avatar

Nombre de messages : 5643
Age : 64
Localisation : 83 Var
Date d'inscription : 07/05/2009

MessageSujet: Re: Bandit manchot   Jeu 9 Fév 2017 - 18:16

Je n'ai plus rien en poche Sad Sad
La prochaine fois, j'y vais avec une Thomson à Camembert... pirat

A+
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Yannick

avatar

Nombre de messages : 8083
Age : 47
Localisation : Bretagne
Date d'inscription : 15/02/2010

MessageSujet: Re   Ven 10 Fév 2017 - 0:21

Ca y est, cette fois je suis plumé même virtuellement !
Laughing
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
jjn4

avatar

Nombre de messages : 1761
Date d'inscription : 13/09/2009

MessageSujet: +++   Sam 11 Fév 2017 - 13:38

Ygeronimi a écrit:
je suis plumé

C'est pas un peu frisquet, par les temps qui courent ?
Laughing affraid alien geek Laughing
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://jjn4.e-monsite.com
Jicehel

avatar

Nombre de messages : 5929
Age : 46
Localisation : 77500
Date d'inscription : 18/04/2011

MessageSujet: Re: Bandit manchot   Sam 11 Fév 2017 - 20:26

Joli Wink
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Marc

avatar

Nombre de messages : 865
Age : 57
Localisation : TOURS
Date d'inscription : 17/03/2014

MessageSujet: Re: Bandit manchot   Sam 11 Fév 2017 - 21:10

EXTRA Jjn4 !

Quelle imagination ! Quel talent !

Maintenant, il ne me reste plus qu'a faire la manche à la sortie de l'église ! Crying or Very sad

Quoi qu'il en soit, BRAVO !
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Contenu sponsorisé




MessageSujet: Re: Bandit manchot   

Revenir en haut Aller en bas
 
Bandit manchot
Revenir en haut 
Page 1 sur 1
 Sujets similaires
-
» bandit 1250S ABS

Permission de ce forum:Vous ne pouvez pas répondre aux sujets dans ce forum
FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC :: PANORAMIC :: Les jeux faits avec Panoramic-
Sauter vers: