Panorabrique pour Android

' Panorabric la version Android de test (limitée à 20 objets)
' Prevu pour Samsung S3
' Resolution de l'écran 600 x 380

label clic,fin, boucle_principale

' Déclarations
dim objet%, i, j, i2, j2, ecran%, aff_vies%, aff_score%
dim h,l : h=600: l=380
dim x_r , y_r, hauteur_r, largeur_r : ' Variables de la raquette
dim hauteur_b, largeur_b : hauteur_b = 8 : largeur_b=21  : ' constantes des briques
dim xb, yb, Nb_lignes, Nb_briques_restantes : ' variables pour la gestion des briques
dim x_ball,y_ball, r_ball, c, r, n_ball : r_ball = 10 : ' variables de la balle
dim vies, score : vies = 3 : score = 0
dim nom_couleur$, Nb_couleur% : Nb_couleur% = 18 : ' Tableau des couleurs
dim t_c(Nb_couleur%,3)
dim ombre, lumiere  : ombre=30 : lumiere = 30
dim marge_cote, marge_haut, hauteur_menu : marge_cote = 8 : marge_haut = 30 :hauteur_menu = 100
dim Nb_b_ligne : Nb_b_ligne = int((l - 3*marge_cote)/(largeur_b+5))

' Initialisation de la fenêtre
height 0, h: width 0,l : caption 0, "PANORABRIC Android - V1.0"
border_small 0 : i =  h - hauteur_menu + 20
button 1 : hide 1 : ' Creation du bouton gauche
top 1, i : left 1,10 : caption 1,"<" : on_click 1,clic
button 2 : hide 2 : ' Creation du bouton droite
top 2, i : left 2,50+width(1) : caption 2,">" : on_click 2,clic
button 3 : hide 3 : ' Creation du bouton quitter
top 3, i : left 3,l-width(3)-28 : caption 3,"Quitter" : on_click 3,clic
timer 4 : objet% = 5 : ' On prend 3 objets
hauteur_r = 10 : largeur_r=60 : y_r = h-120-hauteur_r

' Données à charger dans le tableau des couleurs
data "0 - Noir", 0,  0,  0,  "1 - Blanc", 255,255,255
data "2 - couleur de fond - kaki foncé", 155,155, 55
data "3 - Kaki", 180,180,80, "4 - gris foncé",  80, 80, 80
data "5 - bleu" ,80, 80,215, "6 - rouge", 215, 80, 80
data "7 - vert", 80,215, 80, "8 - gris", 155,133,155
data "9 - vert clair", 100,215,100, "10 - violet", 215, 80,215
data "11 - kaki clair", 215,215, 80, "12 - bleu cyan", 80,215,215
data "13 - bleu moyen", 100,100,215, "14 - vert moyen",55,215,133
data "15 - violet",133, 55,215,      "16 - marron clair",215,133, 55
data "17 - bleu nuit",  55, 55,133

' Chargement du tableau des couleurs
for i = 1 to Nb_couleur%
 read nom_couleur$
 for j = 1 to 3 : read c : t_c(i,j)=c : next j
next i

' Dessin de l'aire de jeu
ecran% = objet% : picture ecran%
top ecran%,0: left ecran%,1
h = h - hauteur_menu : height ecran%, h: width ecran%,l-2*marge_cote
2D_target_is ecran%: objet% = objet% +1

' Trace le contour
2d_pen_color t_c(3,1), t_c(3,2), t_c(3,3) : 2d_fill_color t_c(3,1), t_c(3,2), t_c(3,3)
2d_rectangle 0,h,marge_cote,0 : 2d_rectangle marge_cote,0,l-2*marge_cote,20
2d_rectangle l-3*marge_cote,h,l-2*marge_cote,0

' Créations des compteurs de vies et du score
aff_vies% = objet% : alpha aff_vies% : objet% = objet% + 1
color aff_vies%, t_c(3,1), t_c(3,2), t_c(3,3)
top aff_vies%,2 : left aff_vies%, 30 : width aff_vies%,140
caption aff_vies%, "Vies = "+str$(vies)

