FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC

Développement d'applications avec le langage Panoramic
 
AccueilAccueil  FAQFAQ  RechercherRechercher  S'enregistrerS'enregistrer  MembresMembres  GroupesGroupes  Connexion  
Derniers sujets
» ajouter des blancs dans un TXT
par lepetitmarocain Hier à 13:00

» Planétarium virtuel.
par Oscaribout Mar 14 Aoû 2018 - 19:45

» 11 (en analyse): commandes sur TAB et SUB_MENU.
par Jack Mar 14 Aoû 2018 - 14:10

» 10 (en analyse): Erreur sur variable locale.
par Jack Mar 14 Aoû 2018 - 14:05

» Métamatière, éternité et renouvellement
par Oscaribout Mar 14 Aoû 2018 - 12:40

» De retour...
par Yannick Lun 13 Aoû 2018 - 15:11

» bug SEVERE fnc+sub : (35)name already defined
par Oscaribout Dim 12 Aoû 2018 - 23:55

» Encadrement
par Jean Claude Dim 12 Aoû 2018 - 11:53

» Des rectangles...
par JL35 Dim 12 Aoû 2018 - 10:53

» TRIGGER_KEY_COMBINED_TOUCH
par Jean Claude Mar 7 Aoû 2018 - 20:58

» ITEM_SELECT N,L pour synedit
par Jean Claude Mar 7 Aoû 2018 - 19:11

» amélioration panoramic
par silverman Dim 5 Aoû 2018 - 18:34

» Commande file_readln.
par Pedro Alvarez Dim 5 Aoû 2018 - 17:08

» Klaus ?
par Jack Sam 4 Aoû 2018 - 22:48

» Défragmentation du disque dur
par JL35 Sam 4 Aoû 2018 - 21:06

Navigation
 Portail
 Index
 Membres
 Profil
 FAQ
 Rechercher
Rechercher
 
 

Résultats par :
 
Rechercher Recherche avancée
Août 2018
LunMarMerJeuVenSamDim
  12345
6789101112
13141516171819
20212223242526
2728293031  
CalendrierCalendrier

Partagez | 
 

 Demo Menu Toolbar Image

Aller en bas 
AuteurMessage
Yannick

avatar

Nombre de messages : 8081
Age : 47
Localisation : Bretagne
Date d'inscription : 15/02/2010

MessageSujet: Demo Menu Toolbar Image   Jeu 5 Jan 2017 - 7:57

Je continue dans mon obsession des menus images.
Twisted Evil
Voilà une démo d' une toolbar image avec les dernières commandes
que nous a offert Jack.
Laughing

( le zip avec les images est sur mon webdav )
Code:
variables()
labels()
gui()

end

' ==============================================================================

sub variables()
   dim_local i%

'  incrementation des objets
   dim no%

'  adresse du dossier courrant
   dim path$ : path$=dir_current$
   if right$(path$,1)="" : path$=left$(path$,len(path$)-1) : end_if
   path$=path$+""

'  adresse du dossier image
   dim IMG_path$ : IMG_path$=path$+"img"

'  adresse des images
   dim Tbimg$  : Tbimg$=IMG_path$+"00.bmp"
   dim img$(6) : for i%=1 to 6 : img$(i%)=IMG_path$+"0"+str$(i%)+".bmp" : next i%

'  objets
   dim pan%    : no%=no%+1 : pan%=no%
   dim tbfond% : no%=no%+1 : tbfond%=no%
   dim Btn%(6) : for i%=1 to 6 : no%=no%+1 : Btn%(i%)=no% :next i%
   dim pan2%   : no%=no%+1 : pan2%=no%
   dim alph%   : no%=no%+1 : alph%=no%

'  application
   dim posx%
   dim posy%
   dim ClicBtn%
   dim SurvolBtn%
end_sub

sub labels()
   label ActiveBtn
   label mouse_out
   label clic_down
   label clic_up
   label MenuClic
end_sub

' ==============================================================================

