Conso-essence

' dépense,conso et moyenne pour ma Citroen c4
'  
error_french

variables()      :' en ligne 14
labels()         :' en ligne 66
gui()            :' en ligne 72
init()           :' en ligne 229

end

' -----------------------------------------------------------------------------

sub variables()    :' vient de 5
  dim_local i%

  dim Path$  : Path$=dir_current$     :' retourne le repertoire courant
  if right$(Path$,1)="\" : Path$=left$(Path$,len(Path$)-1) : end_if
  Path$=Path$+"\"
  dim Param$  : Param$= Path$+"Param.inf"
  dim ListeV$ : ListeV$=Path$+"ListeV.txt"    :' pour villes
  dim ListeC$ : ListeC$=Path$+"ListeC.txt"    :' pour citroen C4
  dim Histo$  : Histo$ =Path$+"Histo.txt"
  dim PathCar$: PathCar$=Path$+"Vehicules\"

  dim KGF$

  dim no%       :' no% ---> pour numéroter ,incrémenter les objets
  dim Mm%     : no%=no%+1 : Mm%=no%     :' donc main menu  = 1
  dim Sm%(11) : for i%=1 to 11 : no%=no%+1 : Sm%(i%)=no%  : next i%    :' sous/menu de Main menu  donc objets 2 a 12
  dim Pan%(4) : for i%=0 to 4  : no%=no%+1 : Pan%(i%)=no% : next i%    :' panels de récup des dimensions de travail du form 0: donc objets 13 a 17

  dim Alph%(7)   : for i%=1 to 7  : no%=no%+1 : Alph%(i%)=no%: next i%       :' pour alpha    donc objets 18 a 24
  dim Edi%(6)    : for i%=1 to 6  : no%=no%+1 : Edi%(i%)=no% : next i%       :' pour edit     donc objets 25 a 30
  dim Comb%      : no%=no%+1 : Comb%=no%                                     :' pour combo    donc objet 31
  dim BtnCpt%    : no%=no%+1 : BtnCpt%=no%                                   :' pour bouton   donc objet 32
  dim Btn%       : no%=no%+1 : Btn%=no%                                      :' pour button   donc objets 33
  dim Gril%      : no%=no%+1 : Gril%=no%                                     :' pour          donc objet 34
  dim Mem%       : no%=no%+1 : Mem%=no%                                      :' pour          donc objet 35
  dim MemV%      : no%=no%+1 : MemV%=no%                                     :' pour          donc objet 36
  dim ApanTtl%(4): for i%=1 to 4  : no%=no%+1 : ApanTtl%(i%)=no% : next i%   :' pour          donc objets  37 a 41

 dim Odial%  : no%=no%+1 : Odial%=no%                                        :' pour Open dialogue    objet 42

 dim F_OW%  : no%=no%+1 : F_OW%=no%                                          :' pour File_open_write   objet 43
 dim F_OR%  : no%=no%+1 : F_OR%=no%                                          :' pour File_open_read    objet 44

  dim NbreR%       :' nombre de lignes du grid
  dim NbreC%       :' nombre de colonnes du grid
  dim Car$

  dim distparcourue
  dim TotalKm       : TotalKm = 0         :' pour compteur total
  dim dist
  dim conso
  dim conso100
  dim consototale
  dim TotalEuro     : TotalEuro = 0
  dim prixlit
  dim moyengene
  dim Minter        : ' =  moyenne intermediaire
end_sub

' ------------------------------------------------------------------------------

sub labels()    :' vient de 6
 label clic , close , affichage
end_sub

' -------------------------------------------------------

