Un éditeur MultiPlatforme Panoramic, FBpano, etc...

dim keywords$

keywords = " dim data print ... "

if instr(keywords, " " + lcase(word) + " ") > 0 then ...  '  word est un mot-clé

 
' **********************************************************************
' Editeur FBPano, d'apres le programme de demonstration de FLTK : www.fltk.org/doc-1.3/editor.html
' Modification par MiNiBuG
' **********************************************************************

' #compile -gui

CONST FORM_WIDTH  = 750          ' Largeur de la fenetre principale
CONST FORM_HEIGHT = 500          ' Hauteur de la fenetre principale
CONST FONT_SIZE  = 16            ' Taille des caracteres
CONST FONT_COLOR  = FL_BLACK      ' Couleur du texte
CONST BKG_COLOR  = FL_WHITE      ' Couleur du fond
CONST LNUM_COLOR  = FL_BLACK      ' Couleur des numeros de lignes
CONST LNUM_WIDTH  = 60            ' Largeur de la marge pour num. lignes

DIM search$                      ' Chaine pour la recherche
DIM find$, rep$                  ' Chaines pour le remplacement
DIM nf%                          ' Nb de polices
DIM fontnum%()                    ' Numéros des polices
DIM fontname$()                  ' Noms des polices
DIM fontsize% : fontsize = 16    ' Taille de la police
DIM font% = FL_COURIER            ' Police selectionnee
DIM i%                            ' Variable de boucle
DIM keywords$                    ' Liste des mots_cles

ENUM GUI
  fmMain                          ' Form principale
    menu1, editor1, buffer1
  fmReplace                      ' Form rechercher/remplacer
    edFind, edReplace, btRepAll, btRepNext, btCancel
  fmParametres                    ' Form paramètres
    lsPolice, tbSize, btFermerParam, btWrap, btLine
    ctCouleur
        rdColFond, rdColText, rdColNomb, rdColCom, rdColMC, rdColPp, rdColAutr
        CoulChoix, edResult
END_ENUM

FORM fmMain, 15, 35, FORM_WIDTH, FORM_HEIGHT, "Editeur"
  FORM_BEGIN fmMain
      MENU menu1, 0, 0, FORM_WIDTH, 25
      TEXT_EDITOR editor1,  0, 25, FORM_WIDTH, FORM_HEIGHT - 25
      TEXT_BUFFER buffer1
  FORM_END fmMain

FORM fmReplace, 200, 200, 380, 110, "Remplacement"
  FORM_BEGIN fmReplace
      EDIT edFind,    110, 10, 260, 25, "Chercher :"
      EDIT edReplace, 110, 40, 260, 25, "Remplacer par :"
      BUTTON btRepAll,  10, 75, 110, 25, "Remplacer tout"
      BUTTON btRepNext, 130, 75, 170, 25, "Remplacer Suivant", , T_Button_Return
      BUTTON btCancel,  310, 75,  60, 25, "Fermer"
  FORM_END fmReplace

FORM fmParametres, 200, 200, 380, 420, "Liste des polices"
  FORM_BEGIN fmParametres
      LIST lsPolice, 5, 5, 180, 375
      nf = FONT_LIST(fontnum(), fontname())
      FOR i = 0 TO nf - 1
        LIST_ITEM_ADD lsPolice, "@S12@F" & "@." & fontname(i)
      NEXT i
      LIST_ITEM_SELECT lsPolice, 1

      TRACK_BAR tbSize, 225, 5, 150, 25, "Taille", FL_ALIGN_LEFT, T_Track_Val
      FONT_TEXT tbSize, font, 16
      POSITION_RANGE tbSize, 8, 30, 1
      POSITION tbSize, fontsize
      BUTTON btWrap, 190, 35, 185, 30, "Retour à la ligne", , T_Button_Light
      BUTTON btLine, 190, 65, 185, 30, "Affichage lignes", , T_Button_Light
      MARK_ON btLine

      CONTAINER ctCouleur, 190, 100, 185, 280, "", , T_Container
        CONTAINER_BEGIN ctCouleur
            RADIO rdColFond, 195, 102, 175, 30, "Fond"
            RADIO rdColText, 195, 122, 175, 30, "Texte"
            RADIO rdColNomb, 195, 142, 175, 30, "Nombres"
            RADIO rdColCom, 195, 162, 175, 30, "Commentaires"
            RADIO rdColMC, 195, 182, 175, 30, "Mots clés"
            RADIO rdColPp, 195, 202, 175, 30, "Préprocesseur"
            RADIO rdColAutr, 195, 222, 175, 30, "Autre"
            MARK_ON rdColFond
            COLOR_CHOOSER CoulChoix, 195, 247, 175, 100, , , FL_COLORCHOOSER_BYTE
            EDIT edResult, 195, 350, 175, 25
    CONTAINER_END ctCouleur

      BUTTON btFermerParam, 5, 385, 370, 30, "Fermer"
  FORM_END fmParametres

