Petit défi avec un objet memo.

Sujet: Petit défi avec un objet memo. Ven 18 Oct 2013 - 16:59

Bonjour à tous.

L'un d'entre vous pourrait-il me programmer un objet ressemblant à celui visible sur le site suivant:

http://www.traduction-rapide.net/

Je cite l'objet jaune, de dimensions variables, contenant un objet memo à l'intérieur.

Merci de votre aide.

Sujet: re Ven 18 Oct 2013 - 18:10

J' ai du mal à voir ce que tu veux exactement... scratch

cà ?

Sujet: Petit défi avec un objet memo. Ven 18 Oct 2013 - 21:33

Bonsoir.

Non, en fait, il s'agit de la zone jaune à droite où l'on saisit le texte à traduire.

Merci.

Sujet: Re: Petit défi avec un objet memo. Sam 19 Oct 2013 - 0:31

Où tu vois une zone jaune pour saisir le texte ? Moi, je vois ceci:
[img]

[/img]

Sujet: Re: Petit défi avec un objet memo. Sam 19 Oct 2013 - 1:30

Est-ce qu’on parle du même site ?
Moi, je vois ça :

Sujet: re Sam 19 Oct 2013 - 1:35

J' ai la même page que Klaus.
Pas poli ce site Mad

, il demande des sous....

Laughing

Sujet: Re: Petit défi avec un objet memo. Sam 19 Oct 2013 - 2:05

Bizarre ! La page que j’ai est autre !
A moi, ils ne m’ont pas demandé des flousses.
Ils ont peut-être deviné que je n’en ai pas !

Sujet: Re: Petit défi avec un objet memo. Sam 19 Oct 2013 - 2:07

Comme ceci, par exemple ?

Code:: ' couleur de fond de la form
dim fond_r% : fond_r% = 255
dim fond_g% : fond_g% = 255
dim fond_b% : fond_b% = 255

color 0,fond_r%, fond_g%, fond_b%

' dessiner la bulle
picture 1
top 1,100 : left 1,100 : width 1,300 : height 1,200
color 1,fond_r%, fond_g%, fond_b%
2d_target_is 1 : 2d_pen_width 2 : 2d_pen_color 195,195,196
2d_circle 20,10,10 : 2d_circle 290,10,10
2d_circle 290,180,10
2d_rectangle 20,0,290,190
2d_rectangle 10,10,300,180
2d_line 10,180,0,200
2d_line 20,190,0,200
2d_pen_color fond_r%, fond_g%, fond_b%
2d_line 11,10,298,10
2d_line 11,179,298,179
2d_line 20,2,20,10 : 2d_line 289,2,289,10
2d_line 20,180,20,188 : 2d_line 289,180,289,188
2d_pen_color 0,0,0
2d_pen_width 1
2d_flood 100,150,255,255,0

' placer le mémo
memo 2 : top 2,top(1)+10 : left 2,left(1)+20
height 2,height(1)-30 : width 2,400

' placer le bouton
button 3 : width 3,100 : caption 3,"Traduire"
top 3,top(2)+height(2) : left 3,left(2)+(width(2)-width(3))/2
height 3,20

Sujet: Re: Petit défi avec un objet memo. Sam 19 Oct 2013 - 2:23

Ça c’est du Klaus !
Bravo tu as relevé le défi !

Voici ma solution. Ce n’est pas identique à ce qui est demandé, mais ça pourrait plaire, qui sait ?

Code:: rem ============================================================================
dim pi,p,x,y,a,xc,yc,r1,r2
pi = acos(-1) : p = pi/180 :xc = 300 : yc = 220 : r1 = 250 : r2 = 200

picture 1 : width 1,590 : height 1,450 : 2d_target_is 1
2d_poly_from xc+r1,yc
for a = 0 to 2*pi step p
x = xc +r1*cos(a) : y = yc + r2 * sin(a) : 2d_poly_to x,y
next a
2d_flood xc+200,yc,255,255,0
2d_circle 100,100,20 : 2d_circle 500,100,20
2d_circle 100,340,20 : 2d_circle 500,340,20
2d_poly_from 88,325 : 2d_poly_to 20,370 : 2d_poly_to 105,357
2d_flood 80,350,255,0,0

memo 2 : top 2,120 : left 2,100 : width 2,400 : height 2,200 : bar_vertical 2
color 2,100,250,250 : item_add 2,"Entrez votre texte ici" : set_focus 2
button 3 : top 3 , 320 : left 3,260 : caption 3,"Traduire"
rem ============================================================================

Sujet: Re: Petit défi avec un objet memo. Sam 19 Oct 2013 - 9:48

