Est-ce 3d_chain ou 3d_collision qui pose problème?

' ******************************************************************************
' ***************************** COMMANDES CLAVIER ******************************
' ******************************************************************************
dim esc  :' * TOUCHE ESC ==> MET FIN AU PROGRAMME:................... CASE 27  *
dim tpu  :' * TOUCHE "page up" ==> DÉCOLLER (vision aérienne):....... CASE 33  *
dim tpd  :' * TOUCHE "page down" ==> REDESCENDRE (vision aérienne):.. CASE 34  *
dim tfg  :' * TOUCHE FLÈCHE GAUCHE ==> PIVOTER À GAUCHE personnage... CASE 37  *
dim tfh  :' * TOUCHE FLÈCHE HAUTE ==> AVANCER personnage............. CASE 38  *
dim tfd  :' * TOUCHE FLÈCHE DROITE ==> PIVOTER À DROITE personnage... CASE 39  *
dim tfb  :' * TOUCHE FLÈCHE BASSE ==> RECULER personnage............. CASE 40  *
dim tcb  :' * TOUCHE "B" ==> REGARDER VERS LE BAS:................... CASE 66  *
dim tch  :' * TOUCHE "H" ==> REGARDER VERS LE HAUT:.................. CASE 72  *
' ******************************************************************************
' ****************************** PAVÉ NUMÉRIQUE ********************************
' ******************************************************************************
dim pn1  :' * TOUCHE "1" ==> RECULER VERS LA GAUCHE:................. CASE 97  *
dim pn2  :' * TOUCHE "2" ==> RECULER:................................ CASE 98  *
dim pn3  :' * TOUCHE "3" ==> RECULER VERS LA DROITE:................. CASE 99  *
dim pn4  :' * TOUCHE "4" ==> DÉPLACEMENT LATÉRAL VERS LA GAUCHE:..... CASE 100 *
dim pn5  :' * TOUCHE "5" ==> RETOUR AU POINT D'ORIGINE:.............. CASE 101 *
dim pn6  :' * TOUCHE "6" ==> DÉPLACEMENT LATÉRAL VERS LA DROITE:..... CASE 102 *
dim pn7  :' * TOUCHE "7" ==> AVANCER VERS LA GAUCHE:................. CASE 103 *
dim pn8  :' * TOUCHE "8" ==> AVANCER:................................ CASE 104 *
dim pn9  :' * TOUCHE "9" ==> AVANCER VERS LA DROITE:................. CASE 105 *
dim pnp  :' * TOUCHE "+" ==> MONTER:................................. CASE 107 *
dim pnm  :' * TOUCHE "-" ==> DESCENDRE:.............................. CASE 109 *
' ******************************************************************************
dim rot,chy,phy,bh:rot=180:chy=1.7:phy=1.7
dim d,h,i,j,k,n,p,r,s,v,prot,nob
h=21:v=20:n=h*v-1:h=h+1:v=v+1:d=1
dim a(h+1,v+1),mur(h+1,v+1),c(4)

label r1,r2,r3,r4,r5,r6,r7,t1,t2,bouge
on_key_down 0,t1
on_key_up 0,t2
lab():scene()

timer 200:timer_interval 200,1:on_timer 200,bouge
end

bouge:
timer_off 200
deplace()
timer_on 200
return

sub deplace()
dim_local vrot,vd,vhy,i,mv,pv,x,z,a$,p$
vrot=1:vd=0.2:vhy=0.5:mv=6:pv=7
if esc=1 then fin()
if tpu=1
  if chy<300 then for i=chy to 200 step 05:cam_position o3d_x_position(mv),i,o3d_z_position(mv):display:next i:chy=300
end_if
if tpd=1
  if chy>phy then for i=200 to phy step -5:cam_position o3d_x_position(mv),i,o3d_z_position(mv):display:next i:chy=phy
