Tchernobyl

rem ' TCHERNOBYL
dim i , j , k , f(25) , heu , sec , panne , a$
label lux , new , fin , err , term , aie , ann , aide
on_error_goto err
width 0,800 : caption 0,string$(50," ")+"CENTRALE NUCLÉAIRE DE TCHERNOBYL"
progress_bar 1
left 1,20 : top 1,10 : width 1,200 : height 1,200
progress_bar 2
left 2,240 : top 2,10 : width 2,200 : height 2,200
progress_bar 3
left 3,460 : top 3,10 : width 3,200 : height 3,200

for i=0 to 4
 for j=1 to 5
  button i*5+j+3      : edit i*5+j+28          : button i*5+j+53
  left i*5+j+3,38*i+35 : left i*5+j+28,38*i+255 : left i*5+j+53,38*i+475
  top i*5+j+3,j*38-15  : top i*5+j+28,j*38-15  : top i*5+j+53,j*38-15
  width i*5+j+3,15    : width i*5+j+28,15      : width i*5+j+53,15
  height i*5+j+3,15    : height i*5+j+28,15    : height i*5+j+53,15
  on_click i*5+j+3,lux : inactive i*5+j+28      : on_click i*5+j+53,new
  inactive i*5+j+53
 next j
next i

alpha 79
left 79,20 : top 79,260 : width 79,640 : height 79,25 : color 79,92,92,92
alpha 80
left 80,21 : top 80,261 : width 80,638 : height 80,23 : color 80,236,233,216
alpha 81
left 81,25 : top 81,265 : font_bold 81 : font_color 81,0,0,255
caption 81,"TOUT VA POUR LE MIEUX A LA CENTRALE NUCLÉAIRE DE TCHERNOBYL"
alpha 82
left 82,25 : top 82,300
alpha 83
left 83,25 : top 83,325
heu=val(mid$(time$,4,2))*60+val(right$(time$,2))
panne=int(rnd(24)+2)
alpha 84
left 84,26 : top 84,225 : font_bold 84 : font_size 84,10
caption 84,"BOUTONS DE CONTRÔLE"
alpha 85
left 85,248 : top 85,225 : font_bold 85 : font_size 85,10
caption 85,"VOYANTS DE CONTRÔLE"
alpha 86
left 86,460 : top 86,225 : font_bold 86 : font_size 86,10
caption 86,"BOUTONS DE RÉPARATION"
button 87 : left 87,680 : top 87,140 : caption 87,"Aide"
on_click 87,aide : inactive 87

for i=1 to 200
 j=int(rnd(25)+29)
 k=int(rnd(25)+29)
 color j,255,200,0
 color k,255,200,0
 wait 100
 color j,255,255,255
 color k,255,255,255
 wait 10
next i
beep
gosub ann
fin:

end

lux:
gosub ann
k=0 : beep
if sec<1 then goto aie
for i=4 to 28
 if clicked(i)=1 then k=i-3
next i
if k=panne
 for i=1 to 25
  f(i)=0
  color i+28,255,255,255
 next i
 return
end_if
f(k)=bin_xor(f(k),1)
if f(k)=1
 color k+28,255,0,0
else
 color k+28,255,255,255
end_if
k=0
for i=1 to 25
 if f(i)=1 then k=k+1
next i
if k=24
 active panne+53
 set_focus panne+53
end_if
return

new:
color panne+28,255,0,0 : beep
wait 999
font_color 81,0,0,255
caption 81,"TOUT VA POUR LE MIEUX A LA CENTRALE NUCLÉAIRE DE TCHERNOBYL"
caption 82,"BRAVO, vous avez réussi à sauver le monde !!!"
caption 83,""
inactive panne+53
for i=1 to 25
 color i+28,255,255,255
next i
midi_on
for i=1 to 60
 j=int(rnd(25)+29)
 k=int(rnd(25)+29)
 color j,255,200,0
 color k,255,200,0
 midi_play int(rnd(40)+40),10
 color j,255,255,255
 color k,255,255,255
next i
midi_off
wait 500
goto term

ann:
active 87
font_color 81,255,0,0 : sec=60-(val(mid$(time$,4,2))*60+val(right$(time$,2))-heu)
caption 81,"RIEN NE VA PLUS A LA CENTRALE NUCLÉAIRE DE TCHERNOBYL QUI VA EXPLOSER DANS "+str$(sec)+" SECONDES"
caption 82,"Vous êtes ingénieur et vous êtes le seul a pouvoir empêcher l'explosion."
caption 83,"Dépêchez-vous pour isoler le lieu de la panne et la réparer !!!"
return

aie:
color 0,255,0,0
caption 82,""
font_bold 83 : font_size 83,20
caption 83,"LA CENTRALE VA EXPLOSER DANS 1 SECONDE"
wait 3000
terminate
return

aide:
a$="AIDE A LA SAUVEGARDE DE LA CENTRALE NUCLÉAIRE DE TCHERNOBYL :"+chr$(13)
a$=a$+"  Les voyants jaunes signifient que tout va bien."+chr$(13)
a$=a$+"Par contre, quand tout devient blanc, c'est que les 25 circuits"+chr$(13)
a$=a$+"de refroidissement de la centrale ont disjoncté."+chr$(13)
a$=a$+"  Il faut donc tous les remettre en marche avant que la centrale"+chr$(13)
a$=a$+"n'explose. Pour cela, il doivent tous appraître en rouge."+chr$(13)
a$=a$+"  Vous devez agir sur les boutons de contrôle et montrer à"+chr$(13)
a$=a$+"l'ordinateur quel est le circuit défectueux pour qu'il vous"+chr$(13)
a$=a$+"active le bouton de réparation correspondant."+chr$(13)
a$=a$+"Dépêchez-vous, car même si l'affichage du temps n'apparaît que"+chr$(13)
a$=a$+"lorsque vous appuyez sur un bouton (vetusté du matériel soviétique"+chr$(13)
a$=a$+"réparé à coup de trombones et d'élastiques) le compteur continue"+chr$(13)
a$=a$+"à tourner (même pendant que vous lisez cette rubrique d'aide)."
message a$
return

err:
goto fin

term:
terminate