Simuler un ON_MOVE sur d'autres FORM que le 0

rem ============================================================================
rem         Code exemple de simulation de ON_MOVE sur un FORM autre que 0
rem                       A adapter selon vos besoins
rem ============================================================================
dim t%,l%,n%
label move
' Déclaration de FORM 10 pour l'exemple
form 10 : top 10,50 : left 10,50 : width 10,400 : height 10,300 : color 10,20,150,250
caption 10,"FORM 10"  
' Sauvegarde de la position du FORM (utile pour le test du déplacement)
t% = top(10) : l% = left(10)
' Déclaration d'un ALPHA servant d'information
alpha 20 : parent 20,10 : top 20,50 : left 20,50 : font_bold 20
font_color 20,255,255,0 : caption 20,"Déplacez ce FORM à l'aide de la souris"
' Déclaration d'un TIMER
timer 999  : on_timer 999,move

end
rem ============================================================================
' Simulation de ON_MOVE sur un FORM autre que FORM 0
move:
   timer_off 999 : ' désactiver le timer  
   ' Si la position du FORM 10 a changé, c'est qu'on a bien déplacé ce FORM  
   if (top(10) <> t% ) or (left(10) <> l%)
      t% = top(10) : l% = left(10) : ' on sauvegarde la nouvelle position
      ' Appellez ici le sous-programme relatif au déplacement du FORM
      ' Par exemple :
      MoveForm()        
   end_if
   timer_on 999 : on_timer 999,move  : ' réactiver le timer
return
rem ============================================================================
' Sous-programme traitant le déplacement du FORM
SUB MoveForm()
   n% = n% + 1 : ' compteur de nombre de fois du déplacement du FORM
   font_color 20,255,255,255 : caption 20, "FORM 10 a été déplacé " + str$(n%) + " fois"
   ' ....
   ' ....
END_SUB
rem ============================================================================