ITEM_DELETE

Bonjour.

J'ai découvert un problème avec la commande ITEM_DELETE.

Si l'on souhaite effacer les éléments d'un memo en utilisant une boucle écrite comme suit:

Code:

res%=count(502)
if res%>0
  for kk%=1 to res%
        item_delete 502,kk%
  next kk%
end_if

Eh bien, seul le 1er élément est effacé !

J'ai donc essayé avec une boucle inversée, et dans ce cas, pas de problème.

Code:

res%=count(502)
if res%>0
  for kk%=res% to 1 step -1
        item_delete 502,kk%
  next kk%
end_if

Bonjour Pan59,
C'est normal que dans ton premier exemple tu ne supprime que le premier item, puisque ton count(502) n'est plus égal à res% dès la première suppression. Par contre, moi je ferai comme dans mon petit code exemple ci-après, où je donne plusieurs façons de faire:

Code:

dim i
memo 1
message "1ère méthode"
for i=1 to 5:item_add 1,"Ligne "+str$(i):next i
message "boucle while"
while count(1)>0
' item_delete 1,count(1)
item_delete 1,1
pause 250
end_while
message "2ème méthode"
for i=1 to 5:item_add 1,"Ligne "+str$(i):next i
message "boucle repeat"
repeat
' item_delete 1,1
item_delete 1,count(1)
pause 250
until count(1)=0
message "fin"
terminate

suivant ces 2 façons de faire tu peux choisir soit de supprimer à partir du premier item ou du dernier item
A+

Tout de même, je trouve que c’est bien bizarre !

Mais ça se comprend !

Code:

dim compt%, i%, n%
memo 10  : height 10,300  : n% = 21
Charger_memo(n%) : print_locate 200,10
 print "CHARGEMENT DU MEMO : MISSION ACCOMPLIE" : message "ok"
compt%=count(10)
Vider_memo1(n%) : print_locate 200,10
 print "SEULS LES ITEMS IMPAIRS SONT EFFACES ! BIZARRE NON?": message "ok"
Vider_memo2(n%) : print_locate 200,10
 print "TOUS LES ITEMS SON EFFACES : MISSION ACCOMPLIE HEIN ! " :  message "ok"
terminate
end

SUB charger_memo(n%)
    dim_local i%
    for i% = 1 to n% : item_add 10,"ligne"+str$(i%) : next i%
END_SUB

SUB Vider_memo1(n%)
    dim_local i%
    for i% = 1 to compt% : item_delete 10,i% : next i%
END_SUB

SUB Vider_memo2(n%)
    dim_local i%
    for i% = compt% to 1 step -1 : item_delete 10,i% : next i%
END_SUB

Supprimer les lignes d'un memo/list/dlist/combo dans une boucle sur l'indexe nécessite certaines précautions.

1. Il n'est pas indiqué q'utiliser count() comme limite de boucle, cat count() varie à chaque itération, et ce n'est pas bon pour une boucle FOR. Il convient dont de charger cette valeur dans une variable, puis d'utiliser cette variable comme limite de FOR.

2. La suppression d'une ligne dans un tel objet décale bien sûr les autres lignes, dont les indexes diminuent de 1. Donc, si je supprime la ligne 1, la ligne 2 devient la ligne actuelle numéro 1. Et si je supprime ensuite la ligne 2, l'actuelle ligne 1 (l'ancienne ligne 2) ne sera pas supprimée, mais l'ancienne ligne 3.

Donc, je conseille ceci:

1. pour effacer complètement un tel objet, solution préférée:

Code:

clear n

2. pour effacer complètement un tel objet dans une boucle:

Code:

limite% = count(n)
for i%=1 to limite%
  item_delete n,1  : <--- toujours supprimer la ligne 1 !
next i%

3. pour effacer une portion au milieu d'un tel objet:

Code:

debut% = 17
fin% = 23
for i%=debut% to fin%
  item_delete n,debut% : ' <--- toujours supprimer la première ligne !
next i%

Ainsi, il n'y a pas d'ambiguité sur l'adressage.

Une autre façon de procéder (en plus de CLEAR comme l’a dit Klaus) est de DELETEr purement et simplement le memo quitte à le récréer aussitôt si besoin est.

Code:

 ' m% est l’identificateur du MEMO
....
DELETE m% : ' Supprime le memo avec tous ses ITEMs
MEMO m% : '  Récrée le memo vide

Néanmoins la commande CLEAR m% remplace les 2 commandes DELETE m% : MEMO m%
On peut donc utiliser l’une ou l’autre des methodes :
Si on n’a plus besoin du memo il est plus simple de faire DELETE m% ;
Mais si on veut seulement supprimer les ITEMs et garder le MEMO vide on fait : CLEAR m%

Attention toutefois quand on utilise delete n sur un memo ou un list! Si vous utilisez la commande print pour le remplir, vous aurez droit à une erreur lorsque vous essayerez de le supprimer.

Code:

memo 1
print_target_is 1
print "BONJOUR"
print "Tout le monde!"
print "Vive PANORAMIC..."
message "suppression du memo"
' print_target_is 0
delete 1
memo 1
print_target_is 1
print "Hello Papydall"

Il faut ne pas oublier de réatribuer le print_target d'origine avant la suppression! print_target_is 0!
A+

Chaque jour on apprend un petit peu plus et on devient un petit peu moins ignorant !

VIVE PANORAMIC ! VIVE LE FORUM !