Clone Début - Tableur

' ******************************************************************************
' *** Achtung die  "LoadProgram.dll" von Klaus wird benötigt
' *** Note the "LoadProgram.dll" Klaus is needed
' *** Notez le "LoadProgram.dll" Klaus est nécessaire
' ******************************************************************************
' *** Mit Hilfe von Entwicklung Clientarena von klaus
' ******************************************************************************
label labels
gosub labels
' ***
gosub constantes
gosub variables
gosub form0000              :' Grundform
gosub CLIENTFORM            :' Clientform variabel
gosub main
end
' ******************************************************************************
labels:
label form0000  :' Grundform
' *** VARIABLEN FÜR OBJEKTE anhängen und OBJEKTE abhängen LoadProgram.DLL ******
LABEL OBJEKT_AN              :' Objekt anhängen
DIM PARENTNUMMER1%
DIM PARENTNUMMER2%
DIM ancien%
' ******************************************************************************
label constantes
label variables
label CLIENTFORM
label main
label add_object
label scroll
Label scroll_horizontal
label add_client_area
label area1
return
' ******************************************************************************
constantes:
dim max_client_area%    : max_client_area% =    2
'
' dim max_height%          : max_height%      = (SCREEN_Y-190) * 7
'
dim max_height%          : max_height%      = 30000  :' PIXEL Clientarena
'
' dim max_width%            : max_width%      = SCREEN_X +20 :' muß immer > SCREEN_X
'
dim max_width%          : max_width%      = 2000    :' Pixel Clientarena
'
dim option_left_hide%    : option_left_hide% =    0
dim option_top_hide%    : option_left_hide% =    0
return
' ******************************************************************************
variables:
'
dim no%, n_client_area%, client_area%(max_client_area%)
dim no_name%, no_memo%
'
dim scroll_bar%(max_client_area%)
dim scroll_bar_horizontal%(max_client_area%)
dim scroll_pos%(max_client_area%)
dim scroll_pos_horizontal%(max_client_area%)
dim n_obj%(max_client_area%)
'
dim tab_obj%(200,max_client_area%)
dim SEITE%
dim i%
DIM j%
dim n%
dim x_client_area%
' *** Variabe for Grid *********************************************************
DIM Zeilennummer$
DIM Spaltennummer$
DIM Spalte%
DIM Zeile%
DIM TABTEXTE$(Zeile%,Spalte%)
' DIM TABWERTE%(Zeile%,Spalte%)
DIM a
DIM b
Return
' ********** Grundform *********************************************************
form0000:
TOP                    0000,0
LEFT                    0000,0
width                  0000,SCREEN_X
height                  0000,SCREEN_Y-44
caption                0000,"  Clone - Tableur  "
color                  0000,000,000,000        :' schwarz / black
PARENTNUMMER2% = HANDLE(0000)
'
' ********** Clientform variabel  **********************************************
' *** client area # 1 **********************************************************
CLIENTFORM:
COMMAND_TARGET_IS 0000
no% =          no% + 10
Form            no%
hide            no%
gosub add_client_area
top            no%,2
left            no%,2
width          no%,SCREEN_X-12
height        no%,SCREEN_Y-177
FONT_NAME      no%,"Courier NEW"
FONT_SIZE      no%,06
COLOR          no%,229,229,229
PARENTNUMMER1% = HANDLE(no%)    :' Form 0001 auf Form 0000
PARENTNUMMER2% = HANDLE(0000)    :' Form 0000
GOSUB OBJEKT_AN
BORDER_HIDE  no%
'
' ******************************************************************************
' *** AB HIER PROGRAMM *********************************************************
' *** Programm - Teil beginn *** Tabelle erstellen *****************************
'
Zeilennummer$  = "0000"
Spaltennummer$ = "0000"
Spalte%        = 00020    :' grid_column_width
Zeile%        = 01562    :' grid_row
'
' ******************************************************************************
no% =      no% + 1
grid                  no%
parent    no%,client_area%(n_client_area%)
hide                  no%
top                  no%,001      :' Anzahl Pixel von oben
left                  no%,100      :' Anzahl der Pixel von links
width                no%,1026    :' Tabellen Breite
height                no%,max_height%-0300    :' GRID HEIGHT
' ***
FONT_NAME            no%,"Courier NEW"
FONT_SIZE            no%,10
' ***
grid_column          no%,Spalte%  :' Anzahl Spalten
grid_row              no%,Zeile%  :' Anzahl Zeilen
grid_column_width    no%,50      :' Breite Spalten
grid_row_height      no%,18      :' Höhe Spalten
grid_row_fixed        no%,1        :' Anzahl fixierter Zeilen
grid_column_fixed    no%,1        :' Anzahl fixierter Spalten
grid_fixed_color      no%,255,0,0  :' Farbe der fixierten Spalten/Zeilen
grid_one_column_width no%,2,50    :' Erste Spalte mit xx Pixel
grid_one_row_height  no%,2,20    :' Erste Zeile mit xx Pixel
' grid_column_sizing_on no%        :' Spalten sind mit der Maus verschiebbar
grid_column_sizing_off no%          :' Spalten sind mit der Maus nicht verschiebbar
' grid_row_sizing_on no%          :' Zeilen sind mit der Maus verschiebbar
grid_row_sizing_off no%            :' Zeilen sind mit der Maus nicht verschiebbar
'
' Beschriftung von Zeilen X und Spalten Y **************************************
' *** Beschriftung der 2. bis X. Zeile  ****************************************
'
show no%
For i% = 1 to Zeile%
Zeilennummer$ = "0000"
Zeilennummer$ = Zeilennummer$+STR$(i%)
Zeilennummer$ = Right$(Zeilennummer$,4)
Zeilennummer$ = " " + Zeilennummer$
grid_write no%,i%+1,1,Zeilennummer$      :' schreiben ab 2. Zeile, 1. Spalte
next i%
'
gosub add_object
'
' ******************************************************************************
' *** Tabellenüberschrift ******************************************************
no% =      no% + 1
grid                  no%
parent                no%,client_area%(n_client_area%)
top                  no%,000      :' Anzahl Pixel von oben
left                  no%,100      :' Anzahl der Pixel von links
width                no%,1026    :' Tabellen Breite
height                no%,23      :' GRID HEIGHT
' ***
FONT_NAME            no%,"Courier NEW"
FONT_SIZE            no%,10
' ***
grid_column          no%,20      :' Anzahl Spalten
grid_row              no%,01      :' Anzahl Zeilen
grid_column_width    no%,50      :' Breite Spalten
grid_row_height      no%,20      :' Höhe Spalten
' grid_column_fixed    no%,20        :' Anzahl fixierter Spalten
' grid_row_fixed        no%,1        :' Anzahl fixierter Zeilen
grid_fixed_color      no%,255,0,0  :' Farbe der fixierten Spalten/Zeilen
' grid_one_column_width no%,1,50    :' Erste Spalte mit xx Pixel
' grid_one_row_height  no%,1,20    :' Erste Zeile mit xx Pixel
' grid_column_sizing_on no%        :' Spalten sind mit der Maus verschiebbar
grid_column_sizing_off no%          :' Spalten sind mit der Maus nicht verschiebbar
' grid_row_sizing_on no%          :' Zeilen sind mit der Maus verschiebbar
grid_row_sizing_off no%            :' Zeilen sind mit der Maus nicht verschiebbar
'
' *** Beschriftung der 2. bis Y. Spalte ****************************************
'
 For i% = 1 to 20
 Spaltennummer$ = "0000"
 Spaltennummer$ = Spaltennummer$+STR$(i%)
 Spaltennummer$ = Right$(Spaltennummer$,4)
 Spaltennummer$ = " " + Spaltennummer$
 grid_write no%,1,i%+1,Spaltennummer$      :' schreiben ab 2. Spalte, 1. Zeile
 next i%