sub gui()
   dim_local i%,l%

   height 0,400
   width 0,600
   top 0,(screen_y-height(0))/2
   left 0,(screen_x-width(0))/2
   color 0,150,196,206
   caption 0,"Démo Toolbar Image"
  
   panel pan%
   height pan%,34
   width pan%,width_client(0)-10
   top pan%,5
   left pan%,5
   color pan%,73,149,166
   on_mouse_move pan%,mouse_out
  
   picture tbfond%
   parent tbfond%,pan%
   height tbfond%,32
   width tbfond%,96
   top tbfond%,1
   left tbfond%,5
   file_load tbfond%,Tbimg$
   cursor_point tbfond%
   on_mouse_move tbfond%,ActiveBtn
  
   create_hide
   for i%=1 to 6
      picture Btn%(i%)
      parent Btn%(i%),pan%
      height Btn%(i%),32
      width Btn%(i%),32
      top Btn%(i%),1
      file_load Btn%(i%),img$(i%)
      if i%=1 or i%=2
         l%=5
         left Btn%(i%),left(tbfond%)
         hint Btn%(i%),"Home"
         if i%=1
            on_mouse_down Btn%(i%),clic_down
            on_mouse_up Btn%(i%),clic_up
            on_click Btn%(i%),MenuClic
         end_if
      end_if
      if i%=3 or i%=4
         l%=42
         left Btn%(i%),left(tbfond%)+32
         hint Btn%(i%),"Preview"
         if i%=3
            on_mouse_down Btn%(i%),clic_down
            on_mouse_up Btn%(i%),clic_up
            on_click Btn%(i%),MenuClic
         end_if
      end_if
      if i%=5 or i%=6
         l%=79
         left Btn%(i%),left(tbfond%)+64
         hint Btn%(i%),"Next"
         if i%=5
            on_mouse_down Btn%(i%),clic_down
            on_mouse_up Btn%(i%),clic_up
            on_click Btn%(i%),MenuClic
         end_if
      end_if
      cursor_point Btn%(i%)
   next i%
   create_show
  
   panel pan2%
   height pan2%,26
   width pan2%,width_client(0)-10
   top pan2%,height_client(0)-height(pan2%)-5
   left pan2%,5
   color pan2%,73,149,166
  
   alpha alph%
   parent alph%,pan2%
   top alph%,5
   left alph%,5
   font_name alph%,"Courier New"
   font_size alph%,12
   font_bold alph%
   font_color alph%,255,255,255
   caption alph%,""
end_sub

' ==============================================================================

ActiveBtn:
   off_mouse_move tbfond%
   posx% = mouse_x_position(tbfond%)
   if posx%>0  and posx%<33
      SurvolBtn%=Btn%(1)
      ClicBtn%=Btn%(2)
      show Btn%(1)
      hide Btn%(3)
      hide Btn%(5)
   else
      if posx%>32 and posx%<65
         SurvolBtn%=Btn%(3)
         ClicBtn%=Btn%(4)
         show Btn%(3)
         hide Btn%(1)
         hide Btn%(5)
      else
         SurvolBtn%=Btn%(5)
         ClicBtn%=Btn%(6)
         show Btn%(5)
         hide Btn%(1)
         hide Btn%(3)
      end_if
   end_if
   on_mouse_move tbfond%,ActiveBtn
return

' ------------------------------------------------------------------------------

mouse_out:
   off_mouse_move pan%
   DeselectAll()
   on_mouse_move pan%,mouse_out
return

' ------------------------------------------------------------------------------

clic_down:
   off_mouse_down SurvolBtn%
      show ClicBtn%
   on_mouse_down SurvolBtn%,clic_down
return

' ------------------------------------------------------------------------------

clic_up:
   off_mouse_up SurvolBtn%
      hide ClicBtn%
   on_mouse_up SurvolBtn%,clic_up
return

' ------------------------------------------------------------------------------

MenuClic:
   if number_click = Btn%(1)
      caption alph%,"Home"
      return
   end_if
   if number_click = Btn%(3)
      caption alph%,"Preview"
      return
   end_if
   if number_click = Btn%(5)
      caption alph%,"Next"
      return
   end_if
return

' ==============================================================================

sub DeselectAll()
   dim_local i%
   for i%=1 to 6 step 3 : hide Btn%(i%) : next i%
   for i%=2 to 6 step 3 : hide Btn%(i%) : next i%
end_sub

Pour avoir vos propres images :

image de fond de la toolbar : (00.bmp) 32x96px
les 3 images de survol (01.bmp,03.bmp,05.bmp) 32x32px
les 3 images de clic (02.bmp,04.bmp,06.bmp) 32x32px
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Jean Claude

avatar

Nombre de messages : 5574
Age : 64
Localisation : 83 Var
Date d'inscription : 07/05/2009

MessageSujet: Re: Demo Menu Toolbar Image   Jeu 5 Jan 2017 - 8:07

Salut Ygeronimi,
Je viens de tester.

Jolie et fonctionnel.
Enfin une toolbar avec images et 100% Panoramic.

cheers
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Yannick

avatar

Nombre de messages : 8081
Age : 47
Localisation : Bretagne
Date d'inscription : 15/02/2010

MessageSujet: re   Jeu 5 Jan 2017 - 8:26

Merci Jean Claude.

Là où mon cerveau a le plus chauffé c' est pour récupérer l' objet concerné
et simulé un "Mouse_Move (N)". 
Je me voyais mal créer 3 label par bouton (imagine une barre avec 20 boutons Wink ).

Peut être une prochaine demande pour Jack. Twisted Evil
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Contenu sponsorisé




MessageSujet: Re: Demo Menu Toolbar Image   

Revenir en haut Aller en bas
 
Demo Menu Toolbar Image
Revenir en haut 
Page 1 sur 1
 Sujets similaires
-
» [Demo] Pierre Michel, l’Orfèvre de l’Image
» roll-over, zone réactive, image et son
» [résolu] Lien dans image survolée vers page html
» agrandir reduire une image en son centre
» [VX]Dark earth[Stopper]

Permission de ce forum:Vous ne pouvez pas répondre aux sujets dans ce forum
FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC :: PANORAMIC :: Vos sources, vos utilitaires à partager-
Sauter vers: