Les cris des animaux

OK, si papydal ou toi n'avait pas sévi d'ici là, je regarderais (pas sûr que je trouve, mais en tout cas, je regarderais)

Salut ygeronimi

J’ai téléchargé le zip.
Au test :
main.bas ====> message d’erreur : ‘Impossible to load the file. Line 265’

Code:: file_load 114,Animal$(6)

Main_admin.bas ====> message d’erreur : ‘Impossible to load the file. Line 256’

Code:: file_load 223,text$(215)

A+

Je viens de regarder, à mon avis ça vient d'un problème dans l'utilisation de file_name$(902)
Il ne doit pas aimer que tu l'utilises 2 fois à mon avis, du coup il s'attend à 2 entrées.
Tu dois passer par une variable temporaire.
Je t'ai codé un exemple sur l'ajout d'animal
Ca donne ce code:

Code:: ' ------------------------------------------------------------------------------
dim x%, Menu%,Fich_Travail$,choix_dial1% ,choix_dial1$,Animal$,L%,L$,sep%,cell$(8)
dim Dossier$,Doss_Bdd$,Doss_Langue$,Doss_Img$,Doss_Son$
dim Fich_Ref$,file$,tmp$
' ------------------------------------------------------------------------------
label Adressage
label Menu,Creer_Base,Ajout_Animal,Modif_Animal,Creer_Langue,Ajout_Ligne,Modif_Ligne,Quitter
label Dial_box1,Enrgt_Animal,Selection_Ligne,Ecouter,Enrgt_Donnees,Init_Fich_Travail
label Fich_Ref,Enrgt_Langue,Charge_Fich,Selection_Item ,Ajouter,Modifier,Sauvegarde
' ******************************************************************************
height 0,400:width 0,650:top 0,(screen_y-400)/2:left 0,(screen_x-650)/2
caption 0,"Outils Administrateur":application_title "Outils Administrateur"

