Encore une petite sub palette

v% = VAL(CLIPBOARD_STRING_PASTE$)
R% = INT(v%/65536): G% = BIN_AND(v%,65280)/256: B% = BIN_AND(v%,255)

SUB Palette()
' Choix d'une couleur parmi 216 (couleurs de base Html), résultat dans
' le clipboard sous la forme d'une chaîne de valeur: R*65536 + G*256 + B
' Récupération: v% = VAL(CLIPBOARD_STRING_PASTE$)
' ------------  R%=INT(v%/65536): G%=BIN_AND(v%,65280)/256: B%=BIN_AND(v%,255)
DIM_LOCAL i%,j%,x%,y%,r%,g%,b%,wf%,hf%,wc%,hc%,f%
f% = 3000: WHILE OBJECT_EXISTS(f%)=1: f%=f%+1000: END_WHILE
wf% = 30: hf% = 16: wc% = 6*wf%: hc% = 36*hf%
FORM f%: TOP f%, 0: LEFT f%, 0: BORDER_SMALL f%: TO_FOREGROUND f%
CAPTION f%, "- PALETTE DE 216 COULEURS -"
WIDTH f%, wc%+16: HEIGHT f%, hc%+34
PICTURE f%+1: PARENT f%+1,f%: WIDTH f%+1, wc%: HEIGHT f%+1,hc%
2D_TARGET_IS f%+1: r% = 0: g% = 0: b% = 0
FOR j% = 0 TO 35
    y% = j%*hf%
    FOR i% = 0 TO 5
        x% = i%*wf%
        2D_FILL_COLOR r%,g%,b%: 2D_RECTANGLE x%,y%,x%+wf%-1,y%+hf%-1
        b% = b% + HEX("33")
        IF b% > 255
            b% = 0: g% = g% + HEX("33")
            IF g% > 255 THEN g% = 0: r% = r% + HEX("33")
        END_IF
    NEXT i%
NEXT j%
WHILE MOUSE_LEFT_DOWN(f%+1) = 0: WAIT 200:END_WHILE
x% = MOUSE_X_POSITION(f%+1): y% = MOUSE_Y_POSITION(f%+1)
r% = COLOR_PIXEL_RED(f%+1,x%,y%)
g% = COLOR_PIXEL_GREEN(f%+1,x%,y%)
b% = COLOR_PIXEL_BLUE(f%+1,x%,y%)
CLIPBOARD_STRING_COPY STR$(65536*r%+256*g%+b%)
2D_TARGET_IS 0: DELETE f%
END_SUB

dim v%,G%,B%,R%
palette()
resultat()
end

sub resultat()
v% = VAL(CLIPBOARD_STRING_PASTE$)
R% = INT(v%/65536): G% = BIN_AND(v%,65280)/256: B% = BIN_AND(v%,255)
caption 0," "+str$(R%)+" "+str$(G%)+" "+str$(B%)
end_sub


SUB Palette()
' Choix d'une couleur parmi 216 (couleurs de base Html), résultat dans
' le clipboard sous la forme d'une chaîne de valeur: R*65536 + G*256 + B
IF LABEL("Chx_Coul") = 0 THEN LABEL Chx_Coul
DIM_LOCAL i%,j%,x%,y%,r%,g%,b%,wf%,hf%,wc%,hc%,ix%,f%: f% = 3000
ix% = 0: wf% = 30: hf% = 16: wc% = 6*wf%: hc% = 36*hf%
FORM f%: TOP f%, 0: LEFT f%, 0: BORDER_SMALL f%
CAPTION f%, "- PALETTE DE 216 COULEURS -"
WIDTH f%, wc%+16: HEIGHT f%, hc%+34
PICTURE f%+1: PARENT f%+1,f%: WIDTH f%+1, wc%: HEIGHT f%+1,hc%
ON_CLICK f%+1,Chx_Coul
2D_TARGET_IS f%+1: r% = 0: g% = 0: b% = 0
FOR j% = 0 TO 35
    y% = j%*hf%
    FOR i% = 0 TO 5
        x% = i%*wf%
        2D_FILL_COLOR r%,g%,b%: 2D_RECTANGLE x%,y%,x%+wf%-1,y%+hf%-1
        b% = b% + HEX("33")
        IF b% > 255
            b% = 0: g% = g% + HEX("33")
            IF g% > 255 THEN g% = 0: r% = r% + HEX("33")
        END_IF
    NEXT i%