sub gui()        :' vient de 7
  dim_local h%,w%,t%,a$,i%,l%,b$

  height 0,665    
  width 0,1330
  top 0,(screen_y-height(0))/2
  left 0,(screen_x-width(0))/2
  caption 0,"CONSOMMATION  CARBURANT de ma  "
  on_close 0,close

  main_menu Mm%
  ' menu n°1
  sub_menu Sm%(1) : parent Sm%(1),Mm% : caption Sm%(1),"Véhicule"      :' objet n°1
  sub_menu Sm%(2) : parent Sm%(2),Sm%(1): caption Sm%(2),"Nouveau"     : on_click Sm%(2),clic   :' objet n°2  lignes 294
  sub_menu Sm%(3) : parent Sm%(3),Sm%(1): caption Sm%(3),"Ouvrir"      : on_click Sm%(3),clic   :' objet n°3  lignes 299
  sub_menu Sm%(4) : parent Sm%(4),Sm%(1): caption Sm%(4),"Enregistrer" : on_click Sm%(4),clic   :' objet n°4  lignes 304
  sub_menu Sm%(5) : parent Sm%(5),Sm%(1): caption Sm%(5),"-"                                    :' objet n°5
  sub_menu Sm%(6) : parent Sm%(6),Sm%(1): caption Sm%(6),"Quitter"     : on_click Sm%(6),clic   :' objet n°6  lignes 309
  ' menu 2
  sub_menu Sm%(7) : parent Sm%(7),Mm% : caption Sm%(7),"Affichage"                                               :' objet 8
  sub_menu Sm%(8) : parent Sm%(8),Sm%(7): caption Sm%(8),"Table"      : mark_on Sm%(8) : on_click Sm%(8),clic    :' objet 9   ligne 314
  sub_menu Sm%(9) : parent Sm%(9),Sm%(7): caption Sm%(9),"Graphique"  : mark_off Sm%(9): on_click Sm%(9),clic    :' objet 10   ligne 322
  ' menu n°3
  sub_menu Sm%(10) : parent Sm%(10),Mm% : caption Sm%(10),"Paramètres"                                         :' objet n°10  
  sub_menu Sm%(11) : parent Sm%(11),Sm%(10): caption Sm%(11),"KGF.dll - Rechercher sur PC"    : on_click Sm%(11),clic  :' objet n°11  lignes 335

  panel Pan%(0)          :' objet 12
  full_space Pan%(0)
  h%=height(Pan%(0))
  w%=width(Pan%(0))

  panel Pan%(1)          :' objet 13  , c'est la partie gauche là ou est le questionnaire
  parent Pan%(1),Pan%(0)
  height Pan%(1),h%-24
  width Pan%(1),270
  top Pan%(1),0
  left Pan%(1),0
  color Pan%(1),251,208,175
  
  a$=" DATE, LIEU, QUANTITE MISE, MONTANT €, COMPTEUR KM TOTAL, "
  t%=-30
  for i%=1 to 5
    t%=t%+50
    alpha Alph%(i%)
    parent Alph%(i%),Pan%(1)
    top Alph%(i%),t%
    left Alph%(i%),10
    caption Alph%(i%),left$(a$,instr(a$,",")-1)
    if i%<5
      a$=right$(a$,len(a$)-instr(a$,","))
    end_if
    font_name Alph%(i%),"Times new roman"
    font_bold Alph%(i%)
  next i%

  t%=-15
  for i%=1 to 4      :' 4 éléments on saute le combo pour le " lieu "
    edit Edi%(i%)
    parent Edi%(i%),Pan%(1)
    color Edi%(i%),254,240,205
    if i%=2
      t%=t%+100
    else
      t%=t%+50
        if i%=1 or i%=4 or i%=5
          width Edi%(i%),90
        end_if
    end_if
      top Edi%(i%),t%
      left Edi%(i%),10
      font_name Edi%(i%),"Arial"
  next i%

  combo Comb%                :' c'est le 5em élément qui correspond a " lieu "
  parent Comb%,Pan%(1)
  top Comb%,85
  left Comb%,10
  width Comb%,250
  font_name Comb%,"Arial"
  font_size Comb%,10
  color Comb%,254,240,205
  if file_exists(ListeV$)=1 : file_load Comb%,ListeV$ : end_if
  
  l%=width(Pan%(1))-151
  a$="<,"
  b$="Enregistrer les données," :'  formulaire,"
  button Btn% :' objets 32
  parent Btn%,Pan%(1)
  height Btn%,42
  width Btn%,42
  top Btn%,height(Pan%(1))-47
  left Btn%,l%
  font_name Btn%,"Wingdings"
  font_size Btn%,12
  caption Btn%,a$
  hint Btn%,b$
  cursor_point Btn%
  on_click Btn%,clic

  panel Pan%(2)                :' objet 15
  parent Pan%(2),Pan%(0)
  height Pan%(2),h%-24
  width Pan%(2),w%-270
  top Pan%(2),0
  left Pan%(2),270
  color Pan%(2),251,108,105

  Grid Gril%                   :' objet 35
  parent Gril%,Pan%(2)
  height Gril%,height(Pan%(2))-20
  width Gril%,width(Pan%(2))-20
  top Gril%,10
  left Gril%,10
  font_name Gril%,"Arial"
  NbreR% =2
  NbreC% =8
  InitialiseGrid(NbreR%,NbreC%)  :' en ligne 266
  color Gril%,254,240,205
  inactive Gril%

  panel Pan%(3)                  :' objet 16
  parent Pan%(3),Pan%(0)
  height Pan%(3),24
  width Pan%(3),w%
  top Pan%(3),h%-24
  left Pan%(3),0
  color Pan%(3),51,208,105

  l%=-230
  for i%=1 to 4
    l%=l%+300
    Alpha ApanTtl%(i%)
    parent ApanTtl%(i%),Pan%(3)
    top ApanTtl%(i%),5
    left ApanTtl%(i%),l%
    font_name ApanTtl%(i%),"Arial"
    font_size ApanTtl%(i%),10
    font_bold ApanTtl%(i%)
  next i%
  
 Create_hide
 
  panel Pan%(4)              :' objet 17 pour le graphique
  parent Pan%(4),Pan%(0)
  height Pan%(4),h%-24
  width Pan%(4),w%-270
  top Pan%(4),0
  left Pan%(4),270
  color Pan%(4),255,255,255

  dlist Mem%
  dlist MemV%
  if file_exists(ListeV$)=1 : file_load Comb%,ListeV$ : end_if