main_menu 1
sub_menu 2 :parent 2,1 :caption 2,"Fichier"
sub_menu 3 :parent 3,1 :caption 3,"Base"
sub_menu 4 :parent 4,1 :caption 4,"Langue"
sub_menu 5 :parent 5,2 :caption 5,"Quitter" :on_click 5,Menu
sub_menu 6 :parent 6,3 :caption 6,"Créer" :on_click 6,Menu
sub_menu 7 :parent 7,3 :caption 7,"Ajouter item" :on_click 7,Menu
sub_menu 8 :parent 8,3 :caption 8,"Modifier item" :on_click 8,Menu
sub_menu 9 :parent 9,4 :caption 9,"Créer" :on_click 9,Menu
sub_menu 10:parent 10,4:caption 10,"Ajouter item" :on_click 10,Menu
sub_menu 11:parent 11,4:caption 11,"Modifier item" :on_click 11,Menu
' ------------------------------------------------------------------------------
for x%=100 to 400 step 100
container x% :hide x%
top x%,10:left x%,5:height x%,325:width x%,625
font_name x%,"Times new roman":font_size x%,10
next x%
' ------------------------------------------------------------------------------
memo 101:parent 101,100:top 101,15:left 101,7:width 101,350:height 101,300
bar_both 101
alpha 102:parent 102,100:top 102,15:left 102,360:caption 102,"Animal :" :font_color 102,20,60,215
alpha 103:parent 103,100:top 103,15:left 103,490:caption 103,"Sexe :" :font_color 103,20,60,215
alpha 104:parent 104,100:top 104,60:left 104,360:caption 104,"Frère / Soeur" :font_color 104,20,60,215
alpha 105:parent 105,100:top 105,105:left 105,360:caption 105,"Père" :font_color 105,20,60,215
alpha 106:parent 106,100:top 106,105:left 106,490:caption 106,"Mère" :font_color 106,20,60,215
alpha 107:parent 107,100:top 107,150:left 107,360:caption 107,"Image - Photo \*.jpg":font_color 107,20,60,215
alpha 108:parent 108,100:top 108,195:left 108,360:caption 108,"Son \*.mp3" :font_color 108,20,60,215
alpha 109:parent 109,100:top 109,240:left 109,360:caption 109,"Nom du cri" :font_color 109,20,60,215
edit 110 :parent 110,100:top 110,30:left 110,360
combo 111 :parent 111,100:top 111,30:left 111,490:width 111,80
item_add 111,"Mâle"
item_add 111,"Femelle"
edit 112 :parent 112,100:top 112,75:left 112,360
edit 113 :parent 113,100:top 113,120:left 113,360
edit 114 :parent 114,100:top 114,120:left 114,490
edit 115 :parent 115,100:top 115,165:left 115,360:width 115,210
edit 116 :parent 116,100:top 116,210:left 116,360:width 116,210
edit 117 :parent 117,100:top 117,255:left 117,360
button 118:parent 118,100:top 118,165:left 118,580:width 118,22:height 118,22
caption 118,"1":font_name 118,"Wingdings":cursor_point 118:on_click 118,Dial_box1
button 119:parent 119,100:top 119,210:left 119,580:width 119,22:height 119,22
caption 119,"1":font_name 119,"Wingdings":cursor_point 119:on_click 119,Dial_box1
button 120:parent 120,100:top 120,295:left 120,545:caption 120,"Enregistrer"
cursor_point 120:on_click 120,Enrgt_Animal
' ------------------------------------------------------------------------------
list 221:parent 221,200:top 221,15:left 221,7:width 221,180:height 221,150
on_double_click 221,Selection_Ligne
alpha 222:parent 222,200:top 222,165:left 222,5:caption 222,"Double click sur une ligne"+chr$(13)+"pour sélectionner "
font_italic 222 :font_color 222,20,60,215
picture 223:parent 223,200:height 223,150:width 223,150:top 223,170:left 223,185
alpha 224:parent 224,200:top 224,300:left 224,33:caption 224,"Photo / Image actuel :" :font_color 224,20,60,215
font_italic 224
alpha 202:parent 202,200:top 202,15:left 202,360:caption 202,"Animal :" :font_color 202,20,60,215
alpha 203:parent 203,200:top 203,15:left 203,490:caption 203,"Sexe :" :font_color 203,20,60,215
alpha 204:parent 204,200:top 204,60:left 204,360:caption 204,"Frère / Soeur" :font_color 204,20,60,215
alpha 205:parent 205,200:top 205,105:left 205,360:caption 205,"Père" :font_color 205,20,60,215
alpha 206:parent 206,200:top 206,105:left 206,490:caption 206,"Mère" :font_color 206,20,60,215
alpha 207:parent 207,200:top 207,150:left 207,360:caption 207,"Image - Photo \*.bmp" :font_color 207,20,60,215
alpha 208:parent 208,200:top 208,195:left 208,360:caption 208,"Son \*.mp3" :font_color 208,20,60,215
alpha 209:parent 209,200:top 209,240:left 209,360:caption 209,"Nom du cri" :font_color 209,20,60,215
edit 210 :parent 210,200:top 210,30:left 210,360
combo 211 :parent 211,200:top 211,30:left 211,490:width 211,80
item_add 211,"Mâle"
item_add 211,"Femelle"
edit 212 :parent 212,200:top 212,75:left 212,360
edit 213 :parent 213,200:top 213,120:left 213,360
edit 214 :parent 214,200:top 214,120:left 214,490
edit 215 :parent 215,200:top 215,165:left 215,360:width 215,210
edit 216 :parent 216,200:top 216,210:left 216,360:width 216,210
edit 217 :parent 217,200:top 217,255:left 217,360
button 218:parent 218,200:top 218,165:left 218,573:width 218,22:height 218,22
caption 218,"1":font_name 218,"Wingdings":cursor_point 218:on_click 218,Dial_box1
button 219:parent 219,200:top 219,210:left 219,573:width 219,22:height 219,22
caption 219,"1":font_name 219,"Wingdings":cursor_point 219:on_click 219,Dial_box1
button 225:parent 225,200:top 225,210:left 225,599:width 225,22:height 225,22
caption 225,"X":font_name 225,"Webdings":cursor_point 225:on_click 225,Ecouter
hint 225,"Ecouter"
button 220:parent 220,200:top 220,295:left 220,545:caption 220,"Enregistrer"
cursor_point 220:on_click 220,Enrgt_Donnees
' ------------------------------------------------------------------------------
edit 303:parent 303,300:top 303,15:left 303,5
edit 304:parent 304,300:top 304,15:left 304,315
memo 301:parent 301,300:top 301,40:left 301,5 :width 301,300:height 301,200
memo 302:parent 302,300:top 302,40:left 302,315:width 302,300:height 302,200
alpha 305:parent 305,300:top 305,245:left 305,5:caption 305,"Fichier référence":font_italic 305
alpha 306:parent 306,300:top 306,245:left 306,315:caption 306,"Fichier en création":font_italic 306
button 307:parent 307,300:top 307,15:left 307,130:height 307,22:width 307,22
caption 307,"1":font_name 307,"Wingdings":cursor_point 307:hint 307,"Choisissez le fichier de référence"
button 308:parent 308,300:top 308,295:left 308,545
caption 308,"Enregistrer":cursor_point 308:hint 308,"Enregistrer le fichier en création"
on_click 307,Fich_Ref
on_click 308,Enrgt_Langue
' ------------------------------------------------------------------------------
alpha 401:parent 401,400:top 401,15:left 401,13:Caption 401,"Fichier :"
edit 402 :parent 402,400:top 402,35:left 402,13
list 403 :parent 403,400:top 403,60:left 403,13:width 403,400
alpha 406:parent 406,400:top 406,160:left 406,100:caption 406,"":font_italic 406:font_color 406,100,0,185
alpha 404:parent 404,400:top 404,180:left 404,13:caption 404,""
edit 405 :parent 405,400:top 405,200:left 405,13:width 405,400
edit 407 :hide 407:parent 407,400:top 407,200:left 407,13:width 407,50
button 408:parent 408,400:top 408,230:left 408,336:cursor_point 408
button 409:parent 409,400:top 409,295:left 409,545:caption 409,"Enregistrer"
cursor_point 409:on_click 409,Sauvegarde
' ------------------------------------------------------------------------------
dlist 900 :dlist 901:sound 905
' ------------------------------------------------------------------------------
gosub Adressage
end
' ******************************************************************************
Adressage:
Dossier$=dir_current$
Doss_Bdd$=Dossier$+"\Bdd"
Doss_Langue$=Dossier$+"\Langues"
Doss_Img$=Dossier$+"\Images"
Doss_Son$=Dossier$+"\Sons"
return
' ------------------------------------------------------------------------------
Menu:
For x%=5 to 11
if clicked(x%)=1 then Menu%=x%
Next x%
Select Menu%
Case 5
Gosub Quitter
Case 6
Gosub Creer_Base
Case 7
Gosub Ajout_Animal
Case 8
Gosub Modif_Animal
Case 9
Gosub Creer_Langue
Case 10
Gosub Ajout_Ligne
Case 11
Gosub Modif_Ligne
End_Select
return
' ------------------------------------------------------------------------------
Creer_Base:
hide 100:hide 200:hide 300:hide 400
if message_input("Nouvelle Base","Langue :","Langue")=1
Fich_Travail$=Doss_Bdd$+"\"+message_text$+"_Bdd.txt"
file_open_write 1000,Fich_Travail$
file_close 1000
if message_information_yes_no("Voulez vous ajouter des animaux"+chr$(13)+"maintenant ?")=1
clear 900
gosub Ajout_Animal
end_if
end_if
return
' ------------------------------------------------------------------------------
Init_Fich_Travail:
if Fich_Travail$=""
if object_exists(902)= 0 then open_dialog 902
dir_dialog 902,Doss_Bdd$
tmp$ = file_name$(902)
if tmp$ <>"" then Fich_Travail$=tmp$
end_if
if object_exists(902)=1 then delete 902
clear 900
if Fich_Travail$<>"" then file_load 900,Fich_Travail$
return
' ------------------------------------------------------------------------------
Ajout_Animal:
show 100:hide 200:hide 300:hide 400
gosub Init_Fich_Travail

