MesMots

Nombre de messages : 586 Date d'inscription : 06/01/2012

Bonjour ! Je viens de terminer une version un peu améliorée (mais il y manque encore une aide) d'un programme simple, celui de mes deux articles dans PLM, lequel permet de jouer à fabriquer des mots d'une syllabe à partir d'un début (b ch cl...), d'un milieu (a ou...) et d'une fin (c t l etc.

Il nécessite cinq fichiers texte à créer au préalable d'un clic droit dans le même dossier, nommés debut (sans accent) milieu fin mots et refus. En cliquant dans les zones vertes en haut, on ajoute des éléments qu'on peut également supprimer d'un clic; Le mot s'affiche en bas, on le prend ou on le laisse... et on retrouve le tout enregistré dans les fichiers !

Je compte le tester d'ici peu dans mon école...

Code:: caption 0,"Mes mots d'une syllabe"

dim i%,n%,nn%,nnn%,obj%,mot$,f$,flag

  for i%=1 to 3
   n%=i%+50
   EDIT n%:color n%,144,195,66:top n%,30:left n%,i%*121
   font_size n%,14
  next i%

LABEL debut,milieu,fin,ajout,mot,vide_ligne,vide_debut,vide_milieu,vide_fin,vide_tout
LABEL verif_mot,ajoute_mot,prends,laisse,save

  for i%=1 to 3
   n%=i%+100
   LIST n%:color n%,223,233,206:top n%,100:left n%,i%*121
   font_size n%,14:height n%,250:sort_on n%
  next i%

ALPHA 151:top 151,380:left 151,121:width 151,363:height 151,40
color 151,231,237,221:font_size 151,20

BUTTON 201:BUTTON 202:BUTTON 203
top 201,352:left 201,142:caption 201,"Ràz"
top 202,352:left 202,263:caption 202,"Ràz"
top 203,352:left 203,384:caption 203,"Ràz"
BUTTON 204:BUTTON 205
top 204,352:left 204,30:caption 204,"Je prends":hide 204
top 205,352:left 205,496:caption 205,"Je laisse":hide 205
BUTTON 206:BUTTON 207:BUTTON 208
top 206,352:left 206,216:caption 206,"Save":width 206,32
top 207,352:left 207,337:caption 207,"Save":width 207,32
top 208,352:left 208,458:caption 208,"Save":width 208,32

file_load 101,"debut.txt":file_load 102,"milieu.txt":file_load 103,"fin.txt"

on_change 51,debut
on_change 52,milieu
on_change 53,fin
on_click 101,vide_ligne:on_click 102,vide_ligne:on_click 103,vide_ligne
on_click 201,vide_debut:on_click 202,vide_milieu:on_click 203,vide_fin
on_click 204,prends:on_click 205,laisse
on_click 206,save:on_click 207,save:on_click 208,save

DLIST 500

END

debut:
obj%=1:gosub ajout
RETURN

milieu:
obj%=2:gosub ajout
RETURN

fin:
obj%=3:gosub ajout
RETURN

ajout:
nn%=obj%+50:nnn%=nn%+50
item_add nnn%,text$(nn%)
gosub mot

RETURN

mot:
caption 151,""
mot$=text$(51)+text$(52)+text$(53)
caption 151,mot$
gosub verif_mot

RETURN

vide_ligne:
item_delete number_click,item_index(number_click)
RETURN

vide_debut:
obj%=101:gosub vide_tout
RETURN

vide_milieu:
obj%=102:gosub vide_tout
RETURN

vide_fin:
obj%=103:gosub vide_tout
RETURN

vide_tout:
clear obj%
RETURN

verif_mot:
file_load 500,"refus.txt"
flag=0:n%=count(500)

  if n%>0
   for i%=1 to count(500)
   if item_read$(500,i%)=mot$:flag=1:end_if
   next i%
  end_if
if flag=0:gosub ajoute_mot:end_if
RETURN

ajoute_mot:
show 204:show 205
RETURN

prends:
file_load 500,"mots.txt"
flag=0:n%=count(500)

  if n%>0
   for i%=1 to count(500)
   if item_read$(500,i%)=mot$:flag=1:end_if
   next i%
  end_if

  if flag=0
   file_open_append 5,"mots.txt":file_writeln 5,mot$:file_close 5:hide 204
  end_if

RETURN

laisse:
file_open_append 4,"refus.txt":file_writeln 4,mot$:file_close 4:hide 205
RETURN

save:
  select number_click
   case 206:file_save 101,"debut.txt"
   case 207:file_save 102,"milieu.txt"
   case 208:file_save 103,"fin.txt"
  end_select
RETURN