FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC

Développement d'applications avec le langage Panoramic
 
AccueilAccueil  FAQFAQ  RechercherRechercher  S'enregistrerS'enregistrer  MembresMembres  GroupesGroupes  Connexion  
Derniers sujets
» Demande pour Jack concernant PanExpress
par Jack Aujourd'hui à 7:48

» Calculatrice
par papydall Hier à 22:54

» EPP_V01 éditeur pour Panoramic
par Minibug Mer 19 Sep 2018 - 21:03

» [RESOLU] Quelle ligne est sélectionnée dans SYNEDIT ?
par Jean Claude Mer 19 Sep 2018 - 21:02

» PanExpress : l'éditeur Panoramic avec création d'objet
par Minibug Mer 19 Sep 2018 - 15:58

» Planétarium virtuel.
par Pedro Alvarez Mer 19 Sep 2018 - 9:28

» Petit coucou en passant !
par Minibug Dim 16 Sep 2018 - 15:03

» bug SEVERE fnc+sub : variables globales corrompus
par silverman Dim 16 Sep 2018 - 13:38

» Verrouiller un form en avant plan
par silverman Dim 16 Sep 2018 - 12:50

» Fin de l'aventure.
par Pedro Alvarez Sam 15 Sep 2018 - 18:16

» Demande d'explications Sur File_Write & File_writeln
par Jack Sam 15 Sep 2018 - 17:26

» MEMO avec des possibilités de commande
par Oscaribout Mer 12 Sep 2018 - 1:06

» La théorie du chaos
par jean_debord Mar 11 Sep 2018 - 9:30

» Orbites de l’ensemble de Mandelbrot
par Jean Claude Lun 10 Sep 2018 - 21:08

» Version instantanée V 0.9.29i2 du 4/09/2018
par silverman Mer 5 Sep 2018 - 10:15

Navigation
 Portail
 Index
 Membres
 Profil
 FAQ
 Rechercher
Rechercher
 
 

Résultats par :
 
Rechercher Recherche avancée
Septembre 2018
LunMarMerJeuVenSamDim
     12
3456789
10111213141516
17181920212223
24252627282930
CalendrierCalendrier

Partagez | 
 

 Maître-expert alphabétique 43° siècle

Aller en bas 
AuteurMessage
jjn4

avatar

Nombre de messages : 1761
Date d'inscription : 13/09/2009

MessageSujet: Maître-expert alphabétique 43° siècle   Lun 20 Fév 2017 - 15:12

Scénario vous lirez
Ce jeu vous jouerez
Scotché vous serez
Code:
rem ' Maître-expert alphabétique - par jjn4 - le 20/02/2017 ===================
   rem Listes pour les définitions --------------------------------------------
   dim LC$(106) : rem Liste des Compléments pour les définitions
   dim LL$(22) : rem Liste des Liens pour les définitions
   dim LLC%(106) : rem Liste des Liens des Compléments
   dim LNS%(106) : rem Liste du Nombre de Sujets des compléments
   dim LS$(116) : rem Liste des Sujets pour les définitions
   dim LSC%(106,5) : rem Liste des Sujets des Compléments
   rem Autres variables -------------------------------------------------------
   dim CRJ%(9) : rem Copie de la Recherche du Joueur
   dim DC$(32) : rem Différentes Consonnes
   dim DV$(32) : rem Différentes Voyelles
   dim EC% : rem Emplacement du Curseur
   dim NB$(6) : rem Nom des Boutons de commande
   dim NL$(21) : rem Nombre de Lettres à utiliser
   dim NLJ% : rem Numéro de la Ligne où en est le Joueur
   dim MT$ : rem Mot à trouver
   dim TA$(17) : rem Texte de l`Aide
   dim TL$(10) : rem Texte de la Légende
   dim V1M% , V2M% , V3M$ , V4M$ : rem Variables à utilisation multiple
   label clic : rem Redirection de tous les on-click

rem Lecture des datas =========================================================
   for V1M% = 1 to 22
      read LL$(V1M%) : rem Lecture des Liens
   next V1M%
   for V1M% = 1 to 116
      read LS$(V1M%) : rem Lecture des Sujets
   next V1M%
   for V1M% = 1 to 106
      read LC$(V1M%) : rem Lecture des Compléments
      read LLC%(V1M%) : rem Lecture des Liens des Compléments
      read LNS%(V1M%) : rem Lecture du Nombre de Sujets des Complements
      for V2M% = 1 to LNS%(V1M%)
         read LSC%(V1M%,V2M%) : rem Lecture des Sujets des Compléments
      next V2M%
   next V1M%
   for V1M% = 1 to 32
      read DV$(V1M%) : rem Lecture des Différentes Voyelles
   next V1M%
   for V1M% = 1 to 32
      read DC$(V1M%) : rem Lecture des Différentes Consonnes
   next V1M%
   for V1M% = 1 to 21
      read NL$(V1M%) : rem Lecture des lettres à utiliser
   next V1M%
   for V1M% = 1 to 6
      read NB$(V1M%) : rem Lecture des noms des boutons de commande
   next V1M%
   for V1M% = 1 to 17
      read TA$(V1M%) : rem Lecture du texte de l`aide
      read V3M$
      TA$(V1M%)=TA$(V1M%)+V3M$
   next V1M%
   for V1M% = 1 to 10
      read TL$(V1M%) : rem Lecture du texte de la légende
      read V3M$
      TL$(V1M%)=TL$(V1M%)+V3M$
   next V1M%
  
rem Form0 =====================================================================
   width 0,1360
   height 0,720
   caption 0,"   Maître-expert alphabétique - par jjn4 - Ver-200217.1.0"

