Version instantanée du 30/12/2016 : PANORAMIC V 0.9.27i9

' Test dessin
LABEL Qes
BORDER_SMALL 0: WIDTH 0,794: HEIGHT 0,1134
FONT_NAME 0,"Arial": FONT_BOLD 0
PICTURE 1: FULL_SPACE 1
BUTTON 2: left 2,WIDTH(0)-100: CAPTION 2,"Dessin": ON_CLICK 2,Qes
END
' ==============================================================================
Qes:
  Desic(1)
RETURN
' ==============================================================================
SUB Desic(p%)
IF LABEL("Clic")=0 THEN LABEL Clic
IF LABEL("Surv")=0 THEN LABEL Surv
IF LABEL("Dclic")=0 THEN LABEL Dclic
IF LABEL("Desfig")=0 THEN LABEL Desfig
IF LABEL("cas4")=0 THEN LABEL cas4
IF LABEL("cas6")=0 THEN LABEL cas6
IF LABEL("Chfig")=0 THEN LABEL Chfig
IF LABEL("Chcol")=0 THEN LABEL Chcol
IF LABEL("Chcol1")=0 THEN LABEL Chcol1
IF LABEL("Chimg")=0 THEN LABEL Chimg
IF LABEL("Chpol")=0 THEN LABEL Chpol
IF LABEL("Valpo")=0 THEN LABEL Valpo
IF LABEL("Valtx")=0 THEN LABEL Valtx
IF LABEL("Anuder")=0 THEN LABEL Anuder
IF LABEL("Fdes")=0 THEN LABEL Fdes
DIM_LOCAL ff%,ft%,fi%,a$,b$,i%,j%,t%,x%,y%,x1%,y1%,x2%,y2%,rx%,ry%,tr%,tg%,tb%
DIM_LOCAL mb%,fig%,an,et%,sp%,cl%,co%,chc%,ffd%,edt%,szt%,mmt%,lst%,pit%
DIM_LOCAL rt%,gt%,bt%,wf%,od%,im%,tg,wbh%,wbv%
' ------------------------------------------------------------------------------
ff% = 950: FORM ff%: BORDER_SMALL ff%: WIDTH ff%,100: HEIGHT ff%,290
         TOP ff%,HEIGHT(0)-HEIGHT(ff%): LEFT ff%,LEFT(0)+WIDTH(0)
         COLOR ff%,164,255,255: CAPTION ff%,"Outils dessin"
         FONT_NAME ff%,"Arial": FONT_BOLD ff%: ON_CLOSE ff%,FDes
         PICTURE ff%+1: PARENT ff%+1,ff%: FULL_SPACE ff%+1
         wbh%=WIDTH(ff%+1): wbv%=HEIGHT(ff%+1): ' dimensions disponibles dans ff%
         DELETE ff%+1
i%=ff%+1: ALPHA i%: PARENT i%,ff%: TOP i%,5: LEFT i%,2: CAPTION i%,"Ép.Trait:"
i%=i%+1: SPIN i%: PARENT i%,ff%: TOP i%,1: LEFT i%,46: WIDTH i%,36: sp%=i%
         MIN i%,1: MAX i%,20: POSITION i%,1
i%=sp%+1: ALPHA i%: PARENT i%,ff%: TOP i%,TOP(i%-1)+25: LEFT i%,2: CAPTION i%,"Couleur:"
i%=i%+1: PICTURE i%: PARENT i%,ff%: TOP i%,TOP(i%-1): LEFT i%,LEFT(sp%)+6
         WIDTH i%,30: HEIGHT i%,18: COLOR i%,0,0,0: ON_CLICK i%,Chcol: cl%=i%
i%=cl%+1: CONTAINER_OPTION i%: PARENT i%,ff%: TOP i%,TOP(i%-1)+20: LEFT i%,0
         WIDTH i%,wbh%-1: HEIGHT i%,160: CAPTION i%,"  - Figure : -": co%=i%
         COLOR co%,255,255,164
i%=i%+1: OPTION i%: PARENT i%,co%: TOP i%,15: LEFT i%,5: CAPTION i%,"Libre"
i%=i%+1: OPTION i%: PARENT i%,co%: TOP i%,TOP(i%-1)+16: LEFT i%,5: CAPTION i%,"Trait"
         MARK_ON i%: fig% = 3
i%=i%+1: OPTION i%: PARENT i%,co%: TOP i%,TOP(i%-1)+16: LEFT i%,5: CAPTION i%,"Rectangle"
i%=i%+1: OPTION i%: PARENT i%,co%: TOP i%,TOP(i%-1)+14: LEFT i%,15: CAPTION i%,"Id. plein"
i%=i%+1: OPTION i%: PARENT i%,co%: TOP i%,TOP(i%-1)+17: LEFT i%,5: CAPTION i%,"Ellipse"
i%=i%+1: OPTION i%: PARENT i%,co%: TOP i%,TOP(i%-1)+14: LEFT i%,15: CAPTION i%,"Id. plein"
i%=i%+1: OPTION i%: PARENT i%,co%: TOP i%,TOP(i%-1)+17: LEFT i%,5: CAPTION i%,"Remplir"
i%=i%+1: OPTION i%: PARENT i%,co%: TOP i%,TOP(i%-1)+16: LEFT i%,5: CAPTION i%,"Texte"
i%=i%+1: OPTION i%: PARENT i%,co%: TOP i%,TOP(i%-1)+16: LEFT i%,5: CAPTION i%,"Image"
         MARK_ON co%+2: FOR j%=co%+1 TO i%: ON_CLICK j%,Chfig: NEXT j%
i%=i%+1: PICTURE i%: PARENT i%,ff%: HIDE i%: TOP i%,TOP(co%)+5: LEFT i%,5
         WIDTH i%,WIDTH(ff%)-26: HEIGHT i%,100: COLOR i%,255,255,255: chc%=i%
         2D_TARGET_IS i%: j% = WIDTH(i%)/2
         2D_FILL_COLOR 0,0,0: 2D_RECTANGLE 0,0,j%,20: ' noir
         2D_FILL_COLOR 255,255,255: 2D_RECTANGLE j%,0,2*j%,20: ' blanc
         2D_FILL_COLOR 164,128,0: 2D_RECTANGLE 0,20,j%,40: ' marron
         2D_FILL_COLOR 164,164,164: 2D_RECTANGLE j%,20,2*j%,40: ' gris
         2D_FILL_COLOR 255,0,0: 2D_RECTANGLE 0,40,j%,60: ' rouge
         2D_FILL_COLOR 0,255,0: 2D_RECTANGLE j%,40,2*j%,60: ' vert
         2D_FILL_COLOR 0,0,255: 2D_RECTANGLE 0,60,j%,80: ' bleu
         2D_FILL_COLOR 255,255,0: 2D_RECTANGLE j%,60,2*j%,80: ' jaune
         2D_FILL_COLOR 255,0,255: 2D_RECTANGLE 0,80,j%,100: ' magenta
         2D_FILL_COLOR 0,255,255: 2D_RECTANGLE j%,80,2*j%,100: ' cyan
         ON_CLICK chc%,Chcol1
i%=i%+1: BUTTON i%: PARENT i%,ff%: TOP i%,TOP(co%)+HEIGHT(co%)+5: LEFT i%,5
         HEIGHT i%,20: CAPTION i%,"Annuler": ON_CLICK i%,Anuder
i%=i%+1: BUTTON i%: PARENT i%,ff%: TOP i%,TOP(i%-1)+22: LEFT i%,LEFT(i%-1)
         HEIGHT i%,20: CAPTION i%,"Quitter": ON_CLICK i%,FDes
' ------------------------------------------------------------------------------
ft%=i%+1: wf%=240: FORM ft%: HIDE ft%: BORDER_SMALL ft%: TOP ft%,TOP(ff%)
         LEFT ft%,LEFT(ff%)+WIDTH(ff%): WIDTH ft%,wf%: HEIGHT ft%,HEIGHT(ff%)
         CAPTION ft%," -   TEXTE   -": COLOR ft%,164,255,255
i%=ft%+1: ALPHA i%: PARENT i%,ft%: TOP i%,4: LEFT i%,5: CAPTION i%,"Police:"
i%=i%+1: EDIT i%: PARENT i%,ft%: TOP i%,1: LEFT i%,40: WIDTH i%,130: edt% = i%
         TEXT i%,"Arial": ON_CLICK i%,Chpol
i%=i%+1: SPIN i%: PARENT i%,ft%: TOP i%,TOP(i%-1): LEFT i%,LEFT(i%-1)+WIDTH(i%-1)+5: szt%=i%
         WIDTH i%,45: MIN i%,6: MAX i%,255: POSITION i%,8: ON_CHANGE i%,Valpo
i%=i%+1: MEMO i%: PARENT i%,ft%: TOP i%,25: LEFT i%,0: WIDTH i%,wf%-18: mmt%=i%
         HEIGHT i%,HEIGHT(ft%)-62: FONT_NAME i%,TEXT$(edt%): FONT_SIZE i%,POSITION(szt%)
i%=i%+1: LIST i%: PARENT i%,ft%: HIDE i%: TOP i%,TOP(mmt%): WIDTH i%,WIDTH(mmt%)
         HEIGHT i%,HEIGHT(ft%)-60: FONT_NAMES_LOAD i%: : ON_CLICK i%,Valpo: lst%=i%
i%=i%+1: PICTURE i%: PARENT i%,ft%: HIDE i%: pit%=i%
' ------------------------------------------------------------------------------
fi%=i%+1: FORM fi%: HIDE fi%: BORDER_SMALL fi%: TOP fi%,TOP(ff%)
         LEFT fi%,LEFT(ff%)+WIDTH(ff%): WIDTH fi%,300: HEIGHT fi%,80
         CAPTION fi%," -   IMAGE   -": COLOR ft%,164,255,255
i%=fi%+1: ALPHA i%: PARENT i%,fi%: TOP i%,3: LEFT i%,5: CAPTION i%,"Image:"
i%=i%+1: EDIT i%: PARENT i%,fi%: TOP i%,1: LEFT i%,40: WIDTH i%,WIDTH(fi%)-60
         ON_CLICK i%,Chimg: ' fi%+2
i%=i%+1: ALPHA i%: PARENT i%,fi%: TOP i%,25: LEFT i%,40: ' fi%+3
i%=i%+1: OPEN_DIALOG i%: od% = i%
i%=i%+1: IMAGE i%: im% = i%
' ------------------------------------------------------------------------------
ffd% = 0: mb% = 0: et% = 1
t% = i%+1: TIMER t%: TIMER_INTERVAL t%,50: ON_TIMER t%,Surv: TIMER_OFF t%
2D_TARGET_IS p%: 2D_FILL_OFF
ON_MOUSE_DOWN p%,Clic
ON_MOUSE_UP p%,Dclic
WHILE ffd% = 0: PAUSE 100: END_WHILE
2D_TARGET_IS 0: TIMER_OFF t%: PAUSE 200: DELETE t%
DELETE fi%: DELETE ft%: DELETE ff%: DELETE od%: DELETE im%: EXIT_SUB
' ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
Clic:
  ' Clic souris
  x1% = MOUSE_X_POSITION(1): y1% = MOUSE_Y_POSITION(1)
  CLIPBOARD_COPY 1
  2D_TARGET_IS 1
  IF fig% = 2: ' tracé libre
    2D_PEN_SOLID: 2D_PEN_WIDTH POSITION(sp%): tr%=COLOR_PIXEL_RED(cl%,2,2)
    tg%=COLOR_PIXEL_GREEN(cl%,2,2): tb%=COLOR_PIXEL_BLUE(cl%,2,2)
    2D_PEN_COLOR tr%,tg%,tb%
  ELSE
    2D_PEN_DOT: 2D_PEN_COLOR 0,0,0: 2D_FILL_OFF
  END_IF
  TIMER_ON 9
RETURN
' ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
Surv:
  ' Dessin provisoire
  x% = MOUSE_X_POSITION(1): y% = MOUSE_Y_POSITION(1)
  GOSUB Desfig
RETURN
' ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
Dclic:
  ' Relâchement bouton: dessin définitif
  TIMER_OFF 9
  x% = MOUSE_X_POSITION(1): y% = MOUSE_Y_POSITION(1)
  CLIPBOARD_PASTE 1
  2D_PEN_SOLID: 2D_PEN_WIDTH POSITION(sp%): tr%=COLOR_PIXEL_RED(cl%,2,2)
  tg%=COLOR_PIXEL_GREEN(cl%,2,2): tb%=COLOR_PIXEL_BLUE(cl%,2,2)
  2D_PEN_COLOR tr%,tg%,tb%
  GOSUB Desfig
RETURN
' ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
Desfig:
  CLIPBOARD_PASTE p%: ' tracé
  SELECT fig%
    CASE 2: 2D_LINE x1%,y1%,x%,y%: x1% = x%: y1% = y%: CLIPBOARD_COPY p%
    CASE 3: IF SCANCODE = 160: ' touche Maj enfoncée
                SCANCODE = 0
                i% = x%-x1%: j% = y%-y1%
                IF i%<>0 AND j%<>0
                    tg = ABS(j%/i%)
                    IF tg<.4
                        y% = y1%: ' ligne horizontale
                    ELSE
                        IF tg>2.35: ' ligne verticale
                            x% = x1%
                        ELSE: ' ligne à 45°
                            IF x% > x1%
                                IF y% > y1%
                                    y% = x%-x1%+y1%: ' vers bas à droite
                                ELSE
                                    y% = y1%-x%+x1%: ' vers haut à droite
                                END_IF
                            ELSE
                                IF y%>y1%
                                    x% = x1%-y%+y1% : ' vers bas à gauche
                                ELSE
                                    x% = x1%-y1%+y%: ' vers haut à gauche
                                END_IF
                            END_IF
                        END_IF
                    END_IF
                END_IF
            END_IF
            2D_LINE x1%,y1%,x%,y%: ' Ligne droite
    CASE 4: ' Rectangle vide ou plein
cas4:
            IF SCANCODE = 160 THEN y% = y1%+(x%-x1%): SCANCODE = 0
            2D_RECTANGLE x1%,y1%,x%,y%
    CASE 5: GOTO cas4
    CASE 6: ' Cercle vide ou plein
cas6:
            rx% = (x%-x1%)/2: ry% = (y%-y1%)/2: ' rayons H et V
            IF SCANCODE = 160 THEN ry% = rx%: SCANCODE = 0: ' cercle
            x2% = x1%+rx%: y2% = y1%+ry%: ' centre
            IF ry% = rx%
                2D_CIRCLE x2%,y2%,rx%
            ELSE
                2D_POLY_FROM x2%+rx%,y2%
                FOR an = 0 TO 2*PI STEP PI/180
                    2D_POLY_TO x2%+rx%*COS(an),y2%+ry%*SIN(an)
                NEXT an
                IF fig% = 7 AND mb% = 0 THEN 2D_FLOOD x2%,y2%,tr%,tg%,tb%
            END_IF
    CASE 7: GOTO cas6
  END_SELECT
RETURN
' ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
Chfig:
  HIDE ft%: HIDE fi%
  fig% = 2
  IF CHECKED(co%+2) = 1 THEN fig% = 3
  IF CHECKED(co%+3) = 1 THEN fig% = 4
  IF CHECKED(co%+4) = 1 THEN fig% = 5
  IF CHECKED(co%+5) = 1 THEN fig% = 6
  IF CHECKED(co%+6) = 1 THEN fig% = 7
  IF CHECKED(co%+7) = 1 THEN fig% = 8
  IF CHECKED(co%+8) = 1 THEN fig% = 9: SHOW ft%: ' insertion texte
  IF CHECKED(co%+9) = 1 THEN fig% = 10: SHOW fi%: ' insertion image
  mb% = 0
RETURN
' ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
Chcol:
  HIDE co%: SHOW chc%
  RETURN
Chcol1:
  x% = MOUSE_X_POSITION(chc%): y% = MOUSE_Y_POSITION(chc%)
  tr%=COLOR_PIXEL_RED(chc%,x%,y%): tg%=COLOR_PIXEL_GREEN(chc%,x%,y%)
  tb%=COLOR_PIXEL_BLUE(chc%,x%,y%): COLOR cl%,tr%,tg%,tb%
  FONT_COLOR mmt%,tr%,tg%,tb%
  HIDE chc%: SHOW co%: mb% = 0
RETURN
' ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
Chimg:
  a$ = FILE_NAME$(od%)
  b$ = UPPER$(FILE_EXTRACT_EXTENSION$(a$))
  IF b$<>".BMP" AND b$<>".JPG" THEN MESSAGE "Doit être .BMP ou .JPG": RETURN
  TEXT fi%+2,a$: ' fichier image
  IF b$ = ".JPG"
    b$="Z:\Fbm.bmp": FILE_LOAD pit%,a$: FILE_SAVE pit%,b$: a$ = b$
  END_IF
  FILE_LOAD im%,a$: ' -> Image
  FILEBIN_OPEN_READ 9,a$: FILEBIN_POSITION 9,18: i%=FILEBIN_READ(9)+256*FILEBIN_READ(9)
  FILEBIN_POSITION 9,22: j%=FILEBIN_READ(9)+256*FILEBIN_READ(9): FILEBIN_CLOSE 9
  CAPTION fi%+3,"Dimensions = "+STR$(i%)+" x "+STR$(j%)+" pixels."
RETURN
' ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
Chpol:
  SHOW lst%
RETURN
' ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
Valpo:
  HIDE lst%
  IF CLICKED(edt%) = 1 THEN TEXT edt%,ITEM_INDEX$(lst%)
  FONT_NAME mmt%,TEXT$(edt%): FONT_SIZE mmt%,POSITION(szt%)
RETURN
' ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
Valtx:
  ' transfert du texte
  WIDTH pit%,900: HEIGHT pit%,500
  FONT_NAME pit%,TEXT$(edt%): FONT_SIZE pit%,POSITION(szt%): FONT_COLOR pit%,tr%,tg%,tb%
  PRINT_TARGET_IS pit%: 2D_TARGET_IS pit%: CLS: 2D_FILL_COLOR 254,254,254: 2D_TARGET_IS p%
  j% = 0: y% = 0
  FOR i% = 1 TO COUNT(mmt%)
    a$ = ITEM_READ$(mmt%,i%): PRINT_LOCATE 0,y%: PRINT a$
    x% = TEXT_WIDTH(a$,pit%): IF x%>j% THEN j%=x%
    y% = y%+TEXT_HEIGHT(a$,pit%)
  NEXT i%
  PRINT_TARGET_IS 0
  WIDTH pit%,j%: HEIGHT pit%,y%
  FOR y% = 0 TO HEIGHT(pit%)-1
    FOR x% = 0 TO WIDTH(pit%)-1
        rt% = COLOR_PIXEL_RED(pit%,x%,y%)
        IF rt%<>254
            gt% = COLOR_PIXEL_GREEN(pit%,x%,y%): bt% = COLOR_PIXEL_BLUE(pit%,x%,y%)
            2D_PEN_COLOR rt%,gt%,bt%: 2D_POINT x1%+x%,y1%+y%
        END_IF
    NEXT x%
    DISPLAY
  NEXT y%
RETURN
' ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
Anuder:
  CLIPBOARD_PASTE p%
RETURN
' ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
FDes:
  ffd% = 1
RETURN
END_SUB
' ==============================================================================

label cercle, rectangle, triangle
picture 10 : 2d_target_is 10
 on_mouse_move 10,cercle
 on_mouse_down 10,rectangle
 on_mouse_up 10,triangle

end
Cercle:
  cls : 2d_fill_color 255,0,0
  2d_circle 50,50,40
return

Rectangle:
  off_mouse_move 10
  cls : 2d_fill_color 255,0,255
  2d_rectangle 10,10,80,80
return

Triangle:
  cls : 2d_poly_from 50,10
  2d_poly_to 10,50 : 2d_poly_to 90,50 : 2d_poly_to 50,10
  2d_flood 50,20,0,0,255
  on_mouse_move 10,cercle
return

label mon_label

picture 1
color 1,255,200,210
on_mouse_down 1,mon_label
end

mon_label:
   off_mouse_down 1
   if mouse_left_down(1)=1
      message "Le bouton gauche la souris est enfoncé sur le picture."
   end_if
   if mouse_right_down(1)=1
      message "Le bouton droit la souris est enfoncé sur le picture."
   end_if
   on_mouse_down 1,mon_label
return

label selection
dim i
list 10 : height 10,300
for i = 1 to 20 : item_add 10,str$(i) : next i
on_mouse_move 10, selection

end
Selection:
'  item_select 10,1  : ' Erreure : value must be positive
  item_select 10,5   : ' Correct
return

rem ============================================================================
rem       Exemple d utilisation de RESTORE_LABEL
rem ============================================================================
label Francais, Anglais, Allemand
dim a$,i
list 10 : height 10,400
RESTORE_LABEL Anglais
for i = 1 to 7 : read a$ : item_add 10,a$ : next i
item_add 10,"==========="
RESTORE_LABEL Francais
for i = 1 to 7 : read a$ : item_add 10,a$ : next i
item_add 10,"==========="
RESTORE_LABEL Allemand
for i = 1 to 7 : read a$ : item_add 10,a$ : next i
rem ============================================================================
Francais:
data "Lundi", "Mardi", "Mercredi", "Jeudi", "Vendredi", "Samedi","Dimanche"
Anglais:
data "Monday", "Tuesday", "Wednesday", "Thursday", "Friday", "Saturday", "Sunday"
Allemand:
data "Montag", "Dienstag", "Mittwoch", "Donnerstag", "Freitag", "Samstag", "Sonntag"
rem ============================================================================