NEXT j%
WHILE ix% = 0: WAIT 300: END_WHILE: ' attente de clic
2D_TARGET_IS 0: DELETE f%: EXIT_SUB
Chx_Coul:
x% = MOUSE_X_POSITION(f%+1): y% = MOUSE_Y_POSITION(f%+1)
r% = COLOR_PIXEL_RED(f%+1,x%,y%)
g% = COLOR_PIXEL_GREEN(f%+1,x%,y%)
b% = COLOR_PIXEL_BLUE(f%+1,x%,y%)
CLIPBOARD_STRING_COPY STR$(65536*r%+256*g%+b%): ix% = 1
RETURN
END_SUB

HIDE 0
Palette216(200,600)
TERMINATE

SUB Palette216(x,y)
' Choix d'une couleur dans une palette de 216 (couleurs html) affichée en x,y
' Résultat dans le clipboard sous forme d'une chaîne r,g,b (ex. "192,24,33")
IF LABEL("Aff_pal216") = 0 THEN LABEL Aff_pal216
IF LABEL("Qui_pal216") = 0 THEN LABEL Qui_pal216
DIM_LOCAL a$, nf, np, nq, nt, nb, wc, hc, r, g, b, i, j
wc = 15: hc = 12
nf=3000: WHILE OBJECT_EXISTS(nf)=1: nf=nf+1: END_WHILE
FORM nf: TOP nf,y: LEFT nf,x: WIDTH nf,12*(wc+1)+16: HEIGHT nf,18*hc+84
BORDER_SMALL nf
CAPTION nf," PALETTE 216 COULEURS HTML": ON_CLOSE nf,Qui_pal216
np=nf+1: WHILE OBJECT_EXISTS(np)=1: np=np+1: END_WHILE
PICTURE np: PARENT np,nf: FULL_SPACE np: 2D_TARGET_IS np
ON_CLICK np,Aff_pal216
nq=np+1: WHILE OBJECT_EXISTS(nq)=1: nq=nq+1: END_WHILE
PICTURE nq: PARENT nq,nf: TOP nq,18*hc+22: LEFT nq,5: WIDTH nq,3*wc
HEIGHT nq,25
nt=nq+1: WHILE OBJECT_EXISTS(nt)=1: nt=nt+1: END_WHILE
ALPHA nt: PARENT nt,nf: TOP nt,TOP(nq): LEFT nt,LEFT(nq)+WIDTH(nq)+5
FONT_NAME nt,"Lucida Console"
nb=nt+1: WHILE OBJECT_EXISTS(nb)=1: nb=nb+1: END_WHILE
BUTTON nb: PARENT nb,nf:TOP nb,TOP(nq): WIDTH nb,50: LEFT nb,WIDTH(nf)-70
CAPTION nb,"OK"
ON_CLICK nb,Qui_pal216
r = 0: g = 0: b = 0
FOR j=0 TO 17
    y = j*(hc+1)
    FOR i = 0 TO 11
        x = i*(wc+1): 2D_PEN_COLOR r,g,b: 2D_FILL_COLOR r,g,b
        2D_RECTANGLE x,y,x+wc,y+hc
        b=b+51
        IF b>255
            b=0: g=g+51
            IF g>255
                g=0: r=r+51
            END_IF
        END_IF
    NEXT i
NEXT j
r=0: g=0: b=0: COLOR nq,r,g,b
CAPTION nt,"#00 00 00"+CHR$(10)+STR$(r)+","+STR$(g)+","+STR$(b)
2D_TARGET_IS nq: 2D_PEN_COLOR 164,164,164
WHILE 1>0: WAIT 100: TO_FOREGROUND nf: END_WHILE
Aff_pal216:
x=MOUSE_X_LEFT_DOWN(np): y=MOUSE_Y_LEFT_DOWN(np)
r=COLOR_PIXEL_RED(np,x,y): g=COLOR_PIXEL_GREEN(np,x,y): b=COLOR_PIXEL_BLUE(np,x,y)
2D_FILL_COLOR r,g,b: 2D_RECTANGLE 0,0,WIDTH(nq),HEIGHT(nq)
a$ = "#"+RIGHT$("0"+HEX$(r),2)+" "+RIGHT$("0"+HEX$(g),2)+" "+RIGHT$("0"+HEX$(b),2)
a$ = a$ + CHR$(10)+STR$(r)+","+STR$(g)+","+STR$(b)
CAPTION nt,a$
RETURN
Qui_pal216:
2D_TARGET_IS 0: DELETE nf
CLIPBOARD_STRING_COPY STR$(r)+","+STR$(g)+","+STR$(b)
END_SUB

HIDE 0
Palette16(100,100)
TERMINATE

