clipboard_paste vers un picture

salut à vous
Je voudrais positionner des bmp dans un picture en passant par clipboard_paste
Il semblerait que ça ne soit pas possible

Nombre de messages : 7112 Localisation : 77 Date d'inscription : 29/11/2007

Ben si, qu'est-ce qui t'en empêche ?
Comme l'image est dans le presse-papier, il n'est plus question de format, bmp ou autre, c'est une image brute.

'positionner', qu'est-ce que tu entends par là ? si tu veux rapatrier ton image à un emplacement précis du picture, il faut d'abord la 'coller' dans un 'Image' (clipboard-paste), puis la recopier dans le picture à un endroit précis (2d_Image_Paste n,x,y).

Mais attention, il faut que les dimensions des objets picture correspondent à celles des images, sinon il y aura des troncatures et/ou des déformations.

Merci JL35 pour ta réponse
Je n'y avais pas pensé et ça me bloquait
je vais appliquer

Nombre de messages : 3 Date d'inscription : 05/12/2015

Bonjour ,
j aurais aimé avoir le code de ce programme
à savoir :

ouvrir une forme ,
y placer plusieurs images à des endroits définis

exemple :
form 400 x 400
image1 : à placer en (0,0) - taille 200 x 200
image2 : à placer en (200,0) - taille 200 x 200
image3 : à placer en (0,200 - taille 200 x 200
image4 : à placer en (200,200) - taille 200 x 200

merci d avance , Nicola

Nombre de messages : 7112 Localisation : 77 Date d'inscription : 29/11/2007

Quelque chose comme ça (c'est une ébauche) ?:

Code:: ' images i1$, i2$, i3$, i4$, 200x200 pixels,
' format bmp obligatoire
FORM 50: WIDTH 50,420: HEIGHT 50,480
PICTURE 51: WIDTH 51,400: HEIGHT 51,400
2D_TARGET_IS 51
IMAGE 52
FILE_LOAD 52,i1$: 2D_IMAGE_PASTE 52,0,0
FILE_LOAD 52,i2$: 2D_IMAGE_PASTE 52,200,0
FILE_LOAD 52,i3$: 2D_IMAGE_PASTE 52,0,200
FILE_LOAD 52,i4$: 2D_IMAGE_PASTE 52,200,200

il faut ajuster les dimensions du Form 50 pour que le picture 400x400 tienne juste dedans (ça dépend du Windows).
On peut aussi faire un Border_Hide du Form, auquel cas on lui donne les mêmes dimensions que le Picture.

Nicola4830, bienvenue parmi la communauté panoramicienne.
JL35 t’a montré le chemin.
Quant à moi, je te propose ce code qui pourrait te donner (à toi et certainement à d’autres) des idées meilleures que les miennes.

Code:: rem ============================================================================
rem ESTHETIQUE POLAIRE PAR PAPYDALL
rem ============================================================================
Init()
Pictures()
Polaires()
Hide_Show_Picture()
END
REM ============================================================================
SUB Init()
   DIM R,A,TETHA : ' Variables de l'équation
' DIM PI : PI = ACOS(-1) : ' Le fameux nombre pi inutile pour la version 27i2
   DIM P : P = PI/180 : ' Facteur de conversion de degrés en radians
   DIM XC,YC : ' Coordonnées du centre de l'écran
   DIM X,Y : ' Coordonnées cartésiennes du point de la courbe
   DIM XP,YP : ' Coordonnées du point à tracer
   DIM D$ : D$ = dir_current$ + chr$(92)
   DIM T : T = 200 : ' Temporisation

END_SUB
REM ============================================================================
SUB pictures()
   dim i,h,w
   full_space 0 : h = height(0) : w = width(0)-5 : color 0,255,255,255
   caption 0,"L'ESTHETIQUE POLAIRE"
   alpha 99 : top 99,100 : left 99,500 : font_bold 99 : font_size 99,28
   font_name 99,"tahoma" : caption 99,"That's all folks!" : hide 99
   for i = 1 to 5
   picture i : full_space i : top i,35-35 : width i, w/5-15 : height i,h/3-20
   left i,width(i) *(i-1)+12*(i)
   next i
   for i = 6 to 10
   picture i : full_space i : top i,35-25+height(i-1) : width i, w/5-15 : height i,h/3-20
   left i,width(i) *(i-6)+12*(i-5)
   next i
   for i = 11 to 15
   picture i : full_space i : top i,35-15+2*height(i-1) : width i, w/5-15 : height i,h/3-20
   left i,width(i) *(i-11)+12*(i-10)
   next i
   for i = 1 to 15 : color i,0,0,0 : next i
   xc = width(1)/2-8 : yc = height(1)/2-17
   a = yc * 0.8
   for i = 1 to 15
   color i,00,00,255 : 2d_pen_color 255,0,0
   2d_target_is i : 2d_fill_color 255,255,0 : 2d_circle xc,yc,yc*.9
   next i
   display

END_SUB
rem ============================================================================
SUB Polaires()
   Quadrifolium() : Quadrifolium_Rayonnee()
   Polaire_3() : Polaire_3_Rayonnee()
   Polaire_5() : Polaire_5_Raonnee()
   Polaire_7() : Polaire_7_Raonnee()
END_SUB
REM ============================================================================
SUB Hide_Show_Picture()
   pause 2000
   Cache_picture() : pause 500
   Montre_picture() : pause 1000
   Cache_picture()
   show 99
END_SUB

REM ============================================================================
SUB Quadrifolium()
   2d_target_is 1
   2d_poly_from xc+a,yc
   for tetha = 0 to 2*pi step p
   r = a*cos(2*tetha) : x = R*COS(tetha) : y = R*SIN(tetha)
   xp = xc + x : yp = yc + y : 2d_poly_to xp,yp
   next tetha
   print_target_is 1 : print_locate 10, height(1) -20
   print " Quadrifolium R = a*cos(2*tetha) "
END_SUB
REM ============================================================================
SUB Quadrifolium_Rayonnee()
   2d_target_is 2
   for tetha = 0 to 2*pi step p
   r = a*cos(2*tetha) : x = R*COS(tetha) : y = R*SIN(tetha)
   xp = xc + x : yp = yc + y : 2d_line xc,yc,xp,yp
   next tetha
END_SUB
REM ============================================================================
SUB Polaire_3()
   2d_target_is 3
   2d_poly_from xc,yc
   for tetha = 0 to 4*pi step p
   R = a*sin(3*tetha/2) : x = R*COS(tetha) : y = R*SIN(tetha)
   xp = xc + x : yp = yc + y : 2d_poly_to xp,yp
   next tetha
END_SUB
REM ============================================================================
SUB Polaire_3_Rayonnee()
   2d_target_is 4
   for tetha = 0 to 4*pi step p
   r = a*sin(3*tetha/2) : x = R*COS(tetha) : y = R*SIN(tetha)
   xp = xc + x : yp = yc + y : 2d_line xc,yc,xp,yp
   next tetha
END_SUB
REM ============================================================================
SUB Polaire_5()
   2d_target_is 5
   2d_poly_from xc+a/9,yc
   for tetha = 0 to 4*pi step p
   R = a/(5+4*cos(3*tetha/2)) : x = R*COS(tetha) : y = R*SIN(tetha)
   xp = xc + x : yp = yc + y : 2d_poly_to xp,yp
   next tetha
END_SUB
REM ============================================================================
SUB Polaire_5_Raonnee()
   2d_target_is 6
   for tetha = 0 to 4*pi step p
   R = a/(5+4*cos(3*tetha/2)) : x = R*COS(tetha) : y = R*SIN(tetha)
   xp = xc + x : yp = yc + y : 2d_line xc,yc,xp,yp
   next tetha
END_SUB
REM ============================================================================
SUB Polaire_7()
   2d_target_is 7
   2d_poly_from xc+a,yc
   for tetha = 0 to 4*pi step p
   R = a/2*(1+cos(tetha)) : x = R*COS(tetha) : y = R*SIN(tetha)
   xp = xc + x : yp = yc + y : 2d_poly_to xp,yp
   next tetha
END_SUB
REM ============================================================================
SUB Polaire_7_Raonnee()
   2d_target_is 8
   for tetha = 0 to 4*pi step p
   R = a/2*(1+cos(tetha)) : x = R*COS(tetha) : y = R*SIN(tetha)
   xp = xc + x : yp = yc + y : 2d_line xc,yc,xp,yp
   next tetha
END_SUB
REM ============================================================================

REM ============================================================================
SUB Cache_picture()
   dim_local Milieu,Gauche,Droite,I
   Milieu = 8 : Gauche = 8 : Droite = 8

   PAUSE T : HIDE Milieu : PAUSE T
   FOR I = 1 to 7
   Gauche = Gauche - 1 : HIDE Gauche : PAUSE T
   Droite = Droite + 1 : HIDE Droite : PAUSE T
   NEXT I
END_SUB
REM ============================================================================
SUB Montre_picture()
   dim_local Milieu,Gauche,Droite,I
   Milieu = 8 : Gauche = 8 : Droite = 8
   PAUSE T : SHOW Milieu : PAUSE T
   FOR I = 1 to 7
   Gauche = Gauche - 1 : SHOW Gauche : PAUSE T
   Droite = Droite + 1 : SHOW Droite : PAUSE T
   NEXT I
END_SUB
REM ============================================================================

Amuse toi bien avec PANORAMIC!
Bonne programmation.

@Nicola4830:
Je te conseille de lire:
- l'aide du langage dans l'éditeur Panoramic - chaque commande y est décrite, avec un bref exemple que tu peux essayer
- les tutos de Jack (auteur de Panoramic). Très complets, pas à pas, à suivre à partir du premier...
- les cours disponibles sur le Mag de Panoramic

Je pense que cela te fournira rapidement les bases. Panoramic est très facile à prendre en main, mais il faut tout de même un minimum de lecture !

» Convertisseur UTF-8 vers ANSI et ANSI vers UTF-8
» Retour vers IE ?...
» Tendre vers PI
» Confirmation TAB
» Conversion Unix vers Dos