Capture des replay TV

Sujet: Capture des replay TV Sam 31 Jan 2015 - 17:54

Pour pouvoir télécharger une émission ou une série qu'on a raté, on verra qu'il y a un très grand choix.

En fait, le programme ci-dessous n'est qu'une interface avec le vrai programme de capture: Captvty.exe, que l'on peut trouver ici, à la source: http://captvty.fr sous forme d'auto-extractible ou de zip (gratuit, évidemment).
L'avantage c'est qu'il est portable et on peut donc l'installer n'importe où.

Pour ma part, j'ai tout regroupé dans un seul dossier C:\Captvty, les exécutables, les fichiers annexes et les fichiers résultats de captures (sous-répertoire Vidéos), comme ça je sais où sont mes affaires.

L'interface permet de lister les fichiers existants (avec taille et durée), de les visualiser, et/ou de nettoyer le répertoire des vidéos.
J'ai un outil qui va lire la durée dans le fichier (Exiftool) mais si cet outil n'est pas présent je fais un calcul approximatif en fonction de la taille du fichier.

Le programme est tout simple, c'est captvty qui fait tout le boulot !

Code:: ' Captvty_lanc: Lancement de Captvty (capture de rattrapage TV)
' Tous les programmes et fichiers sont regroupés dans un même répertoire: C:\Captvty
LABEL Quit, Dirtv, Suptout, Exec, Voir
DIM dsk$,rp$,rv$,fd$,ec$,cptv$,ffm$,a$,b$,c$,d$,t$,r$,i%,j%,u,h%,m%,s%

