Coordination / Avancement / Demande de travail et IRC

Joli Minifly Smile

Bon, moi je n'avance pas aussi vite que je voudrais, pas facile avec les 3 enfants, le gouter, la télé et les calins ... Bon là leur maman les emmène au bain, quelques minutes pour avancer avant d'aller aider ... Smile

Mais bon j'ai pu commencer avant de continuer ce soir.
Félicitation aussi pour le site mis à jour par jpcr et le storyboard que vous avez fait, on a de quoi faire maintenant.

Version mise à jour suite à correctif Panoramic

Code:: Label Ligne_suivante
Label Sub_dessine_map
Label Key_down
Label Fin

Dim FEN_Tileset :' Fenêtre où seront chargés les tiles
Dim X_max, Y_Max :' X_max et Y_Max: Largeur et Hauteur Max de la fenêtre principale
Dim Chemin$ :' Chemin d'origine du prog - normalement ne sert pas mais évite les
:' problème quand on travaille sur plusieurs programmes en même temps
:' qui se trouvent dans différents répertoire
Dim L_Tile, H_Tile :' Largeur et hauteur d'un Tile
Dim Nb_Tiles_ligne :' Nb de Tiles sur une ligne du TileSet
Dim L_Picture, H_Picture : ' Lageur et Hauteur du TileSet
Dim Nb_Tiles :' Nb de Tiles utilisés (Nb de Tiles du TileSet)
Dim N_IMG_TileSet :' Numéro de l'objet qui servira à stocker le TileSet
Dim N_IMG_Tile :' Numéro de l'objet qui servira à stocker le Tile en cours
Dim N_Map :' Numéro de l'objet qui servira à stocker la carte affichée
:' picture avec un tile en plus à gauche, en haut, à droite et en bas
Dim CPT_OBJ :' Le compteur pour les objet (puremment pour se faciliter la vie)
Dim F_Def_Tiles :' Numéro du fichier de Définition des tile
Dim F_Def_Map :' Numéro du fichier de Définition de la carte
Dim L_map, H_map :' Largeur et Hauteur de la carte affichée en tiles
Dim Nb_Tile_L_map, Nb_Tile_H_map :' Nb de Tiles totale en Largeur et en hauteur de la carte
Dim Ligne, Colonne :' Ligne et Colonne de travail pour la carte affichée
Dim Hero_X, Hero_Y :' Position du Héro dans la carte générale
Dim I,J,K,L :' Compteurs
Dim Chaine$,Temp$ :' Variables pour la lecteure des fichiers
Dim I_max_L, I_max_H :' Dimension max autorisée de la carte
Dim Tile, X_Tile, Y_Tile :' N° du tile à afficher et coordonnées
Dim Timer_Clavier : ' Ben là quand même avec le titre, vous pouvez deviner ...
Dim Redessine_carte : ' Redessine la carte si deplacement
Dim Sprite_hero : ' Numero du sprite du Héro
Dim Sprite$,X,Y : ' Nom du sprite à charger et coordonnées du héro sur la carte

' Nb de Tuiles utilisées
Nb_Tiles = 39 : ' 39 tuiles pour le moment dans le tileset
CPT_OBJ = 1 : ' Compteur d'objets
I_max_L = 50 : I_max_H = 50 : ' Limitation des cartes à 50 pour le moment
L_map = 21 : H_map = 17 : ' Affichage de 13 tiles de large et haut

Dim Tbl_tile_carte(I_max_L, I_max_H) :' N° du tiles a afficher (dim max de la carte 50 x 50)
Dim Tbl_franchissable_tile(Nb_Tiles) :' Selon le tile de la carte, franchissable ou non
Dim Tbl_comportement_tile(Nb_Tiles) :' Comportement commun au type de tile

Chemin$="C:\Users\laet\Documents\Panoramic\RPG\"

' Dim max fenêtre
X_max = 1000: Y_Max = 730
WIDTH 0, X_max: HEIGHT 0, Y_max
' HIDE 0

' Dimension d'une tuile (Tile)
L_Tile = 32 : H_Tile = 32

' Dim Image_TileSet
Nb_Tiles_ligne = 20

' Préparations de la carte avec des - 1 (valeur de fin)
FOR I = 1 TO I_max_L: FOR J = 1 TO I_max_H : Tbl_tile_carte(I,J)=-1 : NEXT J : NEXT I

L_Picture = Nb_Tiles_ligne * L_Tile
H_Picture = int(Nb_Tiles / Nb_Tiles_ligne)
IF MOD(Nb_Tiles,Nb_Tiles_ligne) > 0 Then H_Picture=H_Picture + 1
H_Picture = H_Picture * H_Tile