aff_score% = objet% : alpha aff_score% : objet% = objet% + 1
color aff_score%, t_c(3,1), t_c(3,2), t_c(3,3)
top aff_score%,2 : left aff_score%, 200 : width aff_score%,140
caption aff_score%, "Score = "+str$(score)

Init_niveau()

' timer pour deplacements
timer_interval 4,40 : on_timer 4,boucle_principale

' Tout est prêt, on affiche les boutons et on attend le démarrage de la boucle
show 1: show 2: show 3
end

Sub Dessine_raquette()
 ' On trace la forme de la raquette
 2d_pen_width 2 :   2d_pen_color t_c(5,1), t_c(5,2), t_c(5,3) :  2d_fill_color t_c(6,1), t_c(6,2), t_c(6,3)
 2d_rectangle x_r+4,y_r+4,x_r+largeur_r-3,y_r+hauteur_r-3
 ' On ajoute la partie claire
 2d_pen_color t_c(5,1)+lumiere, t_c(5,2)+lumiere, t_c(5,3)+lumiere
 2d_poly_from x_r+2,y_r+hauteur_r-2 : 2d_poly_to x_r+2,y_r+2 : 2d_poly_to x_r+largeur_r-2,y_r+2
 ' On ajoute les ombres
 2d_pen_color t_c(5,1)-ombre, t_c(5,2)-ombre, t_c(5,3)-ombre
 2d_poly_to x_r +largeur_r-2,y_r+hauteur_r-2 : 2D_poly_to x_r+2,y_r+hauteur_r-2: 2d_pen_width 1
End_sub

Sub Efface_raquette()
 2d_pen_color t_c(2,1), t_c(2,2), t_c(2,3) :  2d_fill_color t_c(2,1), t_c(2,2), t_c(2,3)
 2d_rectangle x_r,y_r,x_r+largeur_r,y_r+hauteur_r
End_sub

Sub init_niveau()
 Nb_lignes = 6: Dessine_briques()
 x_r = 0.5 * (l - largeur_r - 2*marge_cote)
 Dessine_raquette()
 Lance_balle()
End_sub

Sub Dessine_briques()
if variable("t_br")=1 then free t_br
dim t_br(Nb_lignes*Nb_b_ligne,5)
dim k: k=0 : Nb_briques_restantes = 0
for i= 1 to Nb_lignes
 yb = 2*marge_haut + (hauteur_b + 15) * i
 For j = 1 to Nb_b_ligne
   xb = 2*marge_cote + (largeur_b + 5) * (j-1)
   k=k+1 : t_br(k,1) = 1 : t_br(k,5) = 100
   t_br(k,2) = t_c(5+i,1): t_br(k,3) = t_c(5+i,2): t_br(k,4) = t_c(5+i,3)
   Nb_briques_restantes = Nb_briques_restantes + 1
   2d_pen_color t_br(k,2), t_br(k,3), t_br(k,4) : trace_brique()
 next j
next i
free k
End_sub

Sub retrace()
'  dim k: k=0
'  For i2= 1 to Nb_lignes
'    yb = 2*marge_haut + (hauteur_b + 15) * i2
'    For j2 = 1 to Nb_b_ligne
'      xb = 2*marge_cote + (largeur_b + 5) * (j2-1)
'      k=k+1 : if t_br(k,1)=1 then trace_brique()
'    Next j2
'  Next i2
'  free k
'  dessine_raquette()
End_sub

Sub trace_brique()
 2d_pen_width 3
 2d_pen_color t_br(k,2), t_br(k,3), t_br(k,4)
 2d_fill_color t_br(k,2), t_br(k,3), t_br(k,4)
 2d_rectangle xb+2,yb+2,xb+largeur_b-2, yb+hauteur_b-2
 2d_pen_color t_br(k,2)+lumiere, t_br(k,3)+lumiere, t_br(k,4)+lumiere
 2d_poly_from xb,yb+hauteur_b : 2d_poly_to xb,yb : 2d_poly_to xb+largeur_b,yb
 2d_pen_color t_br(k,2)-ombre, t_br(k,3)-ombre, t_br(k,4)-ombre
 2d_poly_to xb+largeur_b,yb+hauteur_b : 2d_poly_to xb,yb+hauteur_b
 2d_pen_width 1