Klaus, il y a une petite erreur ligne 30 si je ne m'abuse, tu devrais avoir:

Code:: height 2,height(1)-30 : width 2,width(1)-30

Sinon ça marche bien, il faudrait juste le transformer en objet paramétrable pour faciliter son utilisation (là, il faut tout modifier à la main quand on veut changer la largeur, la hauteur ou la position

La proposition de Papydall est manifestement moins jolie à mon gout mais très facilement parametrable

Sujet: Petit défi avec un objet memo. Sam 19 Oct 2013 - 10:34

Bonjour à tous.

Voici le code modifié, et de plus paramétrable.

Je vous remercie de votre aide.

Code:: ' couleur de fond de la form
dim fond_r% : fond_r% = 255
dim fond_g% : fond_g% = 255
dim fond_b% : fond_b% = 255

dim largeur%, hauteur%, x%, y%
largeur%=500
hauteur%=200
x%=100
y%=100

color 0,fond_r%, fond_g%, fond_b%

' dessiner la bulle
picture 1
top 1,y% : left 1,x% : width 1,largeur% : height 1,hauteur%
color 1,fond_r%, fond_g%, fond_b%
2d_target_is 1 : 2d_pen_width 2 : 2d_pen_color 195,195,196
2d_circle 20,10,10 : 2d_circle largeur%-10,10,10
2d_circle largeur%-10,hauteur%-20,10
2d_rectangle 20,0,largeur%-10,hauteur%-10
2d_rectangle 10,10,largeur%,hauteur%-20
2d_line 10,hauteur%-20,0,hauteur%
2d_line 20,hauteur%-10,0,hauteur%
2d_pen_color fond_r%, fond_g%, fond_b%
2d_line 11,10,largeur%-2,10
2d_line 11,hauteur%-21,largeur%-2,hauteur%-21
2d_line 20,2,20,10 : 2d_line largeur%-11,2,largeur%-11,10
2d_line 20,hauteur%-20,20,hauteur%-12 : 2d_line largeur%-11,hauteur%-20,largeur%-11,hauteur%-12
2d_pen_color 0,0,0
2d_pen_width 1
2d_flood 100,150,255,255,0

' placer le mémo
memo 2
top 2,top(1)+20
left 2,left(1)+30
height 2,height(1)-50
width 2,largeur%-50

' placer le bouton
' button 3 : width 3,100 : caption 3,"Traduire"
' top 3,top(2)+height(2) : left 3,left(2)+(width(2)-width(3))/2
' height 3,20

Sujet: Re: Petit défi avec un objet memo. Sam 19 Oct 2013 - 10:57

Voici une version paramétrable, sous forme de procédure. On peut aller plus loin en mettant les couleurs également dans des paramètres, mais cela rajouterait 9 paramètres supplémentaires !

Code:: ' couleur de fond de la form
dim fond_r% : fond_r% = 255
dim fond_g% : fond_g% = 255
dim fond_b% : fond_b% = 255

color 0,fond_r%, fond_g%, fond_b%

dessiner_objet(100,100,300,200,400)

end

' x%,y%: coin en haut à gauche de la zone de dessin
' w%,h%: dimensions de la zone de dessin
' wm%: largeur du mémo
sub dessiner_objet(x%,y%,w%,h%,wm%)
' dessiner la bulle
picture 1
top 1,y% : left 1,x% : width 1,w% : height 1,h%
color 1,fond_r%, fond_g%, fond_b%
2d_target_is 1 : 2d_pen_width 2 : 2d_pen_color 195,195,196
2d_circle 20,10,10 : 2d_circle w%-10,10,10
2d_circle w%-10,h%-20,10
2d_rectangle 20,0,w%-10,h%-10
2d_rectangle 10,10,w%,h%-20
2d_line 10,h%-20,0,h%
2d_line 20,h%-10,0,h%
2d_pen_color fond_r%, fond_g%, fond_b%
2d_line 11,10,w%-2,10
2d_line 11,h%-1,w%-2,h%-1
2d_line 20,2,20,10 : ' 2d_line 289,2,289,10
2d_line 10,h%-21,w%,h%-21
2d_line 20,h%-20,20,h%-12 : 2d_line w%-11,h%-20,w%-11,h%-12
2d_pen_color 0,0,0
2d_pen_width 1
2d_flood 100,150,255,255,0

' placer le mémo
memo 2 : top 2,top(1)+10 : left 2,left(1)+20
height 2,height(1)-30 : width 2,wm%

' placer le bouton
button 3 : width 3,100 : caption 3,"Traduire"
top 3,top(2)+height(2) : left 3,left(2)+(width(2)-width(3))/2
height 3,20
end_sub

Sujet: Re: Petit défi avec un objet memo. Sam 19 Oct 2013 - 11:40

Super Klaus, a mon avis, il faut rajouter dans la procédure en paramètre, le n° de l'objet de base (1 dans notre exemple) et préciser que la procédure créera les objets N°, N°+1 et N°+2, mais ça tout le monde peut le faire
Je pense qu'il faut aussi rajouter le numéro de l'objet père qui reçoit les objets N°,N°+1 et N°+2

Après pour les couleurs, je suis d'accord, ce sont des paramètres optionnels et si on commence à les ajouter, ça peut commencer à devenir complexe (couleur de fond, couleur des bordures, couleur du texte ...) pas sûr que ce soit utile

Par contre le texte du bouton peut être un paramètre sympa à ajouter (par exemple pour dire "traduire" selon la langue de l'interface) et facile à mettre en oeuvre

Sujet: Re: Petit défi avec un objet memo. Sam 19 Oct 2013 - 11:45

Qu'à cela ne tienne, voici cette version améliorée:

Code:: ' couleur de fond de la form
dim fond_r% : fond_r% = 255
dim fond_g% : fond_g% = 255
dim fond_b% : fond_b% = 255

color 0,fond_r%, fond_g%, fond_b%

dessiner_objet(1,100,100,300,200,400,"Traduire")

end

' n%: numero de l'objet de base (n%, n%+1 et n%+2 utilisés)
' x%,y%: coin en haut à gauche de la zone de dessin
' w%,h%: dimensions de la zone de dessin
' wm%: largeur du mémo
' t$: texte (caption) du bouton
sub dessiner_objet(n%,x%,y%,w%,h%,wm%,t$)
  ' dessiner la bulle
  picture n%
   top n%,y% : left n%,x% : width n%,w% : height n%,h%
   color n%,fond_r%, fond_g%, fond_b%
  2d_target_is n% : 2d_pen_width 2 : 2d_pen_color 195,195,196
  2d_circle 20,10,10 : 2d_circle w%-10,10,10
  2d_circle w%-10,h%-20,10
  2d_rectangle 20,0,w%-10,h%-10
  2d_rectangle 10,10,w%,h%-20
  2d_line 10,h%-20,0,h%
  2d_line 20,h%-10,0,h%
  2d_pen_color fond_r%, fond_g%, fond_b%
  2d_line 11,10,w%-2,10
  2d_line 11,h%-1,w%-2,h%-1
  2d_line 20,2,20,10 : ' 2d_line 289,2,289,10
  2d_line 10,h%-21,w%,h%-21
  2d_line 20,h%-20,20,h%-12 : 2d_line w%-11,h%-20,w%-11,h%-12
  2d_pen_color 0,0,0
  2d_pen_width 1
  2d_flood 100,150,255,255,0

  ' placer le mémo
  memo n%+1 : top n%+1,top(1)+10 : left n%+1,left(1)+20
   height n%+1,height(1)-30 : width n%+1,wm%

  ' placer le bouton
  button n%+2 : width n%+2,100 : caption n%+2,t$
   top n%+2,top(n%+1)+height(n%+1) : left n%+2,left(n%+1)+(width(n%+1)-width(n%+2))/2
   height n%+2,20
end_sub

Panoramic, c'est génial !

Sujet: Re: Petit défi avec un objet memo. Sam 19 Oct 2013 - 11:50

Nickel là, je pense. Bien joué Klaus, un nouvel objet type dans la collection Wink

Sujet: re Sam 19 Oct 2013 - 12:44

Tout à fait Jicehel... Very Happy

...mais va falloir lui trouver un nom plus parlant.

Sujet: Re: Petit défi avec un objet memo. Sam 19 Oct 2013 - 12:49

Une Input_list ?

Sujet: Re: Petit défi avec un objet memo. Sam 19 Oct 2013 - 13:19

Juste pour élargir le sujet: cet "objet", ce n'est rien d'autre qu'un dessin 2d construit dans un picture, avec un mémo et un bouton placé dessus. On peut utiliser cette technique pour habiller n'importe quel objet, créer des encadrements, des effets d'ombre ou 3d... les possibilités sont infinies.

Sujet: Re: Petit défi avec un objet memo. Sam 19 Oct 2013 - 14:01

Absolument. La partie List est facilement remplaçable dans cette procédure.

Sujet: Re: Petit défi avec un objet memo. Sam 19 Oct 2013 - 14:05

Et, avec cette technique, on peut produire toutes sortes de motifs, dessins etc. Info-bulles (un peu comme ici), fonds en dégradé de couleurs, bordures produisant un effet 3d, et même des effets changeants en modifiant le contenu du picture à l'aide d'un timer.

Sujet: Re: Petit défi avec un objet memo. Sam 19 Oct 2013 - 14:14

Sympa ce memo,

Comme nom je verrais bien MEMO_BULLE

Bravo.

A+

Nombre de messages : 598 Date d'inscription : 06/01/2012

Vous êtes en forme, c'est un plaisir de vous suivre !
PS : je suis allé outre-Manche, leur site a un problème, il n'affiche pas les noms des auteurs des posts dans la liste des derniers sujets...

Sujet: Petit défi avec un objet memo. Dim 20 Oct 2013 - 10:14

Bonjour à tous.

Pour Klaus.

Je souhaiterais une petite modification au programme, de façon à ce que les flèches de direction situées en bas à gauche, s'affichent en bas à droite et donc seraient dirigées vers le bas à droite.

Merci encore de votre aide.

Sujet: Re: Petit défi avec un objet memo. Dim 20 Oct 2013 - 10:46

J'ai ajouté un paramètre en seconde position: s%? Si s%=1, la flèche est vers la gauche. Si s%=2, la flèche est vers la droite:

Code:: ' couleur de fond de la form
dim fond_r% : fond_r% = 255
dim fond_g% : fond_g% = 255
dim fond_b% : fond_b% = 255

color 0,fond_r%, fond_g%, fond_b%

dessiner_objet(1,2,100,100,300,200,400,"Traduire")

end

' n%: numero de l'objet de base (n%, n%+1 et n%+2 utilisés)
' s%! sens de la flèche 1=en bas à gauche 2=en bas à droite
' x%,y%: coin en haut à gauche de la zone de dessin
' w%,h%: dimensions de la zone de dessin
' wm%: largeur du mémo
' t$: texte (caption) du bouton
sub dessiner_objet(n%,s%,x%,y%,w%,h%,wm%,t$)
' dessiner la bulle
picture n%
top n%,y% : left n%,x% : width n%,w%+10 : height n%,h%
color n%,fond_r%, fond_g%, fond_b%
2d_target_is n% : 2d_pen_width 2 : 2d_pen_color 195,195,196
2d_circle 20,10,10 : 2d_circle w%-10,10,10
if s%=1 then 2d_circle w%-10,h%-20,10
if s%=2 then 2d_circle 20,h%-20,10
2d_rectangle 20,0,w%-10,h%-10
2d_rectangle 10,10,w%,h%-20
if s%=1
2d_line 10,h%-20,0,h%
2d_line 20,h%-10,0,h%
end_if
if s%=2
2d_line w%,h%-20,w%+10,h%
2d_line w%-10,h%-10,w%+10,h%
end_if
2d_pen_color fond_r%, fond_g%, fond_b%
2d_line 11,10,w%-2,10
2d_line 11,h%-1,w%-2,h%-1
2d_line 20,2,20,10 : 2d_line w%-11,2,w%-11,10
2d_line 10,h%-21,w%-2,h%-21
2d_line 20,h%-20,20,h%-12 : 2d_line w%-11,h%-20,w%-11,h%-12
2d_pen_color 0,0,0
2d_pen_width 1
2d_flood 100,150,255,255,0

' placer le mémo
memo n%+1 : top n%+1,top(1)+10 : left n%+1,left(1)+20
height n%+1,height(1)-30 : width n%+1,wm%

' placer le bouton
button n%+2 : width n%+2,100 : caption n%+2,t$
top n%+2,top(n%+1)+height(n%+1) : left n%+2,left(n%+1)+(width(n%+1)-width(n%+2))/2
height n%+2,20
end_sub

Sujet: Re: Petit défi avec un objet memo. Dim 20 Oct 2013 - 11:05

Heu j'interviens un peu de manière parasite, mais bon, je me permets juste un petit commentaire désobligeant ... Pan, tu peux chercher un peu aussi quand ce n'est pas très difficile pour adapter le code à ton usage... Enfin moi je dis ça, je ne dis rien, mais bon, je le dis quand même, le but du forum est de trouver une solution à ses problème, pas de sous traité une partie plus ou moins intéressante de sa programmation. A partir du moment ou Klaus te donne la piste, la voie ou l'objet exploitable, si tu as besoin d'une petit modif dessus, son code n'est pas trop complexe à comprendre, tu peux le modifier un peu pour en changer un peu la forme ou la couleur sans qu'il intervienne.

Bon, en tout cas, l'objet est encore mieux maintenant puisqu'il a ce paramètre alors j’arrête de ronchonner ...

» Problème avec un objet MEMO.
» Problème avec l'objet Memo.
» Petit défi de programmation.
» Objet Memo.
» Défi avec panoramic.