FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC

Développement d'applications avec le langage Panoramic
 
AccueilAccueil  FAQFAQ  RechercherRechercher  S'enregistrerS'enregistrer  MembresMembres  GroupesGroupes  Connexion  
Derniers sujets
» Calculatrice
par papydall Hier à 22:54

» EPP_V01 éditeur pour Panoramic
par Minibug Mer 19 Sep 2018 - 21:03

» [RESOLU] Quelle ligne est sélectionnée dans SYNEDIT ?
par Jean Claude Mer 19 Sep 2018 - 21:02

» PanExpress : l'éditeur Panoramic avec création d'objet
par Minibug Mer 19 Sep 2018 - 15:58

» Planétarium virtuel.
par Pedro Alvarez Mer 19 Sep 2018 - 9:28

» Demande pour Jack concernant PanExpress
par Marc Mar 18 Sep 2018 - 23:56

» Petit coucou en passant !
par Minibug Dim 16 Sep 2018 - 15:03

» bug SEVERE fnc+sub : variables globales corrompus
par silverman Dim 16 Sep 2018 - 13:38

» Verrouiller un form en avant plan
par silverman Dim 16 Sep 2018 - 12:50

» Fin de l'aventure.
par Pedro Alvarez Sam 15 Sep 2018 - 18:16

» Demande d'explications Sur File_Write & File_writeln
par Jack Sam 15 Sep 2018 - 17:26

» MEMO avec des possibilités de commande
par Oscaribout Mer 12 Sep 2018 - 1:06

» La théorie du chaos
par jean_debord Mar 11 Sep 2018 - 9:30

» Orbites de l’ensemble de Mandelbrot
par Jean Claude Lun 10 Sep 2018 - 21:08

» Version instantanée V 0.9.29i2 du 4/09/2018
par silverman Mer 5 Sep 2018 - 10:15

Navigation
 Portail
 Index
 Membres
 Profil
 FAQ
 Rechercher
Rechercher
 
 

Résultats par :
 
Rechercher Recherche avancée
Septembre 2018
LunMarMerJeuVenSamDim
     12
3456789
10111213141516
17181920212223
24252627282930
CalendrierCalendrier

Partagez | 
 

 Le jeu des 6 palets

Aller en bas 
AuteurMessage
Marc

avatar

Nombre de messages : 865
Age : 57
Localisation : TOURS
Date d'inscription : 17/03/2014

MessageSujet: Le jeu des 6 palets   Mer 28 Déc 2016 - 0:19

Bonjour à tous !

Le jeu des six palets consiste à recouvrir la totalité d’un cercle blanc avec 6 palets.
On rencontre ce jeu sur les fêtes foraines.

Voici une  version pour ordinateur  très "sprite" :
- Les palets sont des sprites ;
- L’image de fond est un sprite ;
- Les écritures sont des sprites.

Il se joue avec la souris.
Il est en noir et blanc, libre à chacun de le coloriser !

A vos souris !

Spritement vôtre !
Code:
' ------------------------------------------------------------------------------
'  JEU DES 6 PALETS
'  MARC37 - Décembre 2016 - Panoramic v0.9.27.i8
'  http://panoramic-language.pagesperso-orange.fr/French/index.html
' ------------------------------------------------------------------------------
DIM x%,y%,F%,G%
DIM jeu%
WIDTH 0, 800
HEIGHT 0, 700
LEFT 0,(screen_x-800)/2
TOP 0,(screen_y-700)/2

LABEL Quitter

ON_CLOSE 0, Quitter

Creation_jeu()

Jeu%=6

WHILE 0=0
   G%= MOUSE_LEFT_UP(10)
   F%= MOUSE_LEFT_DOWN(10)
   IF F% = 1 THEN Zone_cliquee()
END_WHILE

END
' ------------------------------------------------------------------------------
SUB Zone_cliquee()
    x%= MOUSE_X_POSITION(10)
    y%= MOUSE_Y_POSITION(10)
    IF Jeu%>0 AND x%>580 AND x%<720 AND y%>280 AND y%<420 THEN saisie_depose()
    IF y%>600 AND y%<630
        IF x%>635 AND x%<735 THEN TERMINATE
        IF x%>500 AND x%<560 THEN Aide()
        IF x%>50 AND x%<150 THEN Rejouer()
        IF x%>230 AND x%<420 THEN Demonstration()
    END_IF
END_SUB
' ------------------------------------------------------------------------------
SUB saisie_depose()
    WHILE Jeu% > 0
        x%= MOUSE_X_POSITION(10)
        y%= MOUSE_Y_POSITION(10)
        SPRITE_X_POSITION Jeu%, x%-100
        SPRITE_Y_POSITION Jeu%, y%-100
        IF MOUSE_LEFT_UP(10)=1 then Jeu%=Jeu%-1 : EXIT_WHILE
    END_WHILE
END_SUB
' ------------------------------------------------------------------------------
SUB Creation_jeu()
    Creation_dessin_palets()
    Creation_image_de_fond()
END_SUB
' ------------------------------------------------------------------------------
SUB Creation_dessin_palets()
    DIM_LOCAL i%
    2D_PEN_COLOR 50,50,50 : ' couleur contour palets
    2D_CIRCLE 101,100,100
    2D_FLOOD 260,260,0,0,0
    FOR i% = 1 to 6
        2D_FLOOD 100,100,150,150,150 : ' couleur palets
        2D_CIRCLE 101,100,100
        IMAGE i%
        2D_IMAGE_COPY i%,0,0,201,200
    NEXT i%
END_SUB
' ------------------------------------------------------------------------------
SUB Creation_image_de_fond()
    CLS
    2D_PEN_COLOR 50,50,50
    2D_CIRCLE 300,300,179
    2D_FLOOD 260,260,240,240,240 : ' couleur grand cercle
    2D_FLOOD 1,1,50,50,50 : ' couleur de fond
    IMAGE 7
    2D_IMAGE_COPY 7,0,0,800,700
    SCENE2D 10
    FULL_SPACE 10
    SPRITE 7
    SPRITE_IMAGE_LOAD 7,7
    SPRITE 10
    FONT_NAME 10,"arial"
    FONT_SIZE 10,20
    FONT_BOLD 10
    FONT_COLOR 10,255,0,0 : ' couleur des textes
    FONT_ITALIC 10
    SPRITE_TEXT 10," Rejouer "
    SPRITE_X_POSITION 10, 43
    SPRITE_Y_POSITION 10, 600
    SPRITE 11
    SPRITE_TEXT 11," Démonstration "
    SPRITE_X_POSITION 11, 220
    SPRITE_Y_POSITION 11, 600
    SPRITE 12
    SPRITE_TEXT 12," Aide "
    SPRITE_X_POSITION 12, 495
    SPRITE_Y_POSITION 12, 600
    SPRITE 13
    SPRITE_TEXT 13," Quitter "
    SPRITE_X_POSITION 13, 630
    SPRITE_Y_POSITION 13, 600
    DIM_LOCAL i%
    ' *************** Création SPRITES palets
    FOR i% = 6 to 1 STEP -1
        SPRITE i%
        SPRITE_IMAGE_LOAD i%,i%
        SPRITE_X_POSITION i%, (i%*-1)+550
        SPRITE_Y_POSITION i%, i%*2+250
    NEXT i%
    SPRITE_CREATE_HIDE
    SPRITE 14
    FONT_SIZE 10,50
    FONT_BOLD_OFF 10
    SPRITE_TEXT 14," SPECIMEN "
    SPRITE_POSITION 14, 105,270
END_SUB
' ------------------------------------------------------------------------------
SUB Aide()
    DIM_LOCAL Txt$
    Txt$="Jeu des 6 palets :"+CHR$(13)+CHR$(13)
    Txt$ = Txt$ + "Le but du jeu est de recouvrir TOTALEMENT le cercle blanc"+CHR$(13)
    Txt$ = Txt$ + "avec les 6 palets. Un seul pixel blanc restant visible et c'est perdu !"+CHR$(13)
    Txt$ = Txt$ + "A l'aide la souris, déplacez chaque palet."+CHR$(13)
    Txt$ = Txt$ + "Un palet laché est un palet joué : vous ne pouvez plus le déplacer !"+CHR$(13)+CHR$(13)
    Txt$ = Txt$ + "Marc37 - décembre 2016 - Programmé en langage PANORAMIC v0.9.27i8"+CHR$(13)+CHR$(13)
    Txt$ = Txt$ + "http://panoramic-language.pagesperso-orange.fr/French/index.html"
    MESSAGE Txt$