End_sub

Sub efface_brique()
 2d_pen_width 3
 2d_pen_color t_c(2,1), t_c(2,2), t_c(2,3)
 xb = 2*marge_cote + (largeur_b + 5) * (i-1) : yb = 2*marge_haut + (hauteur_b + 15) * (temp)
 2d_rectangle xb,yb,xb+largeur_b+1, yb+hauteur_b+1
 2d_pen_width 1
End_sub

Sub Lance_balle()
 y_ball = y_r - 2*r_ball :  x_ball = int(rnd(l-60)) + 2*marge_cote : r=1
End_sub

Sub efface_balle()
 2d_pen_color t_c(2,1), t_c(2,2), t_c(2,3) :  2d_fill_color t_c(2,1), t_c(2,2), t_c(2,3)
 2d_circle x_ball+r_ball, y_ball+r_ball, r_ball
End_sub

Sub trace_balle()
 2d_pen_color t_c(3,1)-ombre, t_c(3,2)-ombre, t_c(3,3)-ombre
 2d_fill_color t_c(3,1), t_c(3,2), t_c(3,3)
 2d_Circle x_ball+r_ball, y_ball+r_ball, r_ball
 2d_pen_color t_c(4,1), t_c(4,2), t_c(4,3)
 2d_fill_color t_c(4,1)+lumiere, t_c(4,2)+lumiere, t_c(4,3)+lumiere
 2d_Circle x_ball+r_ball-3, y_ball+r_ball-3, r_ball-6
End_sub

Sub recommence()
 vies = 3 : score = 0 : Efface_raquette()
 Efface_balle() : Init_niveau()
 timer_on 4
End_sub

Sub Deplace_balle()
 If x_ball> l-4*marge_cote-2*r_ball then x_ball = l-4*marge_cote-2*r_ball : c = 2 : retrace()
 If x_ball < 2* marge_cote  Then x_ball = 2 * marge_cote : c = 1 : retrace()
 If y_ball < (marge_haut + r_ball) Then y_ball = marge_haut + r_ball : r = 2 : retrace()
 If c < 2 Then x_ball = x_ball + 5 : Else: x_ball = x_ball - 5
 If r < 2 Then y_ball = y_ball - 5 : Else: y_ball = y_ball + 5
End_sub

boucle_principale:
if variable("temp") = 0 then dim temp
 timer_off 4
 Efface_balle()
 Deplace_balle()
 ' Teste si collision avec une brique
 if (r= 1 and y_ball <= (2*marge_haut + hauteur_b + (hauteur_b + 15) * Nb_lignes))
   i = int((x_ball - 2*marge_cote) / (largeur_b + 5))+1
   temp = int ((y_ball - 2*marge_haut - hauteur_b) / (hauteur_b +15))+1
   j = (temp-1)*Nb_b_ligne +i
   if j <= (Nb_lignes*Nb_b_ligne) and j>0
     if t_br(j,1) = 1
         r=2 : t_br(j,1) = 0
         Efface_brique() : retrace()
         Nb_briques_restantes = Nb_briques_restantes - 1 : score = score + t_br(j,5)
     end_if
   end_if
 else
   if (r= 2 and  (y_ball  > (40 + hauteur_b)) and (y_ball < (25 + hauteur_b + (hauteur_b + 15) * Nb_lignes) ))
     i = int((x_ball - 30) / (largeur_b + 10)) +1
     temp = int (((y_ball+2*r_ball) -25 -hauteur_b) / (hauteur_b +15))
     j = (temp-1)*Nb_b_ligne +i
     if j <= (Nb_lignes*Nb_b_ligne) and j>0
       if t_br(j,1) = 1
         r=1 : t_br(j,1) = 0
         Efface_brique() : retrace()
         Nb_briques_restantes = Nb_briques_restantes - 1 : score = score + t_br(j,5)
       end_if
     end_if
   end_if
 end_if

' Verifie si la balle touche la raquette
 if r=2 and y_ball > y_r - 2 * r_ball - 4
     if ((x_ball > (x_r - r_ball)) and (x_ball < (x_r + largeur_r)))
       r = 1
           score=score+1
     else
       if r=2 and y_ball > y_r
           ' Balle perdue
           wait 100: Lance_balle()
           vies = vies-1
       end_if
     retrace()
     end_if
 end_if
 Trace_balle()
 caption aff_vies%, "Vies = "+str$(vies)
 caption aff_score%, "Score = "+str$(score)
 if Nb_briques_restantes = 0
   Message "Bravo, niveau suivant ..."
   Efface_balle() :  Init_niveau()
 end_if
 
 if vies < 1 then goto fin
 free temp
 timer_on 4
return

clic:
 timer_off 4
 select number_click

  case 1 : ' On test si l'on a appuyé sur la flèche de gauche
    Efface_raquette()            : ' Efface ancienne raquette
    x_r = x_r - (largeur_r / 2)  : ' Mise à jour de la position de la raquette suite à l'appuie sur la flèche
    if x_r < 10 then x_r=10      : ' Mais on ne doit pas dépasser les bords !!
    Dessine_raquette()           : ' Actualise l'affichage de la raquette

  case 2 : ' On test si l'on a appuyé sur la flèche de droite
    Efface_raquette()            : ' Efface ancienne raquette
    x_r = x_r + (largeur_r / 2)  : ' Mise à jour de la position de la raquette suite à l'appuie sur la flèche
    if x_r > l - largeur_r-26 then x_r = l - largeur_r-26  : ' Mais on ne doit pas dépasser les bords !!
    Dessine_raquette()          : ' Actualise l'affichage de la raquette

  case 3 : goto fin : ' On test si l'on a appuyé sur le bouton pour Quitter
 
 end_select
 timer_on 4
return

fin:
 timer_off 4
 terminate

rem ============================================================================
' Sous-programme modifié par Papydall
clic:
timer_off 4
select number_click
' On test si l'on a appuyé sur la flèche de gauche
  case 1
    Efface_raquette()            : ' Efface ancienne raquette
    x_r = x_r - (largeur_r / 2)  : ' Mise à jour de la position de la raquette suite à l'appuie sur la flèche
    if x_r < 10 then x_r=10      : ' Mais on ne doit pas dépasser les bords !!
    Dessine_raquette()           : ' Actualise l'affichage de la raquette

' On test si l'on a appuyé sur la flèche de droite
   case 2
     Efface_raquette()            : ' Efface ancienne raquette
     x_r = x_r + (largeur_r / 2)  : ' Mise à jour de la position de la raquette suite à l'appuie sur la flèche
     if x_r > l - largeur_r-26 then x_r = l - largeur_r-26  : ' Mais on ne doit pas dépasser les bords !!
     Dessine_raquette()          : ' Actualise l'affichage de la raquette
' On test si l'on a appuyé sur le bouton pour Quitter
   case 3 : goto fin
end_select

timer_on 4
return
rem ============================================================================

' Panorabric prévue pour PC (Resolution de l'écran 600 x 380)
' La résolution c'est par ce que je suis parti de la version Android de mon S3...

label clic,fin, boucle_principale, t1, t2

