Cadre pour image

DIM x%,y%,e%,coef
width 0,800: height 0,640
x% = 50: y% = 40: e% = 30: ' coordonnées et épaisseur du cadre
coef = 0.75
Cadre("C:\GRAPH\JPG\goldgate.jpg",x%,y%,coef,e%,255*256*256): ' cadre rouge
END
' ==============================================================================
SUB Cadre(f$,x%,y%,coef,e%,rgb%)
  ' Affichage sur la cible 2D de l'image f$ (JPG ou BMP) entourée d'un  cadre
  ' dentelé d'épaisseur e%, couleur rgb% (65536*R+256*G+B)
  ' x%,y% sont les coordonnées du coin supérieur gauche de l'image elle-même.
  ' coef = coefficient de réduction ou d'agrandissement de l'image d'origine
  '        <1 réduction, >1 agrandissement (exemples: coef = 3/4, coef = 1.2)
  DIM_LOCAL tp%,ft$,v%(8),w%,h%,l%,p%,n%,xc%,yc%,wc%,hc%,x1%,y1%,r%,g%,b%
  ft$ = "Tempor.bmp": ' temporaire
  tp% = 920: ' objet temporaire
  IF UPPER$(FILE_EXTRACT_EXTENSION$(f$))<>".BMP"
      PICTURE tp%: LEFT tp%,2000
      FILE_LOAD tp%,f$: FILE_SAVE tp%,ft$: f$ = ft$: DELETE tp%
  END_IF
  FILEBIN_OPEN_READ 9,f$
      FILEBIN_POSITION 9,18: FILEBIN_BLOCK_READ 9,8,v%(0)
      w% = v%(0)+256*v%(1)+65536*v%(2)+16777216*v%(3)
      h% = v%(4)+256*v%(5)+65536*v%(6)+16777216*v%(7)
  FILEBIN_CLOSE 9
  IF coef <> 1
      w% = w%*coef: h% = h%*coef
      SCENE2D tp%: HIDE tp%: WIDTH tp%,w%: HEIGHT tp%,h%
      SPRITE tp%: SPRITE_FILE_LOAD tp%,f$: SPRITE_SCALE tp%,coef,coef
      SNAPSHOT tp%,ft$: f$ = ft$: DELETE tp%
  END_IF
  IF e%<(w%/50) THEN e% = w%/50
  wc% = w%+2*e%: hc% = h%+2*e%: ' enveloppe du cadre
  l% = hc%/20: ' largeur d'une dent (arbitraire)
  n% = hc%/l%: hc% = n%*l%: ' ajustage des dimensions du cadre
  n% = wc%/l%: wc% = n%*l%
  xc% = x%-(wc%-w%)/2: yc% = y%-(hc%-h%)/2
  p% = e%/3: ' profondeur des dents (moduler ?)
  2D_PEN_WIDTH 1: 2D_LINE xc%,yc%,xc%,yc%: ' coin sumérieur gauche du cadre
  FOR y1% = yc% TO yc%+hc%-l% STEP l%: ' gauche
      2D_POLY_TO xc%+p%,y1%+l%/2: 2D_POLY_TO xc%,y1%+l%
  NEXT y1%
  FOR x1% = xc% TO xc%+wc%-l% STEP l%: ' bas
      2D_POLY_TO x1%+l%/2,yc%+hc%-p%: 2D_POLY_TO x1%+l%,yc%+hc%
  NEXT x1%
  FOR y1% = yc%+hc% TO yc%+l% STEP -1*l%: ' droite
      2D_POLY_TO xc%+wc%-p%,y1%-l%/2: 2D_POLY_TO xc%+wc%,y1%-l%
  NEXT y1%
  FOR x1% = xc%+wc% TO xc%+l% STEP -1*l%: ' haut
      2D_POLY_TO x1%-l%/2,yc%+p%: 2D_POLY_TO x1%-l%,yc%
  NEXT x1%
  2D_POLY_TO xc%,yc%: ' terminer
  2D_PEN_WIDTH 1: 2D_RECTANGLE x%-1,y%-1,x%+w%+1,y%+h%+1: ' intérieur du cadre (image)
  r% = INT(rgb%/65536): g% = BIN_AND(rgb%,65280)/256: b% = BIN_AND(rgb%,255)
  2D_FLOOD x%-2,y%,r%,g%,b%: ' couleur du cadre
  IMAGE tp%: FILE_LOAD tp%,f$: 2D_IMAGE_PASTE tp%,x%,y%: DELETE tp%
  IF FILE_EXISTS(ft$) = 1 THEN FILE_DELETE ft$
END_SUB
' ==============================================================================