dsk$ = LEFT$(DIR_CURRENT$,3): ' volume de travail
rp$ = dsk$+"Captvty\"
rv$ = rp$+"Vidéos\"
cptv$ = rp$+"Captvty.exe"
' Chemin éventuel de ffmpeg
ffm$ = "C:\UTIL\ffmpeg.exe": ' facultatif (durée vidéo, sinon elle sera estimée)
IF DIR_EXISTS(rp$)=0 THEN DIR_MAKE rp$
IF DIR_EXISTS(rv$)=0 THEN DIR_MAKE rv$
IF FILE_EXISTS(cptv$)=0 THEN MESSAGE "Exécutable Captvty.exe non trouvé !": TERMINATE
WIDTH 0,640: HEIGHT 0,520: BORDER_SMALL 0: ' COLOR 0,255,0,0
CAPTION 0," = CAPTURE DES REPLAY TV ="
FONT_NAME 0,"Arial": FONT_SIZE 0,11: COLOR 0,200,255,255: ON_CLOSE 0,Quit
BUTTON 20: TOP 20,10: LEFT 20,20: WIDTH 20,240: CAPTION 20,"Supprimer tout le contenu actuel"
ON_CLICK 20,Suptout
BUTTON 25: TOP 25,TOP(20): LEFT 25,WIDTH(0)/2: WIDTH 25,240: CAPTION 25,"Lancer le programme de capture"
ON_CLICK 25,Exec
CHECK 26: TOP 26,TOP(25)+30: LEFT 26,LEFT(25)+20: WIDTH 26,250
CAPTION 26,"Arrêter le pc en fin de capture"
CONTAINER 1: TOP 1,0: LEFT 1,0: WIDTH 1,WIDTH(0)-16: HEIGHT 1,280: COLOR 1,255,0,0: HIDE 1
MEMO 2: PARENT 2,1: TOP 2,7: LEFT 2,50: WIDTH 2,WIDTH(1)-100: HEIGHT 2,HEIGHT(1)-20
COLOR 2,255,220,220: FONT_NAME 2,"Arial": FONT_SIZE 2,11
r$ = CHR$(13)+CHR$(10)
a$ = " Dans la fenêtre de Captvty, cliquer l'icône de la chaîne, à gauche:"
a$=a$+r$+" -> Chargement de la liste des émissions disponibles."
a$=a$+r$+" - cliquer sur un élément pour afficher le résumé de l'émission"
a$=a$+r$+" - double-clic sur l'élément pour lancer le téléchargement"
a$=a$+r$+" -> dans C:\Captvty\Vidéos (format MPEG-2 TS)"
a$=a$+r$+" On peut suivre la progression dans l'onglet 'Téléchargement'"
a$=a$+r$+" (NB: on peut lancer plusieurs téléchargements en même temps)."+r$
a$=a$+r$+" *********************** Conversion au format MPEG-4: ***********************"
a$=a$+r$+" Onglet Conversion, cliquer 'Vidéos' en bas. S'il n'y est pas, glisser/déposer"
a$=a$+r$+" le fichier capturé dans la fenêtre, puis cliquer la conversion désirée, en bas"
a$=a$+r$+" (MPEG-4)"
a$=a$+r$+" ********************* Conversion (externe) au format AVI: *********************"
a$=a$+r$+" avec FormatFactory."
ITEM_ADD 2,a$
ALPHA 9: TOP 9,TOP(1)+HEIGHT(1): LEFT 9,WIDTH(0)/2-100: CAPTION 9,"Contenu de "+rv$
FONT_BOLD 9
ALPHA 14: TOP 14,TOP(9)+18: LEFT 14,0: FONT_ITALIC 14: FONT_SIZE 14,10
CAPTION 14," Taille: Durée:"
IF FILE_EXISTS(ffm$)= 0 THEN CAPTION 14,"Taille: Durée(~):"
ALPHA 15: TOP 15,TOP(9)+18: LEFT 15,LEFT(9)+15
CAPTION 15,"(cliquer un article pour le voir)": FONT_ITALIC 15
LIST 30: TOP 30,TOP(15)+18: WIDTH 30,65: HEIGHT 30,HEIGHT(0)-HEIGHT(1)-70
LIST 31: TOP 31,TOP(30): LEFT 31,WIDTH(30): WIDTH 31,55: HEIGHT 31,HEIGHT(30)
FONT_SIZE 30,10: FONT_SIZE 31,10
LIST 10: TOP 10,TOP(30): LEFT 10,LEFT(31)+WIDTH(31): WIDTH 10,WIDTH(0)-WIDTH(30)-WIDTH(31)-16: HEIGHT 10,HEIGHT(30)
COLOR 10,255,255,190: FONT_SIZE 10,10: ON_CLICK 10,Voir
MEMO 11: LEFT 11,-1000: WIDTH 11,1200: HIDE 11
MEMO 12: WIDTH 12,600: HIDE 12
GOSUB Dirtv
END
' ==============================================================================
Quit:
TERMINATE
' ==============================================================================
Dirtv:
EXECUTE_WAIT "CMD.exe /C DIR /-C "+rv$+" | clip"
CLEAR 10: CLEAR 11: CLEAR 30: CLEAR 31: CLIPBOARD_PASTE 11
IF COUNT(11) > 0
FOR i%=1 TO COUNT(11)
a$ = ITEM_READ$(11,i%)
IF a$<>"" AND LEFT$(a$,1)<>" " AND MID$(a$,22,5)<>"<REP>"
t$ = LTRIM$(MID$(a$,18,18)): t$ = LEFT$(t$,LEN(t$)-5)
t$=LEFT$(t$,LEN(t$)-1)+"."+RIGHT$(t$,1)
a$ = RIGHT_POS$(a$,37)
d$ = ""
FileShort(rv$+a$): b$=CLIPBOARD_STRING_PASTE$
IF FILE_EXISTS(ffm$)=1
VideoDuree(b$): d$ = CLIPBOARD_STRING_PASTE$
ELSE
u=VAL(t$): j%=u/.190: ' très approximatif, en secondes
h% = INT(j%/3600): m%=INT(j%-h%*3600)/60:s%=j%-h%*3600-m%*60
d$ = STR$(h%)+":"+RIGHT$("0"+STR$(m%),2)+":"+RIGHT$("0"+STR$(s%),2)
END_IF
ITEM_ADD 10,a$: ITEM_ADD 30,t$+" M": ITEM_ADD 31,d$
END_IF
NEXT i%
END_IF
RETURN
' ==============================================================================
Suptout:
a$ = "Suppression définitive de tous les articles du répertoire Vidéos ?"
i% = MESSAGE_CONFIRMATION_YES_NO(a$)
IF i% = 1
EXECUTE_WAIT "CMD.exe /C DEL /Q "+rv$+"\*.*"
GOSUB Dirtv
END_IF
RETURN
' ==============================================================================
Exec:
HIDE 20: HIDE 25: SHOW 1
EXECUTE_WAIT cptv$
IF CHECKED(26) = 1
EXECUTE "Cmd.exe /c %windir%\system32\Shutdown.exe -f -s -t 0": ' Arrêt du pc
ELSE
GOSUB Dirtv
END_IF
RETURN
' ==============================================================================
Voir:
i% = ITEM_INDEX(10): ' Aperçu (ou visualisation complète...) de l'article choisi
IF i%>0 AND i%<=COUNT(10)
a$ = rv$+ITEM_READ$(10,i%): FileShort(a$): a$ = CLIPBOARD_STRING_PASTE$
EXECUTE_WAIT a$
END_IF
RETURN
' ==============================================================================
SUB FileShort(f$)
' Conversion chemin de f$ en chemin 'court' format Ms-Dos 8.3 -> clipboard
EXECUTE_WAIT "cmd /c for %A in ("+CHR$(34)+f$+CHR$(34)+") do @echo %~sA | clip"
CLIPBOARD_STRING_COPY LEFT$(CLIPBOARD_STRING_PASTE$, LEN(CLIPBOARD_STRING_PASTE$)-3)
END_SUB
' ==============================================================================
SUB VideoDuree(f$)
' Durée d'une vidéo, résultat dans le clipboard sous la forme hh:mm:ss
' (ffm$ = chemin de ffmpeg.exe)
DIM_LOCAL finf$, a$
finf$ = "Z:\Infos.txt"
EXECUTE_WAIT "CMD.exe /C "+ffm$ + " -i " + CHR$(34)+f$+CHR$(34) + " 2> "+ finf$
FILE_OPEN_READ 9,finf$
WHILE FILE_EOF(9)=0
FILE_READLN 9,a$
IF LEFT$(a$,10)=" Duration"
a$ = MID$(a$,13,8): CLIPBOARD_STRING_COPY a$: EXIT_WHILE
END_IF
END_WHILE
FILE_CLOSE 9: FILE_DELETE finf$
END_SUB
' ==============================================================================

