Le jeu des 6 palets

' ------------------------------------------------------------------------------
'  JEU DES 6 PALETS
'  MARC37 - Décembre 2016 - Panoramic v0.9.27.i8
'  http://panoramic-language.pagesperso-orange.fr/French/index.html
' ------------------------------------------------------------------------------
DIM x%,y%,F%,G%
DIM jeu%
WIDTH 0, 800
HEIGHT 0, 700
LEFT 0,(screen_x-800)/2
TOP 0,(screen_y-700)/2

LABEL Quitter

ON_CLOSE 0, Quitter

Creation_jeu()

Jeu%=6

WHILE 0=0
   G%= MOUSE_LEFT_UP(10)
   F%= MOUSE_LEFT_DOWN(10)
   IF F% = 1 THEN Zone_cliquee()
END_WHILE

END
' ------------------------------------------------------------------------------
SUB Zone_cliquee()
    x%= MOUSE_X_POSITION(10)
    y%= MOUSE_Y_POSITION(10)
    IF Jeu%>0 AND x%>580 AND x%<720 AND y%>280 AND y%<420 THEN saisie_depose()
    IF y%>600 AND y%<630
        IF x%>635 AND x%<735 THEN TERMINATE
        IF x%>500 AND x%<560 THEN Aide()
        IF x%>50 AND x%<150 THEN Rejouer()
        IF x%>230 AND x%<420 THEN Demonstration()
    END_IF
END_SUB
' ------------------------------------------------------------------------------
SUB saisie_depose()
    WHILE Jeu% > 0
        x%= MOUSE_X_POSITION(10)
        y%= MOUSE_Y_POSITION(10)
        SPRITE_X_POSITION Jeu%, x%-100
        SPRITE_Y_POSITION Jeu%, y%-100
        IF MOUSE_LEFT_UP(10)=1 then Jeu%=Jeu%-1 : EXIT_WHILE
    END_WHILE
END_SUB
' ------------------------------------------------------------------------------
SUB Creation_jeu()
    Creation_dessin_palets()
    Creation_image_de_fond()
END_SUB
' ------------------------------------------------------------------------------
SUB Creation_dessin_palets()
    DIM_LOCAL i%
    2D_PEN_COLOR 50,50,50 : ' couleur contour palets
    2D_CIRCLE 101,100,100
    2D_FLOOD 260,260,0,0,0
    FOR i% = 1 to 6
        2D_FLOOD 100,100,150,150,150 : ' couleur palets
        2D_CIRCLE 101,100,100
        IMAGE i%
        2D_IMAGE_COPY i%,0,0,201,200
    NEXT i%
END_SUB
' ------------------------------------------------------------------------------
SUB Creation_image_de_fond()
    CLS
    2D_PEN_COLOR 50,50,50
    2D_CIRCLE 300,300,179
    2D_FLOOD 260,260,240,240,240 : ' couleur grand cercle
    2D_FLOOD 1,1,50,50,50 : ' couleur de fond
    IMAGE 7
    2D_IMAGE_COPY 7,0,0,800,700
    SCENE2D 10
    FULL_SPACE 10
    SPRITE 7
    SPRITE_IMAGE_LOAD 7,7
    SPRITE 10
    FONT_NAME 10,"arial"
    FONT_SIZE 10,20
    FONT_BOLD 10
    FONT_COLOR 10,255,0,0 : ' couleur des textes
    FONT_ITALIC 10
    SPRITE_TEXT 10," Rejouer "
    SPRITE_X_POSITION 10, 43
    SPRITE_Y_POSITION 10, 600
    SPRITE 11
    SPRITE_TEXT 11," Démonstration "
    SPRITE_X_POSITION 11, 220
    SPRITE_Y_POSITION 11, 600
    SPRITE 12
    SPRITE_TEXT 12," Aide "
    SPRITE_X_POSITION 12, 495
    SPRITE_Y_POSITION 12, 600
    SPRITE 13
    SPRITE_TEXT 13," Quitter "
    SPRITE_X_POSITION 13, 630
    SPRITE_Y_POSITION 13, 600
    DIM_LOCAL i%
    ' *************** Création SPRITES palets
    FOR i% = 6 to 1 STEP -1
        SPRITE i%
        SPRITE_IMAGE_LOAD i%,i%
        SPRITE_X_POSITION i%, (i%*-1)+550
        SPRITE_Y_POSITION i%, i%*2+250
    NEXT i%
    SPRITE_CREATE_HIDE
    SPRITE 14
    FONT_SIZE 10,50
    FONT_BOLD_OFF 10
    SPRITE_TEXT 14," SPECIMEN "
    SPRITE_POSITION 14, 105,270
END_SUB
' ------------------------------------------------------------------------------
SUB Aide()
    DIM_LOCAL Txt$
    Txt$="Jeu des 6 palets :"+CHR$(13)+CHR$(13)
    Txt$ = Txt$ + "Le but du jeu est de recouvrir TOTALEMENT le cercle blanc"+CHR$(13)
    Txt$ = Txt$ + "avec les 6 palets. Un seul pixel blanc restant visible et c'est perdu !"+CHR$(13)
    Txt$ = Txt$ + "A l'aide la souris, déplacez chaque palet."+CHR$(13)
    Txt$ = Txt$ + "Un palet laché est un palet joué : vous ne pouvez plus le déplacer !"+CHR$(13)+CHR$(13)
    Txt$ = Txt$ + "Marc37 - décembre 2016 - Programmé en langage PANORAMIC v0.9.27i8"+CHR$(13)+CHR$(13)
    Txt$ = Txt$ + "http://panoramic-language.pagesperso-orange.fr/French/index.html"
    MESSAGE Txt$
END_SUB
' ------------------------------------------------------------------------------
SUB Demonstration()
    Rejouer()
    SPRITE_SHOW 14
    Deplacer_sprite(6,550,250,83 ,114,16)
    Deplacer_sprite(5,550,250,105,247,16)
    Deplacer_sprite(4,550,250,198,339,16)
    Deplacer_sprite(3,550,250,201,111,16)
    Deplacer_sprite(2,550,250,321,118,16)
    Deplacer_sprite(1,550,250,289,248,16)
END_SUB
' ------------------------------------------------------------------------------
SUB Deplacer_sprite(Num_Sprite%,xa%,ya%,xb%,yb%,vitesse)
    DIM_LOCAL distance, nbpoints%,i%,xp%,yp%
    distance = SQR(POWER((xb%-xa%),2)+ POWER((yb%-ya%),2))
    NbPoints% = INT(Distance / vitesse)
    FOR i% = 1 to nbpoints%
        xp%=INT(((xb%-xa%)/nbpoints%) *i%)+xa%
        yp%=INT(((yb%-ya%)/nbpoints%) *i%)+ya%
        SPRITE_POSITION Num_Sprite%, xp%, yp%
    NEXT i%
    SPRITE_POSITION Num_Sprite%, xb%, yb%
END_SUB
' ------------------------------------------------------------------------------
SUB Rejouer()
    SPRITE_HIDE 14
    DIM_LOCAL i%
    Jeu%=6
    FOR i% = 6 to 1 STEP -1
        SPRITE_X_POSITION i%, (i%*-1)+550
        SPRITE_Y_POSITION i%, i%*2+250
    NEXT i%
END_SUB
' ------------------------------------------------------------------------------
Quitter:
    Jeu%= 0
    TERMINATE
RETURN
' ------------------------------------------------------------------------------