Utilitaire : Captureur d'écran

rem ' Capt-Ecran
dim a$ , b$ , b , i , ir : b=2
label go , rapide , cadre , aide
width 0,220 : height 0,70 : set_focus 0 : caption 0,"CAPT-ECRAN"
button 1 : on_click 1,rapide
left 1,10 : top 1,5 : width 1,55 : caption 1,"Rapide"
button 2 : on_click 2,cadre : font_bold 2
left 2,70 : top 2,5 : width 2,50 : caption 2,"Cadré"
button 3
left 3,125 : top 3,5 : width 3,35
caption 3,"Aide" : on_click 3,aide
on_key_up 0,go
on_key_up 1,go
on_key_up 2,go
on_key_up 3,go

dlist 6 : rem Liste contenant les noms des répertoires existant en C:
dir_change "C:\"
b$=file_find_first$
while b$<>"_"
 if instr(b$,".")=0 then item_add 6,b$
 b$=file_find_next$
end_while
file_find_close
for i=1 to count(6)
 if item_read$(6,i)="NewPic" then ir=1
next i
if ir=0 then dir_make "C:\NewPic"

alpha 7
width 7,60 : left 7,140 : top 7,4
caption 7,string$(8," ")+"Pressez"+chr$(13)+string$(9," ")+"clavier"

end

rapide:
font_bold 1 : font_bold_off 2 : b=1
return

cadre:
font_bold 2 : font_bold_off 1 : b=2
return

go:
b$=chr$(int(rnd(26))+65)+"-"
for i=1 to 20
 b$=b$+chr$(int(rnd(26))+97)
next i : b$=b$+"-"
for i=1 to 3
 b$=b$+chr$(int(rnd(10))+48)
next i
b$=b$+".jpg"
if b=2
 a$="C:\Progra~1\IRFANVIEW\i_view32.exe /capture=4 /convert=c:\NewPic\"+b$
else
 hide 0
 a$="C:\Progra~1\IRFANVIEW\i_view32.exe /capture=1 /convert=c:\NewPic\"+b$
 beep
end_if
execute_wait a$
show 0
return

aide:
a$="AIDE AU CAPTUREUR D'ECRAN PANORAMIC :"+chr$(13)
a$=a$+string$(53,"-")+chr$(13)
a$=a$+" - Le mode RAPIDE sert à faire des captures d'écran en rafale."+chr$(13)
a$=a$+"  Pour cela, après avoir executé CAPT-ECRAN, vous devez le mettre"+chr$(13)
a$=a$+"  au dessus des autres fenêtres en cliquant sur sa représentation"+chr$(13)
a$=a$+"  miniaturisée située dans la barre des tâches, puis vous pressez une"+chr$(13)
a$=a$+"  touche du clavier. Un bip se fait entendre au moment de la capture."+chr$(13)
a$=a$+"  CAPT-ECRAN enregistre automatiquement la totalité de l'écran et"+chr$(13)
a$=a$+"  en stocke l'image dans C:\NewPic."+chr$(13)
a$=a$+" - Le mode CADRÉ sert à faire des captures d'image soigneusement"+chr$(13)
a$=a$+"  dimensionnées, ce qui suppose que vous ayez tout votre temps."+chr$(13)
a$=a$+"  Pour faire une capture en mode CADRÉ, cliquez sur la fenêtre minia-"+chr$(13)
a$=a$+"  turisée de CAPT-ECRAN pour la placer au dessus des autres fenêtres"+chr$(13)
a$=a$+"  puis appuyez sur n'importe quelle touche du clavier. Un cadre de"+chr$(13)
a$=a$+"  dimensionnement va appraître. Entourez l'image que vous souhaitez"+chr$(13)
a$=a$+"  capturer avec ce cadre en faisant glisser la souris, puis cliquez."+chr$(13)
a$=a$+"  C'est tout et l'image sera immédiatement enregistrée dans NewPic."
message a$
return