Défilement dans une grande image

LABEL Redim0,Dscr
DIM fi$,pic,hf,wf,i,scv,sch
fi$ = "C:\GRAPH\JPG\Joconde.jpg"
hf = 3591: wf = 2403: ' dimensions de l'image.
ON_RESIZE 0,Redim0
pic = 5: PICTURE pic: WIDTH pic,wf: HEIGHT pic,hf: FILE_LOAD pic,fi$
scv = 1: SCROLL_BAR scv: VERTICAL scv : ON_CHANGE scv,Dscr
sch = 2: SCROLL_BAR sch: HORIZONTAL sch: ON_CHANGE sch,Dscr
GOSUB Redim0: ' init
END
' ===================================================================
Dscr:
  ' Déplacement d'un scroll bar
  i = -1*(hf-HEIGHT_CLIENT(0)): TOP pic,i*POSITION(scv)/100: ' V
  i = -1*(wf-WIDTH_CLIENT(0)): LEFT pic,i*POSITION(sch)/100: ' H
RETURN
' ===================================================================
Redim0:
  ' Redimensionnement du Form 0 -> redifinition des scroll bars
  LEFT scv,WIDTH_CLIENT(0)-WIDTH(scv): HEIGHT scv,HEIGHT_CLIENT(0): ' V
  TOP sch,HEIGHT_CLIENT(0)-HEIGHT(sch): WIDTH sch,WIDTH_CLIENT(0): ' H
RETURN
' ===================================================================[code][/code]

rem ' Articulation gde image dans pt form avec ascenseur
rem ' JL35 - https://panoramic.1fr1.net/t6535-defilement-dans-une-grande-image
LABEL redim_0,dim_scr , move
DIM PH$,HTPH%,LGPH%,I%,J%,PS%
PH$="C:\Robo.jpg"
HTPH%=3591 : LGPH%=2403: ' dimensions de l'image.
width 0,1200 : height 0,700 : ON_RESIZE 0,redim_0
PICTURE 5 : WIDTH 5,LGPH% : HEIGHT 5,HTPH%: FILE_LOAD 5,PH$ : on_mouse_move 5,move
SCROLL_BAR 1: VERTICAL 1 : width 1,50 : ON_CHANGE 1,dim_scr
SCROLL_BAR 2: HORIZONTAL 2 : ON_CHANGE 2,dim_scr
GOSUB redim_0: ' init
END
' ===================================================================
dim_scr:
  ' Déplacement d'un scroll bar
  I% = -1*(HTPH%-HEIGHT_CLIENT(0)): TOP 5,I%*POSITION(1)/100: ' V
  I% = -1*(LGPH%-WIDTH_CLIENT(0)): LEFT 5,I%*POSITION(2)/100: ' H
RETURN
' ===================================================================
redim_0:
  ' Redimensionnement du Form 0 -> redéfinition des scroll bars
  LEFT 1,WIDTH_CLIENT(0)-WIDTH(1): HEIGHT 1,HEIGHT_CLIENT(0): ' V
  TOP 2,HEIGHT_CLIENT(0)-HEIGHT(2): WIDTH 2,WIDTH_CLIENT(0)-17: ' H
RETURN
' ===================================================================
move: : ' Ajout perso pour faire bouger l'image en tactile
   J%=mouse_y_position(5)
   if J%<>PS%
      if J%>PS%
         top 5,top(5)+1
      else
         top 5,top(5)-1
      end_if
   end_if
   PS%=mouse_y_position(5)
return

maximize 0
'
label load_image_dans_container_my_image,bouge2
dim null,container_my_image,my_image,lastX,lastY,pastX,pastY,imx,imy,taille_imx,taille_imy

' génère une image
container_my_image=1000
my_image=2000
gosub load_image_dans_container_my_image

' déplace l'image dans le container_my_image
on_mouse_move container_my_image,bouge2


END
load_image_dans_container_my_image:
' ****************** fabrique une image pour la démonstration : debut **********
create_hide
  picture 123 : width 123,1000 : height 123,1000  :' fabrique un picture temporaire pour générer une image de container_my_image*container_my_image
create_show
color 123,0,0,0
dim i,x1,y1,x2,y2,r,g,b
2d_target_is 123
for i=1 to 100
   x1=int(rnd(500))
   y1=int(rnd(500))
   x2=int(rnd(500)+500)
   y2=int(rnd(500)+500)
   r=int(rnd(255))
   g=int(rnd(255))
   b=int(rnd(255))
   2d_pen_color r,g,b
   2d_fill_color r,g,b
   2d_rectangle x1,y1,x2,y2
next i
clipboard_copy 123
2d_target_is 0 : delete 123  :' plus besoin du picture temporaire
' ****************** fabrique une image pour la démonstration : fin ************

image my_image
clipboard_paste my_image :' image de démonstration
' on peut charger une image à partir du disque dur
' file_load my_image,"Mon_image.bmp"

' dimension de my_image
taille_imx=1000
taille_imy=1000

' le container; en fait c'est un picture
picture container_my_image : width container_my_image,550 : height container_my_image,550 : top container_my_image,50 : left container_my_image,150 :' un container_my_image de taille 550*550
2d_target_is container_my_image : 2d_image_paste my_image,0,0                                                                                       :' colle l'image dans le picture

return

bouge2:
off_mouse_move container_my_image
   '
   null=scancode :' rafraichir le scancode
   if scancode=1
      2d_clear
      pastX=mouse_x_position(container_my_image)
      pastY=mouse_y_position(container_my_image)
      imx=imx+(pastx-lastx)
      imy=imy+(pasty-lasty)
      if imx<width(container_my_image)-taille_imx then imx=width(container_my_image)-taille_imx     :' <--- taille_imx
      if imx>0 then imx=0
      if imy<height(container_my_image)-taille_imy then imy=height(container_my_image)-taille_imy   :' <--- taille_imy
      if imy>0 then imy=0
      2d_image_paste my_image,imx,imy
      lastx=pastx
      lasty=pasty
   else
      lastX=mouse_x_position(container_my_image)
      lastY=mouse_y_position(container_my_image)
   end_if
   '
on_mouse_move container_my_image,bouge2 :' pb(bug?) avec bouton gauche: si le bouton est enfoncé dans le container_my_image, l'évènement est
                                        :' détecté même si la souris est en dehors du container_my_image!!! Pas génant mais bon à connaitre
return

label defilementVertical,redimensionnerFenetre

creerFenetreScrollableVerticalement()

alpha 3
top 3,1800
left 3,200
caption 3,"Hello !"

end

sub creerFenetreScrollableVerticalement()
    width 0,600
    height 0,500
    on_resize 0,redimensionnerFenetre

    scroll_bar 1
    vertical 1
    left 1,width_client(0) - width(1)
    height 1,height_client(0)
    on_change 1,defilementVertical

    panel 2
    width 2,width_client(0) - width(1)
    height 2,2000 : ' hauteur de 2000 pixels par exemple

    max 1,height(2) - height_client(0)
  
    command_target_is 2
end_sub

defilementVertical:
    top 2,(-1) * position(1)
return

redimensionnerFenetre:
    left 1,width_client(0) - width(1)
    height 1,height_client(0)
    width 2,width_client(0) - width(1)
    max 1,height(2) - height_client(0)
return