'
' Chargement du tileset et définition des valeurs liées
' -----------------------------------------------------------------------------------------
FEN_Tileset= CPT_OBJ : CPT_OBJ = CPT_OBJ + 1
FORM FEN_Tileset
TOP FEN_Tileset, 0
LEFT FEN_Tileset, 0
WIDTH FEN_Tileset, L_Picture + 2* L_Picture
HEIGHT FEN_Tileset, H_Picture + 2* H_Picture

N_IMG_TileSet = CPT_OBJ : CPT_OBJ = CPT_OBJ + 1
PICTURE N_IMG_TileSet
PARENT N_IMG_TileSet,FEN_Tileset
TOP N_IMG_TileSet, 0
LEFT N_IMG_TileSet, 0
WIDTH N_IMG_TileSet, L_Picture
HEIGHT N_IMG_TileSet, H_Picture
FILE_LOAD N_IMG_TileSet,chemin$+"TileSet.bmp"

HIDE FEN_Tileset

' -----------------------------------------------------------------------------------------
' Creation de l'objet servant à copier le tile

N_IMG_Tile = CPT_OBJ : CPT_OBJ = CPT_OBJ + 1
IMAGE N_IMG_Tile

Hero_X = 5 : Hero_Y = 5 : ' On fait partir le héro au hazard de la case 5,5
'
' ---------------------------------------------------------------------------------------------
' Chargement des propriétés des Tiles
' --------------------------------------------------------------------------------------------
F_Def_Tiles = CPT_OBJ : CPT_OBJ = CPT_OBJ + 1
FILE_OPEN_READ F_Def_Tiles, Chemin$+"Def_Tiles"
FILE_READLN F_Def_Tiles,Chaine$: ' On passe les 2 lignes de commentaire
FILE_READLN F_Def_Tiles,Chaine$

I=0 : ' Compeur pour vérifier que tous les tiles ont bien été définis
WHILE FILE_EOF(F_Def_Tiles) <> 1

' Lecture et traitement de la ligne correspondant à un Tile
FILE_READLN F_Def_Tiles,Chaine$
' On retire les blancs si il y en a
Chaine$=trim$(Chaine$)

' Récupération du premier caractère
Temp$=Left$(Chaine$,1)
' Si c'est une ligne blanche ou un commentaire on passe à la ligne suivante
IF (Temp$="" or Temp$="'") THEN GOTO ligne_suivante

I=I+1 :' On est sur une ligne de définition de tile
J = INSTR(Chaine$,";") : ' On lit le numéro du tile et on vérifie sa cohérence
IF J > 0
Temp$=LEFT$(Chaine$, (J - 1))
Chaine$=RIGHT$(Chaine$, LEN (Chaine$) - J)
K=Val(Temp$)
IF K < I or K > I
Message "Valeur inatendue pour le Tile n°" + STR$(i) + CHR$(10) + CHR$(13) + "La valeur lue était : " + Temp$
Goto ligne_suivante
END_IF
ELSE
Message "Ligne invalide pour le" + CHR$(10) + CHR$(13) + "Tile n°"+STR$(i)
' Eventuellement créer un fichier de log des erreurs
Goto ligne_suivante
END_IF
J = INSTR(Chaine$,";")
Chaine$=RIGHT$(Chaine$, LEN (Chaine$) - J) : ' On n'utilise pas le nom du tile
J = INSTR(Chaine$,";")
Temp$=LEFT$(Chaine$, (J - 1)) : ' On lit si le tiles est franchissable ou non
Chaine$=RIGHT$(Chaine$, LEN (Chaine$) - J)
IF Temp$ = "Oui"
Tbl_franchissable_tile(I) = 1
ELSE
IF Temp$ = "Non"
Tbl_franchissable_tile(I) = 0
ELSE
Message "Valeur inatendue pour le Tile n°" + STR$(i) + CHR$(10) + CHR$(13) + "La valeur lue était : " + Temp$
Goto ligne_suivante
END_IF
END_IF
J = INSTR(Chaine$,";")
Temp$=LEFT$(Chaine$, (J - 1)) : ' On lit le comportement du tile
Chaine$=RIGHT$(Chaine$, LEN (Chaine$) - J)
Tbl_comportement_tile(I) = Val(Temp$)

' On ne traite pas la dernière partie (Commentaire) pour afficher la carte

ligne_suivante:
END_WHILE
IF I < Nb_Tiles THEN Message "Attention, le seulement " + STR$(i) + " tiles traités sur " + + STR$(Nb_Tiles) + " attendus"
FILE_CLOSE F_Def_Tiles

'
' -------------------------------------------------------------------------------------------
' Chargement de la carte
' -------------------------------------------------------------------------------------------
F_Def_Map = CPT_OBJ : CPT_OBJ = CPT_OBJ + 1
FILE_OPEN_READ F_Def_Map, Chemin$+"Carte.txt"
FILE_READLN F_Def_Map,Chaine$: ' On passe les 3 lignes de commentaire
FILE_READLN F_Def_Map,Chaine$
FILE_READLN F_Def_Map,Chaine$
FILE_READLN F_Def_Map,Chaine$

