MémoSite: pour avoir sous la main vos identifiants et ...

dim a$,b$,lien$,e1$,e2$,e3$,fi$,f,nbe,no,lig,nbb,pv$,n,lienp$
label new,new2,new3,new4,new5,new6,new7,new8,new9,new10,new11,init,go,aide
label modsup,md1,modif,sup,modlien,modlien2,modident,modident2,modident3
label modiMDP,modiMDP2,modiMDP3,modiel,modiel2,modiel3,modibuton,modibuton2
label modibuton3,fin,ferme_form,enregmodif
' ******************************************************************************
width 0,200:left 0,10:height 0,screen_y:caption 0,"Mémo Sites":on_close 0,fin
memo 100:height 100,80:width 100,140:top 100,20:left 100,20:color 100,250,250,0:font_color 100,0,0,255:font_size 100,10
button 101:height 101,15:width 101,15:top 101,50:left 101,170:caption 101,"+":font_bold 101:on_click 101,new
hint 101,"Enregistrement d'un nouveau site"
button 102:height 102,15:width 102,15:top 102,25:left 102,170:caption 102,"?":font_bold 102:on_click 102,aide
hint 102,"Aide"
button 103:height 103,15:width 103,15:top 103,75:left 103,170:caption 103,"M":font_bold 103:on_click 103,modsup
hint 103,"Modification ou Suppression d'un élément"
' ******************************************************************************
form 200:width 200,screen_x-100:top 200,50:left 200,50:height 200,390:caption 200,"Mémo Sites: Enregistrement":hide 200
command_target_is 200:on_close 200,ferme_form
alpha 201:top 201,10:left 201,10:caption 201,"Lien du site: collez ici le lien (EX:http://panoramic.1fr1.net/login)":font_name 201,fixedsys
edit 202:top 202,30:left 202,10:width 202,screen_x-130
hint 202,"Ouvrez votre navigateur internet à la page d'identification du Site à enregistrer."+chr$(13)+"Copiez le lien qui apparaît en haut de votre navigateur et collez-le ICI."
alpha 203:top 203,70:left 203,10:caption 203,"Identifiant d'accès au site:(EX:Tartempion01)":font_name 203,fixedsys
edit 204:top 204,90:left 204,10:width 204,200
hint 204,"Entrez votre identifiant"+chr$(13)+"Correspondant au Site (Sortie par Entrée)."
hide 203:hide 204
alpha 205:top 205,130:left 205,10:caption 205,"Mot de Passe d'accès au site:(EX:123456Z)":font_name 205,fixedsys
edit 206:top 206,150:left 206,10:width 206,200
hint 206,"Entrez votre Mot de Passe"+chr$(13)+"Correspondant au Site (Sortie par Entrée)."
hide 205:hide 206
alpha 207:top 207,190:left 207,10:caption 207,"Autre élément d'accès au site:(EX: Code Postal)":font_name 207,fixedsys
edit 208:top 208,210:left 208,10:width 208,200
hint 208,"Entrez l'élément supplémentaire"+chr$(13)+"Correspondant au Site (Sortie par Entrée)."
hide 207:hide 208
alpha 209:top 209,250:left 209,10:caption 209,"Nom du site:(EX: Panoramic)":font_name 209,fixedsys
edit 210:top 210,270:left 210,10:width 210,100
hint 210,"Entrez le Nom du Site"+chr$(13)+"qui apparaîtra sur le boutton (13 caractères maxi. Sortie par Entrée)."
hide 209:hide 210
button 211:top 211,310:width 211,160:left 211,(screen_x/2)-160:caption 211,"Valider et Quitter":font_name 211,fixedsys
hide 211
' ******************************************************************************
form 300:width 300,screen_x-220:top 300,50:left 300,215:height 300,390:caption 300,"Mémo Sites: Modification ou suppression d'un élément":hide 300
command_target_is 300:on_close 300,ferme_form
alpha 301:top 301,10:left 301,10:caption 301,"Cliquez dans la colone de gauche sur l'élément à modifier ou à supprimer":font_name 301,fixedsys
container_option 302:top 302,10:left 302,10:caption 302,"  Cochez votre option  ":width 302,125:height 302,70:hide 302
option 303:parent 303,302:top 303,20:left 303,10:caption 303," Mofification "
option 304:parent 304,302:top 304,40:left 304,10:caption 304," Suppression "
alpha 305:top 305,10:left 305,10:caption 305,"Lien du site: collez ici le lien (par coller uniquement)":font_name 305,fixedsys
edit 306:top 306,30:left 306,10:width 306,screen_x-280
button 307:height 307,15:width 307,15:top 307,33:left 307,width(306)+20:caption 307,"X":font_bold 307
hint 307,"Modification du lien":hide 305:hide 306:hide 307
alpha 308:top 308,70:left 308,10:caption 308,"Identifiant d'accès au site":font_name 308,fixedsys
edit 309:top 309,90:left 309,10:width 309,200
hint 309,"Entrez votre identifiant"+chr$(13)+"Correspondant au Site (Sortie par Entrée)."
button 310:height 310,15:width 310,15:top 310,93:left 310,width(309)+20:caption 310,"X":font_bold 310
hint 310,"Modification de l'identifiant":hide 308:hide 309:hide 310
alpha 311:top 311,130:left 311,10:caption 311,"Mot de Passe d'accès au site":font_name 311,fixedsys
edit 312:top 312,150:left 312,10:width 312,200
hint 312,"Entrez votre Mot de Passe"+chr$(13)+"Correspondant au Site (Sortie par Entrée)."
button 313:height 313,15:width 313,15:top 313,153:left 313,width(309)+20:caption 313,"X":font_bold 313
hint 313,"Modification du Mot de Pass":hide 311:hide 312:hide 313
alpha 314:top 314,190:left 314,10:caption 314,"Autre élément d'accès au site:(EX: Code Postal)":font_name 314,fixedsys
edit 315:top 315,210:left 315,10:width 315,200
hint 315,"Entrez l'élément supplémentaire"+chr$(13)+"Correspondant au Site (Sortie par Entrée)."
button 316:height 316,15:width 316,15:top 316,213:left 316,width(309)+20:caption 316,"X":font_bold 316
hint 316,"Modification du Mot de Pass":hide 314:hide 315:hide 316
alpha 317:top 317,250:left 317,10:caption 317,"Nom du site:(EX: Panoramic)":font_name 317,fixedsys
edit 318:top 318,270:left 318,10:width 318,100
hint 318,"Entrez le Nom du Site"+chr$(13)+"qui apparaîtra sur le boutton (13 caractères maxi. Sortie par Entrée)."
button 319:height 319,15:width 319,15:top 319,273:left 319,width(318)+20:caption 319,"X":font_bold 319
hint 319,"Modification du Nom du Site":hide 317:hide 318:hide 319
alpha 320:top 320,320:left 320,10:caption 320,"pour sortir sans valider, utilisez la croix rouge":font_color 320,50,0,255:font_name 320,fixedsys
button 321:top 321,315:width 321,160:left 321,(screen_x/2)-160:caption 321,"Valider et Quitter":font_name 321,fixedsys
hide 320:hide 321
' ******************************************************************************
form 400:width 400,screen_x-220:top 400,450:left 400,215:height 400,int((screen_x/2))-130
caption 400,"Mémo Sites: Aide":hide 400:color 400,220,220,220:on_close 400,ferme_form
command_target_is 400
alpha 401:top 401,10:font_name 401,fixedsys:hide 401
' ******************************************************************************
command_target_is 200
f=file_exists("memosite.mst")
if f=0 then file_open_write 212,"memosite.mst":nbe=0:file_writeln 212,nbe:file_close 212
dlist 213:file_load 213,"memosite.mst"
a$=item_read$(213,count(213)):nbe=val(a$)
if nbe>0 then gosub init
END
' ******************************************************************************
aide:
show 400:show 401
a$=" MEMO SITE: pour faciliter vos accès Internet."+chr$(13)+chr$(13)
a$=a$+" Ce petit programme a pour but d'afficher sur votre bureau une fenêtre dans laquelle,"
a$=a$+" vous pourrez accèder à vos sites Internet,"+chr$(13)
a$=a$+" en ayant sous la main vos identifiants et vos codes d'accès."+chr$(13)+chr$(13)
a$=a$+" La fenêtre vous propose un bouton par site préalablement enregistré."+chr$(13)+chr$(13)
a$=a$+" En haut de cette fenêtre, un post-it affiche votre Identifiant, votre Mot de Passe,"+chr$(13)
a$=a$+" et un troisième élément (pour certains sites: un code postal, ...)"+chr$(13)
a$=a$+" Ce post-it vous permet de copier votre identifiant et de le le coller sur le site sélectionné. (idem pour le mot de passe)"+chr$(13)+chr$(13)
a$=a$+" A droite de ce post-it il y a 3 boutons: 1) [?] pour visualiser l'aide"+chr$(13)
a$=a$+"                                          2) [+] pour enregistrer un nouveau site"+chr$(13)
a$=a$+"                                          3) [M] pour Modifier ou supprimmer un site"+chr$(13)+chr$(13)+chr$(13)
a$=a$+"-------------------------------------------------------------------------"+chr$(13)
a$=a$+" MEMO SITE: enregistrez votre premier site."+chr$(13)+chr$(13)
a$=a$+" Cliquez sur [+] pour accèder à la fenêtre d'enregistrement."
a$=a$+" Démarrez votre navigateur Internet sur votre site le plus utilisé,"+chr$(13)
a$=a$+" allez jusqu'à la page qui vous demande votre identifiant et votre code d'accès (Mot de Passe),"+chr$(13)
a$=a$+" copier le lien en haut de votre navigateur et collez-le dans l'edit prévu à cet effet."+chr$(13)
a$=a$+" Ensuite complètez identifiant, mot de passe etc..."+chr$(13)
a$=a$+" Notez que le nom du site sera celui qui apparaîtra sur le bouton correspondant"+chr$(13)
a$=a$+" Après validation le programme redémarre avec le bouton correspondant au site que vous venez de créer"+chr$(13)+chr$(13)+chr$(13)+chr$(13)+chr$(13)
a$=a$+"MémoSite.Jean claude.2011."
caption 401,a$
return
' ******************************************************************************
modsup:
if nbe<1 then message "Pas d'enregistrement":return
show 300:pv$="M"
return