end_sub

' ------------------------------------------------------------------------------

sub init()       :' vient de 8
dim_local a$

  if dir_exists(PathCar$)=0 then dir_make PathCar$
  if file_exists(ListeC$)=1 : file_load Mem%,ListeC$ : end_if

  if file_exists(Param$)=0
    if file_exists(Kgf$)=0
      if message_warning_yes_no("La dll KGF.dll n' a pas été trouvée !"+Chr$(13)+"Voulez vous indiquer son emplacement sur votre ordinateur ?")=1
        Open_dialog Odial%
        dir_dialog Odial%,"C:\"
        filter Odial%,"*.dll|*.dll"
        a$=file_name$(Odial%)
        delete Odial%

        if a$<>"_"
          KGF$=a$
          file_open_write F_OW%,Param$
          file_writeln F_OW%,KGF$
          file_close F_OW%
        else
          Message "Vous ne disposez pas de cette dll."+chr$(13)+"Vous pouvez la télécharger à cette adresse :"+chr$(13)+"http://klauspanoramic.comxa.com/versions/KGF.zip"
          inactive Sm%(9)
        end_if
        else
          inactive Sm%(9)
      end_if
    end_if
    else
      File_open_read F_OR%,Param$
      file_readln F_OR%,KGF$
      file_close F_OR%
  end_if
end_sub

' ------------------------------------------------------------------------------

