tesseract-ocr

Variables()
Labels()
Gui()
Init()

end

' ******************************************************************************
'                                 VARIABLES
' ******************************************************************************

Sub Variables()
'  dll
   dim kgf$
'  pluggins
   dim tsr$,nconv$
'  paramètres
   dim Param$
   Param$=dir_current$+"\Param.txt"
'  Evenements
   dim clic%,change%
'  Objets
   dim no%,cadre1%,cadre2%,cadre3%,
   dim file_in%,but_rech%,but_preview%,but_save%,file_out%,view%,img%,bar%
   dim Param_list%,param%,E_kgf%,E_tsr%,E_nconv%
   dim but_kgf%,but_tsr%,but_nconv%,But_enrgt%
'  fonctions
   dim file_in$,file_out$,PV%,larg%,haut%
End_sub

' ******************************************************************************
'                                 LABELS
' ******************************************************************************

Sub Labels()
   label Clic,Change
End_sub

Clic:
   clic%=number_click
   if clic%=but_rech%    : file_find() : end_if
   if clic%=but_preview% : Pre_view()  : end_if
  
   if clic%=but_kgf%
      no%=no%+1
      O_open_dialog(No%,0,"C:","*.dll",5)
      Nom_court(file$)
      kgf$=nc$
      text E_kgf%,kgf$
      if kgf$<>"":Add_param("kgf",kgf$):end_if
   end_if
  
   if clic%=but_tsr%
      no%=no%+1
      O_open_dialog(No%,0,"C:","*.exe",5)
      Nom_court(file$)
      tsr$=nc$
      text E_tsr%,tsr$
      if tsr$<>"":Add_param("tsr",tsr$):end_if
   end_if
  
   if clic%=but_nconv%
      no%=no%+1
      O_open_dialog(No%,0,"C:","*.exe",5)
      Nom_court(file$)
      nconv$=nc$
      text E_nconv%,nconv$
      if nconv$<>"":Add_param("nco",nconv$):end_if
   end_if
  
   if clic%=but_enrgt% : Save_param():end_if
   if clic%=but_save%  : Save_text() :end_if
  
return

Change:
   change%=number_change
   if change%=bar%         : Pos_image() : end_if
return
' ******************************************************************************
'                          GENERAL USER INTERFACE
' ******************************************************************************

Sub Gui()
   O_Form(0,0,1,0,0,500,750,"Panoramic - OCR")
   font_name 0,"arial"

   no%=no%+1 : cadre1%=no%
   O_Panel(no%,0,1,0,0,60,width(0)-16)
  
   no%=no%+1
   O_Alpha(no%,cadre1%,1,5,5,0,0,"File in :")
   font_bold no%
  
   no%=no%+1 : file_in%=no%
   O_Edit(no%,cadre1%,1,20,5,0,600,"",1)
  
   no%=no%+1 : but_rech%=no%
   O_Button(no%,cadre1%,1,top(file_in%),left(file_in%)+605,22,30,".../...",1)
  
   no%=no%+1 : but_preview%=no%
   O_Button(no%,cadre1%,1,top(file_in%),left(but_rech%)+35,22,30,"Txt",1)
  
   no%=no%+1 : but_save%=no%
   O_Button(no%,cadre1%,0,top(file_in%),left(but_preview%)+35,22,30,"Save",1)

' Vue du fichier traité

   no%=no%+1 : cadre2%=no%
   O_Panel(no%,0,0,60,0,height(0)-98,width(0)-16)
  
   no%=no%+1 : view%=no%
   O_Memo(no%,cadre2%,1,5,5,height(cadre2%)-10,width(cadre2%)-10,"")
   Bar_both no%
  
' Vue du fichier a traité

   no%=no%+1 : cadre3%=no%
   O_Panel(no%,0,1,60,0,height(0)-98,width(0)-16)

   no%=no%+1 : img%=no%
   O_Picture(no%,cadre3%,1,5,5,height(cadre2%)-10,width(cadre2%)-30,"")
   color no%,230,230,230
  
   no%=no%+1 : bar%=no%
   scroll_bar no%
   parent no%,cadre3%
   vertical no%
   top no%,2
   left no%,width(cadre3%)-22
   height no%,height(cadre3%)-4
   min no%,0 : max no%,600
   on_change no%,change
  
   no%=no%+1 : Param_list%=no%
   dlist no%
End_sub