SUB Palette16(x,y)
' Choix d'une couleur dans une palette de 16 (couleurs html de base) affichée en x,y
' Résultat dans le clipboard sous forme d'une chaîne r,g,b (ex. "192,24,33")
IF LABEL("Aff_pal16") = 0 THEN LABEL Aff_pal16
IF LABEL("Qui_pal16") = 0 THEN LABEL Qui_pal16
DIM_LOCAL ch$(16),nc$(16)
DIM_LOCAL a$, nf, np, nq, nt, nb, wc, hc, r, g, b, i, j, k
DATA "Pal16"
DATA "000000","000080","0000FF","008000","008080","00FF00","00FFFF","800000"
DATA "800080","808000","808080","C0C0C0","FF0000","FF00FF","FFFF00","FFFFFF"
DATA " black"," navy","  blue"," green"," teal","  lime"," cyan","maroon"," purple"
DATA " olive"," gray"," silver","  red","magenta","  yellow","  white": ' noms standards
RESTORE: READ a$: WHILE a$<>"Pal16": READ a$: END_WHILE
FOR i=1 TO 16: READ ch$(i): NEXT i: FOR i=1 TO 16: READ nc$(i): NEXT i
wc = 40: hc = 20
nf=3000: WHILE OBJECT_EXISTS(nf)=1: nf=nf+1: END_WHILE
FORM nf: TOP nf,y: LEFT nf,x: WIDTH nf,4*(wc+1)+16: HEIGHT nf,4*(hc+14)+66
BORDER_SMALL nf
CAPTION nf," -   16  COULEURS  HTML   -": ON_CLOSE nf,Qui_pal16
np=nf+1: WHILE OBJECT_EXISTS(np)=1: np=np+1: END_WHILE
PICTURE np: PARENT np,nf: FULL_SPACE np: 2D_TARGET_IS np: PRINT_TARGET_IS np
ON_CLICK np,Aff_pal16
nq=np+1: WHILE OBJECT_EXISTS(nq)=1: nq=nq+1: END_WHILE
PICTURE nq: PARENT nq,nf: TOP nq,4*(hc+14)+5: LEFT nq,0: WIDTH nq,wc
HEIGHT nq,25
nt=nq+1: WHILE OBJECT_EXISTS(nt)=1: nt=nt+1: END_WHILE
ALPHA nt: PARENT nt,nf: TOP nt,TOP(nq): LEFT nt,LEFT(nq)+WIDTH(nq)+5
FONT_NAME nt,"Lucida Console"
nb=nt+1: WHILE OBJECT_EXISTS(nb)=1: nb=nb+1: END_WHILE
BUTTON nb: PARENT nb,nf:TOP nb,TOP(nq): WIDTH nb,40: LEFT nb,WIDTH(nf)-56
CAPTION nb,"OK"
ON_CLICK nb,Qui_pal16
k = 1
FOR j=0 TO 3
    y = j*(hc+14)
    FOR i = 0 TO 3
        a$ = ch$(k): r=HEX(LEFT$(a$,2)): g=HEX(MID$(a$,3,2)): b=HEX(RIGHT$(a$,2))
        x = i*(wc+1): 2D_PEN_COLOR r,g,b: 2D_FILL_COLOR r,g,b
        2D_RECTANGLE x,y,x+wc,y+hc
        2D_FILL_COLOR 255,255,255: PRINT_LOCATE x,y+hc: PRINT nc$(k)
        k = k+1
    NEXT i
NEXT j
r=0: g=0: b=0: COLOR nq,r,g,b
CAPTION nt,"#00 00 00"+CHR$(10)+STR$(r)+","+STR$(g)+","+STR$(b)
2D_TARGET_IS nq: 2D_PEN_COLOR 164,164,164
WHILE 1>0: WAIT 100: TO_FOREGROUND nf: END_WHILE
Aff_pal16:
x=MOUSE_X_LEFT_DOWN(np): y=MOUSE_Y_LEFT_DOWN(np)
r=COLOR_PIXEL_RED(np,x,y): g=COLOR_PIXEL_GREEN(np,x,y): b=COLOR_PIXEL_BLUE(np,x,y)
2D_FILL_COLOR r,g,b: 2D_RECTANGLE 0,0,WIDTH(nq),HEIGHT(nq)
a$ = "#"+RIGHT$("0"+HEX$(r),2)+" "+RIGHT$("0"+HEX$(g),2)+" "+RIGHT$("0"+HEX$(b),2)
a$ = a$ + CHR$(10)+STR$(r)+","+STR$(g)+","+STR$(b)
CAPTION nt,a$
RETURN
Qui_pal16:
2D_TARGET_IS 0: DELETE nf
CLIPBOARD_STRING_COPY STR$(r)+","+STR$(g)+","+STR$(b)
END_SUB