ON_CLICK btRepAll, remplacer_tout
ON_CLICK btRepNext, remplacer_suivant
ON_CLICK btCancel, annuler_remplacer
ON_CLICK lsPolice, changer_police
ON_CLICK btFermerParam, cacher_parametres
ON_CLICK tbSize, changer_taille_police
ON_CLICK btWrap, wrap
ON_CLICK btLine, affichage_numlines

ON_CLICK rdColFond, changer_couleur
ON_CLICK rdColText, changer_couleur
ON_CLICK rdColNomb, changer_couleur
ON_CLICK rdColCom, changer_couleur
ON_CLICK rdColMC, changer_couleur
ON_CLICK rdColPp, changer_couleur
ON_CLICK rdColAutr, changer_couleur
ON_CLICK CoulChoix, changer_couleur

MENU_ITEM_ADD menu1, "&Fichier/&Nouveau ", "Ctrl+N", , nouveau
MENU_ITEM_ADD menu1, "&Fichier/&Ouvrir ", "Ctrl+O", , ouvrir
MENU_ITEM_ADD menu1, "&Fichier/&Enregistrer ", "Ctrl+E", FL_MENU_DIVIDER, enregistrer
MENU_ITEM_ADD menu1, "&Fichier/&Quitter ", "Ctrl+Q", , quitter

MENU_ITEM_ADD menu1, "E&dition/Co&uper ", "Ctrl+X", , couper
MENU_ITEM_ADD menu1, "E&dition/&Copier ", "Ctrl+C", , copier
MENU_ITEM_ADD menu1, "E&dition/Co&ller ", "Ctrl+V", FL_MENU_DIVIDER, coller
MENU_ITEM_ADD menu1, "E&dition/&Rechercher ", "Ctrl+F", , rechercher
MENU_ITEM_ADD menu1, "E&dition/Rechercher le &suivant ", "F3", , rechercher_suivant
MENU_ITEM_ADD menu1, "E&dition/R&emplacer ", "Ctrl+R", , remplacer

MENU_ITEM_ADD menu1, "&Exécution/E&xécuter ", "F9", , executer

MENU_ITEM_ADD menu1, "O&ptions/&Syntaxe/&Panoramic  ", "F1", FL_MENU_RADIO + FL_MENU_VALUE, syntaxe_panoramic
MENU_ITEM_ADD menu1, "O&ptions/&Syntaxe/&FBPano  ", "F2", FL_MENU_RADIO, syntaxe_fbpano
MENU_ITEM_ADD menu1, "O&ptions/&Paramètres ", "Ctrl+P", , choix_parametres

fontsize = 16

COLOR_FL editor1, BKG_COLOR
FONT_TEXT editor1, font, fontsize
COLOR_TEXT_FL editor1, FONT_COLOR
COLOR_CURSOR_FL editor1, FONT_COLOR
COLOR_NUMLINES_FL editor1, LNUM_COLOR
EDITOR_NUMLINES editor1, LNUM_WIDTH, font, fontsize

EDITOR_SET_BUFFER editor1, buffer1

SET_RESIZABLE fmMain

START fmMain

' ----------------------------------------------------------------------
' Sous-programmes utilitaires
' ----------------------------------------------------------------------