rem Affichage du cache de préparation du jeu ==================================
   form 10
      width 10,1360
      height 10,720
      caption 10,"Maître-expert alphabétique - suspens..."
   panel 20
      parent 20,10
      left 20,250
      top 20,200
      width 20,850
      height 20,85
      font_bold 20
      font_size 20,24
      font_name 20,"Arial"
      caption 20,"M A Î T R E - E X P E R T   A L P H A B É T I Q U E"

rem Affichage du support des définitions ======================================
   panel 60
      left 60,10
      top 60,5
      width 60,1320
      height 60,58
      color 60,255,255,100
   alpha 65
      parent 65,60
      left 65,10
      top 65,5
      font_bold 65
      font_size 65,12
      font_color 65,0,0,255
      caption 65,"Définition :"
   alpha 70
      parent 70,60
      left 70,140
      top 70,5
      font_bold 70
      font_size 70,12
      font_color 70,255,0,0
   alpha 75
      parent 75,60
      left 75,300
      top 75,5
      font_bold 75
      font_size 75,12
      font_color 75,0,200,0
   alpha 80
      parent 80,60
      left 80,10
      top 80,30
      font_bold 80
      font_size 80,12

rem Affichage de la grille de recherche =======================================
   for V1M% = 1 to 15 : rem Objets-système 100 à 234 à pas de 1 mais à rebours
      for V2M% = 1 to 9                              : rem 226 227 ... 233 234
         panel (V1M%-1)*9+V2M%+99                    : rem 217 218 ... 224 225
            left (V1M%-1)*9+V2M%+99,V2M%*40-30       : rem 208 209 ... 215 216
            top (V1M%-1)*9+V2M%+99,(16-V1M%)*40+30   : rem ... ... ... ... ...
            width (V1M%-1)*9+V2M%+99,40              : rem 109 110 ... 116 117
            height (V1M%-1)*9+V2M%+99,40             : rem 100 101 ... 107 108
            font_bold (V1M%-1)*9+V2M%+99
            font_size (V1M%-1)*9+V2M%+99,22
            font_name (V1M%-1)*9+V2M%+99,"Arial"
      next V2M%
   next V1M%
   colorise()
  
rem Affichage de la grille de réponse =========================================
   alpha 244
      left 244,385
      top 244,70
      width 244,80
      height 244,600
      color 244,150,255,255
   alpha 246
      left 246,465
      top 246,70
      width 246,80
      height 246,600
      color 246,255,160,255
   alpha 248
      left 248,545
      top 248,70
      width 248,80
      height 248,600
      color 248,175,255,175
   for V1M% = 1 to 15 : rem Objets-système 250 à 384 à pas de 1 mais à rebours
      for V2M% = 1 to 9                              : rem 376 377 ... 383 384
         alpha (V1M%-1)*9+V2M%+249                   : rem 367 368 ... 374 375
            left (V1M%-1)*9+V2M%+249,V2M%*26+363     : rem 358 359 ... 365 366
            top (V1M%-1)*9+V2M%+249,(16-V1M%)*40+32  : rem ... ... ... ... ...
            width (V1M%-1)*9+V2M%+249,24             : rem 259 260 ... 266 267
            height (V1M%-1)*9+V2M%+249,36            : rem 250 251 ... 257 258
      next V2M%
   next V1M%
  
rem Affichage des boutons des lettres =========================================
   for V1M% = 1 to 3 : rem Objets-système 400 à 420 à pas de 1
      for V2M% = 1 to 7                                     : rem 400 407 414
         button (V1M%-1)*7+V2M%+399                         : rem 401 408 415
            left (V1M%-1)*7+V2M%+399,640+(V1M%-1)*150       : rem 402 409 416
            top (V1M%-1)*7+V2M%+399,V2M%*86-16              : rem 403 410 417
            width (V1M%-1)*7+V2M%+399,140                   : rem 404 411 418
            height (V1M%-1)*7+V2M%+399,80                   : rem 405 412 419
            font_bold (V1M%-1)*7+V2M%+399                   : rem 406 413 420
            font_size (V1M%-1)*7+V2M%+399,32
            font_name (V1M%-1)*7+V2M%+399,"Arial"
            caption (V1M%-1)*7+V2M%+399,NL$((V1M%-1)*7+V2M%)
            on_click (V1M%-1)*7+V2M%+399,clic
            inactive (V1M%-1)*7+V2M%+399
      next V2M%
   next V1M%
  
rem Affichage des boutons de commande =========================================
   button 500 : rem Flèche gauche
      left 500,1095
      top 500,70
      width 500,115
      height 500,80
      font_size 500,50
      font_name 500,"Wingdings"
      caption 500,chr$(239)
      on_click 500,clic
      inactive 500
   button 510 : rem Flèche droite
      left 510,1215
      top 510,70
      width 510,115
      height 510,80
      font_size 510,50
      font_name 510,"Wingdings"
      caption 510,chr$(240)
      on_click 510,clic
      inactive 510
   for V1M% = 1 to 6 : rem Objets-système 520, 530, 540, 550, 560 et 570
      button V1M%*10+510
         left V1M%*10+510,1095
         top V1M%*10+510,V1M%*86+70
         width V1M%*10+510,235
         height V1M%*10+510,80
         font_bold V1M%*10+510
         font_size V1M%*10+510,24
         font_name V1M%*10+510,"Arial"
         caption V1M%*10+510,NB$(V1M%)
         on_click V1M%*10+510,clic
   next V1M%
   inactive 520
   inactive 540
  