if count(900)>0
for x%=1 to count(900)
item_add 101,item_read$(900,x%)
next x%
end_if
return
' ------------------------------------------------------------------------------
Dial_box1:
if clicked(118)=1
choix_dial1%=115
choix_dial1$=Doss_Img$
else
if clicked(119)=1
choix_dial1%=116
choix_dial1$=Doss_Son$
else
if clicked(218)=1
choix_dial1%=215
choix_dial1$=Doss_Img$
else
if clicked(219)=1
choix_dial1%=216
choix_dial1$=Doss_Son$
end_if
end_if
end_if
end_if
open_dialog 902
dir_dialog 902,choix_dial1$
if file_name$(902)<>"_" then text choix_dial1%,file_name$(902)
if choix_dial1%=215 and text$(215)<>"" then file_load 223,text$(215)
delete 902
return
' ------------------------------------------------------------------------------
Enrgt_Animal:
Animal$=text$(110)+";"+str$(item_index(111))+";"+text$(112)+";"+text$(113)+";"+text$(114)+";"+text$(115)+";"+text$(116)+"|"+text$(117)
item_add 900,Animal$
item_add 101,Animal$
for x%=110 to 117 :text x%,"":next x%
if Fich_Travail$<>"" then file_save 900,Fich_Travail$
return
' ------------------------------------------------------------------------------
Modif_Animal:
show 200:hide 100:hide 300:hide 400
gosub Init_Fich_Travail
if Fich_Travail$<>"" then file_load 900,Fich_Travail$
if count(900)>0
for x%=1 to count(900)
sep%=instr(item_read$(900,x%),";")
item_add 221,str$(x%)+" / "+left$(item_read$(900,x%),sep%-1)
next x%
end_if
return
' ------------------------------------------------------------------------------
Selection_Ligne:
L%=item_index(221)
L$=item_read$(900,L%)
for x%=1 to 6
sep%=instr(L$,";")
cell$(x%)=left$(L$,sep%-1)
L$=right$(L$,len(L$)-sep%)
next x%
sep%=instr(L$,"|")
cell$(7)=left$(L$,sep%-1)
cell$(8)=right$(L$,Len(L$)-sep%)
for x%=1 to 8
if x%=2
if cell$(x%)=str$(1) then text 209+x%,"Mâle"
if cell$(x%)=str$(2) then text 209+x%,"Femelle"
else
text 209+x%,cell$(x%)
end_if
next x%
if text$(215)<>""
file_load 223,text$(215)
else
file_load 223,doss_img$+"\defaut.bmp"
end_if
return
' ------------------------------------------------------------------------------
Ecouter:
if text$(216)<>""
file_load 905,text$(216)
play 905
end_if
return
' ------------------------------------------------------------------------------
Enrgt_Donnees:
for x%=1 to 8
if x%=2
if item_index(209+x%)>0
cell$(x%)=str$(item_index(209+x%))
else
if text$(209+x%)="Mâle" then cell$(x%)="1"
if text$(209+x%)="Femelle" then cell$(x%)="2"
end_if
else
cell$(x%)=text$(209+x%)
end_if
next x%
L$=cell$(1)+";"+cell$(2)+";"+cell$(3)+";"+cell$(4)+";"+cell$(5)+";"+cell$(6)+";"+cell$(7)+"|"+cell$(8)
for x%=210 to 217 :text x%,"":next x%
file_load 223,doss_img$+"\defaut.bmp"
item_delete 900,L%
item_insert 900,L%,L$
file_save 900,Fich_Travail$
return
' ------------------------------------------------------------------------------
Creer_Langue:
hide 100:hide 200:hide 300:hide 400
if message_input("Nouvelle Langue","Langue :","Langue")=1
Fich_Travail$=Doss_Langue$+"\"+message_text$+".txt"
File$=message_text$+".txt"
file_open_write 1000,Fich_Travail$
file_close 1000
if message_information_yes_no("Voulez vous ajouter des animaux"+chr$(13)+"maintenant ?")=1
show 300:hide 100:hide 200:hide 400
text 304,file$
end_if
end_if
return
' ------------------------------------------------------------------------------
Fich_Ref:
if Fich_Ref$=""
open_dialog 906
dir_dialog 906,Doss_Langue$
if file_name$(906)<>"_" then Fich_ref$=file_name$(906)
text 303,file_extract_name$(file_name$(906))
file_load 301,Fich_Ref$
end_if
if object_exists(906)=1 then delete 906
return
' ------------------------------------------------------------------------------
Enrgt_Langue:
file_save 302,Fich_Travail$
Fich_Travail$=""
text 304,"":text 303,""
clear 301:clear 302
hide 300
return
' ------------------------------------------------------------------------------
Ajout_Ligne:
show 400:hide 100:hide 200:hide 300
hide 407
left 405,13:width 405,400
caption 404,"Ligne à ajouter :"
caption 408,"Ajouter"
on_click 408,Ajouter
hint 409,"Enregistrer les ajouts"
if Fich_Travail$=""
gosub Charge_Fich
else
if message_confirmation_yes_no("Voulez vous changer de fichier ?")=1 then gosub Charge_Fich
end_if
return
' ------------------------------------------------------------------------------
Modif_Ligne:
show 400:hide 100:hide 200:hide 300
caption 406,"(Double cliquez sur un item pour le selectionner )"
show 407
left 405,63:width 405,350
on_double_click 403,Selection_Item
caption 404,"Ligne Texte à Modifier :"
caption 408,"Modifier"
on_click 408,Modifier
hint 409,"Enregistrer les modifications"
if Fich_Travail$=""
gosub Charge_Fich
else
if message_confirmation_yes_no("Voulez vous changer de fichier ?")=1 then gosub Charge_Fich
end_if
return
' ------------------------------------------------------------------------------
Charge_Fich:
open_dialog 902
dir_dialog 902,Doss_Langue$
if file_name$(902)<>"_"
Fich_Travail$=file_name$(902)
text 402,file_extract_name$(file_name$(902))
end_if
clear 900
if Fich_Travail$<>"" then file_load 900,Fich_Travail$
if count(900)>0
for x%=1 to count(900)
item_add 403,str$(x%)+" / "+item_read$(900,x%)
next x%
end_if
if object_exists(902)=1 then delete 902
return
' ------------------------------------------------------------------------------
Selection_Item:
text 407,str$(item_index(403))
text 405,item_read$(900,item_index(403))
return
' ------------------------------------------------------------------------------
Ajouter:
item_add 900,text$(405)
item_add 403,text$(405)
text 405,""
return
' ------------------------------------------------------------------------------
Modifier:
item_delete 900,val(text$(407))
item_delete 403,val(text$(407))
item_insert 900,val(text$(407)),text$(405)
item_insert 403,val(text$(407)),text$(405)
text 405,"":text 407,""
return
' ------------------------------------------------------------------------------
Sauvegarde:
file_save 900,Fich_Travail$
Fich_Travail$=""
text 402,"":text 405,"":text 407,""
clear 403
hide 400
return
' ------------------------------------------------------------------------------
Quitter:
Terminate