Chaine$=trim$(Chaine$)

J = INSTR(Chaine$,";")
Temp$=LEFT$(Chaine$, (J - 1)) : ' On lit si le tiles est franchissable ou non
Chaine$=RIGHT$(Chaine$, LEN (Chaine$) - J)

Nb_Tile_L_map = Val( Temp$ )
Nb_Tile_H_map = Val( Chaine$ )

FOR I = 1 TO Nb_Tile_H_map
' Lecture et traitement de la ligne correspondant à un Tile
FILE_READLN F_Def_MAP,Chaine$
' On retire les blancs si il y en a
Chaine$=trim$(Chaine$)
J = INSTR(Chaine$,";") : ' On lit le numéro de la ligne et on vérifie sa cohérence
Temp$=LEFT$(Chaine$, (J - 1))
' Message "Lut sur ligne " + STR$(I) + ":" + Chaine$
Chaine$=RIGHT$(Chaine$, LEN (Chaine$) - J)
IF VAL(Temp$) <> I
Message "Problème sur le fichier carte pour la ligne " + STR$(I) + CHR$(10) + CHR$(13) + "La valeur lue est : " + Temp$
GOTO FIN
END_IF
FOR K = 1 TO Nb_Tile_L_map - 1
J = INSTR(Chaine$,";") : ' On lit le numéro du tile de la case
Temp$=LEFT$(Chaine$, (J - 1))
Chaine$=RIGHT$(Chaine$, LEN (Chaine$) - J)
Tbl_tile_carte(K, I) = val(Temp$)
NEXT K
Tbl_tile_carte(K, I) = val(Chaine$)
NEXT I
FILE_CLOSE F_Def_Map

N_MAP = CPT_OBJ : CPT_OBJ = CPT_OBJ + 1
PICTURE N_MAP
TOP N_MAP, 0
LEFT N_MAP, 0
WIDTH N_MAP, L_map * L_Tile
HEIGHT N_MAP, H_map * H_Tile

Sprite_Hero = CPT_OBJ : CPT_OBJ = CPT_OBJ + 1
IMAGE Sprite_Hero : Sprite$= "front"
GOSUB Sub_dessine_map

Timer_Clavier = CPT_OBJ : CPT_OBJ = CPT_OBJ + 1
TIMER Timer_Clavier: timer_interval Timer_Clavier,30 : On_timer Timer_Clavier, Key_down
END

' Dessiner la carte

Sub_dessine_map:
I = Hero_X - int(0.5 * L_MAP) - 1
IF I + L_Map => Nb_Tile_L_map THEN I = Nb_Tile_L_map - L_MAP -1
IF I < 0 THEN I = 0

J = Hero_Y - int(0.5 * H_MAP) -1
IF J + H_Map > Nb_Tile_H_map THEN J = Nb_Tile_H_map - H_MAP
IF J < 0 THEN J = 0

FOR K = 1 TO H_MAP
FOR L = 1 TO L_MAP
' Message "I : " + str$(i) + " L: " + str$(L) + " J: "+ str$(J) + " K: " + str$(K)
Tile = Tbl_tile_carte(I+L,J+K)
Y_Tile = int(Tile / Nb_Tiles_ligne)
X_Tile = (Tile - (Y_Tile * Nb_Tiles_ligne) -1) * L_Tile
Y_Tile = Y_Tile * H_Tile
' Message "Tile = " + STR$(Tile) + " : I = " + STR$(I) + " : J = " + STR$(J) + " : X_Tile = " + STR$(X_Tile) + " : Y_Tile = " + STR$(Y_Tile)
2D_TARGET_IS N_IMG_TileSet
2D_IMAGE_COPY N_IMG_Tile,X_Tile,Y_Tile,X_Tile + L_Tile, Y_Tile + H_Tile
2D_TARGET_IS 0
2D_IMAGE_PASTE N_IMG_Tile, (L-1) * L_Tile, (K-1) * H_Tile
NEXT L
NEXT K
FILE_LOAD Sprite_Hero, chemin$ + "Tiles_bmp\hero_"+Sprite$+".bmp"
IF Hero_X < (0.5 * L_MAP)
X = Hero_X - 1
ELSE
IF Hero_X > Nb_Tile_L_map - (0.5 * L_MAP)
X = Hero_X - (Nb_Tile_L_map - L_MAP) -1
IF L_MAP > Nb_Tile_L_map then X=X - (L_MAP - Nb_Tile_L_map)
ELSE
X = int (0.5 * L_MAP)
END_IF
END_IF
IF Hero_Y <(0.5 * H_MAP)
Y = Hero_Y - 1
ELSE
IF Hero_Y > Nb_Tile_H_map - (0.5 * H_MAP)
Y = Hero_Y - (Nb_Tile_H_map - H_MAP) -1
IF H_MAP > Nb_Tile_H_map then Y=Y - (H_MAP - Nb_Tile_H_map)
ELSE
Y = int(0.5 * H_MAP)
END_IF
END_IF