'
' ******************************************************************************
'
grid_write no%,1,1," TEST"                :' schreiben in Spalte 1, Zeile 1
' gosub add_object
'
' ******************************************************************************
' *** Bar rechts auf Variabler Clientarena # 1 *********************************
no% =      no% + 1
scroll_bar no%
scroll_bar%(n_client_area%) = no%
parent    no%,client_area%(n_client_area%)
vertical  no%
top        no%,0
left      no%,SCREEN_X-30
height    no%,SCREEN_Y-195
min        no%,0
max        no%, max_height% - height(client_area%(n_client_area%))-20
'
on_change no%,scroll
'
' *** Bar unten auf Variabler Clientarena # 1 **********************************
no% =      no% + 1
scroll_bar no%
scroll_bar_horizontal%(n_client_area%) = no%
parent    no%,client_area%(n_client_area%)
horizontal no%
top        no%,SCREEN_Y-194
left      no%,0
width      no%,SCREEN_X-29
min        no%,0
max        no%, max_width% - width(client_area%(n_client_area%))-20
'
on_change no%,scroll_horizontal
'
Return
' ******************************************************************************
' ******************************************************************************
add_object:
  n_obj%(n_client_area%) = n_obj%(n_client_area%) + 1

  tab_obj%(n_obj%(n_client_area%),n_client_area%) = no%

  return
' ******************************************************************************
add_client_area:
  n_client_area% = n_client_area% + 1
  client_area%(n_client_area%) = no%
  return
'
' ******************************************************************************
scroll:
  n% = number_change
  for i%=1 to n_client_area%
    if scroll_bar%(i%)=n%
      x_client_area% = i%
      exit_for
    end_if
  next i%
  n% = position(scroll_bar%(x_client_area%)) - scroll_pos%(x_client_area%)
  scroll_pos%(x_client_area%) = position(scroll_bar%(x_client_area%))
  if x_client_area%<>1
'    caption separator%(x_client_area%),"Client area "+str$(x_client_area%)+" Page "+str$(int(scroll_pos%(x_client_area%)/560)+1)
  end_if
  for i%=1 to n_obj%(x_client_area%)
    top tab_obj%(i%,x_client_area%),top(tab_obj%(i%,x_client_area%)) - n%
    if option_top_hide%=1
      if top(tab_obj%(i%,x_client_area%))<10
        hide tab_obj%(i%,x_client_area%)
      else
        show tab_obj%(i%,x_client_area%)
      end_if
    end_if
  next i%
  return
' ******************************************************************************
scroll_horizontal:
  n% = number_change
  for i%=1 to n_client_area%
    if scroll_bar_horizontal%(i%)=n%
      x_client_area% = i%
      exit_for
    end_if
  next i%
  n% = position(scroll_bar_horizontal%(x_client_area%)) - scroll_pos_horizontal%(x_client_area%)
  scroll_pos_horizontal%(x_client_area%) = position(scroll_bar_horizontal%(x_client_area%))
  for i%=1 to n_obj%(x_client_area%)
    left tab_obj%(i%,x_client_area%),left(tab_obj%(i%,x_client_area%)) - n%
'
    if option_left_hide%=1
      if left(tab_obj%(i%,x_client_area%))<10
        hide tab_obj%(i%,x_client_area%)
      else
        show tab_obj%(i%,x_client_area%)
      end_if
    end_if
  next i%
  return
' ******************************************************************************
area1:
  hide client_area%(x_client_area%)
  x_client_area% = 1
  show client_area%(x_client_area%)
'  caption separator%(x_client_area%),"Client area "+str$(x_client_area%)+" Page "+str$(int(scroll_pos%(x_client_area%)/560)+1)
  return
' ******************************************************************************
main:
  x_client_area% = 1
  gosub area1
  return
' ******************************************************************************
' *** Objekt anhängen *****DLL KLAUS *******************************************
OBJEKT_AN:
dll_on "LoadProgram.dll"
ancien% = dll_call3("SetFormParent",PARENTNUMMER1%,PARENTNUMMER2%,1)
dll_off
RETURN
' ******************************************************************************