end_if
if tfg=1 then prot=prot+vrot:3d_y_rotate 3,prot
if tfd=1 then prot=prot-vrot:3d_y_rotate 3,prot
if tfh=1 then 3d_move 3,vd
if tfb=1 then 3d_move 3,vd-(2*vd)
if tcb=1 then bh=bh+.2:if bh>11 then bh=11
if tch=1 then bh=bh-.2:if bh<-11 then bh=-11
if pn1=1 then 3d_move mv,vd-(2*vd):3d_x_position mv,o3d_x_position(mv)+(cos(rot*3.1415/180)*vd):3d_z_position mv,o3d_z_position(mv)-(sin(rot*3.1415/180)*vd)
if pn2=1 then 3d_move mv,vd-(2*vd)
if pn3=1 then 3d_move mv,vd-(2*vd):3d_x_position mv,o3d_x_position(mv)-(cos(rot*3.1415/180)*vd):3d_z_position mv,o3d_z_position(mv)+(sin(rot*3.1415/180)*vd)
if pn4=1 then 3d_x_position mv,o3d_x_position(mv)+(cos(rot*3.1415/180)*(vd*2)):3d_z_position mv,o3d_z_position(mv)-(sin(rot*3.1415/180)*(vd*2))
if pn5=1 then bh=0:rot=180:chy=1.7:phy=1.7:3d_position mv,0,chy,0:3d_y_rotate mv,rot:3d_move mv,-13
if pn6=1 then 3d_x_position mv,o3d_x_position(mv)-(cos(rot*3.1415/180)*(vd*2)):3d_z_position mv,o3d_z_position(mv)+(sin(rot*3.1415/180)*(vd*2))
if pn7=1 then 3d_move mv,vd:3d_x_position mv,o3d_x_position(mv)+(cos(rot*3.1415/180)*vd):3d_z_position mv,o3d_z_position(mv)-(sin(rot*3.1415/180)*vd)
if pn8=1 then 3d_move mv,vd
if pn9=1 then 3d_move mv,vd:3d_x_position mv,o3d_x_position(mv)-(cos(rot*3.1415/180)*vd):3d_z_position mv,o3d_z_position(mv)+(sin(rot*3.1415/180)*vd)
if pnp=1 then phy=phy+vhy:chy=chy+vhy
if pnm=1 then phy=phy-vhy:chy=chy-vhy

3d_position pv,o3d_x_position(mv),o3d_y_position(mv),o3d_z_position(mv):3d_rotate pv,o3d_x_rotate(mv),o3d_y_rotate(mv),o3d_z_rotate(mv):3d_move pv,1
cam_position o3d_x_position(mv),sin(bh/6.28)+chy,o3d_z_position(mv):point_position o3d_x_position(pv),phy,o3d_z_position(pv)

' ******************************************************************************
 if o3d_collision(p,3)=1
    caption 0,"Collision !!!"
 else
    caption 0,""
 end_if
' ******************************************************************************

' affichage des positions de x, y et z ainsi que de l'angle de rotation
x=o3d_x_position(mv):z=o3d_z_position(mv)
p$="X= "+str$(int(x*100)/100)+"  Y= "+str$(int(chy*100)/100)+"  Z= "+str$(int(z*100)/100):a$="Angle= "+str$(wrap_value(prot))+"°"
3d_position 4,o3d_x_position(pv),phy+0.3,o3d_z_position(pv):3d_text_change 4,p$
3d_position 5,o3d_x_position(pv),phy-0.7,o3d_z_position(pv):3d_text_change 5,a$
3d_rotate 4,o3d_x_rotate(mv),o3d_y_rotate(mv)+180,o3d_z_rotate(mv)
3d_rotate 5,o3d_x_rotate(mv),o3d_y_rotate(mv)+180,o3d_z_rotate(mv)
end_sub

' sub de création de la scene3d
sub scene()
full_space 0:scene3d 1:hide 1:full_space 1:light_position 0,1500,0

