Bug dans la fonction MOUSE_LEFT_DOWN()

La fonction MOUSE_LEFT_DOWN est supposée retourner 1 si le bouton gauche est enfoncé, et 0 sinon. Or, elle retourne bien 0 si le bouton n'est pas enfoncé. Mais so l'on enfonce le bouton et on le maintient enfoncé, elle retourne 1 au premier appel, mais ensuite toujours 0 bien que le bouton reste enfoncé !

Dans le programme suivant, il suffit de déplacer la souris dans la form, puis enfoncer le bouton pour constater cela:

Code:

label tick
dim x%, y%, d%
timer 1 : timer_interval 1,100 : on_timer 1,tick
end

tick:
timer_off 1
d% = mouse_left_down(0)
x% = mouse_x_position(0)
y% = mouse_y_position(0)
if d%=1
  caption 0,"Enfoncé: "+str$(x%)+","+str$(y%)
else
  caption 0,"Relâché: "+str$(x%)+","+str$(y%)
end_if
timer_on 1
return

Ce n'est pas normal. Je me souviens avoir utilisé cela dans certains programmes, et ça marchait. J'ai la version actuelle de Panoramic (V0.9.26), et je suis sous W10.

En relâchant le bouton et appuyant à nouveau, l'état enfoncé est à nouveau reconnu une seule fois, puis la fonction retourne à nouveau 0. C'est un bug évident.

J'ai tenté de reproduire ton problème et j'ai le même résultat sous win7.32 avec la dernière version de panoramic.

Regardes par contre avec un exemple proche du tien :

Code:

label tick
dim x%, y%, d%
BUTTON 1 : on_click 1,tick
end

tick:
d% = mouse_left_down(0)
x% = mouse_x_position(0)
y% = mouse_y_position(0)
if d%=1
  caption 0,"Enfoncé: "+str$(x%)+","+str$(y%)
else
  caption 0,"Relâché: "+str$(x%)+","+str$(y%)
end_if
return

Tu cliques sur le bouton il est détecté puis tu cliques dans le form et tu recommence sur le bouton, il est de nouveau détecté !

Oui, c'est une autre façon de mettre le même bug en évidence. La détection par mouse_left_down ne marche qu'une fois, comme un fusil à 1 coup: il faut "recharger" en relâchant, puis recliquant. Donc, BUG !

Je ne sais pas si c'est vraiment un bug, ça y ressemble... mais on peut y pallier.
Personnellement je teste
MOUSE_LEFT_DOWN(n) = 1 pour la détection de l'appui, et ensuite
MOUSE_LEFT_UP(n) = 1 pour la détection du relâchement du bouton

Code:

Picture 1: Full_Space 1: Print_Target_is 1: Font_Size 1,12: Font_Bold 1

While Mouse_Left_Down(1) = 0: Print_Locate 0,0: Print "Relâché": Pause 50: End_While
While Mouse_Left_Up(1) = 0
    Print_Locate 0,0: Print "Enfoncé": Pause 50
End_While
Print_Locate 0,0: Print "Relâché"
End

PS Je m'aperçois que ce n'est peut-être pas aussi simple que ça en a l'air... je regarde de plus près.

Comme ça c'est mieux (clic dans le picture pour dessiner des figures à main levée, puis relâcher, clic le carré rouge en haut à droite pour sortir):

Code:

PICTURE 1: FULL_SPACE 1
Dessin(1): Message "Terminé !"
TERMINATE

SUB Dessin(p%)
' dessin à main levée dans le picture p%
DIM_LOCAL xd,yd,x,y
CAPTION 0,"Cliquer pour dessiner"
2D_TARGET_IS p%: 2D_PEN_WIDTH 3: 2D_FILL_COLOR 255,0,0
2D_RECTANGLE WIDTH(p%)-15,0,WIDTH(p%),15
WHILE 2 > 1
    WHILE MOUSE_LEFT_DOWN(p%) = 0: PAUSE 100: END_WHILE
    xd = MOUSE_X_POSITION(p%): yd = MOUSE_Y_POSITION(p%): ' point de départ du dessin
    IF xd>(WIDTH(p%)-15) AND yd<15 THEN EXIT_WHILE
    WHILE MOUSE_LEFT_UP(p%) = 0
        x = MOUSE_X_POSITION(p%): y = MOUSE_Y_POSITION(p%)
        CAPTION 0, "x="+STR$(x)+" y="+STR$(y)
        2D_LINE xd,yd,x,y: xd = x: yd = y: PAUSE 100
    END_WHILE
END_WHILE
END_SUB

Merci, Jl35 ! Ceci met également ce bug en évidence, et également dans la fonction MOUSE_LEFT_UP... Mais ton astuce est LE moyen de contourner ce problème. Je l'ai adaptée à mon petit code de déplacement d'objets, qui marche bien ainsi.

Ceci dit, c'est bien un bug, et ces fonctions ne marchent pas comme décrites dans la doc. Elles ne peuvent pas servir pour détecter si le bouton est enfoncé ou non, à un unstant t donné. Cela ne marche qu'une fois. Jack, si tu lis ça...

Tu as raison Klaus, évidemment. Même si on peut contourner l'obstacle, c'en est bien un.

Bonjour à tous,

J'ai déjà été confronté à ça, mais pas sûr que ce soit un bug; dans l'aide:

Citation :

la fonction MOUSE_LEFT_DOWN(N) est utilisée pour savoir si le bouton gauche de la souris a été enfoncé sur un objet système...

C'est écrit 'a été', donc l'état passe à 1 quand on l'enfonce, puis à 0 la frame suivante. Sinon ça aurait été écrit 'est'.

???

pas "a été", mais "est" !

Alors on a tous les 2 raison, regarde un peu plus bas, dans la rubrique 'UTILISATION'.(Du coup, bug ou pas?)
Sinon, il y a Nardo26 qui a fait une dll pour détecter si un bouton de la souris est enfoncé(il me semble), ou il y a aussi la fonction 'GetAsyncKeyState' de user32 qui fait ça aussi.(Et scancode, mais moins pratique à mon avis)

Pour Scancode il faut réinitialiser la fonction après chaque lecture (Scancode=0), c'est sans doute ce qui serait nécessaire pour Mouse_Left_Down, mais ce n'est pas prévu.

Et finalement, c'est peut-être l'utilisation de Scancode (je ne me souvenais plus que ça marchait pour la souris, merci Minibug silverman) qui serait le plus pratique pour ça:

Code:

LABEL tt
DIM s
EDIT 1: WIDTH 1,100: font_bold 1: on_close 0,tt

WHILE 2 > 1
    TEXT 1,""
    s = SCANCODE: SCANCODE = 0
    SELECT s
        CASE 1: TEXT 1,"Bouton gauche"
        CASE 2: TEXT 1,"Bouton droit"
    END_SELECT
    PAUSE 100
END_WHILE
tt:
terminate

Le seul souci c'est qu'il réagit sur tout l'écran, alors il faut s'assurer qu'on est bien sur le bon objet.

Un petit programme tout simple pour visualiser l'état des boutons de la souris. Et on voit que pour Panoramic, les boutons ne restent pas enfoncés, même si physiquement c'est le cas.

Code:

label tick

2d_rectangle 100,10,300,400
2d_line 100,180,300,180
2d_line 200,10,200,180
2d_flood 150,100,255,255,255
2d_flood 250,100,255,255,255

timer 1 : timer_interval 1,100 : on_timer 1,tick

end

tick:
  timer_off 1
  if mouse_left_down(0)=1
    2d_flood 150,100,255,0,0
  else
    2d_flood 150,100,255,255,255
  end_if
  if mouse_right_down(0)=1
    2d_flood 250,100,255,0,0
  else
    2d_flood 250,100,255,255,255
  end_if
  timer_on 1
  return

J'aimerais que ce comportement soit corrigé. Il est facile de savoir s'il y a eu un clic droit ou gauche, par les évènements on_click. Mais ce que je veux savoir, à n'importe quel moment, c'est l'état enfoncé ou non des boutons, indépendemment de tout clic. C'est ce que le nom de la fonction ainsi que l'entête de l'aide laisse entendre.