rem Affichage du tableau de légende ===========================================
   container 600
      hide 600
      left 600,60
      top 600,66
      width 600,425
      height 600,250
      caption 600,"Règles du jeu et légende des couleurs"
   alpha 610
      parent 610,600
      left 610,10
      top 610,20
      V3M$=""
      for V1M% = 1 to 10
         if V1M%=4
            V3M$=V3M$+chr$(13)
         end_if
         V3M$=V3M$+TL$(V1M%)
         if V1M%<10
            V3M$=V3M$+chr$(13)
         end_if
         if V1M%>4 and V1M%<10
            V3M$=V3M$+chr$(13)+string$(25," ")
         end_if
      next V1M%
      caption 610,V3M$
   for V1M% = 1 to 5 : rem Objets système 620, 630, 640, 650 et 660
      alpha V1M%*10+610 : rem Couleurs des possibilités -----------------------
         parent V1M%*10+610,600
         left V1M%*10+610,10
         top V1M%*10+610,V1M%*26+79
         width V1M%*10+610,60
         height V1M%*10+610,25
   next V1M%
   color 620,0,200,255
   color 630,10,255,100
   color 640,255,50,50
   color 650,255,180,255
   color 660,0,0,0
   midi_on
   midi_volume 127
   hide 10
  
end : rem ' Début des routines ================================================

sub aband() : rem Le joueur abandonne la recherche ============================
   dim_local v1ab%
   for v1ab% = 400 to 420
      inactive v1ab%
   next v1ab%
   inactive 500
   inactive 510
   if active(520)=1
      inver(520)
   end_if
   inver(530)
   inver(540)
   caption 70,MT$
   caption 80,"Les définitions ne sont données qu'en cas de réussite, désolé."
end_sub

sub aide() : rem Affichage du scénario du jeu =================================
   dim_local v1ai%
   V3M$=""
   application_title "   Scénario du jeu"
   inver(560)
   for v1ai% = 1 to 17
      if v1ai%>1
         if left$(TA$(v1ai%),3)="   "
            V3M$=V3M$+chr$(13)
         end_if
      end_if
      V3M$=V3M$+TA$(v1ai%)
      if v1ai%<17
         V3M$=V3M$+chr$(13)
      end_if
   next v1ai%
   message V3M$
   inver(560)
end_sub

clic: : rem Redirection de tous les on-click ==================================
   select number_click
      case 500 : gauche()
      case 510 : droite()
      case 520 : reponse()
      case 530 : jouer()
      case 540 : aband()
      case 550 : legende()
      case 560 : aide()
      case 570 : quitter()
   end_select
   if number_click>399 and number_click<421
      lettre()
   end_if
   midi_instrument 115
   midi_play 90,10
return

sub choix() : rem Choix du mot à trouver ======================================
   dim_local v1ch% , v2ch%
   v1ch%=int(rnd(2))+2
   MT$=""
   for v2ch% = 1 to v1ch%
      MT$=MT$+DC$(int(rnd(32))+1)+DV$(int(rnd(32))+1)
   next v2ch%
   if len(MT$)>9
      MT$=left$(MT$,9)
   end_if
   MT$=upper$(MT$)
end_sub

sub colorise() : rem Met la grille de recherche aux bonnes couleurs ===========
   dim_local v1ci% , v2ci%
   for v1ci% = 1 to 15
      for v2ci% = 1 to 9
         if v2ci%<4
            color (v1ci%-1)*9+v2ci%+99,150,255,255
         end_if
         if (v2ci%>3) and (v2ci%<7)
            color (v1ci%-1)*9+v2ci%+99,255,220,255
         end_if
         if v2ci%>6
            color (v1ci%-1)*9+v2ci%+99,175,255,175
         end_if
      next v2ci%
   next v1ci%
end_sub

sub couleur() : rem Colorise le fond de la grille de recherche ================
   dim_local v1co%
   for v1co% = 1 to 3
      color 99+(NLJ%-1)*9+v1co%,150,255,255
   next v1co%
   for v1co% = 4 to 6
      color 99+(NLJ%-1)*9+v1co%,255,220,255
   next v1co%
   for v1co% = 7 to 9
      color 99+(NLJ%-1)*9+v1co%,175,255,175
   next v1co%
   if len(MT$)<9
      for v1co% = len(MT$)+1 to 9
         color 99+(NLJ%-1)*9+v1co%,255,255,0
      next v1co%
   end_if
end_sub

sub definition()
   dim_local v1af% , v2af% , v3af%
   v1af%=int(rnd(2))+1
   if v1af%=1
      V4M$="Genre d"
   else
      V4M$="Sorte d"
   end_if
   v2af%=int(rnd(106))+1
   v3af%=int(rnd(LNS%(v2af%)))+1
   V3M$=left$(LS$(LSC%(v2af%,v3af%)),1)
   if V3M$="a" or V3M$="e" or V3M$="i" or V3M$="é" or V3M$="h"
      V4M$=V4M$+"'"
   else
      V4M$=V4M$+"e "
   end_if
   caption 80,V4M$+LS$(LSC%(v2af%,v3af%))+" "+LL$(LLC%(v2af%))+LC$(v2af%)
   if right$(MT$,1)="E" or right$(MT$,1)="A"
      caption 75,"Nom féminin"
   else
      caption 75,"Nom masculin"
   end_if
   caption 70,MT$
end_sub

sub droite() : rem Faire aller le curseur vers la droite ======================
   dim_local v1dr%
   if EC%<len(MT$)
      EC%=EC%+1
   else
      EC%=1
   end_if
   couleur()
   color 99+(NLJ%-1)*9+EC%,0,255,0
end_sub

