Fais_moi un diaporama

dim x
picture 1
border_hide 0
top 0, 50
left 0, 20
width 0, 594
height 0, 400
width 1, 600
height 1, 400

stretch_on 1
for x=1 to 1000
  '
  file_load 1, "chemin d'acces du JPG"

  if key_down_code =27 then terminate
    wait 800
    file_load 1, "chemin d'acces du JPG"
    wait 800
    next x

    stop

LABEL Listphot
DIM f$, rep$, srep$

DLIST 10
OPEN_DIALOG 100

GOSUB Listphot
print str$(count(10)): ' nombre d'images trouvées
END

Listphot:
f$ = FILE_NAME$(100)
IF LEN(f$) < 4 THEN RETURN: ' pas de répertoire choisi
rep$ = FILE_EXTRACT_PATH$(f$): ' extraction du nom du répertoire
srep$ = DIR_CURRENT$: ' sauvegarde du répertoire courant
DIR_CHANGE rep$: ' on se positionne dans le répertoire choisi
f$ = FILE_FIND_FIRST$
WHILE f$ <> "_"
    IF UPPER$(RIGHT$(f$,3)) = "JPG" THEN ITEM_ADD 10, f$
    f$ = FILE_FIND_NEXT$
END_WHILE
FILE_FIND_CLOSE
DIR_CHANGE srep$: ' restore du répertoire courant
RETURN

' récupération de tout les noms des photos (f$) du répertoire (rep$)
' pour les stocker dans le LIST ou DLIST n°10, pour pouvoir les travailler par la suite
' PAR JL35 (Supplément de commentaires: JEAN CLAUDE)

LABEL Listphot
DIM f$:' pour désigner le nom d'une image
dim rep$:' pour répertoire
dim srep$:' pour sauvegarde du répertoire courant

LIST 10:' mettre un DLIST à place (LIST non visible)

OPEN_DIALOG 100:' déclaration de l'obet OPEN_DIALOG, qui permet de visualiser une
                ' fenêtre pour choisir le répertoire (dossier) qui contient les photos

GOSUB Listphot:' execute la section de programme (label: Lisphot) jusqu'au RETURN

print str$(count(10)): ' nombre d'images trouvées

END
' ==============================================================================
Listphot:
f$ = FILE_NAME$(100):' le nom du répertoire choisi par l'utilisateur est stocké dans f$
IF LEN(f$) < 4 THEN RETURN: ' pas de répertoire choisi donc on attend (return)

rep$ = FILE_EXTRACT_PATH$(f$): ' extraction du nom du répertoire
caption 0, rep$:' cette ligne te permet de voir rep$ dans le bandeau de la fenêtre (à supprimer si nécessaire)

srep$ = DIR_CURRENT$: ' sauvegarde du répertoire courant
' (permet de de retrouver dans le même répertoire au prochain lancement du programme)

DIR_CHANGE rep$: ' on se positionne dans le répertoire choisi  pour extraire les photos

f$ = FILE_FIND_FIRST$:' permet de trouver la première image du répertoire f$

  WHILE f$ <> "_":' tant que f$ trouve une image execute le code jusqu'a END_WHILE
'                (tant que la condition f$<> "_" est vrai)

    IF UPPER$(RIGHT$(f$,3)) = "JPG" THEN ITEM_ADD 10, f$
        ' si les 3 derniers caractères de f$, (en majuscules: UPPER$)
        ' sont "JPG" alors on insere f$ (le nom de l'image) dans le DLIST 10.
       
f$ = FILE_FIND_NEXT$:' permet de continuer la recherche des photos
                    ' qui suivent la précédente trouvée

  END_WHILE: ' fin de la boucle WHILE
            ' (si la condition f$<> "_" n'est plus vrai on sort de la boucle)
           
FILE_FIND_CLOSE:' termine l'action de rcherche des photos
                ' (vu que la condition WHILE n'est plus vrai)

DIR_CHANGE srep$: ' restore du répertoire courant

RETURN

' ========================
' Maintenant les noms des photos du dossier choisi sont dans le DLIST 10

' Recherche des dimensions en pixels (largeur et hauteur) d'une image aux
' formats Jpg, Bmp, Gif ou Tga
DIM f$, w%, h%

f$ = "C:\GRAPH\JPG\Joconde.jpg": ' exemple d'utilisation

Dimima(f$, w%, h%): ' -> dimensions dans w% et h% (erreur si w% < 0)

END

SUB Dimima(f$, wi%, hi%)
DIM_LOCAL dim_s$, dim_sz%, dim_v%(3000), dim_ad%, dim_offs%, dim_posit%
IF LABEL("reter") = 0 THEN LABEL reter
IF LABEL("retel") = 0 THEN LABEL retel
dim_s$ = UPPER$(RIGHT$(f$, 4)): w% = -1
IF FILE_EXISTS(f$) = 0 THEN GOTO retel: ' EXIT_SUB
FILEBIN_OPEN_READ 9, f$: dim_sz% = FILEBIN_SIZE(9)
FILEBIN_BLOCK_READ 9,26,dim_v%(0)
IF dim_s$ = ".JPG"
    IF dim_v%(0) <> 255 OR dim_v%(1) <> 216 THEN w% = -2: GOTO reter: ' EXIT_SUB
    dim_ad% = 0: dim_offs% = 0
    REPEAT
        REPEAT
            dim_posit% = dim_ad% + 2 + dim_offs%
            IF dim_posit% >= dim_sz% THEN w% = -3: GOTO reter: ' EXIT_SUB
            FILEBIN_POSITION 9, dim_posit%: FILEBIN_BLOCK_READ 9,4,dim_v%(0)
            IF dim_v%(0) <> 255 THEN w% = -4: GOTO reter: ' EXIT_SUB
            dim_offs% = 256*dim_v%(2) + dim_v%(3)
            dim_ad% = FILEBIN_POS(9) - 4
        UNTIL (dim_v%(1) >= 192 AND dim_v%(1) <= 195): ' # FFC0 à FFC3
        FILEBIN_BLOCK_READ 9,5,dim_v%(0)
    UNTIL dim_v%(0) = 8
    h% = 256*dim_v%(1) + dim_v%(2): w% = 256*dim_v%(3) + dim_v%(4)