Sub Param()
    if param%>0
       Show param%
    else
       no%=no%+1 : param%=no%
       O_Form(no%,0,1,0,0,200,600,"Paramètres")
       font_name no%,"arial"
      
       no%=no%+1
       O_Alpha(no%,param%,1,5,5,0,0,"KGF.dll")
      
       no%=no%+1 : E_kgf%=no%
       O_Edit(no%,param%,1,20,5,0,500,"",1)
      
       no%=no%+1 : But_kgf%=no%
       O_Button(no%,param%,1,top(E_kgf%),510,20,30,".../...",1)
      
       no%=no%+1
       O_Alpha(no%,param%,1,45,5,0,0,"Tesseract.exe")

       no%=no%+1 : E_tsr%=no%
       O_Edit(no%,param%,1,60,5,0,500,"",1)
      
       no%=no%+1 : But_tsr%=no%
       O_Button(no%,param%,1,top(E_tsr%),510,20,30,".../...",1)
      
       no%=no%+1
       O_Alpha(no%,param%,1,85,5,0,0,"Nconvert.exe")

       no%=no%+1 : E_nconv%=no%
       O_Edit(no%,param%,1,100,5,0,500,"",1)
      
       no%=no%+1 : But_nconv%=no%
       O_Button(no%,param%,1,top(E_nconv%),510,20,30,".../...",1)
      
       no%=no%+1 : But_enrgt%=no%
       O_Button(no%,param%,1,height(param%)-68,width(param%)-100,0,0,"Enregistrer",1)
      
    end_if
End_sub

' ******************************************************************************
'                                      INIT
' ******************************************************************************

Sub Init()
   dim_local i%,a$
   If file_exists(Param$)=1
      file_load param_list%,Param$
      for i%=1 to count(param_list%)
         a$=item_read$(param_list%,i%)
         if left$(a$,3)="kgf"
            kgf$   =right$(a$,len(a$)-4)
         end_if
         if left$(a$,3)="tsr"
            tsr$  =right$(a$,len(a$)-4)
         end_if
         if left$(a$,3)="nco"
            nconv$=right$(a$,len(a$)-4)
         end_if
      next i%
   Else
      Param()
   End_if
   dll_on kgf$
End_sub


' ******************************************************************************
'                               BIBLIOTHEQUE OBJETS
' ******************************************************************************

Sub O_Form(No%,P%,V%,T%,L%,H%,W%,C$)
   if No%> 0 then FORM No%
   if P% > 0 then Parent No%,P%
   If V% = 0 Then hide No%
   If H% > 0 Then Height No%,H%
   If W% > 0 Then Width No%,W%
   If T% > 0 : Top No%,T% : Else : Top No%,(Screen_y-H%)/2 : End_If
   If L% > 0 : Left No%,L%: Else : Left No%,(Screen_x-W%)/2: End_If
   if C$<>"" then Caption No%,C$
End_Sub
' ______________________________________________________________________________
Sub O_Alpha(No%,P%,V%,T%,L%,H%,W%,C$)
   ALPHA No%
   if P% > 0 then Parent No%,P%
   If V% = 0 Then hide No%
   If H% > 0 Then Height No%,H%
   If W% > 0 Then Width No%,W%
   If T% > 0 Then Top No%,T%
   If L% > 0 Then Left No%,L%
   if C$<>"" then Caption No%,C$
End_Sub
' ______________________________________________________________________________
Sub O_Edit(No%,P%,V%,T%,L%,H%,W%,T$,Ch%)
   EDIT No%
   if P% > 0 then Parent No%,P%
   If V% = 0 Then hide No%
   If H% > 0 Then Height No%,H%
   If W% > 0 Then Width No%,W%
   If T% > 0 Then Top No%,T%
   If L% > 0 Then Left No%,L%
   If T$<>"" Then Text No%,T$
   If Ch%=1  Then On_Change No%,Change
End_Sub
' ______________________________________________________________________________
Sub O_Button(No%,P%,V%,T%,L%,H%,W%,C$,Cl%)
   BUTTON No%
   if P% > 0 then Parent No%,P%
   If V% = 0 Then hide No%
   If H% > 0 Then Height No%,H%
   If W% > 0 Then Width No%,W%
   If T% > 0 Then Top No%,T%
   If L% > 0 Then Left No%,L%
   if C$<>"" then Caption No%,C$
   if Cl%> 0 then on_click No%,Clic
   cursor_point No%
End_Sub
' ______________________________________________________________________________
Sub O_Memo(No%,P%,V%,T%,L%,H%,W%,F$)
   MEMO No%
   if P% > 0 then Parent No%,P%
   If V% = 0 Then hide No%
   If H% > 0 Then Height No%,H%
   If W% > 0 Then Width No%,W%
   If T% > 0 Then Top No%,T%
   If L% > 0 Then Left No%,L%
   if F$<>""
   if file_exists(F$)=1 then file_load No%,F$
   end_if
End_Sub
' ______________________________________________________________________________
Sub O_Picture(No%,P%,V%,T%,L%,H%,W%,P$)
   PICTURE No%
   if P% > 0 then Parent No%,P%
   If V% = 0 Then hide No%
   If H% > 0 Then Height No%,H%
   If W% > 0 Then Width No%,W%
   If T% > 0 Then Top No%,T%
   If L% > 0 Then Left No%,L%
   if P$<>"" then File_load No%,P$