sub InitialiseGrid(R%,C%)     :' vient de  188 -
  dim_local i%,a$
  
  a$=" DATE, LIEU, QUANTITE MISE, MONTANT €, COMPTEUR KM TOTAL, PRIX € / L, DIST PARCOURUE , MOYENNE /100, "

  grid_row_fixed Gril%,1
  grid_column_fixed Gril%,0
  grid_row Gril%,R%       :' 2 lignes
  grid_column Gril%,C%    :' 8 colonnes
  grid_one_column_width Gril%,1,100       :' pour date
  grid_one_column_width Gril%,2,190       :' pour lieu
  grid_one_column_width Gril%,3,120       :' pour quantité mise
  grid_one_column_width Gril%,4,90        :' pour montant
  grid_one_column_width Gril%,5,160       :' compteur km total
  grid_one_column_width Gril%,6,80        :' pour prix au litre
  grid_one_column_width Gril%,7,140       :' pour distance parcourue
  grid_one_column_width gril%,8,130       :' moyenne aux 100
  for i%=1 to 8
    grid_write Gril%,1,i%,left$(a$,instr(a$,",")-1)
      if i%<8
        a$=right$(a$,len(a$)-instr(a$,","))
      end_if
  next i%
end_sub

' -----------------------------------------------------------------------------

clic:     :' vient de 85,86,87,89,92,93,96
  if number_click = Sm%(2):' vient de 85
    NewCar()                 :' ligne 348 ---> pour moi Citroen C4
    return
  end_if

  if number_click = Sm%(3)    :' vient de 86
    OpenCar()                 :' en ligne  586 * --->  ma C4
    return
  end_if

  if number_click = Sm%(4)    :' vient de 87
    SaveCar()                 :' en ligne 578     ---> ma C4
    return
  end_if

  if number_click = Sm%(6)   :' vient de 89
    Quitter()                :' en ligne 589
    return
  end_if

  if number_click = Sm%(8)   :' vient de 92
    mark_on Sm%(8)
    mark_off Sm%(9)
    hide Pan%(4)
    show Pan%(2)
    return
  end_if

  if number_click = Sm%(9)    :' vient de 93
    if Car$<>""
    mark_on Sm%(9)
    mark_off Sm%(8)
    hide Pan%(2)
    show Pan%(4)
    Histogramme()             :' en ligne 666
  else
    message "Vous devez ouvrir ou créer un fichier !"
  end_if
  return
  end_if

  if number_click = Sm%(11)   :' vient de 96
    FindKgfdll()              :' en ligne 718
    return
  end_if

  if number_click = Btn%
    SaveFormulaire()      :' en ligne 385
    return
  end_if
return

' -----------------------------------------------------------------------

sub NewCar()      :' vient 295

  dim_local a$,b$,v%,i%

  if message_input("Nouveau véhicule","Marque , Modèle","")=1  :' ****
  a$=message_text$                                             :'    *
                                                               :'    *
  if a$<>""    :' ***************************************            *
    Car$=a$                                        :'   *            *
    Car$=upper$(Car$)                              :'   *            *
      if count(Mem%)>0   :' ******************          *            *
        for i%=1 to count(Mem%)          :'  *          *            *
          b$=item_read$(Mem%,i%)         :'  *          *            *
            if b$=Car$  :' *****             *          *            *
              v%=1      :'     *             *          *            *
              exit_for  :'     *             *          *            *
            end_if      :' *****             *          *            *
        next i%                          :'  *          *            *
        if v%=0         :' ************      *          *            *
          item_add Mem%,Car$      :'  *      *          *            *
          file_save Mem%,ListeC$  :'  *      *          *            *
        end_if          :' ************      *          *            *
        else                            :'   *          *            *
        item_add Mem%,Car$              :'   *          *            *
        file_save Mem%,ListeC$          :'   *          *            *
        end_if         :' ********************          *            *
  end_if       :' ***************************************            *
                                                              :'     *
        caption 0,"CONSOMMATION  CARBURANT de ma  "+Car$      :'     *
          active Btn%                                         :'     *
          active Gril%                                        :'     *
                                                              :'     *
  end_if   :' ********************************************************
end_sub

' -----------------------------------------------------------------------------

