MINI SYSTEME EXPERT (Intelligence Artificielle)

chemin$=DIR_CURRENT$+chr$(92)  

' #################################################################################################################
' #################################################################################################################
' ################                                                                                 ################
' ################       BASE DE CONNAISSANCES RELATIONNELLE INTERROGEABLE EN LANGAGE NATUREL      ################
' ################                                                                                 ################
' ################                              RELATIONS TRAITEES :                               ################
' ################                           HORIZONTALES ET VERTICALES                            ################
' ################               INDIRECTION / COMPOSITION DE FONCTIONS / SYLLOGISMES              ################
' ################                                                                                 ################
' ################                     AUTEUR : PHILIPPE LARVET (COPYRIGHT 1984)                   ################
' ################                                                                                 ################
' ################       Article paru dans le magazine MICRO-SYSTEMES de juillet-aout 1984         ################
' ################       http://patrice.dargenton.free.fr/ia/iavb/1984/ArticleIAVB1984.html        ################
' ################                                                                                 ################
' ################                 ADAPTATION POUR PANORAMIC : Minibug (2018-2023)                 ################
' ################                                                                                 ################
' #################################################################################################################
' #################################################################################################################

' ############################################## LISTE DES VARIABLES ##############################################  
DIM no% , form% , memo% , edit% , button% , dlist%
DIM chemin$

DIM JM , KM , NP , NM , NT , NE , NI , ND , JI , LB
DIM A , I , J , K , L , M , N , V , R , T , J1 , J2 , L1 , L2 , I2 , S1 , S2
DIM A$ , H$ , G$ , F$ , T$ , X$ , Z$
DIM B$(101,6) , C$(11) , E$(61) , W$(11) , D(3) , P(3) , E(11) , S(101,4)
  
' ########################################### LABELS ET SOUS-PROGRAMMES ###########################################  
LABEL erreur , decode , agrandissement , suivant                                
  
LABEL ligne2000 , ligne2100 , ligne2120                      
LABEL ligne2160 , ligne2170          
LABEL ligne3000                              
LABEL ligne5000 , ligne6000 , ligne6010 , ligne6170 , ligne6180
LABEL ligne7030 , ligne7050 , ligne7200 , ligne7300 , ligne7330 , ligne7400
LABEL ligne8100 , ligne8140 , ligne8310 , ligne8320
LABEL ligne9200 , ligne9270 , ligne9950
                                                                                            
' ############################################## MOTS NON SIGNIFIANTS #############################################
DATA "EST","LE","LA","DE","UN","UNE","L","DU","D","LES","DES","ET","QU","QUE","QUI"
DATA "SONT","IL","ELLE","A","T","ETE","EN","OU","COMMENT","AU","N","NE","S","SE"
DATA "ETAIT","QUOI","C","CE","QUEL","QUELLE","QUELS","QUELLES","PAR","LEQUEL","LAQUELLE","CA"
DATA "SIGNIFIE","TOUT","OR","TOUS","TOUTE","TOUTES","=","(",")","Y","FF"    

