Jeu de l'élastique revu et remis au goût du moment

rem ============================================================================
rem                  ELASTIC.BAS V 3.0
rem                    PAR PAPYDALL
rem  Adaptation en PANORAMIC d un programme en FREEBASIC
rem ============================================================================
rem  Le programme nécessite KGF.DLL
rem ============================================================================
rem Attrapez le maximum de boules  avec la boule verte en un temps déterminé
rem ça a l air facile ... sauf que la boule verte est accrochée à la souris avec
rem un élastisque ...
rem Bon divertissement !!
rem ============================================================================
Run()
Stop_Run()
rem ============================================================================
SUB Run()
    dim bx,by,bvx,bvy,bax,bay,dt,cx,cy,dll$,res%,mx%,my%,reste,score
    dim dst0,dst1,dst2,dst3,t$
    dll$ = "KGF.dll" : ' Adapter le chemin de la DLL
    full_space 0 : color 0,0,0,0 : font_color 0 ,255,255,0
    picture 10 : full_space 10 : 2d_target_is 10 : print_target_is 10 : hide 10
    Font_bold 10 : font_size 10,20 : font_color 10,255,0,0 : font_name 10,"tahoma"
    2d_fill_on
    image 20
    t$ = "Attrapez le maximum de boules avec la boule verte ... <ESC> pour arrêter"
    caption 0,t$
    dll_on dll$
    if message_confirmation_ok("OK pour commencer ?") = 1 then InitJeu() :  jeu()
END_SUB
' ******************************************************************************
Sub InitCible()
    cx = int(rnd(width(0)-50)+20) : cy = int(rnd(height(0)-50)+20)
end_sub
' ******************************************************************************
Sub InitJeu()
    bx = int(rnd(width(0)-50)+20) : by = int(rnd(height(0)-50)+20)
    res% = dll_call2("AbsoluteMousePosition",bx,by) : InitCible()
end_sub
' ******************************************************************************
SUB Jeu()
    reste = 10000 : ' c'est la durée du jeu
    score = 0 : cursor_hide 0
    repeat
        reste = reste-1
        res% = dll_call2("GetAbsoluteMousePosition",adr(mx%),adr(my%))
        if mx% < 10 then mx% = 10
        if my% < 10 then my% = 10
        if mx% > width(0)-10  then mx% = width(0)-10
        if my% > height(0)-40 then my% = height(0)-40
        bax = sqr((mx%-bx)*(mx%-bx))/2000
        bay = sqr((my%-by)*(my%-by))/2000
        if bx < mx% then bvx = bvx + bax
        if bx > mx% then bvx = bvx - bax
        if by < my% then bvy = bvy + bay
        if by > my% then bvy = bvy - bay
        if bx < 0         then bvx = abs(bvx)* 0.8   : bvy = bvy * 0.8
        if by < 20        then bvy = abs(bvy)* 0.8   : bvx = bvx * 0.8
        if bx > width(0)  then bvx = 0-abs(bvx)* 0.8 : bvy = bvy * 0.8
        if by > height(0) then bvy = 0-abs(bvy)* 0.8 : bvx = bvx * 0.8
        bx = bx + bvx : by = by + bvy
        Dst0 = sqr((cx-bx)*(cx-bx)+(cy-by)*(cy-by))
        dst1 = sqr((cx/2 -bx)*(cx/2-bx) + (cy/2-by)*(cy/2-by))
        dst2 = sqr((cx/3 -bx)*(cx/3-bx) + (cy/3-by)*(cy/3-by))
        dst3 = sqr((cx/1.5 -bx)*(cx/1.5-bx) + (cy/1.5-by)*(cy/1.5-by))
        if reste < 0 then reste = 0
        if (dst0 < 10) and (reste > 0) then Initcible() : score = score + 5
        if (dst1 < 10) and (reste > 0) then Initcible() : score = score + 10
        if (dst2 < 10) and (reste > 0) then Initcible() : score = score + 20
        if (dst3 < 10) and (reste > 0) then Initcible() : score = score + 1
        caption 0,t$ + " TEMPS RESTANT = "+ str$(reste) + "  SCORE "+ str$(score)
        if reste = 0
           print_locate width(10)/2-100,100 : print "!!! GAME OVER !!!" :  Copy_Image()
           if message_information_yes_no("VOULEZ-VOUS REJOUER?") = 1
              InitJeu() : Jeu() : else : Fin()
          end_if
        end_if
        2d_fill_color 000,000,000
        2d_pen_color  255,255,000 : 2d_rectangle 0,0,width(0)-1 ,height(0)-30
        2d_fill_color 000,255,000 : 2d_pen_color 000,255,000 : 2d_circle bx,by,10
        2d_pen_color  255,255,000 : 2d_line bx,by,mx%,my%
        2d_fill_color 255,000,000 : 2d_pen_color 255,000,000 : 2d_circle mx%,my%,10
        2d_fill_color 000,000,255 : 2d_pen_color 000,000,255 : 2d_circle cx,cy, 10
        2d_fill_color 000,255,255 : 2d_pen_color 000,255,255 : 2d_circle cx/2,cy/2,8
        2d_fill_color 255,255,255 : 2d_pen_color 255,255,255 : 2d_circle cx/3,cy/3,5
        2d_fill_color 255,255,255 : 2d_pen_color 255,255,255 : 2d_circle cx/1.5,cy/1.5,15
        Copy_Image()
    until  scancode = 27
    Stop_Run()
END_SUB
rem ============================================================================
SUB Stop_Run()
    res% = dll_call1("KillProcessByHandle",handle(0))
    terminate
END_SUB
rem ============================================================================
SUB Copy_Image()
    2d_image_copy 20,left(10),top(10),width(10),height(10)
    2d_target_is 0: 2d_image_paste 20,left(10),top(10) : 2d_target_is 10
END_SUB
rem ============================================================================