END_SUB
' ------------------------------------------------------------------------------
SUB Demonstration()
    Rejouer()
    SPRITE_SHOW 14
    Deplacer_sprite(6,550,250,83 ,114,16)
    Deplacer_sprite(5,550,250,105,247,16)
    Deplacer_sprite(4,550,250,198,339,16)
    Deplacer_sprite(3,550,250,201,111,16)
    Deplacer_sprite(2,550,250,321,118,16)
    Deplacer_sprite(1,550,250,289,248,16)
END_SUB
' ------------------------------------------------------------------------------
SUB Deplacer_sprite(Num_Sprite%,xa%,ya%,xb%,yb%,vitesse)
    DIM_LOCAL distance, nbpoints%,i%,xp%,yp%
    distance = SQR(POWER((xb%-xa%),2)+ POWER((yb%-ya%),2))
    NbPoints% = INT(Distance / vitesse)
    FOR i% = 1 to nbpoints%
        xp%=INT(((xb%-xa%)/nbpoints%) *i%)+xa%
        yp%=INT(((yb%-ya%)/nbpoints%) *i%)+ya%
        SPRITE_POSITION Num_Sprite%, xp%, yp%
    NEXT i%
    SPRITE_POSITION Num_Sprite%, xb%, yb%
END_SUB
' ------------------------------------------------------------------------------
SUB Rejouer()
    SPRITE_HIDE 14
    DIM_LOCAL i%
    Jeu%=6
    FOR i% = 6 to 1 STEP -1
        SPRITE_X_POSITION i%, (i%*-1)+550
        SPRITE_Y_POSITION i%, i%*2+250
    NEXT i%
END_SUB
' ------------------------------------------------------------------------------
Quitter:
    Jeu%= 0
    TERMINATE
RETURN
' ------------------------------------------------------------------------------
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
Minibug

avatar

Nombre de messages : 3021
Age : 51
Localisation : Vienne (86)
Date d'inscription : 09/02/2012

MessageSujet: Re: Le jeu des 6 palets   Mer 28 Déc 2016 - 8:12

Bonjour Marc37 !

Pas si simple que ça en a l'aire...
Voila encore un jeu bien tordu !

lol! lol! lol! lol!
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://gpp.panoramic.free.fr
Jean Claude

avatar

Nombre de messages : 5643
Age : 64
Localisation : 83 Var
Date d'inscription : 07/05/2009

MessageSujet: Re: Le jeu des 6 palets   Mer 28 Déc 2016 - 9:35

Effectivement,
Même avec la démonstration, très difficile d'y arriver. Alors s'il n'y en avait pas, de démo, ça deviendrait un bon casse-tête.

Bravo Marc, excellent jeu.
Revenir en haut Aller en bas
Voir le profil de l'utilisateur
papydall

avatar

Nombre de messages : 5991
Age : 68
Localisation : Moknine (Tunisie) Entre la chaise et le clavier
Date d'inscription : 03/03/2012

MessageSujet: Re: Le jeu des 6 palets   Mer 28 Déc 2016 - 11:25

Salut tout le monde


Minibug a écrit:
Pas si simple que ça en a l'aire...

Je dirais même plus : Pas si simple que ça en a la surface !
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://papydall-panoramic.forumarabia.com/
Minibug

avatar

Nombre de messages : 3021
Age : 51
Localisation : Vienne (86)
Date d'inscription : 09/02/2012

MessageSujet: Re: Le jeu des 6 palets   Mer 28 Déc 2016 - 13:46

En voila au moins 1 qui a compris le jeu de mot !
Bravo Papydall ! cheers
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://gpp.panoramic.free.fr
jjn4

avatar

Nombre de messages : 1761
Date d'inscription : 13/09/2009

MessageSujet: +++   Mer 28 Déc 2016 - 14:01

Effectivement, c'est drôlement dur, ce truc !
Félicitation, Marc37, très beau jeu !
cheers alien santa
Revenir en haut Aller en bas
Voir le profil de l'utilisateur http://jjn4.e-monsite.com
Contenu sponsorisé




MessageSujet: Re: Le jeu des 6 palets   

Revenir en haut Aller en bas
 
Le jeu des 6 palets
Revenir en haut 
Page 1 sur 1
 Sujets similaires
-
» Le jeu des 6 palets

Permission de ce forum:Vous ne pouvez pas répondre aux sujets dans ce forum
FORUM DE DISCUSSION SUR LE LANGAGE PANORAMIC :: PANORAMIC :: Les jeux faits avec Panoramic-
Sauter vers: