DISTANCE ENTRE DEUX POINTS DANS L'ESPACE

rem **************************************************
rem ** **
rem ** DISTANCE ENTRE DEUX POINTS DANS L'ESPACE **
rem ** **
rem **************************************************
rem ********************************
rem ** Code par LLS **
rem ** **
rem ** Copyright juin 2009 **
rem ** Version 1.00 **
rem ********************************
rem déclaration d'étiquette
label calc,propos,quit,prequit,reinit
rem définition de variables
dim i%,j%,k,k%,l%,p(2,3),d,di(3),d1,d2,d2$,d3
rem fenêtre principale
left 0,400 : top 0,250 : width 0,466 : height 0,350
color 0,70,120,160 : display
border_hide 0
rem chargement des images de présentation
for i%=1 to 3
picture i%
j% = i%+3 : button j%
j% = i%+6 : alpha j%
j% = i%+9 : alpha j%
j% = i%+12 : edit j%
j% = i%+15 : edit j%
next i%
alpha 19 : caption 19,"DISTANCE ENTRE DEUX POINTS DANS L'ESPACE"
left 19,30 : top 19,30 : font_color 19,255,0,0
font_size 19,12 : font_name 19,"comic sans ms"
alpha 20 : caption 20,"Version 1.00"
left 20,360 : top 20,50 : font_color 20,0,255,150
font_size 20,10 : font_name 20,"arial"
alpha 21 : alpha 22
hide 21 : hide 22
left 1,0 : top 1,0 : width 1,450 : height 1,16
left 2,450 : top 2,0 : width 2,16 : height 2,16
left 3,20 : top 3,280
left 4,350 : top 4,250 : width 4,100 : height 4,25
left 5,350 : top 5,280 : width 5,100 : height 5,25
left 6,350 : top 6,310 : width 6,100 : height 6,25
for i%=1 to 3
k% = i%*90-60 : l% = k%+20 : j% = i%+6 : left j%,k% : top j%,90
j% = i%+12 : left j%,l% : top j%,85 : width j%,40 : height j%,25
j% = i%+9 : left j%,k% : top j%,130
j% = i%+15 : left j%,l% : top j%,125 : width j%,40 : height j%,25
next i%
caption 7,x1 : caption 8,y1 : caption 9,z1
caption 10,x2 : caption 11,y2 : caption 12,z2
file_load 1,"bandeau.bmp"
file_load 2,"croix.bmp"
file_load 3,"logo.bmp"
caption 4,Calculer : hint 4,"Permet de calculer la distance entre les deux points"
caption 5,"A propos" : hint 5,"A propos de DISTANCE"
caption 6,Quitter : hint 6,"Quitter l'application"
on_click 2,prequit
on_click 4,calc
on_click 5,propos
on_click 6,quit
for i%=1 to 3
j% = i%+12 : on_click j%,reinit
j% = i%+15 : on_click j%,reinit
next i%
end
rem *******************
rem * SOUS PROGRAMMES *
rem *******************
calc:
for i%=1 to 3
j% = i%+12 : if text$(j%) = "" then return
if numeric(text$(j%)) = 0 then return
j% = i%+15 : if text$(j%) = "" then return
if numeric(text$(j%)) = 0 then return
next i%
k = 0
for i%=1 to 3
j% = i%+12 : p(1,i%) = val (text$(j%))
j% = i%+15 : p(2,i%) = val (text$(j%))
di(i%) = p(2,i%)-p(1,i%)
di(i%) = power (di(i%),2)
k = k + di(i%)
next i%
d = sqr (k)
d1 = int(d) : d2 = frac(d) : d2$ = str$ (d2) : d3 = len (d2$)
if d3 > 5 then d2$ = left$ (d2$,5) : d2 = val (d2$)
d = d1 + d2
font_size 21,14 : font_size 22,16
font_name 21,"comic sans ms" : font_name 22,"arial"
caption 21,"La distance entre les 2 points : " : caption 22,d
left 21,60 : top 21,170 : left 22,100 : top 22,200
show 21 : show 22
return
propos:
message "Distance entre deux points dans l'espace - Version 1.00 - Copyright juin 2009"
return
reinit:
hide 21 : hide 22
return
prequit:
file_load 2,"croixdown.bmp"
wait 300
file_load 2,"croix.bmp"
wait 250
quit:
terminate