sub gagne() : rem Le joueur a trouvé la bonne réponse =========================
   dim_local v1gg%
   midi_instrument 9
   midi_play 60,6
   definition()
   for v1gg% = 400 to 420
      inactive v1gg%
   next v1gg%
   inactive 500
   inactive 510
   inver(530)
   inver(540)
end_sub

sub gauche() : rem Faire aller le curseur vers la gauche ======================
   dim_local v1ga%
   if EC%>1
      EC%=EC%-1
   else
      EC%=len(MT$)
   end_if
   couleur()
   color 99+(NLJ%-1)*9+EC%,0,255,0
end_sub

sub inver(qb%) : rem Système d`inversion des boutons ==========================
   if asc(left$(caption$(qb%),1))<95
      font_bold_off qb%
      font_italic qb%
      font_size qb%,18
      inactive qb%
   else
      font_bold qb%
      font_italic_off qb%
      font_size qb%,24
      active qb%
   end_if
   caption qb%,reverse$(caption$(qb%))
end_sub

sub jouer() : rem Le joueur joue ou rejoue ====================================
   dim_local v1jo%
   if caption$(530)="Jouer"
      inver(520)
      inver(540)
   end_if
   caption 530,"Rejouer"
   inver(530)
   choix()
   for v1jo% = 1 to 9
      CRJ%(v1jo%)=0
   next v1jo%
   for v1jo% = 1 to len(MT$)
      CRJ%(v1jo%)=1
   next v1jo%
   vide()
   NLJ%=1
   couleur()
   color 100,0,255,0
   for v1jo% = 400 to 420
      active v1jo%
   next v1jo%
   active 500
   active 510
   inver(540)
   caption 70,""
   caption 75,""
   caption 80,""
   EC%=1
end_sub

sub legende() : rem Explication des règles du jeu =============================
   if hide(600)=1
      show 600
   else
      hide 600
   end_if
   inver(550)
   active 550
   if show(600)=1
      font_size 550,36
   end_if
end_sub

sub lettre() : rem Le joueur propose une lettre ===============================
   dim_local v1tt% , v2tt%
   caption 99+(NLJ%-1)*9+EC%,NL$(number_click-399)
   CRJ%(EC%)=2
   droite()
   for v1tt% = 1 to len(MT$)
      if CRJ%(v1tt%)=2
         v2tt%=v2tt%+1
      end_if
   next v1tt%
   if v2tt%=len(MT$)
      if active(520)=0
         inver(520)
      end_if
   end_if
end_sub

sub perd() : rem Le joueur arrive au bout sans avoir trouvé ===================
   dim_local v1pe%
   for v1pe% = 400 to 420
      inactive v1pe%
   next v1pe%
   inactive 500
   inactive 510
   inver(530)
   inver(540)
   caption 70,MT$
   caption 80,"Les définitions ne sont données qu'en cas de réussite, désolé."
end_sub

sub quitter() : rem Le joueur quitte le jeu ===================================
   dim_local v1qu%
   inver(570)
   V3M$="Attention, si vous quittez ce jeu, vous risquez"+chr$(13)
   V3M$=V3M$+"de glisser vous aussi dans une faille temporelle."+chr$(13)
   V3M$=V3M$+"Persistez-vous cependant dans votre demande ?"
   v1qu%=message_confirmation_yes_no(V3M$)
   if v1qu%=1
      midi_off
      terminate
   else
      inver(570)
   end_if
end_sub

sub reponse() : rem L`ordinateur donne la réponse au joueur ===================
   dim_local v1re% , v2re% , v3re%
   inver(520)
   for v1re% = 1 to len(MT$) : rem Détection des lettres bien placées -------5-
      if caption$(99+(NLJ%-1)*9+v1re%)=mid$(MT$,v1re%,1)
         CRJ%(v1re%)=5
      end_if
   next v1re%
   for v1re% = 1 to len(MT$) : rem Détection des lettres mal placées --------4-
      if instr(MT$,caption$(99+(NLJ%-1)*9+v1re%))>0
         if caption$(99+(NLJ%-1)*9+v1re%)<>mid$(MT$,v1re%,1)
            if CRJ%(v1re%)<3
               CRJ%(v1re%)=4
            end_if
         end_if
      end_if
   next v1re%
   for v1re% = 1 to len(MT$): rem Détection des lettres doubles bien placées 3-
      v3re%=0
      if CRJ%(v1re%)=5
         V3M$=caption$(99+(NLJ%-1)*9+v1re%)
         for v2re% = 1 to len(MT$)
            if mid$(MT$,v2re%,1)=V3M$
               v3re%=v3re%+1
            end_if
         next v2re%
         if v3re%>1
            CRJ%(v1re%)=3
         end_if
      end_if
   next v1re%
   for v1re% = 1 to len(MT$) : rem Détection des lettres doubles mal placées 6-
      v3re%=0
      if CRJ%(v1re%)=4
         V3M$=caption$(99+(NLJ%-1)*9+v1re%)
         for v2re% = 1 to len(MT$)
            if mid$(MT$,v2re%,1)=V3M$
               v3re%=v3re%+1
            end_if
         next v2re%
         if v3re%>1
            CRJ%(v1re%)=6
         end_if
      end_if
   next v1re%
   v2re%=0
   for v1re% = 1 to len(MT$)
      select CRJ%(v1re%)
         case 2 : color 249+(NLJ%-1)*9+v1re%,0,0,0 : rem Lettres absentes ---2-
         case 3 : color 249+(NLJ%-1)*9+v1re%,10,255,100
         case 4 : color 249+(NLJ%-1)*9+v1re%,255,50,50
         case 5 : color 249+(NLJ%-1)*9+v1re%,0,200,255
         case 6 : color 249+(NLJ%-1)*9+v1re%,255,180,255
      end_select
      if (CRJ%(v1re%)=5) or (CRJ%(v1re%)=3)
         V2re%=v2re%+1
      end_if
   next v1re%
   if v2re%=len(MT$)
      gagne()
   else
      if NLJ%<16
         couleur()
         NLJ%=NLJ%+1
         if NLJ%<16
            couleur()
         end_if
         EC%=1
         for v1re% = 1 to 9
            CRJ%(v1re%)=0
         next v1re%
         if NLJ%<16
            color 99+(NLJ%-1)*9+EC%,0,255,0
         else
            perd()
         end_if
      end_if
   end_if
end_sub

sub vide() : rem Vider les grilles de recherche et de réponse =================
   dim_local v1vi%
   for v1vi% = 100 to 234
      caption v1vi%,""
      color v1vi%+150,240,240,240
   next v1vi%
   for v1vi% = 1 to 15
      colorise()
   next v1vi%
end_sub

rem Début des datas ===========================================================
   rem Liens ------------------------------------------------------------------
   data "servant "
   data "permettant d"
   data "fonctionnant "
   data "équipé"
   data "réalisé"
   data "obtenu"
   data "ayant la particularité "
   data "destiné"
   data "créé"
   data "construit"
   data "fabriqué"
   data "équipant "
   data "dont "
   data "traitant d"
   data "utilisé"
   data "très à la mode "
   data "infestant "
   data "élevé"
   data "comportant "
   data "pouvant atteindre "
   data "formé"
   data "résultant "
   rem Sujets -----------------------------------------------------------------
   data "3ème sexe"
   data "abaque moderne"
   data "acarien géant"
   data "addition géométrique"
   data "aéroglisseur"
   data "album"
   data "amphithéâtre"
   data "apéritif"
   data "appeau"
   data "araignée géante"
   data "fusil"
   data "ascenseur"
   data "assurance"
   data "atome géant"
   data "aubergine géante"
   data "aubergiste"
   data "ballon dirigeable"
   data "baluchon"
   data "banjo"
   data "barman"
   data "béret"
   data "beurre"
   data "bicyclette"
   data "bidon"
   data "bobsleigh spatial"
   data "boudin géant"
   data "bougie"
   data "boussole tridimensionnelle"
   data "bovidé à 12 pattes"
   data "boxe moderne"
   data "braguette magnétique"
   data "brochet géant"
   data "brouette"
   data "bulldozer"
   data "cabane de jardin"
   data "cacahuète géante"
   data "cacao"
   data "cafard géant"
   data "caleçon en dentelle"
   data "catapulte"
   data "cerf-volant"
   data "champignon géant"
   data "chapeau"
   data "char d'assaut"
   data "château-fort médiéval moderne"
   data "chenille géante"
   data "chips"
   data "clepsydre"
   data "compas"
   data "compote"
   data "confiture"
   data "contrebasse"
   data "crabe géant"
   data "crapaud intelligent"
   data "dinosaure carnivore géant"
   data "double-décimètre"
   data "éprouvette spéciale"
   data "escargot géant"
   data "faucon extrêmement miniaturisé"
   data "fauteuil"
   data "frisbee"
   data "friteuse spéciale"
   data "fuel"
   data "galipette"
   data "gargouille"
   data "gaufrette"
   data "géométrie"
   data "grande assiette"
   data "gratte-ciel"
   data "gros barbecue"
   data "gros marteau"
   data "guêpe géante"
   data "guignol gore"
   data "haltère de plus de 400 kg"
   data "haubois"
   data "hélicoptère"
   data "hochet gore"
   data "hors-bord"
   data "hot-dog"
   data "huître géante"
   data "hydravion"
   data "instrument"
   data "klaxon"
   data "lave-linge"
   data "longue-vue"
   data "mante religieuse géante"
   data "maternité"
   data "mathématiques"
   data "mini soucoupe volante"
   data "miroir déformant"
   data "moissonneuse-batteuse"
   data "monocycle"
   data "mouchoir"
   data "moustique géant"
   data "musique"
   data "nouveau continent"
   data "nouveau fruit exotique géant"
   data "nuage bas"
   data "peinture moderne"
   data "petit meuble"
   data "porte-avion spatial"
   data "radeau spatial"
   data "sablier"
   data "sextant"
   data "siège électrique"
   data "soucoupe volante"
   data "soucoupe volante bas de gamme"
   data "sport extrême"
   data "sport très violent"
   data "stylo-bille"
   data "tarte"
   data "téléphone"
   data "thermomètre"
   data "vélociraptor"
   data "ville"
   data "voilier spatial"
   rem Compléments ------------------------------------------------------------
   data "e voyager d'une galaxie à une autre"
   data 2 , 5 , 12 , 17 , 23 , 28 , 40
   data "avec une manivelle"
   data 3 , 4 , 12 , 76 , 84 , 106
   data "e d'un réacteur nucléaire"
   data 4 , 3 , 23 , 33 , 91
   data "à compter les millénaires"
   data 1 , 2 , 2 , 103
   data "à regarder des vidéos"
   data 1 , 3 , 6 , 84 , 99
   data "à faire s'écrouler de vieux immeubles"
   data 1 , 2 , 52 , 95
   data "à compter les moutons"
   data 1 , 2 , 2 , 56
   data "e sans peinture"
   data 5 , 1 , 99
   data " par une erreur de manipulation génétique"
   data 6 , 5 , 1 , 3 , 38 , 55 , 94
   data "e compter les étoiles d'une galaxie"
   data 2 , 3 , 2 , 4 , 56
   data "à fabriquer divers elixirs de Jouvence"
   data 1 , 5 , 3 , 10 , 38 , 57 , 63
   data "à voyager sur les planètes gazeuses"
   data 1 , 3 , 5 , 23 , 25
   data "à déplacer des montagnes"
   data 1 , 4 , 17 , 23 , 34 , 76
   data " par reconstitution génétique"
   data 6 , 2 , 55 , 114
   data "de flotter dans la haute atmosphère"
   data 7 , 2 , 102 , 115
   data "à monter les escaliers"
   data 1 , 2 , 46 , 92
   data " à limiter les excès démographiques"
   data 8 , 2 , 11 , 109
   data " par croisements génétiques"
   data 6 , 5 , 1 , 29 , 38 , 53 , 54
   data " à recevoir les confessions publiques"
   data 8 , 1 , 7
   data "à attraper les tyrannosaurus rex"
   data 1 , 5 , 9 , 26 , 27 , 61 , 71
   data "en cas de panne de soucoupe volante"
   data 1 , 2 , 25 , 102
   data "e par les industriels de la soie"
   data 9 , 2 , 10 , 46
   data " pour se défendre contre les attaques de tyrannosaurus rex"
   data 10 , 2 , 45 , 83
   data " avec de la pâte à modeler"
   data 11 , 2 , 11 , 34
   data "à l'énergie nucléaire"
   data 3 , 5 , 23 , 33 , 84 , 91 , 110
   data "aux voyages temporels"
   data 1 , 3 , 12 , 25 , 85
   data " par manipulation génétique"
   data 9 , 5 , 3 , 29 , 53 , 94 , 97
   data "à se garantir contre les décalages temporels"
   data 1 , 3 , 13 , 85 , 103
   data "à manger un gigot de tyrannosaurus rex"
   data 1 , 2 , 68 , 70
   data "à transmettre des messages inter-continentaux"
   data 1 , 2 , 40 , 61
   data " par la nouvelle physique quantique"
   data 9 , 2 , 1 , 14
   data "de la nouvelle cuisine entièrement virtuelle"
   data 1 , 2 , 16 , 20
   data "les autobus et servant à véhiculer les robots" ,
   data 12 , 1 , 105
   data "à faire le trajet Terre-Lune et inversement"
   data 1 , 4 , 12 , 17 , 23 , 40
   data "les chances de survie sont supérieures à 10%"
   data 13 , 2 , 30 , 108
   data "es courbes balistiques en spirales"
   data 14 , 1 , 88
   data " par les personnes déménageant sur une autre planète"
   data 15 , 2 , 18 , 92
   data "à produire de la musique quantique"
   data 1 , 2 , 19 , 52
   data "à faire cuire un dinosaure"
   data 1 , 3 , 62 , 68 , 70
   data "de l'alcool quantique"
   data 1 , 2 , 16 , 20
   data "aux voyages interplanétaires"
   data 1 , 5 , 12 , 17 , 23 , 28 , 116
   data "avec un moteur diesel"
   data 3 , 2 , 48 , 107
   data "au décollage des autobus volants"
   data 1 , 2 , 40 , 101
   data "de bermuda"
   data 1 , 2 , 39 , 93
   data "à labourer les champs"
   data 1 , 2 , 23 , 92
   data "à stocker de l'antimatière"
   data 1 , 2 , 24 , 35
   data " par génie génétique à des fins militaires"
   data 9 , 5 , 1 , 3 , 38 , 54 , 94
   data "au 27ème siècle"
   data 16 , 2 , 31 , 39
   data " par génie génétique pour l'industrie alimentaire"
   data 9 , 5 , 3 , 29 , 38 , 58 , 97
   data " pour alimenter les tyrannosaurus rex du zoo préhistorique"
   data 11 , 2 , 26 , 29
   data "à s'éclairer dans l'espace intersidéral"
   data 1 , 1 , 27
   data "à se repérer dans l'espace intersidéral"
   data 1 , 2 , 2 , 28
   data "à fermer les pantalons depuis le 23ème siècle"
   data 1 , 1 , 31
   data "que seuls les coups avec la tête sont autorisés"
   data 7 , 1 , 30
   data "à nourrir les brontosaures au zoo préhistorique"
   data 1 , 3 , 15 , 36 , 42
   data "les rivières depuis le 28ème siècle"
   data 17 , 2 , 32 , 53
   data "les campagnes depuis le 34ème siècle"
   data 17 , 3 , 58 , 94 , 114
   data " avec de la graisse de cafard"
   data 11 , 3 , 22 , 26 , 37
   data "e à ranger tout ce qui est radioactif"
   data 8 , 1 , 35
   data " avec du sperme de crocodile"
   data 11 , 3 , 22 , 26 , 37
   data "à chasser le mammouth comme dans la préhistoire"
   data 1 , 2 , 9 , 40
   data "à mesurer la 4ème dimension"
   data 1 , 4 , 2 , 4 , 56 , 67
   data " par les enfants en milieu spatial"
   data 15 , 1 , 41
   data " à se protéger des chutes de débrits spatiaux"
   data 8 , 3 , 21 , 43 , 45
   data " pour la chasse au tyrannosaurus rex"
   data 15 , 4 , 9 , 19 , 44 , 71
   data "e pour l'industrie alimentaire"
   data 18 , 3 , 46 , 72 , 80
   data "es à partir de viande de limace géante"
   data 11 , 1 , 47
   data "avec du pétrole"
   data 3 , 2 , 48 , 107
   data "à fractionner des géocroiseurs"
   data 1 , 3 , 40 , 71 , 83
   data "à tracer des triangles"
   data 1 , 2 , 17 , 40
   data "e à partir de chair de criquets"
   data 6 , 3 , 50 , 51 , 66
   data " à améliorer l'image de soi"
   data 8 , 2 , 39 , 90
   data " à débarrasser les lits de leurs acariens"
   data 8 , 2 , 59 , 83
   data "e à partir de bouse de vache"
   data 11 , 3 , 50 , 51 , 66
   data "e à produire des ultra-sons"
   data 8 , 1 , 52
   data " en navigation spatiale"
   data 15 , 1 , 104
   data " à partir de pétrole"
   data 11 , 4 , 8 , 22 , 37 , 79
   data " pour l'industrie alimentaire"
   data 9 , 4 , 3 , 38 , 58 , 94
   data "par dégravitation"
   data 3 , 3 , 41 , 60 , 76
   data "à cuisiner des sauterelles"
   data 1 , 1 , 62
   data "à mesurer la bonne humeur des gens de façon objective"
   data 1 , 4 , 31 , 39 , 82 , 113
   data " à partir de sperme d'éléphant"
   data 11 , 4 , 1 , 22 , 37 , 63
   data "trois sauts périlleux"
   data 19 , 1 , 64
   data "les immeubles modernes"
   data 12 , 2 , 40 , 65
   data "e avec la partie chitineuse des insectes"
   data 11 , 1 , 66
   data "à plus de 3 dimensions"
   data 3 , 2 , 14 , 67
   data "4000 à 5000 mètres de hauteur"
   data 20 , 4 , 35 , 45 , 55 , 69
   data " pour amuser les jeunes enfants trop blasés"
   data 15 , 2 , 73 , 77
   data "à se faire les pectoraux"
   data 1 , 2 , 71 , 74
   data "à produire des sons discordants en musique moderne"
   data 1 , 3 , 24 , 52 , 75
   data "les 800 kilomètres/heure"
   data 20 , 5 , 5 , 17 , 33 , 78 , 91
   data " avec de la viande d'escargot"
   data 11 , 3 , 26 , 37 , 79
   data "e pour lutter contre les invasions de crocodiles"
   data 9 , 2 , 10 , 80
   data "à explorer les exoplanètes"
   data 1 , 5 , 5 , 23 , 33 , 54 , 81
   data "avec un pédalier"
   data 3 , 5 , 12 , 33 , 81 , 89 , 91
   data "au 32ème siècle et tombant jusqu'aux genoux"
   data 16 , 2 , 21 , 43
   data "d'un emploi excessif d'insecticides"
   data 22 , 5 , 1 , 3 , 10 , 72 , 94
   data "e avec des punaises des bois"
   data 11 , 4 , 50 , 51 , 66 , 111
   data "à communiquer avec l'ordinateur principal affecté du surnom de Dieu"
   data 1 , 2 , 82 , 112
   data "les soucoupes volantes afin d'éviter les collisions dans l'espace"
   data 12 , 2 , 27 , 83
   data "à deviner les pensées des gens"
   data 1 , 3 , 39 , 43 , 85
   data "les régions marécageuses"
   data 17 , 5 , 32 , 53 , 55 , 58 , 86
   data "e à l'accouchement des robots humanoïdes"
   data 8 , 1 , 87
   data "à mesurer le nombre de dimensions d'un espace"
   data 1 , 5 , 2 , 4 , 56 , 67 , 82
   data "quatre dimensions"
   data 19 , 5 , 33 , 35 , 40 , 56 , 100
   data " de particules polluantes et générant de la neige noire"
   data 21 , 1 , 98
   rem Lettres utilisées pour former les mots ---------------------------------
   data "a" , "a" , "a" , "a" , "e" , "e" , "e" , "e" , "e" , "e" , "e"
   data "e" , "e" , "i" , "i" , "i" , "i" , "o" , "o" , "o" , "u" , "u"
   data "u" , "u" , "ou" , "on" , "oi" , "an" , "en" , "in" , "oin" , "y"
   data "b" , "c" , "d" , "f" , "g" , "j" , "l" , "m" , "n" , "p" , "r"
   data "s" , "t" , "v" , "ch" , "ph" , "br" , "cr" , "dr" , "fr" , "gr"
   data "pr" , "tr" , "bl" , "cl" , "fl" , "pl" , "gl" , "gn" , "ps"
   data "pt" , "ts"
   data "A" , "B" , "C" , "D" , "E" , "F" , "G" , "H" , "I" , "J"
   data "L" , "M" , "N" , "O" , "P" , "R" , "S" , "T" , "U" , "V" , "Y"
   data "Réponse" , "Jouer" , "Abandon" , "Légende" , "Scénario" , "Quitter"
   rem Texte de l`aide --------------------------------------------------------
   data "   Qui d'entre vous n'a jamais rêvé d'épater les copains "
   data "en arrivant au collège ou au travail en"
   data "soucoupe volante ?  Qui n'a jamais rêvé de croiser le chemin "
   data "d'un voyageur temporel qui vous"
   data "révèlerait le moyen de vivre mille ans, de produire "
   data "gratuitement de l'énergie de façon illimitée,"
   data "de faire la découverte du siècle qui révolutionnerait le "
   data "monde, de faire fortune au delà de toute"
   data "espérance...?  Qui n'a jamais rêvé de construire un "
   data "ordinateur qui permettrait de démultiplier"
   data "son intelligence, sa mémoire et son savoir par cent, par mille "
   data "et jusqu'à l'infini ?"
   data "   Eh bien, ça y est, c'est arrivé. Oui enfin, presque... "
   data ""
   data "Voici un logiciel qui, passé sans doute "
   data "incidemment par une faille temporelle, est directement"
   data "issu du 43° siècle et qui, sans dévoiler "
   data "tous les détails des découvertes majeures inventées"
   data "par nos descendants lointains, en fournit "
   data "quand même certains détails intéressants."
   data "   En fait, il s'agit d'un jeu, une sorte de Mastermind "
   data "alphabétique, un croisement entre un"
   data "Mastermind et un pendu, permettant de se familiariser "
   data "avec le vocabulaire qui sera inventé"
   data "plus tard au fur et à mesure des nouveautés technologiques "
   data "du progrès toujours plus"
   data "exponentiel. Et surtout, le plus important, c'est que le "
   data "logiciel donne la définition de ces mots"
   data "encore inconnus, ce qui nous dévoile une part de ces "
   data "inventions fabuleuses tout droit venues"
   data "d'un futur lointain. Cela ne nous dit certes pas comment "
   data "ça marche, mais cela nous permet"
   data "d'imaginer comment nos arrière-arrière petits enfants "
   data "vivront, ce qui est déjà fabuleux."
   data "   Le jeu consiste à deviner la nature et l'ordre des "
   data "lettres composant un mot qui vous"
   data "sera probablement inconnu, puisqu'il provient tout "
   data "droit du 43° siècle (voir scénario),"
   data "mais dont vous aurez le plaisir d'apprendre la définition, "
   data "si vous réussissez à le trouver."
   data "   L'ordinateur vous aide en vous indiquant, pour "
   data "chaque lettre, la justesse"
   data "ou l'erreur de vos réponses par un code composé "
   data "de 5 couleurs :"
   data "Cette lettre est bien placée "
   data "et elle est la seule de ce type"
   data "Cette lettre est bien placée, "
   data "mais existe en plusieurs exemplaires"
   data "Cette lettre est mal placée "
   data "et elle est la seule de ce type"
   data "Cette lettre est mal placée "
   data "et existe en plusieurs exemplaires"
   data "Cette lettre ne se trouve pas dans ce mot." , ""
rem Fin des datas
No alien No alien No


Dernière édition par jjn4 le Dim 9 Avr 2017 - 15:37, édité 1 fois
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://jjn4.e-monsite.com
Yannick

avatar

Nombre de messages : 8083
Age : 47
Localisation : Bretagne
Date d'inscription : 15/02/2010

MessageSujet: re   Mar 21 Fév 2017 - 1:30

scratch drunken bom geek jocolor affraid
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Jean Claude

avatar

Nombre de messages : 5643
Age : 64
Localisation : 83 Var
Date d'inscription : 07/05/2009

MessageSujet: Re: Maître-expert alphabétique 43° siècle   Mar 21 Fév 2017 - 8:24

C'est pas mal, l'idée est bonne.

Mais ce serait franchement mieux avec des mots réels, cela donnerait plus d'attrait au jeu.

A+
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
papydall

avatar

Nombre de messages : 5991
Age : 68
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: Maître-expert alphabétique 43° siècle   Mar 21 Fév 2017 - 12:59

Du 1er coup ! Je suis le plus fort !!! :
 


Je peux fournir mon astuce (trouver le mot recherché du 1er coup) moyennant une poignée de dollars Martiens !
Toute autre monnaie est refusée.
Les enchères sont ouvertes : proposez les vôtres !

NB : C'est de la triche, je vous préviens. king
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
jjn4

avatar

Nombre de messages : 1761
Date d'inscription : 13/09/2009

MessageSujet: +++   Mer 22 Fév 2017 - 11:01

Citation :
ce serait mieux avec des mots réels
Quelle banalité !
Et où seraient les définitions surprenantes ?
Bon, mais avec quelques modifications du programme,
je peux faire ça aussi...

@Papydall :
N'aurait-tu pas fait en sorte que le caption
du container de la légende donne la solution ?
Ah oui, c'est de la triche !
pirat alien geek
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://jjn4.e-monsite.com
papydall

avatar

Nombre de messages : 5991
Age : 68
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: Maître-expert alphabétique 43° siècle   Mer 22 Fév 2017 - 13:08

Ça m’a énervé de ne pas trouvé (assez vite) la solution), alors j’ai mis mon nez dans le code et … il ne me reste plus qu’à dévoiler le mot à chercher en ajoutant dans le code : Sésame ouvre-toi !. king
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
Marc

avatar

Nombre de messages : 865
Age : 57
Localisation : TOURS
Date d'inscription : 17/03/2014

MessageSujet: Re: Maître-expert alphabétique 43° siècle   Mer 22 Fév 2017 - 14:07

Encore un bravo JJN4 !  cheers

Quelle imagination ! Le martien ne prend jamais de vacances !

C'est un jeu pas facile... scratch
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Contenu sponsorisé




MessageSujet: Re: Maître-expert alphabétique 43° siècle   

Revenir en haut Aller en bas
 
Maître-expert alphabétique 43° siècle
Revenir en haut 
Page 1 sur 1
 Sujets similaires
-
» Lieux enregistrés par ordre alphabétique ?
» [résolu] CLASSEMENT des FAVORIS
» Comment classer les itinéraires et traces?
» Peut-on classer par ordre alphabétique ses adresses sur nüvi 660 ?
» TABLEAU alphabétique évolutif avec liens

Permission de ce forum:Vous ne pouvez pas répondre aux sujets dans ce forum
FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC :: PANORAMIC :: Les jeux faits avec Panoramic-
Sauter vers: