MyDrive Connector

Variables()
Labels()
Start_Dll()
GUI()
Init()
end
' ------------------------------------------------------------------------------
Sub Variables()
   dim Titre$ : Titre$ ="My Drive Connector"
   dim W_GUI% : W_GUI% =298
   dim H_GUI% : H_GUI% =450
   dim T_GUI% : T_GUI% =(screen_y-H_GUI%)/2
   dim L_GUI% : L_GUI% =(screen_x-W_GUI%)/2
   dim obj%,O_List%,O_DList%
   dim MDC_DB$: MDC_DB$ =dir_current$+"\Fichiers\MDC_DB.bdd"
   dim MDC_NewFiche%,NF_edit1%,NF_edit2%,NF_edit3%,NF_Button%,clic%,NF_verif%
   dim Select_List%,Nom$,Login$,pw$
   dim MDC_timer%
End_sub
' ------------------------------------------------------------------------------
Sub Labels()
'  Click
   Label Fin,Quitter,clic
'  Change
   Label Toolbar_actions
End_sub
' ------------------------------------------------------------------------------
Sub Start_Dll()
   dim KGF$,res%
   KGF$=Dir_current$+"\Fichiers\KGF.dll"
   dll_on KGF$
End_sub
' ------------------------------------------------------------------------------
Sub GUI()
   width 0,W_GUI% : height 0,H_GUI% : top 0,T_GUI% : left 0,L_GUI%
   Caption 0,Titre$ : font_name 0,"arial" :font_bold 0 :font_color 0,0,0,230
   MenuTB()
   obj%=obj%+1 : O_List%=obj%
   O_List(O_List%,TB_Container%,1,5,0,height(TB_Container%)-6,width(TB_Container%)-1,"")
   cursor_point O_List% : On_click O_List%,clic
   obj%=obj%+1 : O_DList% =obj%
   O_DList(O_DList%,"")
   obj%=obj%+1 : MDC_Timer%=obj%
   O_Timer(obj%,0,500)
End_sub
' ------------------------------------------------------------------------------
Sub Init()
   if file_exists(MDC_DB$)=1
      file_load O_DList%,MDC_DB$
      Init_Liste()
   else
      if message_information_yes_no("La base compte est vide"+chr$(13)+"Voulez vous créer un compte ?...")=1
         F_NewFiche()
      else
         end_sub
      end_if
   end_if
End_sub
' ------------------------------------------------------------------------------
Sub Init_Liste()
   dim_local x%,L$,sep%
   clear O_List%
   if count(O_DList%)>0
      for x%= 1 to count(O_Dlist%)
         L$=item_read$(O_DList%,x%)
         sep%=instr(L$,"|")
         L$=left$(L$,sep%-1)
         item_add O_List%,L$
      next x%
      res% = dll_call4("ModifyToolbar",3,2,1,0)
   else
      res% = dll_call4("ModifyToolbar",3,2,0,0)
   end_if
