Minuteur a intervalles

' -------------------------- MINUTEUR A INTERVALLES ET CYCLES --------------------------

DIM n% , cycle% , travail% , pause% , tp% , min% , sec% , duree%
LABEL demarrer , raz , decompte

BORDER_SMALL 0 : CAPTION 0,"Minuteur à intervalles et cycles"
WIDTH 0,800 : HEIGHT 0,600 : LEFT 0,(SCREEN_X-WIDTH(0))/2 : TOP 0,(SCREEN_Y-HEIGHT(0))/2
FONT_BOLD 0 : FONT_NAME 0,"Arial" : COLOR 0,150,100,255

FOR n%=1 TO 5 : PANEL n% : TOP n%,478 : HEIGHT n%,85 : FONT_SIZE n%,10 : NEXT n%
FOR n%=6 TO 8 : SPIN n% : PARENT n%,n%-5 : TOP n%,30 : WIDTH n%,80 : NEXT n%
LEFT 1,4 : WIDTH 1,155 : CAPTION 1,"CYCLES                      " : LEFT 6,70 : COLOR 1,240,255,150
LEFT 2,159 : WIDTH 2,155 : CAPTION 2,"TRAVAIL                      " : LEFT 7,70 : COLOR 2,0,255,150
LEFT 3,314 : WIDTH 3,155 : CAPTION 3,"REPOS                    " : LEFT 8,70 : COLOR 3,255,200,0
LEFT 4,469 : WIDTH 4,155 : CAPTION 4,"DEMARRER" : COLOR 4,255,70,0 : ON_CLICK 4,demarrer
LEFT 5,624 : WIDTH 5,156 : CAPTION 5,"REMISE A ZERO" : COLOR 5,150,100,255 : ON_CLICK 5,raz
FOR n%=9 TO 11 : ALPHA n% : FONT_SIZE n%,30 : TOP n%,5 : NEXT n%
LEFT 9,5 : CAPTION 9,"STOP"
LEFT 10,35 : TOP 10,80 : FONT_SIZE 10,210 : CAPTION 10,"00:00"
LEFT 11,500 : CAPTION 11,"DUREE : 00:00"
TIMER 12 : ON_TIMER 12,decompte : TIMER_OFF 12

END

' ---------- Demarrer ----------
demarrer:
  IF CAPTION$(4)="DEMARRER"
      cycle%=position(6) : travail%=position(7) : pause%=position(8)
      min%=INT(travail%/60) : sec%=MOD(travail%,60) : duree%=((travail%+pause%)*cycle%)-pause%
      IF cycle%=0 OR travail%=0 THEN RETURN
      CAPTION 2,"TRAVAIL "+STR$(travail%)+" sec.": CAPTION 3,"REPOS "+STR$(pause%)+" sec."
      COLOR 0,0,255,150 : CAPTION 4,"PAUSE" : CAPTION 9,"TRAVAIL"
      FOR n%=6 TO 8 : HIDE n% : NEXT n%
      CAPTION 10,RIGHT$("00"+STR$(min%),2)+":"+RIGHT$("00"+STR$(sec%),2)
      cycle%=cycle%-1 : CAPTION 1,"CYCLES "+STR$(position(6)-cycle%)+"/"+STR$(position(6))
      tp%=1
      TIMER_ON 12
      RETURN
  END_IF
  IF CAPTION$(4)="PAUSE" THEN COLOR 0,255,70,0 : CAPTION 4,"REPRISE" : CAPTION 9,"PAUSE" : TIMER_OFF 12 : RETURN
  IF CAPTION$(4)="REPRISE" THEN COLOR 0,0,255,150 : CAPTION 4,"PAUSE" : CAPTION 9,"TRAVAIL" : TIMER_ON 12 : RETURN
RETURN

' ---------- DECOMPTE ----------
decompte:
  IF sec%>0 : sec%=sec%-1 : ELSE : IF min%>0 THEN min%=min%-1 : sec%=59 : END_IF
  duree%=duree%-1
  IF min%=0 AND sec%=0
      BEEP
      IF pause%=0 THEN tp%=0 : cycle%=cycle%-1 : CAPTION 1,"CYCLES "+STR$(position(6)-cycle%)+"/"+STR$(position(6))
      IF pause%<>0 AND tp%=0 THEN cycle%=cycle%-1 : CAPTION 1,"CYCLES "+STR$(position(6)-cycle%)+"/"+STR$(position(6))
      IF cycle%>=0
        IF tp%=0
            tp%=1 : CAPTION 9,"TRAVAIL" : COLOR 0,0,255,150 : min%=INT(travail%/60) : sec%=MOD(travail%,60)
        ELSE
            IF cycle%=0 THEN GOSUB raz : BEEP : RETURN
            tp%=0 : CAPTION 9,"REPOS" : COLOR 0,255,200,0 : min%=INT(pause%/60) : sec%=MOD(pause%,60)
        END_IF
      ELSE
        GOSUB raz
      END_IF
  END_IF
  CAPTION 10,RIGHT$("00"+STR$(min%),2)+":"+RIGHT$("00"+STR$(sec%),2)
  CAPTION 11,"DUREE : "+RIGHT$("00"+STR$(INT(duree%/60)),2)+":"+RIGHT$("00"+STR$(MOD(duree%,60)),2)
RETURN

' ---------- RAZ ----------
raz:
  TIMER_OFF 12 : COLOR 0,150,100,255 : CAPTION 4,"DEMARRER" : CAPTION 9,"STOP"
  FOR n%=6 TO 8 : SHOW n% : POSITION n%,0 : NEXT n%
  CAPTION 1,"CYCLES                      " : CAPTION 2,"TRAVAIL                      " : CAPTION 3,"REPOS                    "
  CAPTION 10,"00:00" : CAPTION 11,"DUREE : 00:00"
RETURN

TIMER 12 : TIMER_INTERVAL 12,1000 : ON_TIMER 12,decompte : TIMER_OFF 12

TIMER 12 :  ON_TIMER 12,decompte : TIMER_OFF 12