' Déclarations
dim i, j, i2, j2, ecran%, aff_vies%, aff_score%, zdj%, image%
dim h,l : h=600: l=380
dim x_r , y_r, hauteur_r, largeur_r : ' Variables de la raquette
dim hauteur_b, largeur_b : hauteur_b = 8 : largeur_b=21  : ' constantes des briques
dim xb, yb, Nb_lignes, Nb_briques_restantes : ' variables pour la gestion des briques
Nb_lignes = 6
dim x_ball,y_ball, r_ball, n_ball : r_ball = 10 : ' variables de la balle
dim c : ' donne la direction de la balle horizontalement
'        c=1 => la balle va vers la gauche
'        c=2 => elle va à droite
dim r : ' donne la direction de la balle verticalement
'        r=1 => la balle monte
'        r=2 => la balle descend
dim vies, score : vies = 3 : score = 0
dim nom_couleur$, Nb_couleur% : Nb_couleur% = 18 : ' Tableau des couleurs
dim t_c(Nb_couleur%,3)
dim ombre, lumiere  : ombre=30 : lumiere = 16
dim marge_cote, marge_haut, hauteur_menu : marge_cote = 8 : marge_haut = 30 :hauteur_menu = 100
dim Nb_b_ligne : Nb_b_ligne = int((l - 3*marge_cote)/(largeur_b+5))
dim t_br(Nb_lignes*Nb_b_ligne,5)
dim ctrl_mouse : ctrl_mouse = 0 : ' ctrl_mouse = 0 => clavier / boutons ; ctrl_mouse = 1 => souris
'
' ****************************** COMMANDES CLAVIER **************************
dim esc,cesc : cesc=27 : ' * TOUCHE "ESC" ==> MET FIN AU PROGRAMME:.... 27  *
dim tfg,ctfg : ctfg=37 : ' * FLÈCHE GAUCHE ==> DEPLACER À GAUCHE:...... 37  *
dim tfd,ctfd : ctfd=39 : ' * FLÈCHE DROITE ==> DEPLACER À DROITE:...... 39  *
' ***************************************************************************


' Initialisation de la fenêtre
height 0, h: width 0,l : caption 0, "PANORABRIC Android - V1.0"
border_small 0 : i =  h - hauteur_menu + 20

if ctrl_mouse = 0
  button 1 : hide 1 : ' Creation du bouton gauche
  top 1, i : left 1,10 : caption 1,"<" : on_click 1,clic
  button 2 : hide 2 : ' Creation du bouton droite
  top 2, i : left 2,50+width(1) : caption 2,">" : on_click 2,clic
  button 3 : hide 3 : ' Creation du bouton quitter
  top 3, i : left 3,l-width(3)-28 : caption 3,"Quitter" : on_click 3,clic
  ' On détecte le changement d'état des touches
end_if

timer 4 : hauteur_r = 10 : largeur_r=60 : y_r = h-120-hauteur_r


' Données à charger dans le tableau des couleurs
data "0 - Noir", 0,  0,  0,  "1 - Blanc", 255,255,255
data "2 - couleur de fond - kaki foncé", 155,155, 55
data "3 - Kaki", 180,180,80, "4 - gris foncé",  80, 80, 80
data "5 - bleu" ,80, 80,215, "6 - rouge", 215, 80, 80
data "7 - vert", 80,215, 80, "8 - gris", 155,133,155
data "9 - vert clair", 100,215,100, "10 - violet", 215, 80,215
data "11 - kaki clair", 215,215, 80, "12 - bleu cyan", 80,215,215
data "13 - bleu moyen", 100,100,215, "14 - vert moyen",55,215,133
data "15 - violet",133, 55,215,      "16 - marron clair",215,133, 55
data "17 - bleu nuit",  55, 55,133

' Chargement du tableau des couleurs
for i = 1 to Nb_couleur% :  read nom_couleur$
    for j = 1 to 3 : read c : t_c(i,j)=c : next j
next i

' On retire la taille du menu à h pour créer nos objets
h= h - hauteur_menu

' Dessin de l'aire de jeu dans une image cachée qui sert aussi à créer les sprites
ecran% = 5 : picture ecran% : hide ecran%

' Créer l'objet scene2d qui sera notre zone de jeu
zdj% = 6 : scene2d zdj%
top zdj%,0: left zdj%,1
height zdj%, h: width zdj%,l-2*marge_cote

' On creer notre image de transfert
image% = 7 : image image%

' Activer cette ligne pour creer une image de fond basique si besoin (Creer_fond)
' Cette image est modifiable à volonté selon vos goût.
' Je vous en ai fourni une faite rapidement, a vous de faire mieux si vous voulez
'
Creer_fond()

file_load zdj%,"fond.bmp"

x_r = 0.5 * (l - largeur_r - 2*marge_cote) : Dessine_raquette()
Creer_brique()
Trace_balle()