End_sub
' ------------------------------------------------------------------------------
Sub MenuTB()
   dim_local x%
   dim TB_Position% :TB_Position% =0
   dim TB_IcoSize%  :TB_IcoSize% = 16
   dim TB_Lib$      :TB_Lib$ =dir_current$+"\Fichiers\MDC.ilb"
   dim chg_hor%     :chg_hor% =16
   dim chg_ver%     :chg_ver% =(TB_IcoSize%-16)+76
   dim icon$(12),ic$
   dim after%
   dim hint$(12),h$
   dim TB_Edit%, TB_Container%, TB_Button%

   obj%=obj%+1 :TB_Edit%=obj%
   Edit TB_Edit% : hide TB_Edit% :On_Change TB_Edit%,Toolbar_actions

   obj%=obj%+1 :TB_Container%=obj%
   Container TB_Container%

   res% = dll_call4("CreateToolbar",handle(0),handle(TB_Edit%),0,TB_Position%)
   res% = dll_call4("ModifyToolbar",7,TB_IcoSize%,0,0)
   Adapter_Container()
   res% = dll_call4("ModifyToolbar",8,1,0,0)
   res% = dll_call4("ModifyToolbar",2,0,0,0)

   if file_exists(TB_Lib$)=1
      res% = dll_call4("ModifyToolbar",5,adr(TB_Lib$),0,0)
      icon$(1) = "USER_1"
      icon$(2) = "USER_2"
      icon$(3) = "USER_3"
      icon$(4) = " "
      icon$(5) = " "
      icon$(6) = " "
      icon$(7) = " "
      icon$(8) = " "
      icon$(9) = " "
      icon$(10)= " "
      icon$(11)= "USER_7"
      icon$(12)= "USER_6"
   else
      icon$(1) = "KGF_44"
      icon$(2) = "KGF_44"
      icon$(3) = "KGF_44"
      icon$(4) = " "
      icon$(5) = " "
      icon$(6) = " "
      icon$(7) = " "
      icon$(8) = " "
      icon$(9) = " "
      icon$(10)= " "
      icon$(11)= " "
      icon$(12)= "KGF_44"
   end_if
   hint$(1) = "Ajouter un compte"
   hint$(2) = "Supprimer un compte"
   hint$(3) = "Se connecter à un compte"
   hint$(4) = ""
   hint$(5) = ""
   hint$(6) = ""
   hint$(7) = ""
   hint$(8) = ""
   hint$(9) = ""
   hint$(10)= ""
   hint$(11)= ""
   hint$(12)= "Quitter"
  
   for x%=1 to 12
      h$=hint$(x%)
      ic$=icon$(x%)
      res% = dll_call4("AddButtonToToolbar",x%,x%-1,adr(h$),adr(ic$))
      if ic$="USER_7"
         res% = dll_call4("ModifyToolbar",3,x%,0,0)
      end_if
   next x%
End_sub
' ------------------------------------------------------------------------------
Sub Adapter_Container()
   select TB_Position%
     case 0
       top TB_Container%,TB_IcoSize%+10
       width TB_Container%,(width(0)-chg_hor%)
       height TB_Container%,(height(0)-chg_ver%)+10
     case 1
       left TB_Container%,TB_IcoSize%+12
       width TB_Container%,(width(0)-chg_hor%)
       height TB_Container%,(height(0)-chg_ver%)
     case 2
       width TB_Container%,(width(0)-chg_hor%)
       height TB_Container%,(height(0)-chg_ver%)
     case 3
       width TB_Container%,(width(0)-chg_hor%)
       height TB_Container%,(height(0)-chg_ver%)
   end_select
End_sub
' ------------------------------------------------------------------------------
Toolbar_actions:
  TB_Button%=val(text$(TB_Edit%))
  if TB_Button%<0
    Message_Error()
  else
    select TB_Button%
       case 1 : F_NewFiche()
       case 2 : Remove_Fiche()
       case 3 : Connection()
       case 12
          timer_on MDC_timer%
          timer_interval MDC_timer%,500
          on_timer MDC_timer%,fin
    end_select
  end_if
return
' ------------------------------------------------------------------------------
Sub Remove_Fiche()
   dim_local L$
   if Select_list%<>0
      item_delete O_List%,Select_list%
      item_delete O_DList%,Select_List%
      file_save O_DList%,MDC_DB$
      Init_Liste()
   else
      Message "Sélectionnez un nom..."
   end_if
End_sub
' ------------------------------------------------------------------------------
Sub Connection()
  dim_local hnd%,s$,T$,cpt%
  res% = dll_call1("GetKeyboardState",20)
  if res%>0 then res% = dll_call5("SendSingleKey",handle(0),20,0,0,0)
  hide 0
  Execute "http://www.mydrive.ch"
  pause 1000

  while left$(t$,7)<>"MyDrive"
     T$ = string$(255," ")
     hnd% = dll_call1("GetActiveWindowTitle",adr(T$))
     if T$<>string$(255," ")
        if left$(T$,7)="MyDrive"
           exit_while
        end_if
     end_if
  end_while

  s$ = Login$
  hnd% = dll_call0("GetActiveControl")
  res% = dll_call2("SendStringAsText",hnd%,adr(s$))
  s$ = chr$(9)
  res% = dll_call2("SendStringAsText",hnd%,adr(s$))
  pause 1000
  s$ = pw$
  res% = dll_call2("SendStringAsText",hnd%,adr(s$))
  pause 1000
  s$ = chr$(13)
  res% = dll_call2("SendStringAsText",hnd%,adr(s$))
  pause 1000
  show 0
End_sub
' ------------------------------------------------------------------------------
Clic:
   clic%=number_click
   if clic%=NF_Button% :Save_Compte():end_if
   if clic%=O_List% :Select_Liste():end_if
return
' ------------------------------------------------------------------------------
Sub Select_Liste()
   dim_local sep%,L$
   Nom$="":Login$="":pw$=""
   if item_index(O_List%)>0
      Select_List%=item_index(O_List%)
      L$=item_read$(O_DList%,Select_List%)
      sep%=instr(L$,"|")
      Nom$ = left$(L$,sep%-1)
      L$=right$(L$,len(L$)-sep%)
      sep%=instr(L$,"|")
      Login$= left$(L$,sep%-1)
      pw$=right$(L$,len(L$)-sep%)
   end_if
End_sub
' ------------------------------------------------------------------------------
Sub Save_Compte()
    dim_local L$
    if text$(NF_edit1%)="":message "Champ 'Pseudo' vide"+chr$(13)+"Enregistrement impossible...":end_sub:end_if
    if text$(NF_edit2%)="":message "Champ 'Login' vide"+chr$(13)+"Enregistrement impossible...":end_sub:end_if
    if text$(NF_edit3%)="":message "Champ 'Password' vide"+chr$(13)+"Enregistrement impossible...":end_sub:end_if
    Verif_liste()
    if NF_verif%=1
       if message_warning_yes_no("Une fiche :"+text$(NF_edit1%)+" existe déjà !"+chr$(13)+"Voulez créer la fiche ?...")<>1
          Text NF_edit1%,""
          Text NF_edit2%,""
          Text NF_edit3%,""
          Hide MDC_NewFiche%
          end_sub
       end_if
    end_if
    L$=text$(NF_edit1%)+"|"+Text$(NF_edit2%)+"|"+Text$(NF_edit3%)
    item_add O_DList%,L$
    file_save O_DList%,MDC_DB$
    Init_Liste()
    Text NF_edit1%,""
    Text NF_edit2%,""
    Text NF_edit3%,""
    Hide MDC_NewFiche%
End_sub
' ------------------------------------------------------------------------------
Sub Verif_liste()
    dim_local T$,x%
    NF_verif%=0
    if count(O_List%)>0
       for x%=1 to count(O_List%)
           T$=item_read$(O_List%,x%)
           if T$=Text$(NF_edit1%)
              NF_verif%=1
              exit_for
           end_if
       next x%
    end_if
End_sub
' ------------------------------------------------------------------------------
Sub Message_Error()
   if TB_Button%=-1 then Adapter_Container()
   if TB_Button%=-2 then message "Error 2"
   if TB_Button%=-3 then message "Error 3"
   if TB_Button%=-4 then message "Error 4"
End_sub
' ------------------------------------------------------------------------------
Sub F_NewFiche()
   dim_local hnd%
   if MDC_NewFiche%>0
      show MDC_NewFiche%
   else
      obj%=obj%+1 : MDC_NewFiche%=obj%
      O_Form(obj%,0,1,0,0,205,350,"Créer un compte")
      font_name obj%,"arial" : font_size obj%,8
      obj%=obj%+1
      O_Alpha(obj%,MDC_NewFiche%,1,10,10,0,0,"Pseudo")
      obj%=obj%+1 :NF_edit1%=obj%
      O_Edit(obj%,MDC_NewFiche%,1,25,10,0,200)
      obj%=obj%+1
      O_Alpha(obj%,MDC_NewFiche%,1,50,10,0,0,"Login")
      obj%=obj%+1 :NF_edit2%=obj%
      O_Edit(obj%,MDC_NewFiche%,1,65,10,0,300)
      obj%=obj%+1
      O_Alpha(obj%,MDC_NewFiche%,1,90,10,0,0,"Password")
      obj%=obj%+1 :NF_edit3%=obj%
      O_Edit(obj%,MDC_NewFiche%,1,105,10,0,200)
      obj%=obj%+1 :NF_Button%=obj%
      O_Button(obj%,MDC_NewFiche%,1,135,width(MDC_NewFiche%)-100,0,0,"Enregistrer",1)
   end_if
   hnd%=handle(MDC_NewFiche%)
   res% = DLL_call2("WindowTopMost",hnd%,1)
End_sub
' ------------------------------------------------------------------------------
Sub O_Form(No%,P%,V%,T%,L%,H%,W%,C$)
   if No%> 0 then FORM No%
   if P% > 0 then Parent No%,P%
   If V% = 0 Then hide No%
   If H% > 0 Then Height No%,H%
   If W% > 0 Then Width No%,W%
   If T% > 0 : Top No%,T% : Else : Top No%,(Screen_y-H%)/2 : End_If
   If L% > 0 : Left No%,L%: Else : Left No%,(Screen_x-W%)/2: End_If
   if C$<>"" then Caption No%,C$
End_Sub
' ------------------------------------------------------------------------------
Sub O_Alpha(No%,P%,V%,T%,L%,H%,W%,C$)
   ALPHA No%
   if P% > 0 then Parent No%,P%
   If V% = 0 Then hide No%
   If H% > 0 Then Height No%,H%
   If W% > 0 Then Width No%,W%
   If T% > 0 Then Top No%,T%
   If L% > 0 Then Left No%,L%
   if C$<>"" then Caption No%,C$
End_Sub
' ------------------------------------------------------------------------------
Sub O_Edit(No%,P%,V%,T%,L%,H%,W%)
   EDIT No%
   if P% > 0 then Parent No%,P%
   If V% = 0 Then hide No%
   If H% > 0 Then Height No%,H%
   If W% > 0 Then Width No%,W%
   If T% > 0 Then Top No%,T%
   If L% > 0 Then Left No%,L%
End_Sub
' ------------------------------------------------------------------------------
Sub O_List(No%,P%,V%,T%,L%,H%,W%,F$)
   LIST No%
   if P% > 0 then Parent No%,P%
   If V% = 0 Then hide No%
   If H% > 0 Then Height No%,H%
   If W% > 0 Then Width No%,W%
   If T% > 0 Then Top No%,T%
   If L% > 0 Then Left No%,L%
   if F$<>""
   if file_exists F$ then file_load No%,F$
   end_if
End_Sub
' ------------------------------------------------------------------------------
Sub O_Timer(No%,OO%,Inter%)
   TIMER No%
   if OO%=1 then timer_on No%
   if OO%=0 then timer_off No%
   if inter%>0 then timer_interval No%,inter%
End_Sub
' ------------------------------------------------------------------------------
Sub O_Dlist(No%,F$)
   DLIST No%
   if F$<>"" then file_load No%,F$
End_Sub
' ------------------------------------------------------------------------------
Sub O_Button(No%,P%,V%,T%,L%,H%,W%,C$,Cl%)
   BUTTON No%
   if P% > 0 then Parent No%,P%
   If V% = 0 Then hide No%
   If H% > 0 Then Height No%,H%
   If W% > 0 Then Width No%,W%
   If T% > 0 Then Top No%,T%
   If L% > 0 Then Left No%,L%
   if C$<>"" then Caption No%,C$
   if Cl%> 0 then on_click No%,Clic
   cursor_point No%
End_Sub
' ------------------------------------------------------------------------------
Fin:
   timer_off MDC_timer%
Quitter:
   res% = dll_call4("ModifyToolbar",8,0,0,0)
   res% = dll_call1("RemoveToolbar",1)
   terminate