ELSE
    IF dim_s$ = ".BMP"
        w% = dim_v%(18)+256*dim_v%(19)+256*256*dim_v%(20)+256*256*256*dim_v%(21)
        h% = dim_v%(22)+256*dim_v%(23)+256*256*dim_v%(24)+256*256*256*dim_v%(25)
    ELSE
        IF dim_s$ = ".GIF"
            w% = dim_v%(6) + 256*dim_v%(7): h% = dim_v%(8) + 256*dim_v%(9)
        ELSE
            IF dim_s$ = ".TGA"
                w% = dim_v%(12)+256*dim_v%(13): h% = dim_v%(14)+256*dim_v%(15)
            END_IF
        END_IF
    END_IF
END_IF
reter:
FILEBIN_CLOSE 9
retel:
END_SUB

PRINT  "Largeur = "; w%; "  Hauteur =  "; h%

' Recherche des dimensions en pixels (largeur et hauteur) d'une image aux
' formats Jpg, Bmp, Gif ou Tga. Si Exifs (Jpg), date/heure de prise de vue.
DIM f$, w%, h%, dtpv$

f$ = "C:\Photos\...\DSCF1192.jpg": ' à voir

Dimima(f$, w%, h%, dtpv$): ' -> dimensions et date/heure dans w%, h% et dtpv$
print f$ + " " + str$(w%) + "x" + str$(h%) + " - " + dtpv$: ' pour papydall

END
' ==============================================================================
SUB Dimima(f$, wi%, hi%, datpv$)
DIM_LOCAL dim_s$, dim_sz%, dim_v%(3000), dim_ad%, dim_of%, dim_po%, dim_ex%
dim_s$ = UPPER$(FILE_EXTRACT_EXTENSION$(f$)): w% = -1
IF FILE_EXISTS(f$) = 0 THEN EXIT_SUB
FILEBIN_OPEN_READ 9, f$: dim_sz% = FILEBIN_SIZE(9)
FILEBIN_BLOCK_READ 9,100,dim_v%(0)
IF dim_s$ = ".JPG"
    IF dim_v%(0)<>255 OR dim_v%(1)<>216 THEN FILEBIN_CLOSE 9: w% = -2: EXIT_SUB
    dim_ex% = 0
    FOR dim_of% = 4 TO 100
        IF dim_v%(dim_of%)=73 AND dim_v%(dim_of%+1)=73: ' &4949
            IF dim_v%(dim_of%+2)=42 AND dim_v%(dim_of%+3)=0: ' &2A00
                dim_ex% = dim_of%: EXIT_FOR: ' Tiff header (Exif) trouvé
            END_IF
        END_IF
    NEXT dim_of%
    dim_ad% = 0: dim_of% = 0
    REPEAT
        REPEAT
            dim_po% = dim_ad% + 2 + dim_of%
            IF dim_po% >= dim_sz% THEN FILEBIN_CLOSE 9: w% = -3: EXIT_SUB
            FILEBIN_POSITION 9, dim_po%: FILEBIN_BLOCK_READ 9,4,dim_v%(0)
            IF dim_v%(0) <> 255 THEN FILEBIN_CLOSE 9: w% = -4: EXIT_SUB
            dim_of% = 256*dim_v%(2) + dim_v%(3)
            dim_ad% = FILEBIN_POS(9) - 4
        UNTIL (dim_v%(1) >= 192 AND dim_v%(1) <= 195): ' # FFC0 à FFC3
        FILEBIN_BLOCK_READ 9,5,dim_v%(0)
    UNTIL dim_v%(0) = 8
    h% = 256*dim_v%(1) + dim_v%(2): w% = 256*dim_v%(3) + dim_v%(4)
    dtpv$ = ""
    IF dim_ex% > 0: ' infos Exif: date/heure de prise de vue
        FILEBIN_POSITION 9, 0: FILEBIN_BLOCK_READ 9,1000,dim_v%(0)
        FOR dim_of% = dim_ex% TO 1000
            IF dim_v%(dim_of%)=50 AND dim_v%(dim_of%+1)=1: ' &3201
                dim_of% = dim_ex%+dim_v%(dim_of%+8)+256*dim_v%(dim_of%+9): ' offset date/heure
                FOR dim_po% = dim_of% TO dim_of%+18: ' 19 octets
                    dtpv$ = dtpv$ + CHR$(dim_v%(dim_po%))
                NEXT dim_po%
                EXIT_FOR: ' trouvé
            END_IF
        NEXT dim_of%
    END_IF
ELSE
    IF dim_s$ = ".BMP"
        w% = dim_v%(18)+256*dim_v%(19)+256*256*dim_v%(20)+256*256*256*dim_v%(21)
        h% = dim_v%(22)+256*dim_v%(23)+256*256*dim_v%(24)+256*256*256*dim_v%(25)
    ELSE
        IF dim_s$ = ".GIF"
            w% = dim_v%(6) + 256*dim_v%(7): h% = dim_v%(8) + 256*dim_v%(9)
        ELSE
            IF dim_s$ = ".TGA"
                w% = dim_v%(12)+256*dim_v%(13): h% = dim_v%(14)+256*dim_v%(15)
            END_IF
        END_IF
    END_IF
END_IF
FILEBIN_CLOSE 9
END_SUB
' ==============================================================================