SimpleEditor

dim file$,marq$,txt$,sel%,x%
label Ouvrir,Enregistrer,Selection,Quitter

height 0,400
width 0,650
top 0,(screen_y-height(0))/2
left 0,(screen_x-width(0))/2
color 0,150,210,220

font_name 0,"Courier New"
font_size 0,10
font_bold 0
font_color 0,220,0,200

caption 0,"Pano Map"

main_menu 1
sub_menu 2 : parent 2,1  : caption 2,"Ouvrir"       : on_click 2,Ouvrir
sub_menu 6 : parent 6,1  : caption 6,"Enregistrer"  : on_click 6,Enregistrer
sub_menu 7 : parent 7,1  : caption 7,"Quitter"      : on_click 7,Quitter
sub_menu 8 : parent 8,1  : caption 8,string$(10," "): inactive 8
sub_menu 9 : parent 9,1  : caption 9,"Marqueur"
   sub_menu 10 : parent 10,9  : caption 10,"[ ! ]"  : on_click 10,Selection : mark_on 10 : marq$ = "!"
   sub_menu 11 : parent 11,9  : caption 11,"[ # ]"  : on_click 11,Selection
   sub_menu 12 : parent 12,9  : caption 12,"[ / ]"  : on_click 12,Selection
   sub_menu 13 : parent 13,9  : caption 13,"[ * ]"  : on_click 13,Selection
   sub_menu 14 : parent 14,9  : caption 14,"[ | ]"  : on_click 14,Selection
   sub_menu 15 : parent 15,9  : caption 15,"[ - ]"  : on_click 15,Selection

memo 3
height 3,height_client(0)-10
width 3,width_client(0)-10
top 3,5
left 3,5
bar_both 3
color 3,245,245,245

dlist 4
end

Ouvrir:
   open_dialog 5
   dir_dialog 5,":\"
   filter 5,"*.bas;*.bak|*.bas;*.bak"
   file$ = file_name$(5)
   delete 5
  
   if file$<>"_"
      file_load 4,file$
      DetectPlan()
   end_if
return

sub DetectPlan()
   dim_local i%,a$,b$,m%
   if count(4)>0
      for i%=1 to count(4)
         a$= item_read$(4,i%)
         b$= trim$(a$)
         if left$(b$,3)="' "+marq$
            item_add 3,right$(b$,len(b$)-3)
         end_if
      next i%
      m%=message_information_ok("Opération terminée !...")
   else
      m%=message_information_ok("Fichier vide !...")
   end_if
end_sub

Enregistrer:
   Save_dialog 5
   dir_dialog 5,":\"
   filter 5,"*.plan|*.plan"
   file$ = file_name$(5)
   delete 5
  
   if file$<>"_"
      if right$(file$,5)<>".plan"
         file$=file$+".plan"
      end_if
      if file_exists(file$)=0
         file_save 3,file$
      else
         RenameFile()
      end_if
   end_if
return

sub RenameFile()
   dim_local m%,mess$
  
   mess$ = "Un fichier du même nom existe !"+chr$(13)
   mess$ = mess$+"Etes vous sûr de vouloir le remplacer ?..."
  
   m%=message_warning_yes_no(mess$)
   if m%=1
      file_save 3,file$
   end_if
end_sub

Selection:
   for x%=10 to 15
      mark_off x%
      if number_click = x%
         mark_on x%
         sel%=x%-9
      end_if
   next x%
   txt$  ="!#/*|-"
   marq$ = mid$(txt$,sel%,1)
return

Quitter:
   terminate