@ Papydall ,

c' est du grand classique de panoramic...
ce sont des fichiers image
donc quand tu travailles sur un *.bas par l'éditeur
une fois que tu l'as chargé tu le ré enregistres dans son dossier pour que l'éditeur prennent en compte les chemins fixes
puis tu relances et là... miracle ! il retrouve les images... Laughing

c'est d'ailleurs un point que je compte améliorer...
actuellement les adresses des images sont stockées dans le fichier Bdd avec l'adresse complète
ce qui fait que si l'on change le dossier principale de place ( le bureau chez moi ) ben il retrouve plus les fichiers adressés de la sorte
donc il faudra à l'avenir que seul le nom du fichier soit dans le Bdd et l'adressage fait de façon portable comme pour les autres dossiers et fichiers.

Je ne sais pas si j'ai été très clair sur ce coup là ..... scratch

@ Jicehel ,

dès que j'arrête de me battre avec éAide Panoramic bis" j'essaye ta solution
cela me parait cohérent et logique mais à force de lancer et relancer
pour corriger des mini bugs et erreurs ben je n'y avait pas pensé.

D'où l'intérêt de ce forum et que nous soyons tous bêta testeur les uns pour les autres...
...même si le sujet n'est pas dans nos amours.

Merci pour vos remarques à tous les deux

