Compte à rebours

rem ============================================================================
rem           Compte à rebours
rem              Par Papydall
rem ============================================================================

label compte_a_rebours
dim dat1,dat2,sec,j,h,mn,n
dim result,dif,temp,t$,ville$
dim heure,minute,seconde,jour,mois,annee
dim heure2,minute2,seconde2,jour2,mois2,annee2

top 0,50 : left 0,screen_x-500 : width 0,480 : height 0,100
color 0,220,150,50 : font_color 0,0,0,255 : font_bold 0: font_size 0,14
caption 0,"Compte à rebours : Noël 2015"
alpha 10 : top 10,20 : left 10,10
timer 20 : on_timer 20, compte_a_rebours
n = 24*3600 : ' nombre de secondes dans une journée
rem ============================================================================
'  Indiquer ici la date et l'heure du compte à rebours
rem ============================================================================
' jour2 = 01 : mois2 = 01 : annee2 = 2016  : t$ =  "Nouvel an 2016," : ' Nouvel an
jour2 = 25 : mois2 = 12 : annee2 = 2015  : t$ =  "Noël 2015, " : ' Noël
heure2 = 00 : minute2 = 00 : seconde2 = 00
rem ============================================================================
Jour_Julien(jour2,mois2,annee2)    : dat2 = result
Frac_Jour(heure2,minute2,seconde2) : dat2 = dat2 + result
end
rem ============================================================================
compte_a_rebours:
  Get_Date_heure()
  Jour_Julien(jour,mois,annee)    : dat1 = result
  Frac_Jour(heure,minute,seconde) : dat1 = dat1 + result
  dif = (dat2-dat1) * n

  if dif > 0
      j = int(dif/n) : temp = dif - j*n
      h = int(temp/3600) : temp = temp -h*3600
      mn = int(temp/60) : temp = temp - mn*60
      sec = int(temp)
      caption 10, t$ + " c'est dans : " + str$(j) +" j "+str$(h)+" h "+str$(mn)+" mn " +str$(sec)+" s"
  else
      timer_off 20
      caption 10, "L'heure de " + t$ + " est déjà dépassée !"
  end_if
return

rem ============================================================================
' Déterminer le Jour Julien à partir d'une date
SUB Jour_Julien(jour,mois,annee)
    dim_local a,b,d,m,y
    d = jour : m = mois : y = annee
    if m < 3 then y = y - 1 : m = m + 12
    a = int(y/100) : b = 2 - a + int(a/4)
    result = int(365.25*(y+4716)) + int(30.6001*(m+1)) + d + b - 1524.5
END_SUB
rem ============================================================================
' Lire la date et l'heuree système
SUB Get_Date_heure()
    heure = val(mid$(time$,1,2)) : minute  = val(mid$(time$,4,2)) : seconde = val(mid$(time$,7,4))
    jour  = val(mid$(date$,1,2)) : mois    = val(mid$(date$,4,2)) : annee   = val(mid$(date$,7,4))
END_SUB
rem ============================================================================
SUB Frac_Jour(heure,minute,seconde)
    result = (seconde + minute*60 + heure*3600)/n
END_SUB
rem ============================================================================