PS Modif 21h15: ajout du choix d'arrêter le pc en fin d'enregistrement.
Modif 1/2 : durée vidéo, et ajout de on_close 0
Modif 2/2 : bug erreur d'affichage de taille si fichier >= 1G

Sujet: Re: Capture des replay TV Sam 31 Jan 2015 - 19:02

Je viens de voir ton poste, j'ai pas le temps maintenant (je suis en cuisine).

Mais j'y regarderai demain, car çà m'intéresse fortement.

A+

Sujet: re Sam 31 Jan 2015 - 19:18

Encore un truc génial de JL35 !

Je garde pour plus tard, PPE me prend tout mon temps libre en ce moment.

Sujet: Re: Capture des replay TV Sam 31 Jan 2015 - 20:32

C'est vrai qu'il y a un énorme choix dans les replays, et ça peut remonter assez loin dans le temps, mais que des séries, émissions diverses etc., mais pas de films, je pense que légalement c'est interdit, donc on n'en propose pas.

Pour le format capté c'est au format .TS, lisible sur le pc et peut-être sur la tv, avec transport sur clé usb, mais sinon on peut convertir en MPEG-4, plus universel, dans le programme lui-même (voir le mode d'emploi succinct dans la fenêtre, mais c'est tellement simple).

Sujet: re Sam 31 Jan 2015 - 20:53

@ JL35,

Le truc c' est que la redif est active une semaine et que le trois quart du temps tu as plusieurs trucs bien le même soir ou...rien.
Et c' est parfois pas simple de regarder un replay dans le delai.
Pour les films, ils avancent une question de droits d' auteur comme pour les enregistreurs
sur les décodeurs.
C' est un peu de la foutaise, on peut bien les enregistrer sur dvd ou vhs.

Sujet: Re: Capture des replay TV Sam 31 Jan 2015 - 21:14

Perso je vois plutôt ça comme une solution de secours, on n'a pas pu voir une émission pour une raison quelconque, on la télécharge dans les jours qui suivent, mais je n'imagine pas trop un usage intensif ?
Une semaine, si c'est ça, ça me paraît quand même pas mal pour rattraper une émission !

Remarque qu'on peut lancer plusieurs téléchargement en même temps, et puis aller faire un tour, ça peut être long.

Pour les films, ça peut se comprendre, c'est protégé, je laisse aux petits malins le soin de trouver une solution de rechange... à la limite de la légalité évidemment Very Happy

Je précise (ma fille avait des doutes...) qu'une fois le pc arrêté il ne se passe évidemment plus rien, et si on l'arrête avant la fin il faudra tout reprendre ensuite (même si la partie qui a été enregistrée est regardable).

