Nous sommes le 1er Avril : Jour du Poisson d'Avril !

rem ============================================================================
rem                  Poissons siamois
rem                    Par Papydall
rem ============================================================================
rem Deux simples équations paramétriques X = f(t) et Y = g(t) permettent de
rem tracer des jolies courbes.
rem Admirez la courbe des poissons siamois.
rem ============================================================================
rem               _________________________________________________________
rem              |                              ||                        |
rem              |   x = 5*cos(t) - c*cos(5*t)  || avec c = sqr(2) - 1    |
rem              |   y = sin(4*t)               || t variant de 0 à 360°  |
rem              |______________________________||________________________|
rem
rem ============================================================================
picture 10 : width 10,width(0)-100 : height 10,height(0)-100
top 10,20  : left 10,50 : 2d_target_is 10 : print_target_is 10
font_name 10,"arial"    : font_size 10,14 : font_color 10,0,0,255
color 0,0,0,0 : 2d_pen_color 255,150,50   : color 10,0,255,255

Poissons_Siamois(250,150,40)
Poissons_Siamois(050,050,06) : Poissons_Siamois(450,050,06)
Poissons_Siamois(060,350,12) : Poissons_Siamois(440,350,12)

2d_fill_color 0,255,255
print_locate 150,020 : print "VIVE LES MATHEMATIQUES"
print_locate 200,050 : print "Poissons siamois"
print_locate 150,220 : print "Equations paramétriques :"
print_locate 150,250 : print "x = 5 * cos(t) - c * cos(5*t)"
print_locate 150,275 : print "y = sin(4*t)"
print_locate 150,300 : print "avec c = sqr(2) - 1"
print_locate 150,325 : print "t angle variant de 0 à 360°"

END
rem ============================================================================
' Equations paramétriques des poissons siamois
' x = 5*cos(t) - c*cos(5*t)
' y = sin(4*t)
' avec c = sqr(2)-1 = 0.41421356...
' t angle variant de 0 à 360°
' ------------------------------------------------------------------------------
' Paramètres :
' xc,yc : coordonnées du point de contact de deux poissons
' taille : taille en pixels
SUB Poissons_Siamois(xc,yc,taille)
    dim_local x,y,t,xp,yp,c
    degrees
    c = sqr(2) - 1
    if taille < 6 then taille = 6
    2d_poly_from xc+taille*(5-c),yc
    for t = 0 to 360
        x = 5*cos(t) - c * cos(5*t) : y = sin(4*t)
        xp = xc + taille * x : yp = yc + taille * y
        2d_poly_to xp,yp
    next t
    2d_flood xc-2,yc,255,150,50 :  2d_flood xc+2,yc,255,150,50
    2d_flood xc+1-(5-2*c)*taille,yc,255,150,50
    2d_flood xc-1+(5-2*c)*taille,yc,255,150,50
END_SUB
rem ============================================================================

rem ============================================================================
rem           Les poissons grandissent et font la bise
rem ============================================================================
dim x,y,a,t,k,r,rx,rx1,rx2,ry,ry1,ry2,cr,cg,cb
a = 10 : k = 2*sqr(2)
caption 0,"Les poissons grandissent et font la bise      <CLICK> pour arrêter"
degrees : ' On travaille en degrés au lieu de radians
width 0,1300 : height 0,880
picture 10 : width 10,width(0)-100 : height 10,height(0)-80 : top 10,20 : left 10,50
2d_target_is 10 : print_target_is 10 : 2d_fill_on
font_name 10, "comic sans ms" : font_bold 10 :  font_size 10,16 : color 10,0,255,255

for r = .1 to 7.8 step .1
  for t = 0 to 720 step 2
    x = a * (cos(t) + k * cos(t/2)) : y = a * sin(t)
    rx = r*x : rx1 = rx/2 : rx2 = rx*2 : ry = r*y : ry1 = ry/2 : ry2 = ry*2
    cr = 255-10*r : cg = 55+10*r : cb = t*r/150
    2d_pen_color cr,cg,cb : 2d_fill_color cr,cg,cb
    2d_circle 350 + rx1, 100 - ry1,2 : 2d_circle 650 - rx1 , 100 + ry1,2 : ' les petits poissons du haut
    2d_circle 200 + rx , 300 + ry,4  : 2d_circle 800 - rx , 300 + ry,4   : ' les poissons moyens du centre
    2d_circle 350 + rx2, 600 + ry2,8 : ' le grand poisson du bas
   display
  next t
  if scancode = 27 then terminate
next r

2d_fill_color 255,255,255 : 2d_circle 350+rx1-15,100-ry1,6 : 2d_circle 350+rx1+15,100-ry1,6
2d_fill_color 000,000,000 : 2d_circle 350+rx1-15,100-ry1,4 : 2d_circle 350+rx1+15,100-ry1,4
2d_fill_color 255,255,255 : 2d_circle 200+rx-20,300-ry,9   : 2d_circle 200+rx+20,300-ry,9
2d_fill_color 000,000,000 : 2d_circle 200+rx-20,300-ry,6   : 2d_circle 200+rx+20,300-ry,6
2d_fill_color 255,255,255 : 2d_circle 350+rx2-50,600-ry2,15
2d_fill_color 000,000,000 : 2d_circle 350+rx2-50,600-ry2,10

Coeur(500,060,10,1)  : Coeur(500,140,10,-1)
Coeur(500,250,15,1)  : Coeur(500,350,15,-1)
Coeur(1050,600,20,1) : Coeur(1050,630,20,-1)

2d_pen_color 0,255,255 : 2d_fill_color 0,255,255
caption 0,"<ESC> pour sortir ...."
repeat
    for t = 2 to 40  step 2
        2d_fill_color 255,255,255 : 2d_circle 970+t/2,600-5*t,42-t : pause 50
        2d_fill_color 000,255,255 : 2d_circle 970+t/2,600-5*t,42-t : pause 50
    next t
until scancode = 27

for t = height(0) to 10 step -10 : height 0,t : pause 100 : next t
terminate
rem ============================================================================
rem ============================================================================
' Dessiner un coeur
' Equation paramétrique d'une cardioïde
' x = power(sin(t),3)
' y = cos(t) - power(cos(t),4)
' Paramètres :
' xc,yc : coordonnées du creux de la cardioïde
' r : paramètre agissant sur la forme de la cadioïde
' sens : paramètre indiquant le sens de la cardioîde :
' sens = -1 <==== la pointe est dirigée vers le bas
' sens = +1 <==== la pointe est dirigée vers le haut
SUB Coeur(xc,yc,r,sens)
    dim_local x,y,t,s
    degrees :  2d_pen_color 255,0,0 : 2d_poly_from xc,yc
    if sens <= 0 then s = -1 : else : s = 1
    for t = 0 to 360
        x = power(sin(t),3) : y = cos(t) - power(cos(t),4)
        2d_poly_to xc+r*x,yc+s*r*y +5*s
    next t
    2d_flood xc,yc-s*2,255,0,0
END_SUB
rem ============================================================================