caption 0, " Panorabric version PC  -  Vies restantes: " + str$(vies) + "          Score = "+str$(score)

Init_niveau()

' timer pour deplacements
timer_interval 4,30 : on_timer 4,boucle_principale
on_close 0,fin : ' Si on ferme, on ferme par la procédure de sortie

' Tout est prêt, on affiche les boutons et on attend le démarrage de la boucle
if ctrl_mouse = 0
  show 1: show 2: show 3
end_if
on_key_down 0,t1 : on_key_up 0,t2
end

Sub Dessine_raquette()
  2d_target_is ecran%
  color ecran%,0,0,0 : sprite 1 : sprite_hide 1
  if file_exists("raquette.bmp") = 0
    ' On trace la forme de la raquette
    2d_pen_width 2 :  2d_pen_color t_c(5,1), t_c(5,2), t_c(5,3) :  2d_fill_color t_c(6,1), t_c(6,2), t_c(6,3)
    2d_rectangle 4,4,largeur_r-3,hauteur_r-3
    ' On ajoute la partie claire
    2d_pen_color t_c(5,1)+lumiere, t_c(5,2)+lumiere, t_c(5,3)+lumiere
    2d_poly_from 2,-2 : 2d_poly_to 2,2 : 2d_poly_to largeur_r-2,2
    ' On ajoute les ombres
    2d_pen_color t_c(5,1)-ombre, t_c(5,2)-ombre, t_c(5,3)-ombre
    2d_poly_to largeur_r-2,hauteur_r-2 : 2D_poly_to 2,hauteur_r-2: 2d_pen_width 1
    ' file_save ecran%,"raquette.bmp"
  else
    file_load ecran%,"raquette.bmp"
  end_if
  2d_image_copy image%,0,0, largeur_r,hauteur_r
  sprite_image_load 1,image%
End_sub

Sub init_niveau()
  Dessine_briques()
  x_r = 0.5 * (l - largeur_r - 2*marge_cote)
  sprite_position 1,x_r,y_r : sprite_show 1
  Dessine_briques()
  Lance_balle()
End_sub

Sub Creer_fond()
  2d_target_is ecran% :  top ecran%,0: left ecran%,0
  height ecran%, h: width ecran%,l - 2*marge_cote
  ' Créait un fond noir si besoin
  color ecran%,0,0,0
  if file_exists("fond_noir.jpg") = 0 then file_save ecran%,"fond_noir.jpg"
  ' Trace le contour
  if file_exists("fond.bmp")=0
    2d_pen_color t_c(3,1), t_c(3,2), t_c(3,3) : 2d_fill_color t_c(3,1), t_c(3,2), t_c(3,3)
    2d_rectangle 0,h,marge_cote,0 : 2d_rectangle marge_cote,0,l-2*marge_cote,20
    2d_rectangle l-3*marge_cote,h,l-2*marge_cote,0
    2d_image_copy image%,0,0,l-2*marge_cote,h
    file_save ecran%,"fond.bmp"
  end_if
End_sub

Sub Creer_brique()
  dim k: k=0
  ' Trace le contour
  2d_target_is ecran%
  top ecran%,0: left ecran%,0 :  color ecran%,0,0,0
  height ecran%, hauteur_b : width ecran%,largeur_b
  for i= 1 to Nb_lignes
    for j = 1 to Nb_b_ligne
      k=k+1
      t_br(k,2) = t_c(5+i,1): t_br(k,3) = t_c(5+i,2): t_br(k,4) = t_c(5+i,3)
      2d_pen_color t_br(k,2), t_br(k,3), t_br(k,4)
      2d_pen_width 3
      2d_pen_color t_br(k,2), t_br(k,3), t_br(k,4) : 2d_fill_color t_br(k,2), t_br(k,3), t_br(k,4)
      2d_rectangle 2,2,largeur_b-2, hauteur_b-2
      2d_pen_color t_br(k,2)+lumiere, t_br(k,3)+lumiere, t_br(k,4)+lumiere
      2d_poly_from 0, hauteur_b : 2d_poly_to 0,0 : 2d_poly_to largeur_b, 0
      2d_pen_color t_br(k,2)-ombre, t_br(k,3)-ombre, t_br(k,4)-ombre
      2d_poly_to  largeur_b, hauteur_b : 2d_poly_to 0, hauteur_b
      2d_pen_width 1
      2d_image_copy image%,0,0,largeur_b,hauteur_b
      sprite 10+k : sprite_image_load 10+k,image% : sprite_hide 10 + k
    next j
  next i