Je viens de faire une modif (déjà) dans cet esprit: j'ai ajouté un check qui permet d'arrêter automatiquement le pc à la fin des enregistrements si on le désire, ça marche. Mais bon, ça ne bascule quand même pas l'interrupteur éventuel, mais le pc est arrêté et le moniteur éteint (en veille).

Sujet: Re: Capture des replay TV Sam 31 Jan 2015 - 21:27

Vite fait, sinon je vais me faire appeler Jules....

L'intérêt que je trouve (je n'ai pas encore essayé ton programme) au replay, c'est le plus souvent de revoir une émission de recette de cuisine pour prendre le temps de tout noter et de voir comment le cuistot s'y prend. Very Happy

Je ne télécharge pas de film, pas plus que de musique, car je pense que les artistes ont besoin d'avoir le revenu de leur production, donc j'achète CD ou DVD. Mais çà, c'est moi, je ne reproche rien aux autres.

Je regarde ton programme, JL35, demain.

A+

Sujet: Re: Capture des replay TV Sam 31 Jan 2015 - 22:01

C'est à peu près comme ça que je l'entends.
(mais moi j'enregistre les recettes pour mon épouse... Very Happy

)
Et il y a plein d'autres raisons, à chacun d'en faire l'usage qu'il veut. C'est déjà bien que ça existe.

oui

Moi j'ai de la chance, j'ai la plupart des replay déjà sur la box, mais les sites on parfois des replay bcp plus longtemps ce qui peut dépanner dans certains cas. Merci pour cette interface / partage d'astuce.

@JL35
Ton programme bloque à la ligne 77:

Code:: u=VAL(t$): j%=int(u/.190): ' approximatif, en secondes

Not correct expression in fonction.....

Pour ce qui est de captvty.exe , c'est super, c'est un outil génial. Grand merci pour l'info.

A+

Nombre de messages : 7095 Localisation : 77 Date d'inscription : 29/11/2007

Salut Jean Claude,
Je n'ai pas ce problème chez moi, en essayant je constate que ça peut arriver si tu as t$ vide, mais je n'arrive pas à le reproduire en fonctionnement normal, que le répertoire Vidéos soit vide ou occupé... t$ étant la taille du fichier récupérée dans le DIR.
Essaie de mettre un 'Message' pour voir ce que tu as dans t$ avant l'incident ?

oui, ou fais un if t$ <> ""
u=val(t$) ...

else
traitement du cas par ce que ça n'a pas de sens si c'est vide
end_if

Nombre de messages : 7095 Localisation : 77 Date d'inscription : 29/11/2007

D'accord, mais c'est quand même curieux, t$ est la taille du fichier extraite du DIR, ça ne devrait jamais être vide... ?

J'en profite pour préciser que la durée des vidéos calculée ainsi est très approximative (à partir d'un taux de 190 kb/s, ce facteur étant très variable en fonction de la taille des fichiers), et il vaut mieux ne pas trop en tenir compte.
Si on en a besoin, il vaut mieux faire appel à un outil externe (Exiftool ou ffmpeg, ou autre), mais je n'ai pas trouvé (j'ai cherché) où on peut aller lire cette durée dans le fichier, je subodore que ce n'est pas simple du tout.

Bonjour tout le monde
Bonjour JL35
L’erreur signalée par Jean Claude survient dans les conditions suivantes :
On lance le programme de capture
On choisit une chaîne
On choisit une émission
Puis on quitte le programme sans rien faire d’autre.

Edit :
On lance le programme et on le quitte par la croix rouge sans fermer au préalable la fenêtre de Captvty provoque l'erreur.

Nombre de messages : 7095 Localisation : 77 Date d'inscription : 29/11/2007

Bonjour papydall,
Ben non, je ne vois pas trop, quoi qu'on fasse dans la fenêtre de captvty.exe ça n'a aucune influence sur l'interface panoramic, simplement au retour (après fermeture, sur un clic croix rouge) on refait un DIR pour mettre à jour la liste des fichiers (s/p Dirtv).
Je n'arrive pas à reproduire cette erreur.

PS oui je vois mieux: on lance captvty, et sans fermer sa fenêtre on ferme le programme panoramic par le clic sur la croix, là ça produit effectivement une erreur, mais bon, il faut le faire exprès.
On peut facilement remédier en faisant un On_Close 0 sur un TERMINATE.