@ygeronimi

Tu étais on ne peut plus clair !
J’ai pataugé un peu avant de voir clair : j’ai adapté les adresses à ma configuration et ….ça …. MARCHE !

Maintenant mes suggestions et remarques :
*Dans ‘Choisissez une réponse’ le mot croule est mentionné 2 fois de suite.

Jicehel a écrit:: En fait un animal peut faire plusieurs cris et quand on répond bèle par exemple pour la chèvre.
Il ne faudrait pas répondre faux, mais un truc du genre incomplet si la réponse donnée est inclue dans la bonne réponse puisque techniquement ce n'est pas faux ... enfin c'est mon avis...

*Je suis d’accord avec Jicehel sur ce point.

*Toutes les réponses (parmi lesquelles on doit choisir) sont listées les unes sous les autres. Donc pour un grand nombre d’animaux, cette liste va s’allonger démesurément et le choix de la bonne réponse devient un peu pénible d’autant plus que cette liste n’est pas triée dans l’ordre alphabétique ce qui ne facilite pas la tache.

Je suggère donc que (au lieu d’afficher tous les cris de tous les animaux) on affiche seulement 3 (dont une réponse et une seule est correcte). Le « joueur » doit choisir parmi les 3 réponses suggérées celle qu’il estime correcte.