md1:
text 306,"":text 309,"":text 312,"":text 315,"":text 318,""
lien$="":e1$="":e2$="":e3$="":b$=""
no=number_click:lig=no*6
clear 213:file_load 213,"memosite.mst"
b$=item_read$(213,lig)
caption 300,"Mémo Sites: Modification ou suppression de "+b$:hide 301:set_focus 300
lien$=item_read$(213,lig-4)
e1$=item_read$(213,lig-3):item_add 100,e1$
e2$=item_read$(213,lig-2):item_add 100,e2$
e3$=item_read$(213,lig-1):item_add 100,e3$
show 302:mark_off 303:mark_off 304
on_click 303,modif
on_click 304,sup
return

modif:
show 320:show 321:hide 302:caption 300,"Mémo Sites: Modification de "+b$
show 305:show 306:inactive 306:text 306,lien$:show 307
show 308:show 309:inactive 309:text 309,e1$:show 310
show 311:show 312:inactive 312:text 312,e2$:show 313
show 314:show 315:inactive 315:text 315,e3$:show 316
show 317:show 318:inactive 318:text 318,b$:show 319
on_click 307,modlien
on_click 310,modident
on_click 313,modiMDP
on_click 316,modiel
on_click 319,modibuton
on_click 321,enregmodif
return