FUNCTION trouve% (s$, p%, msg%)
  ' Recherche la chaine s à partir de la position du curseur
  ' La position de la chaine trouvee est retournee dans p
  ' msg = TRUE pour afficher le message d'erreur

  p = EDITOR_GET_INSERT_POS(editor1)
  IF BUFFER_SEARCH_FORWARD(buffer1, p, s, p) = 0 THEN
      IF msg THEN MESSAGE "Chaîne """ + s + """ non trouvée !"
      trouve = FALSE
  ELSE
      trouve = TRUE
  END_IF
END_FUNCTION

SUB update_editor (p%, s1$, s2$, rpl%)
  ' Met a jour l'editeur apres recherche ou remplacement
  ' p = position de la chaine recherchee
  ' s1 = chaine recherchee
  ' s2 = chaine de remplacement
  ' rpl = indique si remplacement

  DIM p1%

  p1 = p + LEN(s1)
  BUFFER_SELECT buffer1, p, p1

  IF rpl THEN
      BUFFER_REMOVE_SELECT buffer1
      BUFFER_INSERT buffer1, p, s2
      p1 = p + LEN(s2)
      BUFFER_SELECT buffer1, p, p1
      p = p1
  END_IF

  EDITOR_SET_INSERT_POS editor1, p1
  EDITOR_SHOW_INSERT_POS editor1
END_SUB

' ----------------------------------------------------------------------
' Sous-programmes associes aux evenements
' ----------------------------------------------------------------------

SUB nouveau
  TEXT buffer1, ""
  CAPTION fmMain, "Editeur"
END_SUB

SUB ouvrir
  DIM fname$
  fname = FILE_NAME("Ouvrir", "Fichier texte (*.txt)", CURDIR, 0)
  IF fname = "" OR FILE_EXISTS(fname) = 0 THEN EXIT_SUB
  BUFFER_FILE_LOAD buffer1, fname
  CAPTION fmMain, fname
END_SUB

SUB enregistrer
  DIM fname$
  fname = FILE_NAME("Enregistrer", "Fichier texte (*.txt)", CURDIR, 0)
  IF fname = "" THEN EXIT_SUB
  BUFFER_FILE_SAVE buffer1, fname
END_SUB

SUB quitter
  HIDE fmMain
END_SUB

SUB couper
  EDITOR_CUT editor1
END_SUB

SUB copier
  EDITOR_COPY editor1
END_SUB

SUB coller
  EDITOR_PASTE editor1
END_SUB

SUB rechercher
  DIM p%
  search = MESSAGE_INPUT("Rechercher", "Rechercher", search)
  IF search <> "" THEN
      IF trouve(search, p, TRUE) THEN update_editor p, search, "", FALSE
  END_IF
END_SUB

SUB rechercher_suivant
  DIM p%
  IF search = "" THEN
      search = message_input("Rechercher", "Rechercher", search)
  END_IF
  IF search <> "" THEN
      IF trouve(search, p, TRUE) THEN update_editor p, search, "", FALSE
  END_IF
END_SUB

SUB remplacer
  SHOW fmReplace
END_SUB

SUB remplacer_suivant
  DIM p%
  find = GET_TEXT(edFind)
  IF find = "" THEN EXIT_SUB
  rep = GET_TEXT(edReplace)
  IF trouve(find, p, TRUE) THEN update_editor p, find, rep, TRUE
END_SUB

SUB remplacer_tout
  DIM p%, found%, n%
  find = GET_TEXT(edFind)
  IF find = "" THEN EXIT_SUB
  rep = GET_TEXT(edReplace)
  found = trouve(find, p, TRUE)
  IF NOT found THEN EXIT_SUB
  WHILE found
      n = n + 1
      update_editor p, find, rep, TRUE
      found = trouve(find, p, FALSE)
  END_WHILE
  MESSAGE "Chaîne """ & find & """ remplacée " & n & " fois."
END_SUB

SUB annuler_remplacer
  HIDE fmReplace
END_SUB

SUB executer

END_SUB

SUB syntaxe_panoramic
  PRINT "syntaxe_panoramic"
END_SUB

SUB syntaxe_fbpano
  PRINT "syntaxe_fbpano"
END_SUB

SUB wrap
  DIM n%
  IF CHECKED(btWrap)=1 THEN n = 1 ELSE n = 0
  EDITOR_WRAP editor1, n
END_SUB

SUB affichage_numlines
  DIM n%
  fontsize = GET_POSITION(tbSize)
  IF CHECKED(btLine)=1 THEN n = LNUM_WIDTH ELSE n = 0
  FONT_TEXT editor1, font, fontsize
  EDITOR_NUMLINES editor1, n, font, fontsize
  REDRAW
END_SUB

SUB choix_parametres
  SHOW fmParametres
END_SUB

SUB changer_taille_police
  fontsize = GET_POSITION(tbSize)
  FONT_TEXT editor1, font, fontsize
  EDITOR_NUMLINES editor1, LNUM_WIDTH, font, fontsize
  REDRAW
END_SUB

SUB changer_police
  DIM f$
  f = LIST_ITEM_READ(lsPolice, LIST_ITEM_INDEX(lsPolice))
  f = MID(f, INSTR(f, ".") + 1)
  font = NUM_FONT(f)
  FONT_TEXT editor1, font, fontsize
  EDITOR_NUMLINES editor1, LNUM_WIDTH, font, fontsize
  REDRAW
END_SUB

SUB changer_couleur
  DIM r%, g%, b%
  color_chooser_get_rgb CoulChoix, r, g, b
 
  IF checked(rdColFond)=1 THEN TEXT edResult, "Fond" : COLOR_RGB edResult, r, g, b
  IF checked(rdColText)=1 THEN TEXT edResult, "Texte" : COLOR_TEXT_RGB edResult, r, g, b
  IF checked(rdColNomb)=1 THEN TEXT edResult, "Nombre" : COLOR_TEXT_RGB edResult, r, g, b
  IF checked(rdColCom)=1 THEN TEXT edResult, "Commentaires" : COLOR_TEXT_RGB edResult, r, g, b
  IF checked(rdColMC)=1 THEN TEXT edResult, "Mots clés" : COLOR_TEXT_RGB edResult, r, g, b
  IF checked(rdColPp)=1 THEN TEXT edResult, "Préprocesseur" : COLOR_TEXT_RGB edResult, r, g, b
  IF checked(rdColAutr)=1 THEN TEXT edResult, "Autre" : COLOR_TEXT_RGB edResult, r, g, b
END_SUB

SUB cacher_parametres
  HIDE fmParametres
END_SUB

ENUM GUI
  fmMain                          ' Form principale
     menu1, editor1, buffer1, stylebuffer1

FORM fmMain, 15, 35, FORM_WIDTH, FORM_HEIGHT, "Editeur"
   FORM_BEGIN fmMain
      .....
      TEXT_BUFFER buffer1, style_update
      TEXT_BUFFER stylebuffer1

EDITOR_SET_BUFFER editor1, buffer1
EDITOR_SET_STYLEBUFFER editor1, stylebuffer1

IF checked(rdColText)=1 THEN
     PRINT "Couleur Texte ", r, g, b
     add_style "T", fl_rgb(r, g, b), font, fontsize
END_IF

.... etc (pareil pour les autres styles) ....

sub style_update
  dim p1%, p2%, txt$, style$, last$

  if fl_n_inserted = 0 and fl_n_deleted = 0 then
    buffer_unselect stylebuffer1
    exit_sub
  end_if

  if fl_n_inserted > 0 then
    style = string(fl_n_inserted, "A")
    buffer_replace stylebuffer1, fl_cursor_pos, fl_cursor_pos + fl_n_deleted, style
  else
    buffer_remove stylebuffer1, fl_cursor_pos, fl_cursor_pos + fl_n_deleted
  end_if

  buffer_select stylebuffer1, fl_cursor_pos, fl_cursor_pos + fl_n_inserted - fl_n_deleted

  p1 = buffer_line_start(buffer1, fl_cursor_pos)
  p2 = buffer_line_end(buffer1, fl_cursor_pos + fl_n_inserted - fl_n_deleted)

  if p1 >= p2 then exit_sub

  txt = buffer_text_range(buffer1, p1, p2)
  style = buffer_text_range(stylebuffer1, p1, p2)
  last = right(style, 1)

  gen_style txt, keywords, style

  buffer_replace stylebuffer1, p1, p2, style
  editor_redisplay_range buffer1, p1, p2
end_sub

#lang "fb"

' **********************************************************************
' Editeur FBPano, d'apres le programme de demonstration de FLTK : www.fltk.org/doc-1.3/editor.html
' Modification par MiNiBuG
' **********************************************************************

#compile -gui

CONST FORM_WIDTH  = 750                                  ' Largeur de la fenetre principale
CONST FORM_HEIGHT = 500                                  ' Hauteur de la fenetre principale
CONST LNUM_WIDTH  = 60                                   ' Largeur de la marge pour num. lignes

TYPE RGBCoul = (R%, G%, B%)                              ' Choix des Couleurs RGB

DIM Coul<RGBCoul>                                        ' Choix des Couleurs RGB
DIM Fond<RGBCoul>                                        ' Couleur fond RGB
DIM Lin<RGBCoul>                                         ' Couleur texte lignes RGB
DIM Nbr<RGBCoul>                                         ' Couleur nombres RGB
DIM Com<RGBCoul>                                         ' Couleur commentaire RGB
DIM Mc<RGBCoul>                                          ' Couleur mots clés RGB
DIM Pp<RGBCoul>                                          ' Couleur Préprocesseur RGB
DIM Autr<RGBCoul>                                        ' Couleur autre RGB

DIM search$                                              ' Chaine pour la recherche
DIM find$, rep$                                          ' Chaines pour le remplacement
DIM nf%                                                  ' Nb de polices
DIM fontnum%()                                           ' Numéros des polices
DIM fontname$()                                          ' Noms des polices
DIM fontsize% = 16                                       ' Taille de la police
DIM font%                                                ' Police selectionnee
DIM i%                                                   ' Variable de boucle
DIM keywords$                                            ' Liste des mots_cles

ENUM GUI
  fmMain                                                 ' Form principale
     menu1, editor1, buffer1, stylebuffer1
  fmReplace                                              ' Form rechercher/remplacer
     edFind, edReplace, btRepAll, btRepNext, btCancel
  fmParametres                                           ' Form paramètres
     lsPolice, tbSize, btFermerParam, btWrap, btLin
     ctCouleur                                              ' Container couleurs
        rdFond, rdText, rdNomb, rdCom, rdMc, rdPp, rdAutr
        CoulChoix, edResult
END_ENUM

FORM fmMain, 15, 35, FORM_WIDTH, FORM_HEIGHT, "Editeur"
   FORM_BEGIN fmMain
      MENU menu1, 0, 0, FORM_WIDTH, 25
      TEXT_EDITOR editor1,  0, 25, FORM_WIDTH, FORM_HEIGHT - 25
      TEXT_BUFFER buffer1, style_update
      TEXT_BUFFER stylebuffer1
   FORM_END fmMain

FORM fmReplace, 200, 200, 380, 110, "Remplacement"
   FORM_BEGIN fmReplace
      EDIT edFind,    110, 10, 260, 25, "Chercher :"
      EDIT edReplace, 110, 40, 260, 25, "Remplacer par :"
      BUTTON btRepAll,   10, 75, 110, 25, "Remplacer tout"
      BUTTON btRepNext, 130, 75, 170, 25, "Remplacer Suivant", , T_Button_Return
      BUTTON btCancel,  310, 75,  60, 25, "Fermer"
   FORM_END fmReplace

FORM fmParametres, 200, 200, 380, 420, "Liste des polices"
   FORM_BEGIN fmParametres
      LIST lsPolice, 5, 5, 180, 375
      nf = FONT_LIST(fontnum(), fontname())
      FOR i = 0 TO nf - 1
         LIST_ITEM_ADD lsPolice, "@S12@F" & "@." & fontname(i)
         IF fontname(i) = "Courier New" THEN
           LIST_ITEM_SELECT lsPolice, i + 1
           font = fontnum(i)
         END_IF
      NEXT i

      TRACK_BAR tbSize, 225, 5, 150, 25, "Taille", FL_ALIGN_LEFT, T_Track_Val
      FONT_TEXT tbSize, font, 16
      POSITION_RANGE tbSize, 8, 30, 1
      POSITION tbSize, fontsize
      BUTTON btWrap, 190, 35, 185, 30, "Retour à la ligne", , T_Button_Light
      BUTTON btLin, 190, 65, 185, 30, "Affichage lignes", , T_Button_Light
      MARK_ON btLin

      CONTAINER ctCouleur, 190, 100, 185, 280, "", , T_Container
         CONTAINER_BEGIN ctCouleur
            RADIO rdFond, 195, 102, 175, 30, "Fond"
            RADIO rdText, 195, 122, 175, 30, "Chaines texte"
            RADIO rdNomb, 195, 142, 175, 30, "Nombres"
            RADIO rdCom, 195, 162, 175, 30, "Commentaires"
            RADIO rdMc, 195, 182, 175, 30, "Mots clés"
            RADIO rdPp, 195, 202, 175, 30, "Préprocesseur"
            RADIO rdAutr, 195, 222, 175, 30, "Autre"
            MARK_ON rdFond
            COLOR_CHOOSER CoulChoix, 195, 247, 175, 100, , , FL_COLORCHOOSER_BYTE
            EDIT edResult, 195, 350, 175, 25
 CONTAINER_END ctCouleur

      BUTTON btFermerParam, 5, 385, 370, 30, "Fermer"
   FORM_END fmParametres

ON_CLICK btRepAll, remplacer_tout
ON_CLICK btRepNext, remplacer_suivant
ON_CLICK btCancel, annuler_remplacer
ON_CLICK lsPolice, changer_police
ON_CLICK btFermerParam, cacher_parametres
ON_CLICK tbSize, changer_taille_police
ON_CLICK btWrap, wrap
ON_CLICK btLin, affichage_numLines

ON_CLICK CoulChoix, choix_couleur                   ' Sélection dans le Color_Chooser

ON_CLICK rdFond, changer_couleur_fond               ' Sélection de la couleur de fond
ON_CLICK rdText, changer_couleur_text               ' Sélection de la couleur du texte
ON_CLICK rdNomb, changer_couleur_nomb               ' Sélection de la couleur des nombres
ON_CLICK rdCom, changer_couleur_com                 ' Sélection de la couleur des commentaires
ON_CLICK rdMc, changer_couleur_mc                   ' Sélection de la couleur des mots clés
ON_CLICK rdPp, changer_couleur_pp                   ' Sélection de la couleur du préprocesseur
ON_CLICK rdAutr, changer_couleur_autr               ' Sélection de la couleur autre

MENU_ITEM_ADD menu1, "&Fichier/&Nouveau ", "Ctrl+N", , nouveau
MENU_ITEM_ADD menu1, "&Fichier/&Ouvrir ", "Ctrl+O", , ouvrir
MENU_ITEM_ADD menu1, "&Fichier/&Enregistrer ", "Ctrl+E", FL_MENU_DIVIDER, enregistrer
MENU_ITEM_ADD menu1, "&Fichier/&Quitter ", "Ctrl+Q", , quitter

MENU_ITEM_ADD menu1, "E&dition/Co&uper ", "Ctrl+X", , couper
MENU_ITEM_ADD menu1, "E&dition/&Copier ", "Ctrl+C", , copier
MENU_ITEM_ADD menu1, "E&dition/Co&ller ", "Ctrl+V", , coller

MENU_ITEM_ADD menu1, "&Rechercher/&Rechercher ", "Ctrl+F", , rechercher
MENU_ITEM_ADD menu1, "&Rechercher/Rechercher le &suivant ", "F3", , rechercher_suivant
MENU_ITEM_ADD menu1, "&Rechercher/R&emplacer ", "Ctrl+R", , remplacer

MENU_ITEM_ADD menu1, "&Exécution/E&xécuter ", "F9", , executer

MENU_ITEM_ADD menu1, "O&ptions/&Paramètres ", "Ctrl+P", , choix_parametres

FORM_MINSIZE fmMain, 500, 300                       ' Limitation de la taille minimum d'affichage
SET_RESIZABLE fmMain, editor1                       ' Taille modifiable uniquement pour l'éditeur

EDITOR_NUMLINES editor1, LNUM_WIDTH, font, fontsize

EDITOR_SET_BUFFER editor1, buffer1
EDITOR_SET_STYLEBUFFER editor1, stylebuffer1

IF FILE_EXISTS(exepath()+"\ini\coulsynt.ini")=TRUE THEN
   FILE_OPEN_READ(1, exepath()+"\ini\coulsynt.ini")
      FILE_READ_CSV 1, Fond.R, Fond.G, Fond.B : FILE_READ_CSV 1, Lin.R, Lin.G, Lin.B
      FILE_READ_CSV 1, Nbr.R, Nbr.G, Nbr.B
      FILE_READ_CSV 1, Com.R, Com.G, Com.B
      FILE_READ_CSV 1, Mc.R, Mc.G, Mc.B
      FILE_READ_CSV 1, Pp.R, Pp.G, Pp.B
      FILE_READ_CSV 1, Autr.R, Autr.G, Autr.B
   FILE_CLOSE(1)
   COLOR_NUMLINES_RGB editor1, Lin.R, Lin.G, Lin.B, Fond.R, Fond.G, Fond.B
   COLOR_RGB editor1,Fond.R, Fond.G, Fond.B
END_IF

charger_keyword_fbpano
changer_styles

START fmMain

' ----------------------------------------------------------------------
' Sous-programmes utilitaires
' ----------------------------------------------------------------------

FUNCTION trouve% (s$, p%, msg%)
   ' Recherche la chaine s à partir de la position du curseur
   ' La position de la chaine trouvee est retournee dans p
   ' msg = TRUE pour afficher le message d'erreur

   p = EDITOR_GET_INSERT_POS(editor1)
   IF BUFFER_SEARCH_FORWARD(buffer1, p, s, p) = 0 THEN
      IF msg THEN MESSAGE "Chaîne """ + s + """ non trouvée !"
      trouve = FALSE
   ELSE
      trouve = TRUE
   END_IF
END_FUNCTION

SUB update_editor (p%, s1$, s2$, rpl%)
   ' Met a jour l'editeur apres recherche ou remplacement
   ' p = position de la chaine recherchee
   ' s1 = chaine recherchee
   ' s2 = chaine de remplacement
   ' rpl = indique si remplacement

   DIM p1%

   p1 = p + LEN(s1)
   BUFFER_SELECT buffer1, p, p1

   IF rpl THEN
      BUFFER_REMOVE_SELECT buffer1
      BUFFER_INSERT buffer1, p, s2
      p1 = p + LEN(s2)
      BUFFER_SELECT buffer1, p, p1
      p = p1
   END_IF

   EDITOR_SET_INSERT_POS editor1, p1
   EDITOR_SHOW_INSERT_POS editor1
END_SUB

SUB changer_styles
   ADD_STYLE "T", FL_RGB(Lin.R, Lin.G, Lin.B), font, fontsize
   ADD_STYLE "N", FL_RGB(Nbr.R, Nbr.G, Nbr.B), font, fontsize
   ADD_STYLE "C", FL_RGB(Com.R, Com.G, Com.B), font, fontsize
   ADD_STYLE "M", FL_RGB(Mc.R, Mc.G, Mc.B), font, fontsize
   ADD_STYLE "P", FL_RGB(Pp.R, Pp.G, Pp.B), font, fontsize
   ADD_STYLE "A", FL_RGB(Autr.R, Autr.G, Autr.B), font, fontsize
   ADD_STYLE "S", FL_RGB(Autr.R, Autr.G, Autr.B), font, fontsize
   REDRAW
END_SUB  
  
  
' ----------------------------------------------------------------------
' Sous-programmes associes aux evenements
' ----------------------------------------------------------------------

SUB nouveau
   TEXT buffer1, ""
   CAPTION fmMain, "Editeur"
END_SUB

SUB ouvrir
   DIM fname$, texte$, res% : res=0
   fname = FILE_NAME("Ouvrir", "Fichier basic (*.bas)", CURDIR, 0)
   IF fname = "" OR FILE_EXISTS(fname) = 0 THEN EXIT_SUB
   BUFFER_FILE_LOAD buffer1, fname
   CAPTION fmMain, fname

   texte=UCASE(GET_TEXT(buffer1))
   IF INSTR(texte, "ENUM ")>0 THEN res=1
   IF INSTR(texte, "FORM_BEGIN ")>0 THEN res=1
   ' IF INSTR(texte, "START ")>0 THEN res=1
   IF res=1 THEN
      charger_keyword_fbpano
   ELSE
      charger_keyword_panoramic
   END_IF
   REDRAW
END_SUB

SUB enregistrer
   DIM fname$
   fname = FILE_NAME("Enregistrer", "Fichier texte (*.txt)", CURDIR, 0)
   IF fname = "" THEN EXIT_SUB
   BUFFER_FILE_SAVE buffer1, fname
END_SUB

SUB quitter
   HIDE fmMain
END_SUB

SUB couper
   EDITOR_CUT editor1
END_SUB

SUB copier
   EDITOR_COPY editor1
END_SUB

SUB coller
   EDITOR_PASTE editor1
END_SUB

SUB rechercher
   DIM p%
   search = MESSAGE_INPUT("Rechercher", "Rechercher", search)
   IF search <> "" THEN
      IF trouve(search, p, TRUE) THEN update_editor p, search, "", FALSE
   END_IF
END_SUB

SUB rechercher_suivant
   DIM p%
   IF search = "" THEN
      search = message_input("Rechercher", "Rechercher", search)
   END_IF
   IF search <> "" THEN
      IF trouve(search, p, TRUE) THEN update_editor p, search, "", FALSE
   END_IF
END_SUB

SUB remplacer
   SHOW fmReplace
END_SUB

SUB remplacer_suivant
   DIM p%
   find = GET_TEXT(edFind)
   IF find = "" THEN EXIT_SUB
   rep = GET_TEXT(edReplace)
   IF trouve(find, p, TRUE) THEN update_editor p, find, rep, TRUE
END_SUB

SUB remplacer_tout
   DIM p%, found%, n%
   find = GET_TEXT(edFind)
   IF find = "" THEN EXIT_SUB
   rep = GET_TEXT(edReplace)
   found = trouve(find, p, TRUE)
   IF NOT found THEN EXIT_SUB
   WHILE found
      n = n + 1
      update_editor p, find, rep, TRUE
      found = trouve(find, p, FALSE)
   END_WHILE
   MESSAGE "Chaîne """ & find & """ remplacée " & n & " fois."
END_SUB

SUB annuler_remplacer
   HIDE fmReplace
END_SUB

SUB executer

END_SUB

SUB charger_keyword_fbpano
   FILE_OPEN_READ(1, exepath()+"\ini\mcfbpano.ini")
      FILE_READLN 1,keywords
   FILE_CLOSE(1)
   MESSAGE "Votre programme contient une syntaxe_fbpano"
END_SUB

SUB charger_keyword_panoramic
   FILE_OPEN_READ(1, exepath()+"\ini\mcpano.ini")
      FILE_READLN 1,keywords
   FILE_CLOSE(1)
   MESSAGE "Votre programme contient une syntaxe_panoramic"
END_SUB

SUB wrap
   DIM n%
   IF CHECKED(btWrap)=1 THEN n = 1 ELSE n = 0
   EDITOR_WRAP editor1, n
END_SUB

SUB affichage_numLines
   DIM n%
   fontsize = GET_POSITION(tbSize)
   IF CHECKED(btLin)=1 THEN n = LNUM_WIDTH ELSE n = 0
   FONT_TEXT editor1, font, fontsize
   EDITOR_NUMLINES editor1, n, font, fontsize
   REDRAW
END_SUB

SUB choix_parametres
   SHOW fmParametres
END_SUB

SUB cacher_parametres
   HIDE fmParametres
END_SUB

SUB changer_taille_police
   fontsize = GET_POSITION(tbSize)
   FONT_TEXT editor1, font, fontsize
   EDITOR_NUMLINES editor1, LNUM_WIDTH, font, fontsize
   changer_styles
END_SUB

SUB changer_police
   DIM f$
   f = LIST_ITEM_READ(lsPolice, LIST_ITEM_INDEX(lsPolice))
   f = MID(f, INSTR(f, ".") + 1)
   font = NUM_FONT(f)
   EDITOR_NUMLINES editor1, LNUM_WIDTH, font, fontsize
   FONT_TEXT editor1, font, fontsize
   changer_styles
END_SUB

SUB choix_couleur
   COLOR_CHOOSER_GET_RGB CoulChoix, Coul.R, Coul.G, Coul.B

   IF CHECKED(rdFond)=1 THEN
      TEXT edResult, "Fond" : COLOR_RGB edResult, Coul.R, Coul.G, Coul.B
      Fond.R = Coul.R : Fond.G = Coul.G : Fond.B = Coul.B
      COLOR_NUMLINES_RGB editor1, Lin.R, Lin.G, Lin.B, Fond.R, Fond.G, Fond.B   ' Couleur fond et texte des lignes de l'éditeur
      COLOR_RGB editor1,Fond.R, Fond.G, Fond.B                                    ' Couleur fond de l'éditeur
      REDRAW
   END_IF
   IF CHECKED(rdText)=1 THEN
      TEXT edResult, "Texte" : COLOR_TEXT_RGB edResult, Coul.R, Coul.G, Coul.B
      Lin.R = Coul.R : Lin.G = Coul.G : Lin.B = Coul.B
      COLOR_NUMLINES_RGB editor1, Lin.R, Lin.G, Lin.B, Fond.R, Fond.G, Fond.B   ' Couleur texte des lignes de l'éditeur
      changer_styles
   END_IF
   IF CHECKED(rdNomb)=1 THEN
      TEXT edResult, "Nombre" : COLOR_TEXT_RGB edResult, Coul.R, Coul.G, Coul.B
      Nbr.R = Coul.R : Nbr.G = Coul.G : Nbr.B = Coul.B
      changer_styles
   END_IF
   IF CHECKED(rdCom)=1 THEN
      TEXT edResult, "Commentaires" : COLOR_TEXT_RGB edResult, Coul.R, Coul.G, Coul.B
      Com.R = Coul.R : Com.G = Coul.G : Com.B = Coul.B
      changer_styles
   END_IF
   IF CHECKED(rdMc)=1 THEN
      TEXT edResult, "Mots clés" : COLOR_TEXT_RGB edResult, Coul.R, Coul.G, Coul.B
      Mc.R = Coul.R : Mc.G = Coul.G : Mc.B = Coul.B
      changer_styles
   END_IF
   IF CHECKED(rdPp)=1 THEN
      TEXT edResult, "Préprocesseur" : COLOR_TEXT_RGB edResult, Coul.R, Coul.G,Coul.B
      Pp.R = Coul.R : Pp.G = Coul.G : Pp.B = Coul.B
      changer_styles
   END_IF
   IF CHECKED(rdAutr)=1 THEN
      TEXT edResult, "Autre" : COLOR_TEXT_RGB edResult, Coul.R, Coul.G,Coul.B
      Autr.R = Coul.R : Autr.G = Coul.G : Autr.B = Coul.B
      changer_styles
   END_IF
   FILE_OPEN_WRITE(1, exepath()+"\ini\coulsynt.ini")
      FILE_WRITE_CSV 1, Fond.R, Fond.G, Fond.B
      FILE_WRITE_CSV 1, Lin.R, Lin.G, Lin.B
      FILE_WRITE_CSV 1, Nbr.R, Nbr.G, Nbr.B
      FILE_WRITE_CSV 1, Com.R, Com.G, Com.B
      FILE_WRITE_CSV 1, Mc.R, Mc.G, Mc.B
      FILE_WRITE_CSV 1, Pp.R, Pp.G, Pp.B
      FILE_WRITE_CSV 1, Autr.R, Autr.G, Autr.B
   FILE_CLOSE(1)
END_SUB

SUB changer_couleur_fond
   COLOR_CHOOSER_SET_RGB CoulChoix, Fond.R, Fond.G, Fond.B
END_SUB

SUB changer_couleur_text
   COLOR_CHOOSER_SET_RGB CoulChoix, Lin.R, Lin.G, Lin.B
END_SUB

SUB changer_couleur_nomb
   COLOR_CHOOSER_SET_RGB CoulChoix, Nbr.R, Nbr.G, Nbr.B
END_SUB

SUB changer_couleur_com
   COLOR_CHOOSER_SET_RGB CoulChoix, Com.R, Com.G, Com.B
END_SUB

SUB changer_couleur_mc
   COLOR_CHOOSER_SET_RGB CoulChoix, Mc.R, Mc.G, Mc.B
END_SUB

SUB changer_couleur_pp
   COLOR_CHOOSER_SET_RGB CoulChoix, Pp.R, Pp.G, Pp.B
END_SUB

SUB changer_couleur_autr
   COLOR_CHOOSER_SET_RGB CoulChoix, Autr.R, Autr.G, Autr.B
END_SUB

SUB style_update
   DIM p1%, p2%, txt$, style$, last$

   IF fl_n_inserted = 0 AND fl_n_deleted = 0 THEN
      BUFFER_UNSELECT stylebuffer1
      EXIT_SUB
   END_IF

   IF fl_n_inserted > 0 THEN
      style = STRING(fl_n_inserted, "A")
      BUFFER_REPLACE stylebuffer1, fl_cursor_pos, fl_cursor_pos + fl_n_deleted, style
   else
      BUFFER_REMOVE stylebuffer1, fl_cursor_pos, fl_cursor_pos + fl_n_deleted
   END_IF

   BUFFER_SELECT stylebuffer1, fl_cursor_pos, fl_cursor_pos + fl_n_inserted - fl_n_deleted

   p1 = BUFFER_LINE_START(buffer1, fl_cursor_pos)
   p2 = BUFFER_LINE_END(buffer1, fl_cursor_pos + fl_n_inserted - fl_n_deleted)

   IF p1 >= p2 THEN EXIT_SUB

   txt = BUFFER_TEXT_RANGE(buffer1, p1, p2)
   style = BUFFER_TEXT_RANGE(stylebuffer1, p1, p2)
   last = RIGHT(style, 1)

   GEN_STYLE txt, keywords, style

   BUFFER_REPLACE stylebuffer1, p1, p2, style
   EDITOR_REDISPLAY_RANGE buffer1, p1, p2
END_SUB