2D_IMAGE_PASTE Sprite_Hero, X * L_Tile, Y * H_Tile

RETURN

' Gérer le déplacement

key_down:

Redessine_carte = 0 : Sprite$ = ""

' Flèche gauche
if scancode=37
if Hero_X > 1 and Tbl_franchissable_tile(Tbl_tile_carte(Hero_X-1,Hero_Y)) = 1 Then Hero_X = Hero_X - 1 : Redessine_carte = 1 : Sprite$="left"
end_if

' Flèche droite
if scancode=39
if Hero_X < Nb_Tile_L_map and Tbl_franchissable_tile(Tbl_tile_carte(Hero_X+1,Hero_Y)) = 1 Then Hero_X = Hero_X + 1 : Redessine_carte = 1: Sprite$="right"
end_if

' Flèche haut
if scancode=38
if Hero_Y > 1 and Tbl_franchissable_tile(Tbl_tile_carte(Hero_X,Hero_Y-1)) = 1 Then Hero_Y = Hero_Y - 1 : Redessine_carte = 1: Sprite$="back"
end_if

' Flèche bas
if scancode=40
if Hero_Y < Nb_Tile_H_map and Tbl_franchissable_tile(Tbl_tile_carte(Hero_X,Hero_Y+1)) = 1 Then Hero_Y = Hero_Y + 1 : Redessine_carte = 1 : Sprite$="front"
end_if

' Touche Echap pour Quitter
if scancode=27 then goto fin

If Redessine_carte = 1 Then GOSUB Sub_dessine_map

return

' ******************* Fin gestion déplacement du personnage *******************

FIN:
Terminate

Sujet: Prop: Système économique de notre jeu Mar 20 Sep 2011, 20:54

Proposition économique pour notre monde

La richesse et l’argent
La monnaie
Les aventuriers ont surtout recours à la pièce d’or (po). Une pièce d’or vaut 10 pièces d’argent. Chaque pièce d’argent vaut 10 pièces de cuivre (pc). Une pièce de platine (pp) vaut 10 po.
Une pièce pèse environ 10 grammes et une centaine de pièces pèse un kilo.

Table : les différents types de pièces

Valeur d’échange

PC PA PO PP
Pièce de cuivre (pc) = 1 1/10 1/100 1/1 000
Pièce d’argent (pa) = 10 1 1/10 1/100
Pièce d’or (po) = 100 10 1 1/10
Pièce de platine (pp) = 1 000 100 10 1

Richesses non monétaires
Bien souvent, la richesse des gens ne se calcule pas en pièces. Le prix de certains produits de consommation courante est détaillé ci-dessous.

Table : produits de consommation courante
Prix Article
1 pc Une livre (500 g) de blé
2 pc Une livre (500 g) de farine, ou un poulet
1 pa Une livre (500 g) de fer
5 pa Une livre (500 g) de tabac ou de cuivre
1 po Une livre (500 g) de cannelle, ou une chèvre
2 po Une livre (500 g) de gingembre ou de poivre, ou un mouton
3 po Un cochon
4 po Un mètre carré de lin
5 po Une livre (500 g) d’argent ou de sel
10 po Un mètre carré de soie ou une vache
15 po Une livre (500 g) de safran ou de clous de girofle, ou un bœuf
50 po Une livre (500 g) d’or
500 po Une livre (500 g) de platine

1 po Épieu, Carreaux (10), Marteau léger, Matraque, Flèches (20)
2 po Gantelet, Dague, Lance
5 po Gantelet Clouté, Masse d’armes légère, Pique, Armure matelassée
6 po Serpe, Hachette
8 po Morgenstern, Hache de lancer, Fléau d’armes léger, Pic de guerre lourd
10 po Épée courte, Hache d’armes, Armure de cuir
12 po Masse d’armes lourde, Marteau de guerre
15 po Trident, Cimeterre, Épée longue, Armure de peau
20 po Rapière, Filet
25 po Armure de cuir cloutée
30 po Arc court
50 po Armure d’écailles
75 po Arc long
100 po Arbalète de poing, Chemise de mailles
150 po Cotte de mailles
600 po Armure à plaques

etc ...

ça me semble un peu excessif, tout les jeux auquel j'ai joué( et ça en fait des tonnes) n'ont qu'une seule pièce(po par exemple).

par contre, on proposer des prix a 1/2 po, 1/4 po.

qu'en penses tu?

jp

OK, je ne savais pas que l'on pouvaient diviser des pièces Smile

Par contre même si l'on a des prix en pièce de cuivre ou d'argent, l'or du héro peut n'être qu'un seul compteur, les autres pièces n'étant qu'une astuce pour ne pas afficher les virgules ...