' #################################### EXEMPLE D ASSERTION EN MODE AUTOMATIQUE ####################################
DATA "TOUT STYLO EST BLEU"
DATA "FRANÇOIS POSSÈDE UN STYLO"
DATA "BLEU EST UNE COULEUR"
DATA "ROUGE EST UNE COULEUR"
DATA "TOUT STYLO EST EN PLASTIQUE"
DATA "LE PLASTIQUE EST UNE MATIÈRE"
DATA "FRANÇOIS POSSÈDE-T-IL UN STYLO ROUGE ?"
DATA "QUELLE EST LA COULEUR DU STYLO DE FRANÇOIS ?"
DATA "RAOUL A ACHETÉ UN STYLO ÉGALEMENT"
DATA "DE QUELLE COULEUR EST LE STYLO DE RAOUL ?"
DATA "TOUT STYLO EST EN QUELLE MATIÈRE ?"
DATA "EN QUELLE MATIÈRE EST TOUT STYLO ?"
DATA "FRANÇOIS POSSÈDE-T-IL UN STYLO BLEU ?"
DATA "FRANÇOIS POSSÈDE-T-IL UN STYLO ?"
DATA "COULEUR STYLO FRANÇOIS ?"
DATA "DE QUELLE COULEUR EST LE STYLO DE FRANÇOIS ?"
DATA "ANNIE EST UNE JOLIE FILLE"
DATA "ANNIE EST SAGE"
DATA "MINNA EST UNE FILLE ELLE AUSSI"
DATA "MINNA EST FOFOLLE"
DATA "QUELLE FILLE EST SAGE ?"
DATA "ET LAQUELLE EST FOFOLLE ?"
DATA "JOLIE EST LE CONTRAIRE DE LAIDE"
DATA "EST-CE QU'ANNIE EST LAIDE ?"
DATA "CA SIGNIFIE-T-IL QU'ANNIE EST UNE JOLIE FILLE ?"
DATA "JEAN REGARDE MARIE"
DATA "MARIE REGARDE HUGUES"
DATA "QUI MARIE REGARDE-T-ELLE ?"
DATA "MARIE REGARDE-T-ELLE JEAN ?"
DATA "HUGUES EST LE FRÈRE D'HENRI"
DATA "HENRI EST LE FILS D'OCTAVE"
DATA "OCTAVE EST L'ONCLE D'ANATOLE"
DATA "QUI EST LE FILS DE L'ONCLE D'ANATOLE ?"
DATA "ET QUI REGARDE LE FRÈRE DU FILS DE L'ONCLE D'ANATOLE ?"
DATA "L'ENTREPRISE A UN SIÈGE ET UNE ANNEXE"
DATA "M.BERTRAND EST RESPONSABLE DE L'ANNEXE"
DATA "L'ANNEXE A 15 SERVICES DIFFÉRENTS"
DATA "M.JACQUES EST RESPONSABLE DE LA SAISIE"
DATA "M.RENÉ EST LE CHEF DU SERVICE COMPTABILITÉ"
DATA "M.MARTIN EST UN AMI DE M.JACQUES"
DATA "M.DUBOIS EST CHEF DU SERVICE PHOTO"
DATA "LA SAISIE EST UN SERVICE DÉCENTRALISÉ"
DATA "RENAUD EST LE FILS DE M.BERTRAND"
DATA "DAMIEN EST LE FILS DE M.RENÉ"
DATA "CHEF DE SERVICE ?"
DATA "CHEF DE SERVICE PHOTO ?"
DATA "SERVICE PHOTO ?"
DATA "RESPONSABLE ?"
DATA "M.MARTIN EST L'AMI DE QUI ?"
DATA "QUI EST LE FILS DU RESPONSABLE DES 15 SERVICES ?"
DATA "QUI EST LE FILS D'UN CHEF DE SERVICE ?"
DATA "QUI EST L'AMI DU RESPONSABLE D'UN SERVICE DÉCENTRALISÉ ?"
DATA "TOUT HOMME EST MORTEL"
DATA "OR SOCRATE EST UN HOMME"
DATA "DONC ?"
DATA "TOUT HOMME EST BIPÈDE"
DATA "OR PAUL EST UN HOMME"
DATA "DONC ?"
DATA "DONC ?"
DATA "TOUT CE QUI EST RARE EST CHER"
DATA "UN CHEVAL BON.MARCHÉ EST RARE"
DATA "DONC ?"
DATA "PLATON EST GREC"
DATA "OR PLATON EST PHILOSOPHE"
DATA "DONC ?"
DATA "QUEL PHILOSOPHE EST GREC ?"
DATA "Y A-T-IL UN PHILOSOPHE GREC ?"
DATA "QUI EST GREC ET PHILOSOPHE ?"
DATA "PHILOSOPHE GREC ?"
DATA "PLATON EST-IL GREC ?"
DATA "LES SAVANTS SONT SOUVENT DISTRAITS"
DATA "OR TOUS LES SAVANTS SONT BAVARDS"
DATA "DONC ?"
DATA "TOUS LES HOMMES SONT DES MORTELS"
DATA "OR DES HOMMES SONT JUSTES"
DATA "DONC ?"
DATA "X1 = X2"
DATA "X2 = X3"
DATA "PAR QUOI X1 = X3 ?"
DATA "Y1 = F DE X"
DATA "F DE X ?"
DATA "X = G DE T1"
DATA "V = K DE W"
DATA "T1 = H DE V"
DATA "F DE G DE H DE K DE W ?"
DATA "A QUOI EST = F DE G DE H DE K DE W ?"
DATA "F G H K W ?"
DATA "CHAT = ANIMAL"
DATA "CHAT = MANGEUR(SOURIS)"
DATA "TIGRE = ANIMAL"
DATA "TIGRE = MANGEUR(HOMME)"
DATA "ANIMAL MANGEUR ?"
DATA "MANGEUR D'HOMME = ?"
DATA "DONC ?"
DATA "DONC ?"
DATA "Y A-T-IL UN MANGEUR DE SOURIS ET D'HOMME ?"
DATA "QUI EST MANGEUR D'HOMME ET DE SOURIS ?"
DATA "ARTABAN = CHEVAL DE HENRI.4"
DATA "BLANC = COULEUR D'ARTABAN"
DATA "HENRI.4 = ROI DE NAVARRE"
DATA "LOUIS.14 = ROI DE FRANCE"
DATA "COULEUR DU CHEVAL DU ROI DE NAVARRE ?"
DATA "QUELLE EST LA COULEUR DU CHEVAL DU ROI DE NAVARRE ?"
DATA "QUELLE EST LA COULEUR DU CHEVAL BLANC DU ROI DE NAVARRE ?"
DATA "QUELLE EST LA COULEUR DU CHEVAL DU ROI ?"
DATA "QUEL ROI A UN CHEVAL ?"
DATA "CHEVAL DU ROI ?"
DATA "CHEVAL DU ROI DE NAVARRE ?"
DATA "CHEVAL DU ROI DE FRANCE ?"
DATA "LE CANARI EST UN OISEAU JAUNE"
DATA "JAUNE EST UNE COULEUR"
DATA "QUEL OISEAU EST JAUNE ?"
DATA "QUEL EST L'OISEAU JAUNE ?"
DATA "DE QUELLE COULEUR EST LE CANARI ?"
DATA "QUELLE EST LA COULEUR DU CANARI ?"
DATA "COULEUR CANARI ?"
DATA "COULEUR ?"
DATA "MARSEILLE EST LA VILLE PHOCÉENNE"
DATA "DEFERRE EST LE MAIRE DE MARSEILLE"
DATA "PHOCÉENNE SIGNIFIE ORIGINAIRE DE PHOCÉE"
DATA "LA PHOCÉE EST UNE PROVINCE GRECQUE"
DATA "GASTON EST LE PRÉNOM DE DEFERRE"
DATA "QUEL EST LE PRÉNOM DU MAIRE DE MARSEILLE ?"
DATA "QUEL EST LE PRÉNOM DU MAIRE DE LA VILLE ORIGINAIRE D'UNE PROVINCE GRECQUE ?"
DATA "QUEL EST LE PRÉNOM DU MAIRE DE LA VILLE ORIGINAIRE D'UNE PROVINCE ?"
DATA "PAUL POSSÈDE UN PERROQUET BAVARD"
DATA "MULTICOLORE SIGNIFIE DE PLUSIEURS COULEURS"
DATA "UN PERROQUET EST UN ANIMAL MULTICOLORE"
DATA "QUI POSSÈDE UN ANIMAL DE PLUSIEURS COULEURS ?"
DATA "MARIE EST UNE JOLIE FILLE"
DATA "JOLIE EST LE CONTRAIRE DE LAIDE"
DATA "MARIE EST-ELLE LAIDE ?"
DATA "EST-CE QUE MARIE EST LAIDE ?"
DATA "SABINE AIME JACQUES"
DATA "QUI AIME JACQUES ?"
DATA "QUI AIME SABINE ?"
DATA "QUI JACQUES AIME-T-IL ?"
DATA "JACQUES AIME-T-IL SABINE ?"
DATA "SABINE AIME-T-ELLE JACQUES ?"
DATA "TOUT CHEVAL EST UN ÉQUIDÉ"
DATA "OR TOUT ÉQUIDÉ EST HERBIVORE"
DATA "DONC ?"
DATA "TOUT HOMME EST BIPÈDE"
DATA "OR PAUL EST BIPÈDE"
DATA "DONC ?"
DATA "DONC ?"
DATA "OR PAUL EST BIPÈDE :"
DATA "TOUT HOMME EST RATIONNEL"
DATA "OR ARISTOTE EST RATIONNEL"
DATA "DONC ?"
DATA "ARISTOTE ÉTAIT GREC"
DATA "ARISTOTE ÉTAIT PHILOSOPHE"
DATA "PHILOSOPHE GREC ?"
DATA "OR SOCRATE EST UN HOMME"
DATA "TOUT HOMME EST MORTEL"
DATA "DONC ?"
DATA "DONC ?"
DATA "TOUT HOMME EST MORTEL :"
DATA "TOUT HOMME EST MORTEL"
DATA "TOUT HOMME EST BIPÈDE"
DATA "OR SOCRATE EST UN HOMME"
DATA "DONC ?"
DATA "OR PAUL EST UN HOMME"
DATA "DONC ?"
DATA "DONC ?"
DATA "TOUT LOGICIEN EST INCOMPRIS"
DATA "OR TOUT HOMME SENSÉ EST LOGICIEN"
DATA "DONC ?"
DATA "LE LOUVRE EST BEAU"
DATA "OR J'AIME TOUT CE QUI EST BEAU"
DATA "DONC ?"
DATA "ZZ"  