free k
End_sub

Sub Dessine_briques()
dim k: k=0 : Nb_briques_restantes = 0
for i= 1 to Nb_lignes
  yb = 2*marge_haut + (hauteur_b + 15) * i
  For j = 1 to Nb_b_ligne
    xb = 2*marge_cote + (largeur_b + 5) * (j-1)
    k=k+1 : t_br(k,1) = 1 : t_br(k,5) = 100
    Nb_briques_restantes = Nb_briques_restantes + 1
    sprite_position 10+k, xb, yb : sprite_show 10+k
  next j
next i
free k
End_sub

Sub Lance_balle()
  y_ball = y_r - 2*r_ball :  x_ball = int(rnd(l-60)) + 2*marge_cote : r=1
  sprite_show 2
End_sub

Sub Trace_balle()
  2d_target_is ecran%
  top ecran%,0: left ecran%,0 :  height ecran%, 2*r_ball
  width ecran%,2*r_ball : color ecran%, 0,0,0
  if file_exists("balle.bmp")=0
    2d_pen_color t_c(3,1) - ombre, t_c(3,2) - ombre, t_c(3,3) - ombre
    2d_fill_color t_c(3,1), t_c(3,2), t_c(3,3) : 2d_circle r_ball, r_ball, r_ball
    2d_fill_color t_c(4,1)+lumiere, t_c(4,2)+lumiere, t_c(4,3)+lumiere
    2d_pen_color t_c(4,1), t_c(4,2), t_c(4,3) :  2d_circle r_ball-3, r_ball-3, r_ball-6
    file_save ecran%,"balle.bmp"
  else
    file_load ecran%,"balle.bmp"
  end_if
  2d_image_copy image%,0,0,2*r_ball,2*r_ball
  sprite 2 : sprite_image_load 2,image% : sprite_hide 2
End_sub

Sub recommence()
  vies = 3 : score = 0 : sprite_hide 1
  sprite_hide 2 : Init_niveau()
  timer_on 4
End_sub

Sub Deplace_balle()
  If x_ball> l-4*marge_cote-2*r_ball then x_ball = l-4*marge_cote-2*r_ball : c = 2
  If x_ball < 2* marge_cote  Then x_ball = 2 * marge_cote : c = 1
  If y_ball < (marge_haut + r_ball) Then y_ball = marge_haut + r_ball : r = 2
  If c < 2 Then x_ball = x_ball + 5 : Else: x_ball = x_ball - 5
  If r < 2 Then y_ball = y_ball - 5 : Else: y_ball = y_ball + 5
End_sub