Planning des taches et des IRC

Afin de simplifier la coordination de chacun, j'ouvre un nouveau poste pour les demande de rdv sur IRC et le suivi des tâches de chacun

Pour le moment, Minifly travaille sur l'éditeur de carte et je fais les tilesets

Nous avons discuté avec jpcr, je lui ais proposé que l'on ne fasse un IRC que quand nous aurons pu avancer et mettre en pratique la version corrigée de la copie d'image (dans le prochain instantanné de Jack).

En attendant, chacun peu proposer une rencontre sur l'IRC s'il veut voir un point particulier ou écrire sa question ici ou décrire ce sur quoi il travaille ou qu'il aimerait que quelqu'un prenne en charge.

Un petit programme outils pour extraire rapidement des tiles pour pouvoir les retravailler
et en dessous le programme inverse (les tiles sont dans un répertoire et sont sauvegardés dans un tileset)

Eclateur de bmp en tiles:

Code:: ' Déclaration des variables et constantes
DIM Chemin$, L_Tile, H_Tile, Nb_Tiles_ligne, L_Picture, H_Picture
DIM Nb_lignes, N_IMG_TileSet, N_IMG_Tile, CPT_OBJ, ligne, colonne, compt

Chemin$="C:\Users\laet\Documents\Panoramic\RPG\" : CPT_OBJ = 1

WIDTH 0, 1000: HEIGHT 0, 600

L_Tile = 32 : H_Tile = 32 : ' Dimension d'une Tile (longueur et hauteur)
Nb_Tiles_ligne = 16: Nb_lignes = 16 : ' Nb de tiles sur une ligne de l'image et nombre de lignes de tiles
L_Picture=Nb_Tiles_ligne * L_Tile : ' Taille de l'image en longuer
H_Picture=Nb_lignes * H_Tile : ' Taille de l'image en hauteur

N_IMG_TileSet = CPT_OBJ : CPT_OBJ = CPT_OBJ + 1
PICTURE N_IMG_TileSet
TOP N_IMG_TileSet,0
LEFT N_IMG_TileSet,0
WIDTH N_IMG_TileSet, L_Picture
HEIGHT N_IMG_TileSet, H_Picture

N_IMG_Tile = CPT_OBJ : CPT_OBJ = CPT_OBJ + 1
IMAGE N_IMG_Tile

compt = 1

File_load N_IMG_TileSet,chemin$+"Image.bmp"
For ligne = 0 to (Nb_lignes - 1)
For colonne = 0 to (Nb_Tiles_ligne - 1)
2D_target_is N_IMG_TileSet
2D_IMAGE_COPY N_IMG_Tile,colonne * L_Tile, ligne * H_Tile, colonne * L_Tile + L_Tile, ligne * H_Tile + H_Tile
File_Save N_IMG_Tile, chemin$+"Tiles\" + right$("0000" + str$(compt),4)+".bmp"
compt = compt + 1
Next colonne
Next ligne

Regénérateur de TileSet depuis un répertoire:

Code:: ' Déclaration des variables et constantes
DIM Chemin$, L_Tile, H_Tile, Nb_Tiles_ligne, L_Picture, H_Picture, Dernier
DIM N_IMG_TileSet, N_IMG_Tile, CPT_OBJ, ligne, colonne, compt, nom$, test

Chemin$="C:\Users\laet\Documents\Panoramic\RPG\" : CPT_OBJ = 1

WIDTH 0, 1000: HEIGHT 0, 700

L_Tile = 32 : H_Tile = 32 : ' Dimension d'une Tile (longueur et hauteur)
Nb_Tiles_ligne = 20 : ' Nb de tiles sur une ligne de l'image et nombre de lignes de tiles
L_Picture=Nb_Tiles_ligne * L_Tile : ' Taille de l'image en longuer
H_Picture= 20 * H_Tile : ' Taille de l'image en hauteur
Dernier = 1028

N_IMG_TileSet = CPT_OBJ : CPT_OBJ = CPT_OBJ + 1
PICTURE N_IMG_TileSet
TOP N_IMG_TileSet,0
LEFT N_IMG_TileSet,0
WIDTH N_IMG_TileSet, L_Picture
HEIGHT N_IMG_TileSet, H_Picture

N_IMG_Tile = CPT_OBJ : CPT_OBJ = CPT_OBJ + 1
IMAGE N_IMG_Tile

ligne = 0 : colonne = 0
For compt = 1 to Dernier
nom$ = chemin$+"Tiles\"+ right$("0000" + str$(compt),4)+".bmp"
Test = File_exists (nom$)
IF Test = 1
File_load N_IMG_Tile,nom$
2D_Target_is N_IMG_TileSet
2D_IMAGE_PASTE N_IMG_Tile,colonne * L_Tile, ligne * H_Tile
colonne = colonne + 1
IF colonne = Nb_Tiles_ligne
colonne = 0
ligne = ligne + 1
END_IF
END_IF
Next compt
H_Picture= (ligne+1) * H_Tile : ' Redimensionne la taille de l'image en hauteur
HEIGHT N_IMG_TileSet, H_Picture
File_save N_IMG_TileSet, chemin$ + "NewTileSet.bmp"

Dernière édition par jpcr le Lun 26 Sep 2011, 08:25, édité 1 fois

dans ce cas(mettre des choses..) , on peut aussi utiliser un service de blog comme beaucoup font. Very Happy

par exemple : https://accounts.google.com/ServiceLogin?service=blogger&passive=1209600&continue=http://www.blogger.com/home&followup=http://www.blogger.com/home&ltmpl=start#s01

jp

Tout ce qui nous facilite la vie jpcr est autorisée Smile

On compte sur notre rédacteur préféré ? Smile

MiniFly, tu en es où suréditeur de cartes ?
Quelqu'un veut essayer de travailler sur le principe des combats ? (Voir proposer un source qui montrerait ce que ça donne ?)

combat ? pourquoi pas un truc comme ça : http://www.emuparadise.me/reviews/bof/bof5.jpg

il faut décider de quoi le combat aura l'air avant de se lancer dans la programmation , je pense.

Exactement Jpcr, c'est tout à fait ce que j'ai voulu dire par travailler sur le principe des combats.
Après, il y a plusieurs moyens de proposer la solution (capture d'écran, texte, petit bout de programme pour illustrer, référence à d'autre jeux (mais faisbable quand même Smile

)
PS: Au boulot, je ne peux pas regarder la capture que tu as mis en lien, mais je regarde ça ce soir.

Tiens à votre avis, le personnage reste seul tout le long de l'histoire ou après il forme une petite équipe ?
(et dans ce cas, 2, 3, 4, 5 ou 6 persos ? (après ça deviendrait dur à gérer) )

Dernière édition par 659_minifly le Jeu 29 Sep 2011, 21:05, édité 1 fois

Bonsoir

je viens pour vous expliquer mon état d'avancement avec l'éditeur de Map.

Choix d'un répertoire (pour charger tous les sprites d'un répertoire ) Résolu.

Car pour l'instant avec Panoramic on ne récupère pas le nom du répertoire lorsque on utilise la boite de fichier.

Connaitre les dimensions d'un Tileset ( ~~Presque tout résolu sauf pour les fichiers au format PNG~~ j'utilise un programme de
JL35).

Traduction des fichiers autres que bmp j'utilise Irfanview un programme extérieur pour faire la traduction. Ce programme est mise en route directement a partir de Panoramic donc invisible pour l'utilisateur.
Vous pouvez le télécharger ici :

http://www.irfanview.com/

en plus il est gratuit et en français.

Invité

Excusez moi, je vois qu'il y a un problème pour récupérer le répertoire.
J'ai fait ce programme l'année dernière. J'ai modifié un peu car il est fait pour fonctionner comme include, et je me souvient plus tout à fait comment ça marche, et je suis encore sur mon programme de courrier.

Avec cette boite, je récupère le répertoire. Peut-être que c'est plus simple d'attendre la sortie de celles-ci.

Code:: rem montre une boite de dialogue servant à définir les dossiers, appelé comme #INCLUDE
rem les numéros sont définis par le programe appelant et transmis par la variable "a"
if variable("a")=0 then dim a:a=1 :' seulement pour la mise au point, vu que a est définit ailleurs
if variable("OBJ_")=0 then dim OBJ_
if variable("DIR_a%")=0 then dim DIR_a%
if variable("DIR_a$")=0 then dim DIR_a$
if variable("DIR_f$")=0 then dim DIR_f$
if variable("DIR_test%")=0 then dim DIR_test%
if variable("DIR_dossier$")=0 then dim DIR_dossier$
if variable("OBJ_DIR")=0 then dim OBJ_DIR
if variable("DIR_fichier$")=0 then dim DIR_FICHIER$
if variable("ini_DIR%")=0 then dim ini_dir%
rem passage de paramètres depuis le programme appelant
OBJ_=a : ' ainsi il n'est pas nécessaire de reprendre le programme, transmis par le programme appelant
DIR_Fichier$=dir_current$
OBJ_DIR=OBJ_
form OBJ_DIR :command_target_is OBJ_DIR
width OBJ_DIR,455:border_small OBJ_DIR:color OBJ_DIR,180,180,170:top OBJ_DIR,010:left OBJ_DIR,560 :height OBJ_DIR,560
dir_change "C:\"

label DIR_dossier ,DIR_disque , DIR_choix ,DIR_impose ,DIR_retour ,DIR_exit,DIR_ferme,DIR_sorti,ini_DIR
on_close OBJ_DIR,DIR_ferme
OBJ_DIR=OBJ_+1 :' 16
alpha OBJ_DIR:top OBJ_DIR, 5:left OBJ_DIR,100:font_bold OBJ_DIR:font_size OBJ_DIR,10:' font_color OBJ_DIR,204,204,153
caption OBJ_DIR,"choisir le dossier d'installation"

OBJ_DIR=OBJ_+2 :' 15
edit OBJ_DIR:top OBJ_DIR,35:left OBJ_DIR,5:width OBJ_DIR,435:font_size OBJ_DIR,12:font_bold OBJ_DIR:color OBJ_DIR,255,255,153
OBJ_DIR=OBJ_+3 :' 19
alpha OBJ_DIR:top OBJ_DIR,65:left OBJ_DIR,80:font_color OBJ_DIR,255,255,255:font_bold OBJ_DIR:font_size OBJ_DIR,10:caption OBJ_DIR,"dossier"
OBJ_DIR=OBJ_+4 :' 10
list OBJ_DIR: top OBJ_DIR,85:left OBJ_DIR,5:width OBJ_DIR,230:height OBJ_DIR,390:font_size OBJ_DIR,12:font_bold OBJ_DIR:color OBJ_DIR,255,255,204:on_click OBJ_DIR,DIR_choix
OBJ_DIR=OBJ_+5 :' 11
list OBJ_DIR: top OBJ_DIR,85:width OBJ_DIR,200:left OBJ_DIR,240:height OBJ_DIR,305:font_color OBJ_DIR,160,160,160
OBJ_DIR=OBJ_+6 :' 13
alpha OBJ_DIR:top OBJ_DIR,397:left OBJ_DIR,245:font_color OBJ_DIR,255,255,255:font_bold OBJ_DIR:font_size OBJ_DIR,10:caption OBJ_DIR,"Lecteur:"
OBJ_DIR=OBJ_+7 :' 14
list OBJ_DIR:top OBJ_DIR,415:left OBJ_DIR,245:height OBJ_DIR,60:width OBJ_DIR,50:font_size OBJ_DIR,12:color OBJ_DIR,255,255,210 :on_click OBJ_DIR,DIR_disque

OBJ_DIR=OBJ_+8 :' 18
edit OBJ_DIR:top OBJ_DIR,490:left OBJ_DIR,170:width OBJ_DIR,270:font_size OBJ_DIR,12:font_bold OBJ_DIR:color OBJ_DIR,255,255,153:on_change OBJ_DIR,DIR_impose

OBJ_DIR=OBJ_+9 :' 20
button OBJ_DIR:top OBJ_DIR,410:left OBJ_DIR,330:caption OBJ_DIR,"accepter" :on_click OBJ_DIR,DIR_retour
OBJ_DIR=OBJ_+10 :' 21
button OBJ_DIR:top OBJ_DIR,450:left OBJ_DIR,330:caption OBJ_DIR,"sortir" :on_click OBJ_DIR,DIR_exit

OBJ_DIR=OBJ_+11 :' 17
alpha OBJ_DIR:top OBJ_DIR,500:left OBJ_DIR,5:font_color OBJ_DIR,255,255,255:font_bold OBJ_DIR:font_size OBJ_DIR,10:caption OBJ_DIR,"créé nouveau dossier :"

OBJ_DIR=OBJ_ :command_target_is 0
gosub ini_dir
' goto DIR_sorti :' pour include
end
' ==============================================

ini_DIR:
if ini_dir%=0
for DIR_a%=asc("C") to asc("F")
DIR_a$= chr$(DIR_a%)+":" : if dir_exists(DIR_a$)=1 then item_add OBJ_+7,DIR_a$
next DIR_a%
ini_dir%=1
end_if
return

DIR_dossier:
gosub ini_dir
clear OBJ_+4:clear OBJ_+5
item_add OBJ_+4,".."
DIR_a$ = file_find_first$
while DIR_a$<>"_"
DIR_test%=File_Exists(DIR_a$)
if DIR_test%=0
item_add OBJ_+4,DIR_a$
else
item_add OBJ_+5,DIR_a$
end_if
DIR_a$ = file_find_next$
end_while
file_find_close
return
DIR_disque:
gosub ini_dir
dir_change "C:\"
DIR_f$= item_index$(OBJ_+7):DIR_dossier$=DIR_f$
dir_change DIR_f$ : gosub DIR_dossier
return

DIR_choix:
gosub ini_dir
DIR_f$=item_index$(OBJ_+4)
dir_change DIR_f$
if item_index(OBJ_+4)>1
DIR_dossier$=DIR_dossier$+"\"+DIR_f$
else
for DIR_a%=len(DIR_dossier$) to 1 step -1
if mid$(DIR_dossier$,DIR_a%,1)="\" then exit_for
next DIR_a%
if DIR_a%>2 then DIR_dossier$=left$(DIR_dossier$,DIR_a%-1)
end_if
gosub DIR_dossier
gosub DIR_impose
return

DIR_impose:
if text$(OBJ_+8)<>"" then text OBJ_+2,DIR_dossier$+"\"+text$(OBJ_+8) :else:text OBJ_+2,DIR_dossier$
return

DIR_exit:
active 0:DIR_dossier$="_" :text OBJ_+2,"_"
DIR_f$=left$(DIR_f$,DIR_a%-1) :dir_change DIR_fichier$
return

DIR_retour:
clipboard_string_copy text$(OBJ_+2) :dir_change DIR_Fichier$
return

DIR_ferme:
terminate

DIR_sorti:
dir_change DIR_fichier$:return

Voyez ce que ça donne, et virez si ça ne plait pas.

Merci Cosmos mais j'ai déjà mon programme pour récupérer le nom du répertoire qui fonctionne.

voir :

https://panoramic.1fr1.net/t1695-dir-repertoires-et-fichiers

Nombre de messages : 69 Date d'inscription : 03/04/2011

Bonjour a tous

Bon la ça se bouscule, je n'est pas trop de temps en ce moment.
La livraison de la maison dans très peu de temps maintenant,
et il faut botter le cul de tout le monde pour que ça bouge.
Donc franchement désolé.
Je suis d'un oeil cependant les opérations.
J'ai peut être une solution pour la musique.
Mais nous n'en somme pas la.

je reste dispo vous avez mon mail.
@+

Nombre de messages : 69 Date d'inscription : 03/04/2011

http://crpgpsychopathy.wordpress.com/2011/03/27/whatisthisidonteven-dark-heart-of-uukrul/

Voila ce que j'ai trouver en cherchant un peu, vraiment sympa le truc!

@+

Quelques idées/questions en vrac :
Vous avez prévu:

- des armureries (pour réparer les armures),
- des centres de soins (blessures, maladies, mauvais sorts)?

Au niveau du bestiaire, quelqu'un a des idées ?
La définition des coups portés (hache, fleches,etc...)

Oui, mais c'est encore a développer pour le moment.

J'aimerait alterné le phase de jeu de rôle guidé (type livre dont vous êtes le héro) et les phases de leveling (en plus le bestiaire changerait) au début pauvre ère que tu es, tu dois subsister et gagner un peu d'argent pour t'équiper => lapin, biche puis quand tu as un certain niveau tu as une vision qui te dis d'aller te renseigner sur ton avenir en allant quelque part... Tu y vas => rencontre avec une voyante qui t'annonce une destiné particulière ... Tu t'entraine et tu deviens mercenaire (ça gagne mieux) => missions. Tu fais les missions / levelling => ... le reste est décrit sur le site de jpcr mais il t'enverra le code pour que tu puisse contribuer à faire progresser le jeu. Chacun participe sur le sujet qu'il veut et autant qu'il veut pour le moment. De temps en temps on fait un chat pour se synchroniser et discuter de certains points. Là pour le moment il y en a 2 qui bossent Minifly et jpcr (Editeur de carte et moteur de combat), moi, j'ai des trucs à faire (graphismes), j'ai avancé, mais il faut que je pofine (je voudrais tester avec l'éditeur de carte de minifly, mais il faut que j'ai le temps de le faire fonctionner).

Voilà Nardo Smile

Jack, pourrais-tu faire une sous-catégorie dans les jeux collaboratif du genre
Projet 1: un RPG
et nous mettre gestionnaire de ce répertoire pour que l'on puisse maintenir ce répertoire et l'organiser, archiver, déplacer, créer ... ?

Si c'est possible, merci par avance

Admin Nombre de messages : 2386 Date d'inscription : 28/05/2007

La catégorie "Projet 1: un RPG" a été créée,
et te voila modérateur des 2 catégories du forum "Projets en Commun":
- Idées générales sur des projets en commun
- Projet 1: un RPG

héhé , au boulot!!! Wink

J'espère que la réorganisation vous convient Smile

PS: C'est votre espace, si vous avez des suggestion, n'hésitez pas

oui c'est du super boulot Very Happy

merci a toi!!

Bien travaillé.
A+

Tiens j'ai vu 2 choses:
1/ je ne suis plus modérateur (bon pas grave, normalement, le plus gros de la réorganisation avit été fait, mais je voulais faire encore un peu de réorganisation et supprimer quelques messages qui n'étaient plus utiles)

2/ Il faudrait renommer le sujet, il s'appelle RGP au lieu de RPG, ce n'est pas très grave mais bon, ça serait mieux avec les lettres dans le bon sens Smile

» Un panoramicien en plein travail
» Compilateur : version de travail disponible
» compilateur version de travail 0.1 alpha 3
» compilateur version de travail 0.1 alpha 4
» exemple d'un programme déchargeant un travail sur un autre