Si l’animal en question a plus d’un cri, par exemple : brame, rait, râle, rée
Et si on répond brame, le programme affichera « bonne réponse, mais on dit aussi : rait, râle, rée »

En définitive tu restes le maitre à bord. king

Oui, un choix entre 3, 4 ou 5 réponses (ca peut être une option Wink

)

Dans mon très modeste programme (qui est à l’origine du programme d’ygeronimi qui a su en faire un bon logiciel éducatif), j’ai proposé 3 réponses dont une est juste. L’idée de Jicehel à porter ce nombre à 4 ou 5 peut–être intéressante dans la mesure où on minimise la part du hasard en choisissant une réponse parmi 5 plutôt que parmi 3 seulement.

bounce

Youpi ! les bêta testeurs se déchaînent !
( vous pouvez pas savoir comme çà me fait plaisir, mes progs de facture attirent moins et c'est un peu déprimant )

Je suis parti du prog de papydall ( signalé dans l' "A Propos..." ) et je voulais faire un albino

plus attractif visuellement parlant
mais là...je suis entrain d'accoucher d'un elephant

je vais voir comment réduire la liste
mais dans un post précédent, je proposais de scalper le nombre au cri courant
ex : le chat rep=miaule
le ronronnement est un cas particulier et pour avoir eu beaucoup de ces bébêtes, certains ne savent pas comment il faut faire Wink

il faut que je vois aussi la proposition de Jicehel pur mes boites de dialogue

Là je suis entrain d'ajouter un menu "Scores" pour les conserver et les visualiser , Qui sera champion Question

En fait ygeronimi, le top serait non pas de scalper ton dictionnaire mais de mettre le courant en premier. Les autres seraient considérés comme synonyme. Si l'utilisateur répond l'un d'eux, il a bon. S'il se trompe tu dit que l'animal fait le premier verbe et s'il y a des synonymes, tu ajoutes "On peut aussi dire qu'il ... autres verbes"

là tout de suite j'ai un Pb de boucle

je doit tirer au "hasard" 4 reponses dans un paquet et qu'elles soient differentes

et j'avoue que je bug Laughing

en plus je ne me sers que très peu des "while...repeat...until..end_while" et compagnie
si quelqu'un peut me montrer la lumière Idea

....je suis dans le noir complet... scratch

Après pour arriver à ce que tu dis, il faut que je redécoupe ma chaine avec un nombre variable de variables geek

Il faut aussi dire qu'en limitant le nombre de réponses dans le choix, on diminue aussi le nombre d'erreurs possibles avec les réponses qui ressemble
à la bonne. ce serait un coup de pas de bol pour que deux réponses quasi similaires se retrouvent dans un tirage de 5 sur 150 voir plus

Oublies les synonymes puisque l'on clique. Tu as raisons, ce n'est pas utile.
Tu peux faire un tableau pour mettre les réponses par exemple (rep$(4))
Tu charges ton tableau en mettant la bonne réponses courante dans rep$(0)
Pour les 4 autres tu as plusieurs possibilités: soit tu faits un truc aléatoire et des tests
Soit tu te sert de ta liste et un simple test sur l'index.
Tu charges tes autres réponses en passant sur les réponses suivantes
Si tu atteints la fin de la liste, tu ajoutes les réponses du début de liste par exemple
tu créés un tableau: aff$(4)
tu te fait un tableau cases_libres(4) que tu rempli avec respectivement 0,1,2,3,4
tu faits une boucle avec un indice (i) de 0 à 4
tu faits un tirage alétoire d'un nombre entre 0 et i => place
tu mets rep$(i) dans aff$(place)
tu mets cases_libres(place)=cases_libres(i)
Et tu boucles sur le i suivant
Tu affiches ton tableau aff$ dans l'ordre par une boucle de 0 à 4

....il va vraiment falloir que quelqu'un me donne un cours sur while et repeat Laughing

j'y perds mon lapin ...heu...mon latin... Laughing

j'en suis à ma dixième boucle sans fin lol!

C'est pour ça que là, je te proposais une boucle for i = 0 to 4 ... next i
Ca, je suis sûr que tu maitrises Wink

oui , mais là çà suffit plus Laughing

Bon, quelques évolutions dans le "main" (jeu)

Nombre de propositions de réponse limité à 5 (spécial dédicace pour papydall et jicehel Laughing

)
La liste des réponses possibles est trié ( spécial jicehel Laughing

)
Les scores sont mémorisés et visibles avec la date par le menu "Scores" ( pour les accrocs de la perf )

dispo sur mon webdev :

http://www.mydrive.ch/

panoramicien@ygeronimi_panoramic
panoramic123

bnjour Ygeronimi,
j'ai vu que tu as des problèmes pour tirer des nombres au hasard sans tirer 2 fois le même numéro, c'est ce que j'ai compris. Voici un petit programme dont tu peux t'inspirer et qui ne tirera jamais 2 fois un même numéro. J'utilise une boucle repeat très bien pour ce genre de chose. A toi de voir maintenant si tu peux l'adapter à ton programme que je n'ai pas encore essayé.
A+

Code:: dim a(4),r,t
label tirage
for t=0 to 4:a(t)=0:next t
t=0
repeat
tirage:
r=int(rnd(100))+1
if r=a(0) or r=a(1) or r=a(2) or r=a(3) or r=a(4) then goto tirage
a(t)=r
t=t+1
until t>4
for t=0 to 4:print a(t):next t

@ bignono

Je t'invite à devenir Bêta testeur du jeu Laughing

plus on est de fou .....moins on mange de riz.... Laughing

je crois que j'ai pondu un truc qui y ressemble pour arriver à ma dernière version du jeu
mais je te remercie, je vais étudié çà de très près Shocked

je suis un programmeur décortiqueur de code , j'apprends comme çà... Neutral

c'est pas très orthodoxe mais c'est comme çà...faut que je visualise pour comprendre...
donc n'hésites pas si tu as des exemples de boucles avec "while...end_while" je suis preneur aussi... Laughing

tu peux charger le jeu sur mon webdav , il est en ligne
Embarassed

, je fais une mise à jours tout de suite.

@ Jicehel,

Je viens d'examiner et tester ton code pour la boite de dialogue.

cheers

c'est la solution... Laughing

Salut ygeronimi.

En plus de la boucle REPEAT … UNTIL proposée par Bignono,
Voici un autre exemple de boucle WHILE … END_WHILE qui permet de choisir aléatoirement 5 réponses toutes différentes parmi 150 possibles.

Code:: ' Choisir aléatoirement 5 réponses toutes différentes parmi 150 possibles
' En utilisant une boucle WHILE ... END_WHILE
'
' La boucle WHILE ... END_WHILE est une boucle à priori c.-à-d. qu'elle teste
' la condition de sortie AVANT d'effectuer les instructions entre WHILE et
' END_WHILE. Si la condition est 'VRAI', les instructions sont exécutées jusqu'à
' END_WHILE. Cette dernière instruction renvoie à la condition de sortie pour
' être testée une autre fois. Il est IMPERATIF qu'il existe, dans la boucle,
' une instruction qui MODIFIE la condition de sortie sous peine de provoquer
' une boucle infinie.

dim rep(5),r,t
label tirage

gosub tirage : end

tirage:

while (t < 6) and (r=rep(0) or r=rep(1) or r=rep(2) or r=rep(3) or r=rep(4))
r = int(rnd(150))+1
rep(t) = r
t = t+1
end_while
for t=1 to 5:print rep(t):next t
return

C’est à toi de l’adapter.

@ papydall

Merci pour ton exemple et tes explications
je vais m'entraîner à faire plein de petit while .... Laughing

@ tout les bêta testeurs du jeu

je viens de corriger les boites de dialogue
on ne clique plus qu'une fois.... Laughing

merci à Jicehel pour son astuce.

je dois remercier tout le monde vu que ce que j'ai appris je vous le dois à tous :

Klaus, Jjn4,JL35,Jpcr,Nardo,Jicehel,papydall, Jean claude,Jean Debord,JC,Topmozika,et j'en oublie certainement... Embarassed

bref c'est en ligne, et là , à moins que quelque chose me passe par la tête, je crois que c'est utilisable
que ce soit le jeu ou l'outils admin.

après chacun est libre de compléter les fichiers , faire des traductions....

çà devrait être rigolo en allemand ( ...n'est ce pas les germanophiles Wink

)

Bravo ygeronimi, tu as atteints ton but
Quête validée Wink

@ Jicehel

Reste plus qu'à savoir si le résultat convient à papydall... Question

@ygeronimi

Je n’ai pas encore testé. Mais je le ferais tout à l’heure .

Voici quelques eclaircissements sur les boucles.

Repeat ... Until ...
Cette boucle effectue les instructions placées entre deux bornes (repeat et until) et évalue à chaque répétition une condition de type booléenne avant de continuer la boucle pour décider l’arrêt ou la continuité de la répétition. Il y a donc au moins une fois exécution des instructions.
Il est nécessaire qu'au moins une variable intervenant lors de l'évaluation de fin de boucle soit sujette à modification à l'intérieur de la structure exécutive interne à la boucle.
Syntaxe :
Repeat
...
Commandes
...
Until condition

Code:: DIM i
Repeat
I = i + 1
Print " Boucle itérée " ; i ;" fois "
Until i > 20

Ce programme permet de répéter l'incrémentation de la variable i jusqu'à ce que i soit supérieure à 20.

WHILE … END_WHILE
Ce type de boucle, contrairement à la précédente, évalue une condition avant d'exécuter des instructions (et non pas l'inverse), c'est-à-dire qu'on peut ne pas entrer dans la structure de répétition si les conditions ne sont pas favorables. De plus, au moins une variable de l'expression d’évaluation doit être sujette à modification au sein de la structure de répétition pour qu'on puisse en sortir.

Syntaxe :
WHILE condition
...
Commandes
...
END_WHILE

Code:: Dim code$ , levraicode$, OK
Levraicode$ = "PANORAMIC"
WHILE OK = 0
code$ = message_input$("Entrer le code secret", "code" , "PANORAMIC")
If code$ = levraicode$ then OK = 1
END_WHILE
print " SORTIE DE LA BOUCLE"

**********************************************

!!!! LA FAMILLE M'APPELLE !!!!!

Je serais de retour dès que possible!

Je rentre en méditation sur ces lignes... study

Assures toi d'avoir la dernière version pour tester Laughing

Salut ygeronimi.

J’ai téléchargé la dernière version.
J’ai testé et voila mon diagnostic.
MAIN.BAS
1) Codification :
Dans le sous-programme INIT_LIST (lignes 113 à 120)

