Remplacer une sous-chaîne de caractères par une autre

Remplace(t$,s1$,s2$)

rem ============================================================================
rem                     Remplace.bas par Papydall
rem   Remplacer dans le texte t$, la 1ère occurence (ou toutes les occurences)
rem               de la chaine s1$ par la chaine s2$
rem ============================================================================
dim t$,s1$,s2$,t1$
t$ = "Ceci est un exemple d'utilisation de la SUB Remplace(t$,s1$,s2$): exemple réussi "

s1$ = "exemple"
s2$ = "test"
t1$ = t$
rem ============================================================================
' Exemple d'appel pour remplacer la 1ère occurence de s1$ :
' Remplace(t$,s1$,s2$) : t$ = remplace$
rem ============================================================================
' Exemple d'appel pour remplacer toutes les occurences de s1$
while instr(t$,s1$) > 0 : Remplace(t$,s1$,s2$) : t$ = remplace$ : end_while
rem ============================================================================
 
message "Texte original : " + t1$ + chr$(13) + "On va remplacer " + s1$+" par "+ s2$+chr$(13)+"Texte final : " + t$

end

rem ============================================================================
' Remplacer dans le texte T$, la chaîne S1$ par la chaîne S2$
' Le retour est dans la variable globale REMPLACE$
' Cette procédure (utilisée comme fonction) remplace la 1ère occurence de S1$
' par S2$ dans T$.
' REMARQUE :
' Pour remplacer toutes les occurences de S1$ par S2$ dans T$, l'appel se fera
' comme ceci :
' while instr(t$,s1$) > 0 : Remplace(t$,s1$,s2$) : t$ = remplace$ : end_while
rem ============================================================================
SUB Remplace(t$,s1$,s2$)
    dim_local f$,retour$,g$
    if variable("remplace$") = 0 then DIM remplace$
    f$ = "c:\temp\replace.vbs" : retour$ = "c:\temp\retour.txt" : g$ = chr$(34)
    FILE_OPEN_WRITE 9999, f$
    file_writeln 9999, "Function Replace(string_1,strPattern, strReplaceString)"
    file_writeln 9999, "Set regEx = New RegExp"
    file_writeln 9999, "regEx.Pattern = strPattern"
    file_writeln 9999, "Replace = regEx.Replace(string_1,strReplaceString)"
    file_writeln 9999, "retour = Replace"
    file_writeln 9999, "End Function"
    file_writeln 9999, "Set fso = CreateObject("+g$+"Scripting.FileSystemObject"+g$+")"
    file_writeln 9999, "Set MyFile = fso.CreateTextFile("+g$+retour$+g$+", True)"
    file_writeln 9999, "MyFile.WriteLine(Replace("+g$+t$+g$+","+g$+s1$+g$+","+g$+s2$+g$+"))"
    file_writeln 9999, "MyFile.Close"
    FILE_CLOSE 9999
    EXECUTE_WAIT f$ : FILE_DELETE f$
    file_open_read 9999,retour$ : file_readln 9999,Remplace$
    file_close 9999 : file_delete retour$

END_SUB
rem ============================================================================

 remplace_block(source$,destination$,recherche$,remplace$)

Chers Panoramiciens et Panoramiciennes

Pour fêter l'arrivée du compilateur Panoramic, l'association Panoramicale a le plaisir de vous inviter à son Panoramic Party, le  
dimanche 02 Février à partir de 16 heurs ( heure Panoramicienne)

A cette occasion, notre cher Jean Claude nous organisera un grand méchoui Panoramicien.
Vous pouvez venir nombreux, vos amis sont les bienvenus.
Une participation de deux SUB bien codées sera demandée.

 remplace_block("c:\temp\invitation_source.txt","c:\temp\invitation_destination.txt","Panoramic","langage Panoramic")

REM ============================================================================
REM                     replace_block_of_text.bas
'        remplacer n'importe quoi dans un fichier texte, par n'importe quoi
REM ============================================================================
' Exemple d'appel :
remplace_block("c:\temp\invitation_source.txt","c:\temp\invitation_destination.txt","Panoramic","langage Panoramic")


REM ============================================================================

END
REM ============================================================================
' Remplacer un bloc de texte par un autre bloc de texte dans un fichier texte
' Paramètres :
' Source$      : nom du fichier texte à modifier
' Destination$ : nom du fichier texte modifié
' Recherche$   : bloc de texte à remplacer
' Remplace$    : bloc de texte de remplacement
' ==============================================================================
' Si le fichier source n'existe pas, il y aura un message d'alerte et arrêt du script
' Si le bloc de texte à remplacer n'existe pas dans le fichier source,
' le fichier destination sera identique au fichier source
REM ============================================================================
SUB remplace_block(source$,destination$,recherche$,remplace$)
    dim_local f$,g$
    f$ = "c:\temp\replace_block_of_text.vbs"
    g$ = chr$(34)
REM ============================================================================
    FILE_OPEN_WRITE 9999, f$
    file_writeln 9999, "Option Explicit"
    file_writeln 9999, "Dim oFSO"
    file_writeln 9999, "Set oFSO = CreateObject(" + g$ + "Scripting.FileSystemObject" + g$ + ")"
    file_writeln 9999, "if oFSO.FileExists("+g$+source$+g$+") then"
    file_writeln 9999, "Main"
    file_writeln 9999, "Else"
    file_writeln 9999, "MsgBox " +g$+"Le fichier "  + source$  +" n'existe pas."+g$+",48"+","+g$+"!!! ERREUR !!!" +g$
    file_writeln 9999, "wscript.quit"
    file_writeln 9999, "end if"
REM ============================================================================
    file_writeln 9999, "Sub Main"
    file_writeln 9999, "Dim f, sSourceFile, sDestFile, sSearch, sReplace, sText1, sText2"
    file_writeln 9999, "sSourceFile = " + g$ + source$ + g$
    file_writeln 9999, "sDestFile = " + g$ + destination$ + g$
    file_writeln 9999, "sSearch =  " + g$ + recherche$ + g$
    file_writeln 9999, "sReplace = " + g$ + remplace$ + g$
    file_writeln 9999, "Set f = oFSO.OpenTextFile(sSourceFile)"
    file_writeln 9999, "sText1 = FileReadAll(sSourceFile)"
    file_writeln 9999, "sText2 = Replace(sText1, sSearch, sReplace)"
    file_writeln 9999, "SaveToFile sText2, sDestFile"
    file_writeln 9999, "Wscript.Echo _"
    file_writeln 9999,  g$ + "Texte avant : " + g$ + " & Len(sText1) & " + g$ + " caractères, " + g$ + " & _ "
    file_writeln 9999,  g$+g$ + "texte après : " + g$ + " & Len(sText2) & " + g$ + " caractères (résultat dans " + g$ + " & sDestFile & " + g$ + ")." + g$ + "
    file_writeln 9999, "End Sub"
REM ============================================================================
   file_writeln 9999, "Function FileReadAll(sFile)"
   file_writeln 9999, "Dim f"
   file_writeln 9999, "Set f = oFSO.OpenTextFile(sFile)"
   file_writeln 9999, "FileReadAll = f.ReadAll"
   file_writeln 9999, "f.Close"
   file_writeln 9999, "End Function"
REM ============================================================================
   file_writeln 9999, "Sub SaveToFile(sText, sFile)"
   file_writeln 9999, "Dim f"
   file_writeln 9999, "Set f = oFSO.CreateTextFile(sFile)"
   file_writeln 9999, "f.Write sText"
   file_writeln 9999, "f.Close"
   file_writeln 9999, "End Sub"
REM ============================================================================
   FILE_CLOSE 9999
   EXECUTE_WAIT f$ : FILE_DELETE f$
END_SUB
REM ============================================================================

Voici un petit texte d'essai:

Il était une fois un marchand de salades qui essayait de vendre des radis. Un jour, on lui
amena un radis vert. Il s'écria: "Oh! Mon Dieu!, ce n'est pas un radis rouge!"
Depuis ce jour, il ne vend plus que des radis noirs! Fin de l'histoire des radis.
Moralité: Il vaut mieux continuer à vendre des salades que devenir marchand de radis!

SUB Remplace(b$,c$,source$,destination$)
' remplacer la séquence b$ par c$ dans le fichier source$, résultat dans le fichier destination$
dim_local a$,aa$,k%,u%
file_open_read 1,source$: file_open_write 2,destination$
while file_eof(1) = 0
    file_readln 1,a$
    k% = INSTR(a$, b$)
    WHILE k% > 0
        a$ = LEFT$(a$, k%-1)+c$+MID$(a$,k%+LEN(b$),500)
        u% = k%+LEN(c$): aa$ = MID$(a$, u%, 500)
        k% = INSTR(aa$, b$): IF k% = 0 THEN EXIT_WHILE
        k% = k% + u% -1
    END_WHILE
    file_writeln 2,a$
end_while
file_close 1: file_close 2
end_sub

Voici un petit texte d'essai:

1 radis + 1 radis + 1 radis + 1 radis + 1 radis = 5 radis.
Et combien font 10 x 5 radis?
Sûrement pas 50 radis! Ni 10 radis + 10 radis + 10 radis + 10 radis + 10 radis!
Cela fait tout simplement une botte de radis!

Voici un petit texte d'essai:

1 radis noirs + 1 radis noirs + 1 radis noirs + 1 radis noirs + 1 radis noirs = 5 radis noirs.
Et combien font 10 x 5 radis noirs?
Sûrement pas 50 radis noirs! Ni 10 radis noirs + 10 radis noirs + 10 radis noirs + 10 radis noirs + 10 radis noirs!
Cela fait tout simplement une botte de radis noirs!

dim b$,c$
height 0,545

' Substituer les mots "radis noirs" au mot "radis"!
b$="radis" : c$="radis noirs"

remplace(b$,c$,"c:\temp\source.txt","c:\temp\destination.txt")

' Pour vérifier le résultat
memo 3:width 3,580:height 3,250:file_load 3,"c:\temp\source.txt"
memo 4:width 4,580:height 4,250:top 4,253:file_load 4,"c:\temp\destination.txt"
end

SUB Remplace(b$,c$,source$,destination$)
' remplacer la séquence b$ par c$ dans le fichier source$, résultat dans le fichier destination$
   dim_local a$,d$,k,h
   file_open_read 1,source$ : file_open_write 2,destination$
   while file_eof(1)=0
      file_readln 1,a$
         k=instr(a$,b$) : d$=right_pos$(a$,k+len(b$))
      repeat
         if k>0
            a$=left$(a$,k-1)+c$+d$ : k=instr_pos(a$,d$,1) : h=instr(d$,b$)
            if h>0
               k=k+h-1:d$=right_pos$(a$,k+len(b$))
            else
               k=0
            end_if
         end_if
      until k=0
      file_writeln 2,a$
   end_while
   file_close 1 : file_close 2
end_sub