Sélection d'une fonte.

sub choisir_fonte()
    creer_objet("form",3001,0,largeur_ecran%/2-270,hauteur_ecran%/2-150,540,300,"Choix de la fonte.","",0,0,0,0,0,0)

    creer_objet("alpha",1666,3001,15,25,50,30,"Calibri","Fonte.",1,0,16,128,0,8)
    creer_objet("alpha",1667,3001,190,25,50,30,"Calibri","Style.",1,0,16,128,0,8)
    creer_objet("alpha",1668,3001,325,25,50,30,"Calibri","Taille.",1,0,16,128,0,8)
    creer_objet("alpha",1669,3001,15,190,100,30,"Calibri","Exemple:",1,0,16,128,0,8)
    creer_objet("alpha",1670,3001,190,190,100,50,"Calibri","AaBbYyZz",1,0,16,0,0,128)

    creer_objet("list",1013,3001,15,60,150,100,"Calibri","",1,0,12,255,0,255)
    creer_objet("list",1014,3001,190,60,110,100,"Calibri","",1,0,12,255,0,255)
    creer_objet("list",1015,3001,325,60,50,100,"Calibri","",1,0,12,255,0,255)

    font_names_load 1013
    item_add 1014,"Normal"
    item_add 1014,"Italique"
    item_add 1014,"Gras"
    item_add 1014,"Gras et italique"

    for k%=10 to 32
        item_add 1015,str$(k%)
    next k%
   
    on_click 1013,fonte_exemple
    on_click 1014,style_fonte_exemple
    on_click 1015,taille_fonte_exemple

    creer_objet("button",1746,3001,400,60,100,30,"Calibri","OK",1,0,16,0,0,0)
    creer_objet("button",1747,3001,400,100,100,30,"Calibri","Annuler",1,0,16,0,0,0)
    on_click 1746,valider_fonte
    on_click 1747,annuler_fonte
end_sub

fonte_exemple:
  f$=item_index$(1013)
  if f$="" then f$=item_read$(1013,1)
  font_name 1670,f$
return

style_fonte_exemple:
  c$=item_index$(1014)
  if c$="" then c$="Normal"
  if c$="Normal"
      font_bold_off 1670
      font_italic_off 1670
  end_if
  if c$="Gras"
      font_bold 1670
      font_italic_off 1670
  end_if
  if c$="Italique"
      font_italic 1670
      font_bold_off 1670
  end_if
  if c$="Gras et italique"
      font_bold 1670
      font_italic 1670
  end_if
return

taille_fonte_exemple:
  c$=item_index$(1015)
  if c$="" then c$="10"
  font_size 1670,val(c$)
return

valider_fonte:
  a$=item_index$(1013)
  c$=item_index$(1014)
  l%=val(item_index$(1015))
 
  if a$="" then a$=item_read$(1013,1)
  if c$="" then c$="Normal"
  if item_index$(1015)="" then l%=10

  font_name 801,a$
  font_name 802,a$
  font_size 801,l%
  font_size 802,l%
  if c$="Normal"
      font_bold_off 801
      font_bold_off 802
      font_italic_off 801
      font_italic_off 802
  end_if
  if c$="Gras"
      font_bold 801
      font_bold 802
      font_italic_off 801
      font_italic_off 802
  end_if
  if c$="Italique"
      font_italic 801
      font_italic 802
      font_bold_off 801
      font_bold_off 802
  end_if
  if c$="Gras et italique"
      font_bold 801
      font_bold 802
      font_italic 801
      font_italic 802
  end_if

  hide 3001
return

annuler_fonte:
  hide 3001
return

sub creer_objet(type$,no%,parent%,x%,y%,l%,h%,fontname$,label$,fontbold%,souligne%,fontsize%,r%,g%,b%)

    dim_local flag9%
    flag9%=0

    ' Pour adaptation aux différentes résolutions d'écran.
    if type$<>"form"
      if object_exists(160)=1 then flag9%=show(160)
    end_if

    if object_exists(no%)=1 then delete no%

    if type$="alpha"
      alpha no%
      parent no%,parent%
      ' Placer obligatoirement avant la définition des dimensions.
      font_name no%,fontname$
      if fontbold%>0 then font_bold no%
      if souligne%=1 then font_underline no%
      if fontsize%>0 then font_size no%,fontsize%
      font_color no%,r%,g%,b%
      caption no%,label$
      gauche(no%,x%,flag9%)
      haut(no%,y%,flag9%)
      largeur(no%,l%,flag9%)
      hauteur(no%,h%,flag9%)
      exit_sub
    end_if

    if type$="form"
      form no%
          else
      if type$="button" then button no%
      if type$="check" then check no%:mark_off no%
      if type$="combo" then combo no%
      if type$="container_option" then container_option no%
      if type$="edit" then edit no%
      if type$="list" then list no%
      if type$="memo" then memo no%
      if type$="option" then option no%
      if type$="picture" then picture no%
      parent no%,parent%
    end_if

    if no%=765
      full_space 765
          else
      gauche(no%,x%,flag9%)
      haut(no%,y%,flag9%)
      largeur(no%,l%,flag9%)
      hauteur(no%,h%,flag9%)
    end_if

    if type$="form"
      caption no%,fontname$
      ' Cacher les boutons de réduction, agrandissement et fermeture.
      hnd%=handle(no%)
      res%=dll_call2("SetMinimizeMaximize",hnd%,0)
      res%=dll_call2("SetCloseBox",hnd%,0)
      exit_sub
    end_if

    if len(fontname$)>0
      if type$<>"picture"
          font_name no%,fontname$
            else
          if no%<>765 then stretch_on no%
          if file_exists(fontname$)=1 then file_load no%,fontname$
      end_if
    end_if
    if len(label$)>0
      if type$="check" or type$="button" or type$="container_option" then caption no%,label$
      if type$="memo" then item_add no%,label$
      if type$="picture" then hint no%,label$
    end_if
    if fontbold%>0 and type$<>"picture" then font_bold no%

    if souligne%=1 then font_underline no%
    if fontsize%>0 then font_size no%,fontsize%
   
    if type$="button" then exit_sub

    if type$<>"picture"
      if type$<>"combo"
          font_color no%,r%,g%,b%
            else
          color no%,r%,g%,b%
      end_if
    end_if
end_sub