DES MATHS POUR DES JOLIES FLEURS

rem ============================================================================
rem       DES MATHS POUR DES JOLIES FLEURS
rem                 PAR PAPYDALL
rem ============================================================================

Montre_Moi_Ce_Dont_Tu_Es_Capable_De_Faire()

END
REM ============================================================================
SUB Montre_Moi_Ce_Dont_Tu_Es_Capable_De_Faire()
    dim xc,yc,i,h,w
    full_space 0 : h = height(0) : w = width(0)-5 : color 0,255,255,255
    caption 0,"DES MATHS POUR L'ESTHETIQUE DES COURBES"
    for i = 1 to 5
        picture i : top i,35-35 : width i, w/5-15 : height i,h/3-20
        left i,width(i) *(i-1)+12*(i)
    next i
    for i = 6 to 10
        picture i : top i,35-25+height(i-1) : width i, w/5-15 : height i,h/3-20
        left i,width(i) *(i-6)+12*(i-5)
    next i
    for i = 11 to 15
        picture i : top i,35-15+2*height(i-1) : width i, w/5-15 : height i,h/3-20
        left i,width(i) *(i-11)+12*(i-10)
    next i
    xc = width(1)/2-8 : yc = height(1)/2-17
    for i = 1 to 15
        color i,00,00,255 : 2d_pen_color 0,255,0

        2d_target_is i : 2d_fill_color 255,128,255
         2d_circle xc,yc,yc*.9
    next i
    2d_pen_color 0,255,0
    for i = 1 to 15 : 2d_target_is i :  Flower(i) : next i
END_SUB
REM ============================================================================
rem &&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&
rem ============================================================================
' n : nombre de pétales
SUB Flower(n)
    dim_local x,y,a,t,dt,r,z,f,j,aalpha,tmin,tmax,e
    a = 1 : aalpha = 2*pi/n : tmin = 0-pi/2 : tmax = 3*pi/2 : dt = pi/360
    e = 40
    for j = 1 to n
        for t = tmin to tmax step dt
            if (t > (tmax-dt)) and (t < (tmax+dt))
                r = 0 : z = 0-pi/2
            else
                if (t > (tmin-dt)) and (t < (tmin+dt))
                    r = 0 : z = pi/2
                else
                    r = a*sqr((5-3*sin(t))*(1+sin(t)))
                    z = asin(a*(1-sin(t))*cos(t)/r)
                end_if
             end_if
             f = 0-aalpha*z/pi+pi/2+2*pi*(j-1)/n
             x = r*cos(f) : y = r*sin(f)
             2d_point xc+e*x,yc-e*y
             if scancode <> 0 then end
        next t
        display
    next j
    2d_flood xc,0.1*yc+1,255,255,0
    2d_fill_color 255,0,0 : 2d_circle xc,yc,10
    2d_fill_color 0,0,0   : 2d_circle xc,yc,5
    
END_SUB
rem ============================================================================
rem &&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&
rem ============================================================================