PS2 Pour la durée de la vidéo, comme outil externe, Exiftool est beaucoup trop long à l'exécution, il vaut mieux utiliser ffmpeg qui est très rapide et bien plus universel (et facile à trouver).
Je modifie là-haut pour ces petites mises à jour (y compris le on_close 0 pour l'erreur Jean Claude)

Changer (ligne 77)

Code:: u=VAL(t$): j%=u/.190: ' approximatif, en secondes

Par

Code:: if numeric(t$) > 0 then u=VAL(t$): j%=u/.190: ' approximatif, en secondes

et ça sera OK.

L’erreur survient quand :
Le dossier Videos n’est pas vide et que l’on quitte le programme par la croix rouge sans fermer la fenêtre de Captvty

Le test

Code:: if numeric(t$) > 0 then u=VAL(t$): j%=u/.190: ' approximatif, en secondes

résoud le problème.

Nombre de messages : 7095 Localisation : 77 Date d'inscription : 29/11/2007

Ou comme j'ai fait: clic croix rouge -> Terminate, et là on ferme le tout sans se poser de questions.
Mais ta solution est complémentaire.
Mais d'ailleurs je ne vois pas bien pourquoi le programme cherche à exécuter encore quelque chose alors qu'on clique sur la croix rouge...

JL35 a écrit:: Ou comme j'ai fait: clic croix rouge -> Terminate, et là on ferme le tout sans se poser de questions.
Mais ta solution est complémentaire.
Mais d'ailleurs je ne vois pas bien pourquoi le programme cherche à exécuter encore quelque chose alors qu'on clique sur la croix rouge...

En réalité TOUT n’est pas fermé ; c’est seulement le programme Panoramic qui est fermé, tandis que Captvty.exe continue à tourner : la preuve, sa fenêtre est ouverte.
Pour tout fermer, on doit aussi fermer la fenêtre de Captvty.exe
Le sous-programme Quit : sera

Code:: quit:
EXECUTE_WAIT "cmd /c taskkill /f /im Captvty.exe" : ' Tuer le pocessus
TERMINATE
RETURN

Qu'en penses-tu ?

Nombre de messages : 7095 Localisation : 77 Date d'inscription : 29/11/2007

Evidemment mais je parlais uniquement dans le cas que tu as cité: on peut vouloir laisser tourner captvty.exe pour un ou des téléchargements, et fermer mon programme d'interface en panoramic (clic sur la croix): c'est là que ça coince et qu'il cherche à exécuter je ne sais quoi et qu'il part en erreur.
Avec le On_Close vers un Terminate, là plus de problèmes, fermeture radicale, et Captvty continue à tourner tout seul.

Salut,
Bon, j'ai réussi à faire fonctionner le programme. Comme d'habitude c'était un problème de chemin.

j'ai créer le dossier "captvty" et dézippé à l'intérieur et là ça marche (à condition de lancer au moins 2 fois le programme Panoramic).

Reste à tester.

A+

Nombre de messages : 7095 Localisation : 77 Date d'inscription : 29/11/2007

A remarquer qu'il est possible de regarder ou enregistrer une chaîne en direct (clic droit sur le nom de la chaîne), j'ai essayé mais j'ai des coupures...
Ca permettrait théoriquement d'enregistrer un film qui passe (je ne sais pas si c'est trop légal), mais a priori mon expérience est décevante. A tester en tout cas.

Il semble que c'est ma connexion internet qui n'est pas assez performante, si je me mets en définition minimum ça marche, mais ce n'est guère exploitable (sauf peut-être sur l'ordinateur de Jicehel 1024x768 Very Happy

).

Correction bug d'affichage de la taille si fichier >= 1G
Malgré pas mal de recherches, je n'ai pas trouvé le moyen de lire dans le fichier la durée de la vidéo, si quelqu'un a une idée... c'est quand même bête d'être obligé de faire appel à un outil externe.

Je modère ce que je disais plus haut à propos de l'enregistrement en direct d'une chaîne, en fait je regardais, et là c'était figé par moments, mais en enregistrement la qualité est bonne. Et on a évidemment le droit d'enregistrer n'importe quoi en direct, y compris les films, puisqu'on le fait bien avec d'autres procédés (décodeurs, magnétoscopes etc.)

» Capture d'écran
» Capture écran
» Capture vidéo et audio sur le web
» Capture d'écran (autre)
» Capture d'écran de Windows