enregmodif:
if e1$="" then message "Identifiant Manquant":hide 211:set_focus 309:return
if e2$="" then message "Mot de Passe Manquant":hide 211:set_focus 312:return
if b$="" then message "Nom du Site Mnquant":hide 211:set_focus 318:return
if e3$="" then e3$=" "
lig=lig-5
item_delete 213,lig:item_insert 213,lig,"*"
item_delete 213,lig+1:item_insert 213,lig+1,lien$
item_delete 213,lig+2:item_insert 213,lig+2,e1$
item_delete 213,lig+3:item_insert 213,lig+3,e2$
item_delete 213,lig+4:item_insert 213,lig+4,e3$
item_delete 213,lig+5:item_insert 213,lig+5,b$
file_save 213,"memosite.mst"
hide 200:show 0
execute MemoSite.exe
terminate
return

modibuton:
active 318:inactive 319:text 318,"":set_focus 318
on_key_up 318, modibuton2
return

modibuton2:
if key_up_code=13 then gosub modibuton3
return

modibuton3:
b$=upper$(text$(318))
inactive 318:active 319
return

modiel:
active 315:inactive 316:text 315,"":set_focus 315
on_key_up 315, modiel2
return

modiel2:
if key_up_code=13 then gosub modiel3
return

modiel3:
e3$=text$(315)
inactive 315:active 316
return

modiMDP:
active 312:inactive 313:text 312,"":set_focus 312
on_key_up 312, modiMDP2
return

modiMDP2:
if key_up_code=13 then gosub modiMDP3
return

modiMDP3:
e2$=text$(312)
inactive 312:active 313
return

modident:
active 309:inactive 310:text 309,"":set_focus 309
on_key_up 309, modident2
return

modident2:
if key_up_code=13 then gosub modident3
return

modident3:
e1$=text$(309)
inactive 309:active 310
return

modlien:
inactive 307:active 306:text 306,""
set_focus 306:on_change 306,modlien2
return

modlien2:
active 307:inactive 306
lienp$=text$(306)
return

sup:
n=message_confirmation_yes_no("La suppression de "+b$+" entraine la suppression du bouton correspondant."+chr$(13)+chr$(13)+"Voulez-vous continuer ?")
if n<>1 then return
caption 300,"Mémo Sites: Suppression de "+b$
lig=lig-5
for n=1 to 6:item_delete 213,lig:next n
lig=count(213):nbe=nbe-1:item_delete 213,lig:item_insert 213,lig,nbe
file_save 213,"memosite.mst"
hide 200:show 0
execute MemoSite.exe
terminate
return
' ******************************************************************************
init:
nbb=int((screen_y-100)/40)+1
if nbe>=nbb then return
command_target_is 0
b$=item_read$(213,6)
button 1:top 1,140:width 1,120:height 1,20:left 1,30:caption 1,b$:font_name 1,fixedsys:on_click 1,go
if nbe=1 then return
lig=6
 for no=2 to nbe
  lig=lig+6:b$=item_read$(213,lig)
  button no:top no,top(no-1)+35:left no,30:width no,120:height no,20:caption no,b$:font_name no,fixedsys
  on_click no,go
 next no
return
' ******************************************************************************
go:
if pv$="M" then gosub md1:return
clear 100:lig=0
no=number_click:lig=no*6
b$=item_read$(213,lig)
lien$=item_read$(213,lig-4)
e1$=item_read$(213,lig-3):item_add 100,e1$
e2$=item_read$(213,lig-2):item_add 100,e2$
e3$=item_read$(213,lig-1):item_add 100,e3$
execute lien$
return
' ******************************************************************************
new:
lien$="":e1$="":e2$="":e3$="":b$=""
text 202,"":text 204,"":text 206,"":text 208,"":text 210,""
if nbe=24 then message "Plus de place pour un nouveau Site":return
show 200:hide 0
on_change 202,new2
return

new2:
lien$=text$(202)
show 203:show 204:set_focus 204
on_key_up 204,new3
return

new3:
if key_up_code=13 then gosub new4
return

new4:
e1$=text$(204)
show 205:show 206:set_focus 206
on_key_up 206,new5
return

new5:
if key_up_code=13 then gosub new6
return

new6:
e2$=text$(206)
show 207:show 208:set_focus 208
on_key_up 208,new7
return

new7:
if key_up_code=13 then gosub new8
return

new8:
e3$=text$(208)
show 209:show 210:set_focus 210
on_key_up 210,new9
return

new9:
if key_up_code=13 then gosub new10
return

new10:
b$=upper$(text$(210))
if len(b$)>13 then message "13 caractères Maximum":b$="":text 210,"":return
show 211:on_click 211,new11
return

new11:
if e1$="" then message "Identifiant Manquant":hide 211:set_focus 204:return
if e2$="" then message "Mot de Passe Manquant":hide 211:set_focus 206:return
if b$="" then message "Nom du Site Mnquant":hide 211:set_focus 210:return
if e3$="" then e3$=" "
nbe=nbe+1
item_add 213,lien$:item_add 213,e1$:item_add 213,e2$:item_add 213,e3$:item_add 213,b$:item_add 213,nbe
file_save 213,"memosite.mst"
hide 200:show 0
execute MemoSite.exe
terminate
return
' ******************************************************************************
ferme_form:
show 0:pv$="":clear 100:set_focus 100
return

fin:
terminate