SUB RedimImg(f$,w%,h%,fr$)
  ' Redimensionner l'image f$ (BMP ou JPG) en w%,h%, résultat dans fr$ (BMP)
  ' Si fr$ = "", résultat dans le prese-papier
  ' Si w% = 0 ou h% = 0: redimensionnement proportionnel
  DIM_LOCAL fm$,wi%,hi%,cx,cy,op%
  fm$ = "Provimg.bmp"
  op% = 1900: ' objet provisoire
  IF UPPER$(FILE_EXTRACT_EXTENSION$(f$)) = ".JPG"
      PICTURE op%: FILE_LOAD op%,f$: FILE_SAVE op%,fm$: DELETE op%: f$ = fm$
  END_IF
  FILEBIN_OPEN_READ 1,f$
      FILEBIN_POSITION 1,18: wi% = FILEBIN_READ(1)+256*FILEBIN_READ(1)
      FILEBIN_POSITION 1,22: hi% = FILEBIN_READ(1)+256*FILEBIN_READ(1)
  FILEBIN_CLOSE 1
  IF h% = 0 THEN h% = w%*hi%/wi%
  IF w% = 0 THEN w% = h%*wi%/hi%
  cx = w%/wi%: cy = h%/hi%
  SCENE2D op%: HIDE op%: WIDTH op%,w%: HEIGHT op%,h%
  SPRITE op%: SPRITE_FILE_LOAD op%,f$: SPRITE_SCALE op%,cx,cy
  IF fr$ = ""
      SNAPSHOT op%,fm$
      PICTURE op%+1: FILE_LOAD op%+1,fm$: CLIPBOARD_COPY op%+1
      DELETE op%+1
  ELSE
      SNAPSHOT op%,fr$
  END_IF
  DELETE op%: IF FILE_EXISTS(fm$) = 1 THEN FILE_DELETE fm$
END_SUB

DIM x%,y%,e%,coef,wmax,hmax

width 0,screen_x: height 0,screen_y
x% = 30: y% = 40: e% = 30: ' coordonnées et épaisseur du cadre
wmax=width(0) : hmax=height(0)
' message str$(wmax)+" "+str$(hmax)
' coef = 1
Cadre("C:\GRAPH\JPG\goldgate.jpg",x%,y%,coef,e%,255*256*256): ' cadre rouge
END
' ==============================================================================
SUB Cadre(f$,x%,y%,coef,e%,rgb%)
  ' Affichage sur la cible 2D de l'image f$ (JPG ou BMP) entourée d'un  cadre
  ' dentelé d'épaisseur e%, couleur rgb% (65536*R+256*G+B)
  ' x%,y% sont les coordonnées du coin supérieur gauche de l'image elle-même.
  ' coef = coefficient de réduction ou d'agrandissement de l'image d'origine
  '        <1 réduction, >1 agrandissement (exemples: coef = 3/4, coef = 1.2)
  DIM_LOCAL tp%,ft$,v%(8),w%,h%,l%,p%,n%,xc%,yc%,wc%,hc%,x1%,y1%,r%,g%,b%,coef1,coef2
  ft$ = "Tempor.bmp": ' temporaire
  tp% = 920: ' objet temporaire
  IF UPPER$(FILE_EXTRACT_EXTENSION$(f$))<>".BMP"
      PICTURE tp%: LEFT tp%,2000
      FILE_LOAD tp%,f$: FILE_SAVE tp%,ft$: f$ = ft$: DELETE tp%
  END_IF
  FILEBIN_OPEN_READ 9,f$
      FILEBIN_POSITION 9,18: FILEBIN_BLOCK_READ 9,8,v%(0)
      w% = v%(0)+256*v%(1)+65536*v%(2)+16777216*v%(3)
      h% = v%(4)+256*v%(5)+65536*v%(6)+16777216*v%(7)
  FILEBIN_CLOSE 9

coef1 = wmax/w%
coef2 = hmax/h%
coef = 0+frac(coef1+coef2)

message str$(coef)

  IF coef <> 1
      w% = w%*coef: h% = h%*coef
      SCENE2D tp%: HIDE tp%: WIDTH tp%,w%: HEIGHT tp%,h%
      SPRITE tp%: SPRITE_FILE_LOAD tp%,f$: SPRITE_SCALE tp%,coef,coef
      SNAPSHOT tp%,ft$: f$ = ft$: DELETE tp%
  END_IF
  IF e%<(w%/50) THEN e% = w%/50
  wc% = w%+2*e%: hc% = h%+2*e%: ' enveloppe du cadre
  l% = hc%/20: ' largeur d'une dent (arbitraire)
  n% = hc%/l%: hc% = n%*l%: ' ajustage des dimensions du cadre
  n% = wc%/l%: wc% = n%*l%
  xc% = x%-(wc%-w%)/2: yc% = y%-(hc%-h%)/2
  p% = e%/3: ' profondeur des dents (moduler ?)
  2D_PEN_WIDTH 1: 2D_LINE xc%,yc%,xc%,yc%: ' coin sumérieur gauche du cadre
  FOR y1% = yc% TO yc%+hc%-l% STEP l%: ' gauche
      2D_POLY_TO xc%+p%,y1%+l%/2: 2D_POLY_TO xc%,y1%+l%
  NEXT y1%
  FOR x1% = xc% TO xc%+wc%-l% STEP l%: ' bas
      2D_POLY_TO x1%+l%/2,yc%+hc%-p%: 2D_POLY_TO x1%+l%,yc%+hc%
  NEXT x1%
  FOR y1% = yc%+hc% TO yc%+l% STEP -1*l%: ' droite
      2D_POLY_TO xc%+wc%-p%,y1%-l%/2: 2D_POLY_TO xc%+wc%,y1%-l%
  NEXT y1%
  FOR x1% = xc%+wc% TO xc%+l% STEP -1*l%: ' haut
      2D_POLY_TO x1%-l%/2,yc%+p%: 2D_POLY_TO x1%-l%,yc%
  NEXT x1%
  2D_POLY_TO xc%,yc%: ' terminer
  2D_PEN_WIDTH 1: 2D_RECTANGLE x%-1,y%-1,x%+w%+1,y%+h%+1: ' intérieur du cadre (image)
  r% = INT(rgb%/65536): g% = BIN_AND(rgb%,65280)/256: b% = BIN_AND(rgb%,255)
  2D_FLOOD x%-2,y%,r%,g%,b%: ' couleur du cadre
  IMAGE tp%: FILE_LOAD tp%,f$: 2D_IMAGE_PASTE tp%,x%,y%: DELETE tp%
  IF FILE_EXISTS(ft$) = 1 THEN FILE_DELETE ft$