Code:: while a$<>"_"
if a$<>"_"
item_add 301,a$
else
exit_while
end_if
a$=file_find_next$
end_while

Je te rappelle que la boucle WHILE est une boucle ‘à priori’ c.-à-d. que la condition de sortie est testée avant l’entrée dans la boucle.
Si le programme arrive à la ligne 114 : if a$ <> "_" ce que cette condition est DEJA vérifiée donc cette ligne devient inutile et par conséquent la ligne 116 (else), la ligne 117 (exit_while) et la ligne 118 ( end_if) deviennent inutiles.

La boucle peut-être codée ainsi

Code:: While a$ <> "_"
Item_add 301,a$
A$ = file_find_next$
End_while

2) Exécution
Liste : choisissez une réponse : (enlever le s de réponse)
Parfois on a 2 et même 3 lignes identiques.
Revoir donc le sous-programme correspondant.

3) Voici une copie d’écran concernant une erreur qui n’en est pas une !

Les cris des animaux - Page 5 1157937632

2 lignes identiques (dont la réponse est juste), en choisissant la 2eme le programme répond que c’est faux.

Je n’ai pas trop cherché à corriger cette erreur ( choix de 2 lignes ou plus ayant la même réponse).
Ça doit être dans le sous-programme verif_tirage ou verif_rep ou aux alentours.

4) j’ose te proposer un conseil ou simplement mon point de vue.
Tu es très « avare » dans les remarques !
Essaye à l’avenir de documenter davantage ton programme en mettant des lignes REM pour expliquer le déroulement du programme ( rôle de certaines variables, fonctions des s/p, explication de l’algorithme choisi pour telle ou telle action …)
Ceci peut aider ceux qui utiliseront ton programme ( puisque tu ne l’écris pas seulement pour toi).
Ça peut également être utile même pour toi ( le concepteur du programme) si , plus tard, tu éprouves le besoin de l’améliorer ou le modifier.

Je te propose seulement mon point de vue et tu n’es pas obligé de le suivre !

5) L’idée de départ était mon très modeste programme « les cris des animaux ».
Tu as fais un bon programme éducatif (certes perfectible), mais bon.
Plusieurs membres du forum ont échangé des conseils, des trucs, des astuces, souvent aussi de l’humour.
On est tous gagnants.
Je m’inspirerais de ta façon de programmer pour progresser.
!!! FELICITATIONS !!!

PS : le bouton 'écouter' ne provoque aucun son.

flower