sub SaveFormulaire()        :' vient de 341
  dim_local i%,a$,v%,mes$,M$,prixlit$

  mes$="Format de date invalide ! (jj/mm/aaaa)"
  '  verif du format de la date
  if text$(Edi%(1))<>""
    if numeric(left$(text$(Edi%(1)),2))=0  or numeric(mid$(text$(Edi%(1)),4,2))=0  or numeric(right$(text$(Edi%(1)),4))=0
            message mes$
            exit_sub
      else
        if mid$(text$(Edi%(1)),3,1)<>"/" or mid$(text$(Edi%(1)),6,1)<>"/"
                message mes$
                exit_sub
        end_if
    end_if
  else
    message mes$
    exit_sub
  end_if

  '  ajout d' une ville dans la liste
  if count(MemV%)>0
    v%=0
      for i%=1 to count(MemV%)
        a$=item_read$(MemV%,i%)
          if a$=text$(Comb%)
            v%=1
            exit_for
          end_if
      next i%
      if v%=0
        item_add MemV%,text$(Comb%)
        file_save MemV%,ListeV$
        file_load Comb%,ListeV$
      end_if
  else
    item_add MemV%,text$(Comb%)
    file_save MemV%,ListeV$
    file_load Comb%,ListeV$
  end_if

  '  validité compteur km, quantité mise, montant, prix/l
  for i%=2 to 4
    if text$(Edi%(i%))=""
      Message "Vous n'avez pas renseigner le champ "+caption$(alph%(i%+1))+chr$(13)+"Les calculs sont impossibles."
      exit_sub
    end_if
  next i%

  '  calcul Moy au 100 intermédiaire
  
    if len(grid_read$(Gril%,2,1))>0
          NbreR%=NbreR%+1
          grid_row_insert Gril%,NbreR%
      end_if
      
  ConsoMoyenInter()       :' en ligne 459

  if Minter <> 0 : M$=str$(Minter) : else : M$="" : end_if   :' m$ pour la moyenne de la conso
  if prixlit <> 0     : prixlit$=str$(prixlit)    : else : prixlit$="" : end_if  :' prixlit= prix au litre

  grid_write Gril%,NbreR%,1,text$(Edi%(1))     :' date
  grid_write Gril%,NbreR%,2,text$(Comb%)       :' lieu du complément
  grid_write Gril%,NbreR%,3,text$(Edi%(2))     :' quantité mise
  grid_write Gril%,NbreR%,4,text$(Edi%(3))     :' montant €
  grid_write Gril%,NbreR%,5,text$(Edi%(4))     :' compteur km total
  grid_write Gril%,NbreR%,6,prixlit$           :' prix au litre
  grid_write Gril%,NbreR%,7,distparcourue      :' distance parcourue
  grid_write Gril%,NbreR%,8,M$                 :' pour la conso moyenne au 100

  Calculer()     :' en ligne 520

 end_sub

' ------------------------------------------------------------------------------

sub ConsoMoyenInter()   :' vient de 439

  if NbreR% = 2     :' c'est le 1er enregistrement
     message " Citroen a mis pour 35€ d'essence ce qui correspond a 30 litres environ "
     conso = val(text$(edi%(2)))
     consototale=consototale+conso
     totaleuro=val(text$(edi%(3)))
     prixlit = val(text$(edi%(3)))/conso
     prixlit=prixlit*1000 : prixlit=int(prixlit)/1000
     gosub affichage
  end_if
  
  if NbreR% = 3     :' 2em enregistrement
     message " garage citroen --->leclerc pour complèment de plein.j'ai mis 28,36 litres pour 34 euros"
      conso = val(text$(edi%(2)))
      prixlit=val(text$(edi%(3)))/conso
      prixlit=prixlit*1000 : prixlit=int(prixlit)/1000
      consototale=consototale+conso
      totaleuro=totaleuro+val(text$(edi%(3)))
      gosub affichage
  end_if
  
  if NbreR% =4   :  ' debut des vrais calculs
    distparcourue = val(text$(Edi%(4)))
    totalkm =  val(text$(Edi%(4)))
    dist =  val(text$(Edi%(4)))
    ' ---
    conso = val(text$(edi%(2)))    :' correspond à qté mise entre 2 complèments de plein
    consototale=consototale+conso
    ' ----
    totaleuro=totaleuro+val(text$(edi%(3)))
    prixlit=val(text$(edi%(3)))/conso
    prixlit=prixlit*1000 : prixlit=int(prixlit)/1000
    ' ---
    Minter = (conso/distparcourue)*100      :' corespond à la moyenne
    Minter=Minter*100 : Minter=int(Minter)/100
    gosub affichage     :' en ligne 576
  end_if
  ' -------------------------------------------

  if NbreR% =>5
    ' kilometrage total et parcourue entre 2 pleins
     totalkm = val(text$(Edi%(4)))
     distparcourue = totalkm - val(grid_read$(gril%,NbreR%-1,5))
    ' prix au litre et conso intermediaire et totale
    conso =val(text$(edi%(2)))
    consototale=consototale+conso
    prixlit=val(text$(edi%(3)))/conso
    ' ----
    Minter =(conso/distparcourue)*100
  ' -----
   Minter=Minter*100 : Minter=int(Minter)/100
   prixlit=prixlit*1000 : prixlit=int(prixlit)/1000
   end_if
gosub affichage
end_sub

' --------------------------------------------------

sub calculer()      :' vient de 455
  dim_local a$,b$,c$,d$,i%
  
    if nbrer%=2
      b$ = grid_read$(gril%,2,3)    :' lecture de quatité mise
      consototale = val(b$)         :' pour affichage dans barre inferieure
      c$ = grid_read$(gril%,2,4)    :' lecture de montant en euros
      totaleuro = val(c$)           :' pour affichage dans barre inferieure
      gosub affichage
    end_if
  
    if NbreR%=3
      b$ = grid_read$(gril%,3,3)
      conso=val(b$)
      consototale=val(b$)+val(grid_read$(gril%,NbreR%-1,3))
      c$ = grid_read$(gril%,3,4)
      totaleuro = val(c$)+val(grid_read$(gril%,NbreR%-1,4))
      gosub affichage
    end_if
  ' ---------------------------------------------------
 if NbreR%=>4
'   nombre total de km parcourus
    totalkm=val(grid_read$(gril%,NbreR%,5))    
'    conso essence sur parcours intermédiaire
      b$ = grid_read$(Gril%,nbrer%,3)  :' qté mise
      conso=val(b$)            
'    dépense en euros et consommation totale
      totaleuro = 0   : consototale = 0
     for i%= 2 to NbreR%
       b$ = grid_read$(gril%,i%,4)
       totaleuro=totaleuro+val (b$)
       c$ = grid_read$(gril%,i%,3)
       consototale = (consototale)+val(c$)
     next i%
     consototale=consototale-58.36
     ' moyenne générale
      Conso100 = (Conso /TotalKm)*100
      Conso100 = Conso100*100
      Conso100 = int(Conso100)/100
      moyengene=(consototale/totalkm)*100
      moyengene=moyengene*100
      moyengene=int(moyengene)/100
      gosub affichage
  end_if
end_sub

' ------------------------------------------------------------------------------

affichage:

  caption ApanTtl%(1),"Kilomètrage total : "+str$(TotalKm)+" Km"
  caption ApanTtl%(2),"Dépense totale : "+str$(TotalEuro)+" €"
  caption ApanTtl%(3),"Consommation totale : "+str$(consototale)+" L"
  caption ApanTtl%(4),"Moyenne générale : "+str$(moyengene)+" L/100 km"
return

' -------------------------------------------------------------------

close:         :' vient de fermeture croix
  if message_warning_yes_no("Un fichier est en cours d' utilisation !"+chr$(13)+"Voulez vous sauvegarder vos modifications ?")=1
    grid_save Gril%,NbreR%,NbreC%,PathCar$+Car$+".car"
  end_if
return

' ------------------------------------------------------------------------------

sub OpenCar()        :' vient de 300
  dim_local a$,f$,r$,c$ ,dist
  
  Open_dialog Odial%
  dir_dialog Odial%,PathCar$
  filter Odial%,"*.car|*.car"       :'  filter Odial%,"*.car|*.txt" oté le .txt le 02/10/17  remplacé par car
  a$=file_name$(Odial%)
  delete Odial%

  if a$<>"_"
    f$=a$
    Car$=file_extract_name$(a$)
    Car$=left$(Car$,len(Car$)-4)
    file_open_read F_OR%,f$
    file_readln F_OR%,r$
    NbreR%=val(r$)      :' c'est a dire  2
'    NbreR% = NbreR%+1   :' rajouté le 20/01
    file_readln F_OR%,c$
    NbreC%=val(c$)
    file_close F_OR%
    InitialiseGrid(NbreR%,NbreC%)
    grid_load Gril%,f$
    caption 0,"CONSOMMATION  CARBURANT de ma  "+" - "+Car$
    active Btn%
    active Gril%

      calculer()     :' en ligne  49
  end_if
end_sub

' ------------------------------------------------------------------------------

sub SaveCar()     :' vient de 305,641
  dim_local f$
  if Car$<>""
    f$= PathCar$+Car$+".car"
    grid_save Gril%,NbreR%,NbreC%,f$
  end_if
  '  initialisation du formulaire
  ClearFormulaire()        :' en ligne

end_sub

' -----------------------------------------------------------------

sub ClearFormulaire()     :' vient de
  dim_local i%
  for i%=1 to 4 : text Edi%(i%),"" : next i%
  text comb%,""
end_sub

' ----------------------------------------------------------------------------

sub Quitter()      :' vient de 310
    if message_warning_yes_no("Un fichier est en cours d' utilisation !"+chr$(13)+"Voulez vous sauvegarder vos modifications ?")=1
      SaveCar()     :' en ligne 618
    end_if
  Terminate
end_sub

' ------------------------------------------------------------

sub Histogramme()   :' vient de 328
  dim_local res%
  CreateHistoFile()
  dll_on kgf$
  res% = dll_call2("Histogramme",adr(Histo$),handle(Pan%(4)))
  dll_off
  file_delete Histo$
end_sub

' -----------------------------------------------------------------------

sub CreateHistoFile()
  dim_local i%,a$,v%
  ' message " je suis dans créatehistofile "
  file_open_write F_OW%,Histo$
  file_writeln F_OW%,"#Type=LINE"
  file_writeln F_OW%,"#Bord droit=17"
  file_writeln F_OW%,"#Bord bas=38"
  file_writeln F_OW%,"#Largeur fenêtre="+str$(width(Pan%(4))-50)
  file_writeln F_OW%,"#Hauteur fenêtre="+str$(height(Pan%(4))-50)
  file_writeln F_OW%,"#Style=2D"
  file_writeln F_OW%,"#Grille=H"
  '  file_writeln F_OW%,"#Légendes"
  file_writeln F_OW%,"#Largeur=1"
  file_writeln F_OW%,"#Séries=1"
  file_writeln F_OW%,"#Valeurs="+str$(NbreR%-1)
  file_writeln F_OW%,"#Données=1"
  for i%=2 to NbreR%
    a$=grid_read$(Gril%,i%,8)
      if a$="" then a$="0"
        v%=val(a$)*100
        separator_is_comma
        a$=str$(int(v%)/100)
        file_writeln F_OW%,a$
        separator_is_point
  next i%
  file_writeln F_OW%,"#Minimum Y=0"
  file_writeln F_OW%,"#Maximum Y=10"   :' 30
  file_writeln F_OW%,"#Ecart Y=1"
  file_writeln F_OW%,"#Légende Y=0"
  file_writeln F_OW%,"#Titres"
  file_writeln F_OW%,"Haut=Evolution de la consommation"
  file_writeln F_OW%,"Gauche=Conso. en Litres / 100 Km"
  file_writeln F_OW%,"Bas=Relevés"
  '  file_writeln F_OW%,"Droite=Divers"
  file_writeln F_OW%,"#Légendes séries"
  file_writeln F_OW%,"Carburant"
  file_close F_OW%
end_sub