Fenêtre ouverte dans Windows

dim handle%,adrs%,nom$
dll_on "user32.dll"
rem recherche du handle de la fenêtre "Calculatrice"
nom$="Calculatrice"
adrs%=adr(nom$)
peek_reverse
handle%=dll_call2("FindWindowA",0,peek32(adrs%))
if handle% <> 0
print "handle de la fenêtre = "+str$(handle%)

rem recherche de la position et de la taille
rem A COMPLETER

else
print "la fenêtre n'existe pas"
end_if
dll_off
end

dim handle%,adrs%,bidon%,texte$,texte2$
dll_on "user32.dll"

rem recherche du handle de la fenêtre "Calculatrice"
texte$="Calculatrice"
adrs%=adr(texte$): rem adresse de l'adresse de texte$
peek_reverse: rem car Windows est du type Big Endian
handle%=dll_call2("FindWindowA",0,peek32(adrs%)): rem peek32 est donc un pointeur sur texte$

rem si handle% est nul, la fenêtre n'existe pas

if handle% <> 0
   print "handle de la fenêtre = "+str$(handle%): rem pour info

   rem recherche de la position et de la taille
   texte2$="ABCDABCDABCDABCD": rem string de 4 fois 4 octets pour recueillir LEFT, TOP, RIGHT, BOTTOM

   rem texte2$ doit être considéré comme un "buffer de réception" pour la fonction GetWindowRect

   adrs%=adr(texte2$) : rem adresse de l'adresse de texte2$
   bidon%=dll_call2("GetWindowRect",handle%,peek32(adrs%)): rem cette fonction GetWindowRect va remplir texte2$

   adrs%=peek32(adrs%): rem pointeur sur la réponse de GetWindowRect, c'est à dire directement sur le contenu de text2$

   rem on exploite la réponse de GetWindowrect :
   print "LEFT = "+str$(peek32(adrs%))
   print "TOP = "+str$(peek32(adrs%+4))
   print "RIGHT = "+str$(peek32(adrs%+8))
   print "BOTTOM = "+str$(peek32(adrs%+12))
   print "WIDTH = "+str$(peek32(adrs%+8)-peek32(adrs%)): rem RIGHT - LEFT
   print "HEIGHT = "+str$(peek32(adrs%+12)-peek32(adrs%+4)): rem BOTTOM - TOP
else
   print "la fenêtre n'existe pas"
end_if
dll_off
end

DIM Titre$,x1%,y1%,w1%,h1%,x2%,y2%,w2%,h2%
Titre$ = "PANORAMIC EDITOR": ' Titre de la fenêtre cherchée
Fenetre_Win(Titre$)
font_size 0,12
print: PRINT " x1 = "+STR$(x1%)+"  y1 = "+STR$(y1%)+"  w1 = "+STR$(w1%)+"  h1 = "+STR$(h1%)
print: PRINT " x2 = "+STR$(x2%)+"  y2 = "+STR$(y2%)+"  w2 = "+STR$(w2%)+"  h2 = "+STR$(h2%)
END

SUB Fenetre_Win(Titre$)
  ' Position et dimensions externes et internes de la fenêtre d'exécution
  ' contenant la séquence Titre$
  ' Ex: Fenetre_Win("Portail Orange")
  ' Résultat dans les variables suivantes définies dans l'appelant:
  '           x1%,y1%,w1%,h1% (position et dimensions externes de la fenêtre)
  '   et dans x2%,y2%,w2%,h2% (idem internes, sans les bordures)
  DIM_LOCAL kgf$,res%,hnd%
  kgf$ = "C:\PANORAMIC\KGF\KGF.dll": ' À ajuster !
  DLL_ON kgf$
  hnd% = dll_call2("GetWindowByTitle",1,adr(titre$)): ' n° handle
  ' position et dimensions externes
  res% = DLL_call5("GetFormMetrics",hnd%,adr(x1%),adr(y1%),adr(w1%),adr(h1%))
  ' position et dimensions internes (sans les bordures)
  res% = DLL_call5("GetFormClientMetrics",hnd%,adr(x2%),adr(y2%),adr(w2%),adr(h2%))
  DLL_OFF
END_SUB

IM Titre$,x%,y%,w%,h%
Titre$ = "PANORAMIC EDITOR"
Fenetre_W1(Titre$)
print "Left= "+STR$(x%): PRINT " Top= "+STR$(y%)
PRINT "larg= "+STR$(w%): PRINT "Haut= "+STR$(h%)
END

SUB Fenetre_W1(Titre$)
  ' Position et dimensions de la fenêtre d'exécution du programme contenant
  ' la chaîne Titre$ dans le titre de la fenêtre.
  ' Résultats dans x%,y%,w%,h% définis dans l'appelant
  DIM_LOCAL handle%,adrs%,bidon%,texte2$,x1%,y1%
  DLL_ON "user32.dll"
  ' recherche du handle de la fenêtre
  adrs%=ADR(Titre$): ' adresse de l'adresse de texte$
  PEEK_REVERSE: ' car Windows est du type Big Endian
  handle%=DLL_CALL2("FindWindowA",0,PEEK32(adrs%)): ' peek32 est donc un pointeur sur Titre$
    ' si handle% est nul, la fenêtre n'existe pas
  IF handle% <> 0
      ' recherche de la position et de la taille
      texte2$="ABCDABCDABCDABCD": ' string 4x4 octets pour LEFT, TOP, RIGHT, BOTTOM
      ' texte2$ doit être considéré comme un "buffer de réception" pour la fonction GetWindowRect
      adrs%=adr(texte2$) : ' adresse de l'adresse de texte2$
      bidon%=DLL_CALL2("GetWindowRect",handle%,PEEK32(adrs%)): ' cette fonction GetWindowRect va remplir texte2$
      adrs%=PEEK32(adrs%): ' pointeur sur la réponse de GetWindowRect, c'est à dire directement sur le contenu de text2$
      ' on exploite la réponse de GetWindowrect :
      x% = PEEK32(adrs%): y% = PEEK32(adrs%+4): ' haut/gauche
      x1% = PEEK32(adrs%+8): y1% = PEEK32(adrs%+12): ' bas/droite
      w% = x1%-x%: h% = y1%-y%: ' -> largeur/hauteur
  ELSE
      MESSAGE "la fenêtre n'existe pas"
  END_IF
  DLL_OFF
END_SUB