End_Sub
' ______________________________________________________________________________
Sub O_Open_Dialog(No%,Out%,DD$,Filtre$,O%)
   dim_local F$
   If Object_Exists(No%)=0
      OPEN_DIALOG No%
   End_if
   if DD$<>"" then Dir_Dialog No%,DD$
   if filtre$<>"" then Filter No%,Filtre$+"|"+Filtre$
   F$=File_name$(No%)
   if variable("File$")=0:Dim File$:else:file$="":End_If
   if F$<>"_"
      if O%=1 then text out%,F$
      if O%=2 then Caption Out%,F$
      if O%=3 then item_add Out%,F$
      if O%=4 then file_load Out%,F$
      if O%=5 then File$=F$
   end_if
   Delete No%
End_Sub
' ______________________________________________________________________________
Sub O_Save_Dialog(No%,NOut%,DD$,Filtre$,ext$)
   dim_local F$,i%,ext%
    If Object_Exists(No%)=0
       SAVE_DIALOG No%
    End_If
    If DD$<>"" then Dir_Dialog No%,DD$
    If filtre$<>"" then Filter No%,Filtre$
    F$=file_name$(No%)
    If F$<>"_"
       for i%=1 to len(F$)
          if mid$(f$,i%,1)=".":ext%=1:exit_for:end_if
       next i%
       if ext%=1
          File_Save NOut%,F$
       else
          File_save NOut%,F$+ext$
       end_if
    End_If
    Delete No%
End_Sub
' ______________________________________________________________________________
Sub O_Panel(No%,P%,V%,T%,L%,H%,W%)
   Panel no%
   if P% > 0 then Parent No%,P%
   If V% = 0 Then hide No%
   If H% > 0 Then Height No%,H%
   If W% > 0 Then Width No%,W%
   If T% > 0 Then Top No%,T%
   If L% > 0 Then Left No%,L%
End_sub
' ******************************************************************************
'                                FONCTIONS
' ******************************************************************************

Sub File_find()
   dim_local court$,long$,res%,ext$,t%
   no%=no%+1
   O_Open_dialog(no%,0,"C:","*.jpg;*.pdf",5)
   text file_in%,File$
   if file$<>""
      ext$=upper$(right$(file$,4))
      Nom_court(file$)
      file_in$=nc$

      if ext$=".PDF"
         t%=1
         execute_wait "CMD.exe /c "+nconv$+" -out jpeg "+file$
         file$=left$(file$,len(file$)-4)+".jpg"
         Nom_court(file$)
         file_in$=nc$
      end_if
      
      res% = dll_call3("AnalyzeImageFile",adr(File$),adr(larg%),adr(haut%))
      resize_img(haut%,larg%)
      file_load img%,file$
      stretch_on img%
      file_out$=file_extract_path$(file$)+"\Fichtext.txt"

      Analyze(t%)
   end_if
End_sub

Sub resize_img(h%,l%)
    dim_local x%
    x%=(width(img%)*100)/l%
    height img%,h%*x%/100
    min bar%,0 : max bar%,height(img%)
end_sub

Sub Analyze(t%)
   inactive but_rech%
   inactive but_preview%
   inactive but_save%
   EXECUTE_WAIT "CMD.exe /C "+tsr$+" "+file_in$+" Fichtext -l fra"
   file_load view%,file_out$
   file_delete file_out$
   if t%=1
      file_delete file_in$
   end_if
   active but_rech%
   active but_preview%
   active but_save%
End_sub

Sub Pre_view()
    if PV%=0
       PV%=1
       caption but_preview%,"Img"
       hide cadre3% :show cadre2%
       if count(view%)>0
          show but_save%
       end_if
    else
       PV%=0
       caption but_preview%,"Txt"
       hide cadre2% :show cadre3%
    end_if
End_sub

Sub Pos_image()
    top img%,5-position(bar%)
End_sub

Sub Nom_court(f$)
   dim_local res%,court$,long$
   if variable("nc$")=0
      dim nc$
   end_if
   long$=f$
   court$=string$(255," ")
   res% = DLL_call2("GetShortName",adr(long$),adr(court$))
   nc$=trim$(court$)
End_sub

Sub Save_param()
   if count(param_list%)=3
      file_save param_list%,param$
   else
      if message_warning_yes_no("L' application nécessite les trois paramètres."+chr$(13)+"Voulez vous abandonner ?")=1
         Terminate
      end_if
   end_if
End_sub

Sub Add_param(t$,par$)
   dim_local a$,i%,e%
   if count(param_list%)>0
      for i%=1 to count(param_list%)
         a$=item_read$(param_list%,i%)
         if a$=t$+"|"+par$
            e%=i%
            exit_for
         end_if
      next i%
      if e%>0
         item_delete param_list%,e%
         item_insert param_list%,e%,t$+"|"+par$
      else
         item_add param_list%,t$+"|"+par$
      end_if
   else
      item_add param_list%,t$+"|"+par$
   end_if
End_sub

Sub Save_text()
   no%=no%+1
   O_Save_dialog(No%,view%,"C:","*.txt",".txt")
End_sub