Jeu Code Barre

dim a, x, y, z, out$, al
dim g(50)
label 2bin, init, move, stp
on_error_goto stp

left 0,223
top 0,200
width 0,550
height 0,492
caption 0,"Bar Code Game (Programmed by Lodchjo)"
on_key_up 0, move

alpha 1
left 1,10
top 1,10
width 1,133
height 1,21
caption 1,"Entrez un code barre"

edit 2
left 2,150
top 2,10

button 3
left 3,280
top 3,10
width 3,167
caption 3,"START!"
on_click 3, 2bin
picture 4
left 4,100
top 4,127
width 4,268
height 4,185
2d_target_is 4
2d_pen_width 2
2d_RECTANGLE 1,1,267,185
button 5
left 5,100
top 5,130
width 5,29
height 5,29
caption 5,chr$(35)
hide 5
button 6
left 6,280
top 6,10
width 6,167
caption 6,"STOP"
on_click 6, stp
hide 6
message "C'est l'annéé 2100. A cause d'un erreur système, vous êtes enfermé chez vous dans le MatriX. Il y as une code quelque part, mais vous devez la trouver. Les codes sont écrits sous les codes barre de produits, livres, DVD, etc. Entrez ces codes pour voir si ça vous aide a sortir. Bougez dans le MatriX avec les flèches. Bonne chance!"
end

2bin:
caption 1,text$(2)
hide 2
hide 3
out$=""
a = val (right$("000000000000"+text$(2),13))+1
for x = 50 to 0 step -1
g(x)=0
if a >= power (2,x) then g(x)=1:a=a-power (2,x)
next x
for x = 50 to 0 step -1
out$=out$+str$(g(x))
next x
gosub init
return

init:
show 5
show 6
2d_pen_width 1
for x = 1 to 7
for y = 1 to 6
z = 30+(x-1)*7+y
if al=0 then picture z
top z, 100+y*30
left z, 100+x*30
width z,29
height z,29
color z,0,0,0
if g((x-1)*6+y-1)=0 then show z
if g((x-1)*6+y-1)=1 then hide z
next y
next x
al=1
wait 10
set_focus 0
return

move:
if key_up_code=37 and left(5)>=130 and color_pixel_blue(0,left(5)-15,top(5)+15)>0 then left 5, left(5)-30
if key_up_code=38 and top(5)>=132 and color_pixel_blue(0,left(5)+15,top(5)-15)>0 then top 5, top(5)-30
if key_up_code=39 and left(5)<=338 and color_pixel_blue(0,left(5)+45,top(5)+15)>0 then left 5, left(5)+30
if key_up_code=40 and top(5)<=255 and color_pixel_blue(0,left(5)+15,top(5)+45)>0 then top 5, top(5)+30
if left(5)>338 then message "Félicitations! Vous avez réussi!!":goto stp
return

stp:
hide 5
hide 6
show 2
show 3
left 5,100
top 5,130
return