' création des objets de la scène en 3d
' le décor
3D_SKYBOX 1
' sol de notre scene
3D_PLANE 2:3d_u_tile 2,100:3d_v_tile 2,100:3d_rotate 2,90,0,0:3d_scale 2,100,100,1
' personnage jaune
3D_CONE 3,5,3:3d_color 3,250,200,0:3d_position 3,0,2,0:3d_y_rotate 3,180
' objets textes d'affichage des positions de x et de z ainsi que de l'angle de rotation
3d_text 4,"":3d_scale 4,.1,.1,.1:3d_text 5,"":3d_scale 5,.1,.1,.1

3d_cube 6,1:3d_y_rotate 6,rot:3d_move 6,-13:3d_hide 6
3d_mesh 7

creation()
' ******************************************************************************
' IL n'y a que ces 4 types d'instructions qui détectent une collision, tous les
' autres n'affichent rien dans le caption 0.
' ******************************************************************************
' 3d_collision_as_cube 3:3d_collision_as_cube p
' 3d_collision_as_cube 3:3d_collision_as_faces p
' 3d_collision_as_faces 3:3d_collision_as_cube p
3d_collision_as_faces 3:3d_collision_as_faces p
' ******************************************************************************
show 1
end_sub

sub creation()
' cube en dessous du sol donc invisible qui nous sert à chainer tous les murs
3d_box number_3d_objects+1,1,1,1
p=number_3d_objects
3d_y_position p,-5

for i=1 to h:a(i,1)=8:next i:for j=1 to v:a(1,j)=1:next j
for j=2 to v
  for i=2 to h
if (i=(int(h/2)+1) and j=2) then a(i,j)=a(i,j)-8
if (i=(int(h/2)+1) and j=v) then a(i,j)=a(i,j)-2

    select a(i,j)
      case 1:pan1()
      case 2:pan2()
      case 3
        if a(i-1,j)<4 or (a(i-1,j)>7 and a(i-1,j)<12) then pan1()
        pan2()
      case 4:pan4()
      case 5
        if a(i-1,j)<4 or (a(i-1,j)>7 and a(i-1,j)<12) then pan1()
        pan4()
      case 6:pan2():pan4()
      case 7
        if a(i-1,j)<4 or (a(i-1,j)>7 and a(i-1,j)<12) then pan1()
        pan2():pan4()
      case 8:pan8()
      case 9
        if a(i-1,j)<4 or a(i-1,j)>7 and a(i-1,j)<12 then pan1()
        if a(i,j-1)=1 or a(i,j-1)=4 or a(i,j-1)=5 or a(i,j-1)=8 or a(i,j-1)=9 or a(i,j-1)=12 or a(i,j-1)=13 then pan8()
      case 10
        pan2()
        if a(i,j-1)=1 or a(i,j-1)=4 or a(i,j-1)=5 or a(i,j-1)=8 or a(i,j-1)=9 or a(i,j-1)=12 or a(i,j-1)=13 then pan8()
      case 11
        if a(i-1,j)<4 or (a(i-1,j)>7 and a(i-1,j)<12) then pan1()
        pan2()
        if a(i,j-1)=1 or a(i,j-1)=4 or a(i,j-1)=5 or a(i,j-1)=8 or a(i,j-1)=9 or a(i,j-1)=12 or a(i,j-1)=13 then pan8()
      case 12
        pan4()
        if a(i,j-1)=1 or a(i,j-1)=4 or a(i,j-1)=5 or a(i,j-1)=8 or a(i,j-1)=9 or a(i,j-1)=12 or a(i,j-1)=13 then pan8()
      case 13
        if a(i-1,j)<4 or (a(i-1,j)>7 and a(i-1,j)<12) then pan1()
        pan4()
        if a(i,j-1)=1 or a(i,j-1)=4 or a(i,j-1)=5 or a(i,j-1)=8 or a(i,j-1)=9 or a(i,j-1)=12 or a(i,j-1)=13 then pan8()
      case 14
        pan2():pan4()
        if a(i,j-1)=1 or a(i,j-1)=4 or a(i,j-1)=5 or a(i,j-1)=8 or a(i,j-1)=9 or a(i,j-1)=12 or a(i,j-1)=13 then pan8()
    end_select
  next i
next j
end_sub
' CRÉATION DES MURS DU LABYRINTHE
sub pan1()
  3d_box number_3d_objects+1,20.9,20,2:3d_position number_3d_objects,(i*20)-250,10,(j*20)-440:3d_y_rotate number_3d_objects,90:3d_color number_3d_objects,0,0,100:3d_chain number_3d_objects,p
end_sub

sub pan2()
  3d_box number_3d_objects+1,20.9,20,2:3d_position number_3d_objects,(i*20)-240,10,(j*20)-430:3d_color number_3d_objects,100,0,0:3d_chain number_3d_objects,p
end_sub

sub pan4()
  3d_box number_3d_objects+1,20.9,20,2:3d_position number_3d_objects,(i*20)-230,10,(j*20)-440:3d_y_rotate number_3d_objects,90:3d_color number_3d_objects,0,0,100:3d_chain number_3d_objects,p
end_sub

sub pan8()
  3d_box number_3d_objects+1,20.9,20,2:3d_position number_3d_objects,(i*20)-240,10,(j*20)-450:3d_color number_3d_objects,100,0,0:3d_chain number_3d_objects,p
end_sub

' GÉNÉRATION DU LABYRINTHE
sub lab()
  for j=1 to v+1:a(1,j)=4:a(h+1,j)=1:next j
  for i=2 to h:a(i,v+1)=8:a(i,1)=2:for j=2 to v:a(i,j)=15:next j:next i
  r=int(h/2+1):s=int(v/2+1):a(r,s)=15
  for k=1 to n
  r1:
    i=0
    if a(r-1,s)=15 then i=i+1 :c(i)=1
    if a(r,s-1)=15 then i=i+1 :c(i)=2
    if a(r+1,s)=15 then i=i+1 :c(i)=3
    if a(r,s+1)=15 then i=i+1 :c(i)=4
    if i=0 then goto r2
    if i<>1 then i=int(rnd(i)+1)
        select c(i)
          case 1 :a(r,s)=a(r,s)-(int(a(r,s))-int(int(a(r,s))/2)*2):r=r-1:a(r,s)=a(r,s)-(int(a(r,s)/4)-int(int(a(r,s)/4)/2)*2)*4
          case 2 :a(r,s)=a(r,s)-(int(a(r,s)/8)-int(int(a(r,s)/8)/2)*2)*8:s=s-1:a(r,s)=a(r,s)-(int(a(r,s)/2)-int(int(a(r,s)/2)/2)*2)*2
          case 3 :a(r,s)=a(r,s)-(int(a(r,s)/4)-int(int(a(r,s)/4)/2)*2)*4:r=r+1:a(r,s)=a(r,s)-(int(a(r,s))-int(int(a(r,s))/2)*2)
          case 4 :a(r,s)=a(r,s)-(int(a(r,s)/2)-int(int(a(r,s)/2)/2)*2)*2:s=s+1:a(r,s)=a(r,s)-(int(a(r,s)/8)-int(int(a(r,s)/8)/2)*2)*8
        end_select
    goto r7
  r2:
    if d=-1 then goto r3
    if r<>h then goto r5
    if s<>v then goto r4
    r=2:s=2:goto r6
  r3:
    if r<>2 then goto r5
    if s<>v then goto r4
    r=h:s=2: goto r6
  r4:
    s=s+1:d=-1*d:goto r6
  r5:
    r=r+d
  r6:
    if a(r,s)=15 then goto r2
    goto r1
  r7:
    mur(r,s)=int(rnd(6)+1)
    if mur(r,s)=mur(r-1,s) or mur(r,s)=mur(r+1,s) or mur(r,s)=mur(r,s-1) or mur(r,s)=mur(r,s+1) then goto r7
  next k
end_sub