END_SUB
' ==============================================================================

DIM f$,x,y,w,h,nw,cb%,cr%
f$ = "C:\GRAPH\BMP\goldgate480.bmp": image 480 x 360
FILEBIN_OPEN_READ 1,f$
    FILEBIN_POSITION 1,18: w = FILEBIN_READ(1)+256*FILEBIN_READ(1)
    FILEBIN_POSITION 1,22: h = FILEBIN_READ(1)+256*FILEBIN_READ(1)
FILEBIN_CLOSE 1
x = 30: y = 30
HEIGHT 0,h+3*y : WIDTH 0,w+3*x: BORDER_SMALL 0
PICTURE 1: WIDTH 1,2*x+w: HEIGHT 1,2*y+h
2D_TARGET_IS 1
2D_PEN_WIDTH 3: ' épaisseur trait
2D_PEN_COLOR 128,0,0: ' bordure rouge foncé
IMAGE 2: FILE_LOAD 2,f$
2D_IMAGE_PASTE 2,x,y
nw = 16: ' nombre d'ondulations sur la longueur
Cadre_ondule(x,y,w,h,nw)
cb% = 128: cr% = 65536*255+256*255+255: ' couleurs bordure et remplissage
Remplir(1,10,10,cb%,cr%)
END
' ==============================================================================
SUB Cadre_ondule(x,y,w,h,nw)
  ' Tracé d'un cadre ondulé en x,y, dimensions w x h, sur la cible 2D
  ' nw = nombre d'ondulations horizontales sur la largeur
  ' (paramètres courants: couleur, épaisseur trait, etc)
  DIM_LOCAL nh,r,s,e,x1,y1,i
  nh = 1+INT(nw*h/w): ' nombre d'ondulations en hauteur
  r = w/(2*(2*nw-1)): IF ((2*nh-1)*2*r)>h THEN nh = nh-1: ' si dépassement en hauteur
  x1 = x+r: y1 = y+r
  DEGREES
  s=270: e=0: 2D_ARC x1,y1,r,s,e: ' départ, angle haut/gauche
  x = x1: y = y1
  FOR i = 1 TO nw-1: ' haut
      x = x+2*r
      s=0: e=180: 2D_ARC x,y,r,s,e
      s=180: e=360: IF i = nw-1 THEN e=270
      x = x+2*r: 2D_ARC x,y,r,s,e
  NEXT i
  FOR i = 1 TO nh-1: ' droite
     y = y+2*r
     s=270: e=90: 2D_ARC x,y,r,s,e
     s=90: e=270: IF i = nh-1 THEN e=180
     y = y+2*r: 2D_ARC x,y,r,s,e
  NEXT i
  FOR i = 1 TO nw-1: ' bas
      x = x-2*r
      s=180: e=360: 2D_ARC x,y,r,s,e
      s=0: e=180: IF i = nw-1 THEN e = 90
      x = x-2*r: 2D_ARC x,y,r,s,e
  NEXT i
  FOR i = 1 TO nh-1: ' gauche
      y = y-2*r
      s=90: e=270: 2D_ARC x,y,r,s,e
      s=270: e=90: y = y-2*r: 2D_ARC x,y,r,s,e
  NEXT i
END_SUB
' ==============================================================================
SUB Remplir(p%,x%,y%,cb%,cr%)
  ' Dans le picture p%, à partir du point x%,y%, remplir de la couleur cr% la zone
  ' délimitée par la couleur de bordure cb% (Attention: format BGR)
  DIM_LOCAL res%
  DLL_ON "C:\PANORAMIC\KGF\KGF.dll"
  CLIPBOARD_COPY p%
  res% = DLL_CALL0("LoadPicture"): ' image presse-papier -> image interne
  res% = DLL_CALL4("FloodfillPictureToBorderColor",x%,y%,cr%,cb%)
  res% = DLL_CALL0("SavePicture"): ' image interne -> presse-papier
  CLIPBOARD_PASTE p%
  DLL_OFF
END_SUB
' ==============================================================================