Du coup, j'ai un autre défi

' touches +Volume, Mute, -Volume
label moinsVolume, Mute, plusVolume

dim res%

button 1
top 1,50
left 1,50
caption 1,"-Volume"
on_click 1,moinsVolume

button 2
top 2,50
left 2,150
caption 2,"Mute"
on_click 2,mute

button 3
top 3,50
left 3,250
caption 3,"+Volume"
on_click 3,plusVolume

dll_on "user32.dll"

end
' ------------------------------------------------------------------------------
moinsVolume:
    res% = dll_call4("keybd_event",hex("AE"),0,0,0)
return
' ------------------------------------------------------------------------------
mute:
    res% = dll_call4("keybd_event",hex("AD"),0,0,0)
return
' ------------------------------------------------------------------------------
plusVolume:
    res% = dll_call4("keybd_event",hex("AF"),0,0,0)
return

peek_reverse

' null% = 0 pour les dll windows
dim null%
null%=0

' créer un entier 32 bits (ou plus)
dim int32$
int32$=string$(32,chr$(255)) :' 0xFFFFFFFF

' adresse de l'entier
print peek32(adr(int32$))

dim tmp% : tmp% = peek32(adr(int32$)) :' A NE PAS FAIRE! Risque de plantage car la
' valeur de peek32(adr(int32$)) évolue au cours du programme. C'est une
' caractéristique de panoramic

' exemple d'appel:
' dll_callx("blabla",peek32(adr(int32$)),null%)

' lecture du niveau de volume droite et gauche de l'application Panoramic
dim res%, volume%, voieDroite%, voieGauche%, NULL%

peek_reverse

dll_on "winmm"

' lecture niveau de volume droite et gauche
res% = dll_call2("waveOutGetVolume",NULL%,adr(volume%))

' la variable volume% (32 bits soit 4 octets) représente les niveaux droite et gauche du volume
' les 2 octets de poids fort correspondent à la voie droite [0x0000,0xFFFF]
' les 2 octets de poids faible correspondent à la voie gauche ou signal mono [0x0000,0xFFFF]
  
' voie droite :
voieDroite% = peek16(adr(volume%)+2) :' [0,65535]

' voie gauche :
voieGauche% = peek16(adr(volume%)) :' [0,65535]

print "Niveau voie droite : " + str$(VoieDroite%)
print "Niveau voie gauche ou mono : " + str$(voieGauche%)

end

' régler un niveau de VOLUME pour l'application Panoramic

dim res%, volume$, voieDroite$, voieGauche$, NULL%

dll_on "winmm.dll"

' niveaux droite et gauche à 50%
voieDroite$ = hex$(32767) :' [0,65535]
voieGauche$ = hex$(32767) :' [0,65535]

while len(voieDroite$) < 4
    voieDroite$ = "0" + voieDroite$
end_while

while len(voieGauche$) < 4
    voieGauche$ = "0" + voieGauche$
end_while

volume$ = voieDroite$ + voieGauche$

res% = dll_call2("waveOutSetVolume",NULL%,hex(volume$))

end

' réglage VOLUME

dim res%, volume$, voieDroite$, voieGauche$, NULL%

label reglageVolume

peek_reverse

' potentiomètre de réglage du volume
track_bar 1
top 1,10
width 1,300
min 1,0
max 1,100
position 1,100 :' mettre le curseur au max par défaut
on_change 1,reglageVolume

' lire un mp3 pour tester l'action du réglage
sound 10
file_load 10,"open.mp3"
play 10

dll_on "winmm.dll"

end
' ------------------------------------------------------------------------------
reglageVolume:
    voieDroite$ = hex$(int(position(1) * 655))
    voieGauche$ = hex$(int(position(1) * 655))

    while len(voieDroite$) < 4
        voieDroite$ = "0" + voieDroite$
    end_while

    while len(voieGauche$) < 4
        voieGauche$ = "0" + voieGauche$
    end_while

    volume$ = voieDroite$ + voieGauche$
    res% = dll_call2("waveOutSetVolume",NULL%,hex(volume$))
return

'

dim volume$, voieDroite$, voieGauche$
dim volume%

peek_reverse

' niveaux droite et gauche
voieDroite$ = hex$(16384) :' [0,65535]
voieGauche$ = hex$(32767) :' [0,65535]

while len(voieDroite$) < 4
    voieDroite$ = "0" + voieDroite$
end_while

while len(voieGauche$) < 4
    voieGauche$ = "0" + voieGauche$
end_while

volume$ = voieDroite$ + voieGauche$
print "volume$ = ",volume$
print

volume%=hex(volume$)
print "voieDroite$ = ",hex$(peek16(adr(volume%)+2))
print "voieGauche$ = ",hex$(peek16(adr(volume%)))


end