boucle_principale:
if variable("temp") = 0 then dim temp
  timer_off 4
  Deplace_balle() : sprite_position 2,x_ball,y_ball
  ' Teste si collision avec une brique
  if (r= 1 and y_ball <= (2*marge_haut + hauteur_b + (hauteur_b + 15) * Nb_lignes))
    i = int((x_ball - 2*marge_cote) / (largeur_b + 5))+1
    temp = int ((y_ball - 2*marge_haut - hauteur_b) / (hauteur_b +15))+1
    j = (temp-1)*Nb_b_ligne +i
    if j <= (Nb_lignes*Nb_b_ligne) and j>0
      if t_br(j,1) = 1
          r=2 : t_br(j,1) = 0
          sprite_hide j+10 : Nb_briques_restantes = Nb_briques_restantes - 1 : score = score + t_br(j,5)
      end_if
    end_if
  else
    if (r= 2 and  (y_ball  > (2*marge_haut + hauteur_b)) and (y_ball < (2*marge_haut + hauteur_b + (hauteur_b + 15) * Nb_lignes) ))
      i = int((x_ball - 2*marge_cote) / (largeur_b + 5)) +1
      temp = int (((y_ball+2*r_ball) -2*marge_haut -hauteur_b) / (hauteur_b +15))
      j = (temp-1)*Nb_b_ligne +i
      if j <= (Nb_lignes*Nb_b_ligne) and j>0
        if t_br(j,1) = 1
          r=1 : t_br(j,1) = 0
          sprite_hide j+10 : Nb_briques_restantes = Nb_briques_restantes - 1 : score = score + t_br(j,5)
        end_if
      end_if
    end_if
  end_if

  if ctrl_mouse = 1
      x_r = mouse_x_position(zdj%)
      if x_r < 10 then x_r=10      : ' Mais on ne doit pas dépasser les bords !!
      if x_r > l - largeur_r-26 then x_r = l - largeur_r-26  : ' Mais on ne doit pas dépasser les bords !!
      sprite_x_position 1,x_r
  else
    if tfg=1
      x_r = x_r - (largeur_r / 2)  : ' Mise à jour de la position de la raquette suite à l'appuie sur la flèche
      if x_r < 10 then x_r=10      : ' Mais on ne doit pas dépasser les bords !!
    end_if
    if tfd=1
      x_r = x_r + (largeur_r / 2)  : ' Mise à jour de la position de la raquette suite à l'appuie sur la flèche
      if x_r > l - largeur_r-26 then x_r = l - largeur_r-26  : ' Mais on ne doit pas dépasser les bords !!
    end_if
    sprite_x_position 1,x_r
  end_if

' Verifie si la balle touche la raquette
  if r=2 and y_ball > y_r - 2 * r_ball - 4
      if ((x_ball > (x_r - r_ball)) and (x_ball < (x_r + largeur_r)))
        r = 1
            score=score+1
      else
        if r=2 and y_ball > y_r
            ' Balle perdue
            wait 400: Lance_balle()
            vies = vies-1
        end_if
      end_if
  end_if
  caption 0, " Panorabric version PC  -  Vies restantes = " + str$(vies) + "  - Score = "+str$(score)
  if Nb_briques_restantes = 0
    message "Bravo, niveau suivant ..."
    hide 2 :  Init_niveau()
  end_if

  if vies < 1 then goto fin
  free temp
  timer_on 4
return

clic:
  timer_off 4
  select number_click
  case 1 : ' On test si l'on a appuyé sur la flèche de gauche
    x_r = x_r - (largeur_r / 2)  : ' Mise à jour de la position de la raquette suite à l'appuie sur la flèche
    if x_r < 10 then x_r=10      : ' Mais on ne doit pas dépasser les bords !!
  case 2 : ' On test si l'on a appuyé sur la flèche de droite
    x_r = x_r + (largeur_r / 2)  : ' Mise à jour de la position de la raquette suite à l'appuie sur la flèche
    if x_r > l - largeur_r-26 then x_r = l - largeur_r-26  : ' Mais on ne doit pas dépasser les bords !!
  case 3 : goto fin : ' On test si l'on a appuyé sur le bouton pour Quitter
  end_select
  sprite_x_position 1,x_r
  set_focus 0
  timer_on 4
return

' ****** Procédures événementielles de gestion du clavier

t1:
  if key_down_code=cesc then goto fin
  if key_down_code=ctfg then tfg=1
  if key_down_code=ctfd then tfd=1
return

t2:
  if key_down_code=ctfg then tfg=0
  if key_down_code=ctfd then tfd=0
return

fin:
  timer_off_all : ' Je sais que l'on va faire un terminate, mais arréter les timers évite les messages d'erreur
  caption 0, " Panorabric version PC  -  Vies restantes = " + str$(vies) + "  - Score = "+str$(score)
  wait 2000:  sprite_hide_all
  caption 0, " Panorabric version PC  -  Partie terminée  - Score = "+str$(score)
  file_load zdj%,"fond_noir.jpg" :  wait 3000
  terminate