t1:
if key_down_code=27 then esc=1
if key_down_code=33 then tpu=1
if key_down_code=34 then tpd=1
if key_down_code=37 then tfg=1
if key_down_code=38 then tfh=1
if key_down_code=39 then tfd=1
if key_down_code=40 then tfb=1
if key_down_code=66 then tcb=1
if key_down_code=72 then tch=1
if key_down_code=97 then pn1=1
if key_down_code=98 then pn2=1
if key_down_code=99 then pn3=1
if key_down_code=100 then pn4=1
if key_down_code=101 then pn5=1
if key_down_code=102 then pn6=1
if key_down_code=103 then pn7=1
if key_down_code=104 then pn8=1
if key_down_code=105 then pn9=1
if key_down_code=107 then pnp=1
if key_down_code=109 then pnm=1
return
t2:
if key_down_code=27 then esc=0
if key_down_code=33 then tpu=0
if key_down_code=34 then tpd=0
if key_down_code=37 then tfg=0
if key_down_code=38 then tfh=0
if key_down_code=39 then tfd=0
if key_down_code=40 then tfb=0
if key_down_code=66 then tcb=0
if key_down_code=72 then tch=0
if key_down_code=97 then pn1=0
if key_down_code=98 then pn2=0
if key_down_code=99 then pn3=0
if key_down_code=100 then pn4=0
if key_down_code=101 then pn5=0
if key_down_code=102 then pn6=0
if key_down_code=103 then pn7=0
if key_down_code=104 then pn8=0
if key_down_code=105 then pn9=0
if key_down_code=107 then pnp=0
if key_down_code=109 then pnm=0
return

sub fin()
for i=number_3d_objects to p+1 step -1:3d_chain_break i,p:next i

terminate
end_sub

dim i,j,rot,vrot
label prog,fin
full_space 0:scene3d 1:full_space 1:color 1,240,240,240

3d_box 1,.75,.5,.5:3d_collision_as_faces 1

for i=2 to 500
  3d_box i,.75,.5,.5:3d_position i,250-i,0,-5:3d_color i,i/4,i/8,i/2
  3d_chain i,1
next i

message "on déplace l'objet 1 et tous les autres suivent!"
3d_position 1,-3,1,-5:pause 2000:3d_position 1,-3,0,-5
message "on cache"
3d_hide 1
message "coucou, nous revoilà!"
3d_show 1
message "une petite rotation!"
for i=0 to 360 step 10:3d_y_rotate 1,i:wait 50:next i
message "transparence!"
3d_transparent 1,128:pause 2000:3d_transparent 1,0

3d_box 501,.75,.5,.5:3d_collision_as_faces 501

timer 2 : timer_interval 2,1 : on_timer 2,prog
end
prog:
timer_off 2
if scancode=27 then goto fin
if scancode=37 then rot=rot+1:3d_y_rotate 501,rot
if scancode=38 then 3d_move 501,0.1
if scancode=39 then rot=rot-1:3d_y_rotate 501,rot
if scancode=40 then 3d_move 501,0.1-(2*0.1)
if o3d_collision(1,501)=1
  caption 0,"collision"
else
  caption 0,""
end_if
timer_on 2
return
fin:
3d_delete 501
for i=number_3d_objects to 2 step -1:3d_chain_break i,1:next i
terminate

3D_actor 1
3D_load_object 1,"tris.md2"
cam_z_position 30
light_z_position 30
3D_x_rotate 1,90
3d_load_texture 1,"alita2.jpg"
3d_animation_play 1,7

3D_actor 1
3D_load_object 1,"tris.md2"
cam_z_position 30
light_z_position 30
3D_x_rotate 1,90
3d_load_texture 1,"alita2.jpg"
3d_animation_loop 1,0

dim anim%

label change_animation

3D_actor 1
3D_load_object 1,"tris.md2"
cam_z_position 30
light_z_position 30
3D_x_rotate 1,90
3d_load_texture 1,"alita2.jpg"

3d_text 2,"Model with "+str$(o3d_animation_count(1))+" animations"
3d_scale 2,5,5,5

on_click 1,change_animation
anim%=0
3d_animation_loop 1,anim%

end

change_animation:
anim%=anim%+1
if anim%=11 then anim%=0
3d_text_change 2,"Playing animation #"+str$(anim%)
3d_animation_loop 1,anim%
return