ERROR_FRENCH : ON_ERROR_GOTO erreur

chemin$=DIR_CURRENT$+""

LEFT no%,(SCREEN_X-800)/2 : TOP no%,(SCREEN_Y-600)/2 : WIDTH no%,800 : HEIGHT no%,600 : COLOR no%,200,200,200
   CAPTION no%,"IA - 08.01.2023" : BORDER_SMALL no% : ON_RESIZE no%,agrandissement : form%=no% : no%=no%+1
   MEMO no% : PARENT no%,form% : LEFT no%,5 : TOP no%,5
      WIDTH no%,WIDTH(form%)-27 : HEIGHT no%,HEIGHT(form%)-80 : COLOR no%,240,240,240
      FONT_NAME no%,"@FangSong" : BAR_BOTH no% : memo%=no% : no%=no%+1
   EDIT no% : PARENT no%,form% : LEFT no%,5 : TOP no%,HEIGHT(form%)-70
      WIDTH no%,WIDTH(form%)-185 : HEIGHT no%,30 : COLOR no%,240,240,240
      FONT_NAME no%,"@FangSong" : FONT_BOLD no% : FONT_SIZE no%,10
      ON_KEY_DOWN no%,decode : edit%=no% : no%=no%+1
      
   BUTTON no%: PARENT no%,form% : LEFT no%,WIDTH(form%)-175 : TOP no%,HEIGHT(form%)-70
      WIDTH no%,155 : HEIGHT no%,27 : FONT_SIZE no%,10 : CAPTION no%,"Suivant"
      ON_CLICK no%,suivant : button%=no% : no%=no%+1
      
   DLIST no% : dlist%=no% : no%=no%+1
      IF FILE_EXISTS(chemin$+"mots.ini")=1 THEN FILE_LOAD dlist%,chemin$+"mots.ini"
      ITEM_ADD memo%,"I.A. > Je suis prêt ! "    
   SET_FOCUS edit%
      

REPEAT
   READ A$
   NE=NE+1 : E$(NE)=A$
UNTIL A$="FF"

' ################################################# INITIALISATION ################################################
NP=4 : NM=100

a$="Le programme comprends plus de 170 assertions pour exemples."+CHR$(13)
a$=a$+"Souhaitez vous les utiliser pour tester le programme ?"
IF MESSAGE_CONFIRMATION_YES_NO(a$)<>1
   HIDE button% : A$="ZZ" : WIDTH edit%,WIDTH(form%)-27
END_IF

END

' ############################################## PROCEDURE DECODAGE ###############################################
decode:    

   IF KEY_DOWN_CODE=13
  
      ' =============
      '    ENTREE  
      ' =============
      A$=UPPER$(TEXT$(edit%)) : L=LEN(A$) : NI=0
      ITEM_ADD memo%,"Vous > "+A$ : TEXT edit%,""

      ' --------------------
      '  EXAMEN DE L'ENTREE
      ' --------------------
      IF LEFT$(A$,1)="/" THEN GOTO ligne9950

      IF RIGHT$(A$,1)<>"?" THEN GOTO ligne2000
      
      A$=LEFT$(A$,L-1) : NI=1
      
      ' --------------------
      ' EXTRACTION DES MOTS
      ' --------------------
      ligne2000:
      
      FOR K=1 TO NP
         C$(K)="" : E(K)=0
      NEXT K
      
      L=LEN(A$) : H$=""
      N=1 : ND=0 : J=1

      ligne2100:
      I=J

      ligne2120:
      J=J+1
      G$=MID$(A$,J,1)
      IF G$<>" " AND G$<>"'" AND G$<>"-" AND G$<>"(" AND G$<>")" AND J<=L THEN GOTO ligne2120
        
      F$=MID$(A$,I,J-I)
    
      IF I=1 AND LEFT$(F$,2)="QU" THEN N=0 : GOTO ligne2160

      FOR K=1 TO NE
         IF E$(K)=F$ THEN EXIT_FOR
      NEXT K  
      IF K<=NE THEN GOTO ligne2160

      ND=ND+1
      IF NI=0 AND ND>NP THEN ITEM_ADD memo%,"IA > Votre phrase est trop longue !" : RETURN

      H$=H$+F$ : C$(ND)=F$            
      IF ND>2 THEN GOTO ligne2160
      D(ND)=J

      ligne2160:  
      IF J>L THEN GOTO ligne3000

      ligne2170:
      J=J+1
      IF MID$(A$,J,1)=" " AND J<=L THEN GOTO ligne2170    
      
      IF J<=L THEN GOTO ligne2100  

      ' --------------------
      '    FIN EXTRACTION
      ' --------------------
      ligne3000:  
      IF C$(1)="" THEN ITEM_ADD memo%,"IA > Votre question est incompléte !" : RETURN

      IF NI>0 AND C$(1)="DONC" THEN GOTO ligne9200
      IF NI>0 THEN GOTO ligne6000
      IF ND<=1 THEN ITEM_ADD memo%,"IA > Votre phrase est trop courte !" : RETURN

      '  ---------------------------------------------
      ' CONTROLE EXISTENCE DE L'ASSERTION DANS LA BASE
      ' ----------------------------------------------
      IF NT=0 THEN GOTO ligne5000
      FOR I=1 TO NT
         Z$=""
         FOR J=1 TO NP
            Z$=Z$+B$(I,J)
         NEXT J
         IF Z$=H$ THEN EXIT_FOR
      NEXT I  
      IF I>NT THEN GOTO ligne5000

      ' ---------------------
      ' ASSERTION DEJA CONNUE
      ' ---------------------
      ITEM_ADD memo%,"IA > Assertion déjà connue !" : RETURN

      ' -------------------
      ' ENRICHISSEMENT BASE
      ' -------------------
      ligne5000:  
      FOR I=1 TO NM
         IF B$(I,1)="" THEN EXIT_FOR    
      NEXT I
      IF I>NM THEN ITEM_ADD memo%,"IA > STOP ! La base est pleine !" : TERMINATE

      FOR J=1 TO NP
         B$(I,J)=C$(J)
      NEXT J
      B$(I,NP+1)=A$
      S(I,1)=ND : S(I,2)=D(1) : S(I,3)=D(2)
      ITEM_ADD memo%,"IA > J'ai Compris"
      IF I>NT THEN NT=I
      RETURN

      ' =================
      '   INTERROGATION
      ' =================
      ' CONTROLE EXISTENCE DE CHACUN DES MOTS
      '  ------------------------------------
      ligne6000:
      K=0 : M=NT

      ligne6010:
      T=0 : K=K+1
      
      FOR I = 1 TO NT
         FOR J = 1 TO S(I,1)                    
            IF B$(I,J)=C$(K) THEN EXIT_FOR
         NEXT J
        
         IF J>S(I,1) THEN GOTO ligne6180
        
         T=1
         IF E(K)=0 THEN E(K)=I
        
         IF ND>1 THEN GOTO ligne6170
        
         IF J=2 AND L>(LEN(C$(K))+1)
            ITEM_ADD memo%,"IA > "+LEFT$(B$(I,NP+1),S(I,2)) : GOTO ligne6180  
         END_IF
         ITEM_ADD memo%,"IA > "+B$(I,NP+1) : GOTO ligne6180

         ligne6170:
         A=I : I=NT

         ligne6180:
      NEXT I

      ' ---------------
      '   MOT INCONNU
      ' ---------------
      IF T=0 THEN ITEM_ADD memo%,"IA > Je ne connais pas "+"'"+C$(K)+"' !" : RETURN
      IF ND=1 THEN RETURN
      IF A<M THEN M=A
      IF K<ND THEN GOTO ligne6010
      IF ND>NP THEN GOTO ligne8100
      
      ' ---------------------
      ' RELATION HORIZONTALE
      ' ---------------------
      V = 0
      FOR I=M TO NT
         T=0 : K=0 : J=0
      
         ligne7030:
         K=K+1
         IF K>ND THEN GOTO ligne7300

         ligne7050:
         J=J+1
         IF J>S(I,1) THEN GOTO ligne7200
         IF B$(I,J)<>C$(K) THEN GOTO ligne7050
         T=T+1
        
         IF T>2 THEN GOTO ligne7030
         P(T)=J
         GOTO ligne7030

         ligne7200:
         IF T=0 THEN GOTO ligne7400

         ligne7300:
         IF (T<>ND) OR (T<>S(I,1)) THEN GOTO ligne7330
         ITEM_ADD memo%,"IA > oui" : V=1 : I=NT
         GOTO ligne7400

         ligne7330:
         IF T<>ND THEN GOTO ligne7400
         V=1  
        
         IF P(1)=1 AND P(2)=2 : LB=LEN(B$(I,NP+1))
            ITEM_ADD memo%,"IA > "+RIGHT$(B$(I,NP+1),LB-S(I,3))
            GOTO ligne7400
         END_IF
         IF P(1)=2 THEN ITEM_ADD memo%,"IA > "+LEFT$(B$(I,NP+1),S(I,2)) : GOTO ligne7400
         IF P(1)=3 THEN ITEM_ADD memo%,"IA > "+LEFT$(B$(I,NP+1),S(I,3)) : GOTO ligne7400  
         ITEM_ADD memo%,"IA > "+B$(I,NP+1)

         ligne7400:
      NEXT I
      IF V=1 THEN RETURN

      ' ------------------------
      '    RELATION VERTICALE
      ' ------------------------
      ' COMPOSITION DE FONCTIONS
      ' ------------------------
      ligne8100:
      FOR K=1 TO ND
         W$(K)=C$(K)
      NEXT K
      R=ND

      ligne8140:
      Z$=W$(R-1)+W$(R)
      FOR I=M TO NT
         IF B$(I,2)+B$(I,3)=Z$ THEN EXIT_FOR
      NEXT I
      IF I<=NT
         R=R-1 : W$(R)=B$(I,1)
         IF R>1 THEN GOTO ligne8140  
         ITEM_ADD memo%,"IA > "+W$(1) : RETURN
      END_IF
      
      ' -------------
      '  INDIRECTION
      ' -------------
      I2=E(2) : T=0

      ligne8310:
         E(2)=I2

      ligne8320:
      FOR J1=1 TO S(E(1),1)
         Z$=B$(E(1),J1)
         FOR J2 = 1 TO S(E(2),1)
            IF (E(1)<>E(2)) AND (Z$=B$(E(2),J2)) AND (Z$<>C$(1)) AND (Z$<>C$(2))
               T=1 : ITEM_ADD memo%,"IA > "+B$(E(1),J1) : J1=NP : J2=NP
            END_IF
         NEXT J2
      NEXT J1
      K=2 : recherche()
      IF V=1 THEN GOTO ligne8320
    
      K=1 : recherche()
      IF V=1 THEN GOTO ligne8310
      
      IF T=1 THEN RETURN

      ' -------------
      '  ECHEC FINAL
      ' -------------
      IF N=0 : ITEM_ADD memo%,"IA > Je l'ignore !" : ELSE : ITEM_ADD memo%,"IA > non" : END_IF
      RETURN

      ' =====================
      '  S Y L L O G I S M E
      ' =====================
      ' RECHERCHE MOYEN TERME
      ' ---------------------
      ligne9200:
      S2=NT : S1=NT-1 : T=0
      L1=LEN(B$(S1,NP+1))
      L2=LEN(B$(S2,NP+1))
      FOR K=1 TO 3
         FOR J =1 TO 3          
            IF B$(S1,J)="" THEN GOTO ligne9270
            IF B$(S2,K)<>B$(S1,J) THEN GOTO ligne9270
            T=1 : JM=J : KM=K
            J=NP : K=NP
          
         ligne9270:  
         NEXT J
      NEXT K  
      
      ' ---------------------
      ' ABSENCE DE CONCLUSION
      ' ---------------------
      IF T=0 THEN ITEM_ADD memo%,"IA > Je ne peux rien conclure !" : RETURN

      ' ------------
      '  RESOLUTION
      ' ------------
      SELECT KM
         CASE 1 : X$=RIGHT$(B$(S2,NP+1),L2-S(S2,2))
         CASE 2 : X$=LEFT$(B$(S2,NP+1),S(S2,2))    
         CASE 3 : X$=LEFT$(B$(52,NP+1),S(S2,3))    
      END_SELECT
      
      IF LEFT$(X$,3)="OR " THEN X$=RIGHT$(X$,LEN(X$)-3)

      SELECT JM
         CASE 1 : Z$=RIGHT$(B$(S1,NP+1),L1-S(S1,2))
         CASE 2 : Z$=LEFT$(B$(S1,NP+1),S(S1,2))    
         CASE 3 : Z$=LEFT$(B$(S1,NP+1),S(S1,3))    
      END_SELECT
      
      IF KM+JM=2
         IF LEFT$(X$,4)="EST " THEN X$=RIGHT$(X$,LEN(X$)-4) : X$="QUELQUE "+X$+" "
         IF LEFT$(X$,5)="SONT " THEN X$=RIGHT$(X$,LEN(X$)-5) : X$="QUELQUES "+X$+" "
      END_IF
      
      ITEM_ADD memo%,"IA > Donc "+X$+" "+Z$ : ITEM_ADD memo%,"IA > " : RETURN
              
      ' ====================        
      ' COMMANDES DE SERVICE
      ' ====================
      ' LISTAGE DE LA BASE
      ' --------------------
      
      ligne9950:
      IF A$="/L"
         FOR I = 1 TO NT
            ITEM_ADD memo%,"IA > "+STR$(I)+" "+B$(I,NP+1)
         NEXT I
         RETURN
      END_IF
  
      ' SUPPRESSION
      IF LEFT$(A$,2)="/D"
         IF L<=2 : I=NT : ELSE : I=VAL(RIGHT$(A$,L-2)) : END_IF
         FOR J=1 TO NP+1
            B$(I,J)=""
         NEXT J
         ITEM_ADD memo%,"IA > L'assertion n° "+STR$(I)+" est supprimée !"
         RETURN
      END_IF
      
      ' EFFACEMENT DE TOUTE LA BASE
      IF A$="/EFF"
         IF MESSAGE_CONFIRMATION_YES_NO("Voulez vous effacer toute la base ?")=1
            FOR I=1 TO NT
               FOR J=1 TO NP+1
                  B$(I,J)=""
               NEXT J
            NEXT I
            ITEM_ADD memo%,"IA > La base est entièrement effacée !"
            NI=0
         ELSE
            ITEM_ADD memo%,"IA > Aucun élément n'est effacé !"  
         END_IF
         RETURN
      END_IF
      
   END_IF
  
RETURN  

' REDIMENTIONNEMENT DE LA FENETRE
agrandissement:

   WIDTH memo%,WIDTH(form%)-27 : HEIGHT memo%,HEIGHT(form%)-80
  
   TOP edit%,HEIGHT(form%)-70
   IF HIDE(button%)=1
      WIDTH edit%,WIDTH(form%)-27
   ELSE
      WIDTH edit%,WIDTH(form%)-185
   END_IF
  
RETURN

' ASSERTION AUTOMATIQUE
suivant:

      READ A$
      
      IF A$<>"ZZ"
         INACTIVE button%
         TEXT edit%,A$ : PAUSE 800 : TRIGGER_KEY_DOWN edit%,13,0
         ACTIVE button%
      ELSE
         HIDE button% : WIDTH edit%,WIDTH(form%)-27
         A$="Fin des exemples d'assertions !"+CHR$(13)+CHR$(13)
         A$=A$+"Vous pouvez continuer en rentrant vos propres assertions."
         MESSAGE A$
      END_IF
  
RETURN

' PROCEDURE DE RECHERCHE D'UN PROCHAIN E(K)
SUB recherche()

   V=0
   FOR I=E(K)+1 TO NT
      FOR J=1 TO S(E(K),1)
         IF (B$(I,J)=C$(K)) THEN V=1 : E(K)=I : J=NP : I=NT
      NEXT J
   NEXT I
  
END_SUB    
          
' PROCEDURE ERREUR
erreur:

   MESSAGE STR$(ERROR_NUMBER)+" "+ERROR_TYPE$+" a la ligne "+STR$(ERROR_LINE)
  
TERMINATE

' #################################################################################################################