1.99 ajout ReadBinaryFileRecord, WriteBinaryFileRecord

' demo_fichiers_binaires_zones_fixes.bas

' Ce programme crée un fichier binaire contenant
' 12 "enregistrements" ayant chacun 3 zones:
'    1 entier contenant le numéro d'enregistrement
'    1 flottant contenant le numéro d'enregistrement * 3 + 0.17
'    1 chaîne de caractères contenant str$(zone flottante)
' Afin de produire des enregsitrements de longueur fixe,
' la 3ème zone est fixée à 60 caractères. Chaque enregsitrement
' a donc 4 + 8 + 60 = 72 caractères.
'
' Le programme propose une zone pour saisir un numéro d'enregistrement
' entre 1 et 12, un bouton "Lire" et un mémo montrant les données lues.

label lire, sortie

dim i%, v, s$, buf$, n%, p%, num%
dim nom$ : nom$ = "test_fichier_binaire.dat"

on_close 0,sortie

alpha 1 : top 1,20 : left 1,20 : caption 1,"Enregistrement (1...12):"
edit 11 : top 11,20 : left 11,150 : width 11,40 : text 11,"0"
button 12 : top 12,50 : left 12,150 : caption 12,"Lire" : on_click 12,lire
memo 13 : top 13,80 : left 13,150 : width 13,300 : height 13,300

KGF_initialize("KGF.dll")

OpenBinaryFile(nom$)

' on crée d'abord un fichier "vide" de 12*72 caractères,
' soit 864 caractères
buf$ = string$(12*72," ")
WriteStringToBinaryFile(nom$,buf$)

' boucle pour la création des 12 enregistrements
for i%=1 to 12
  ' la variable i% est la zone 1
  ' on construit la zone 2
  v = i%*3 + 0.17
  ' et la zone 3
  s$ = left$(str$(v)+string$(60," "),60)
  ' on écrit l'enregistrement à sa place
  p% = (i%-1)*72 + 1 : ' calculer la position de début
  ' d'abord, écrire la zone 1:
  ReplaceBlockInBinaryFileByInteger(nom$,i%,p%,0)
  ' puis, écrire la zone 2:
  ReplaceBlockInBinaryFileByFloat(nom$,v,p%+4,0)
  ' enfin, écrire la zone 3:
  ReplaceBlockInBinaryFile(nom$,adr(s$),60,p%+12,1)
next i%

end

lire:
  if numeric(text$(11))=0
    message "Invalide."
    return
  end_if
  num% = val(text$(11))
  if num%<1 or num%>12
    message "Invalide."
    return
  end_if
  p% = (num%-1)*72 + 1 : ' calculer la position de début
  clear 13
  item_add 13,"Enregistrement "+str$(num%)
  ' d'abord lire la zone 1
  i% = 0
  ReadBlockFromBinaryFileToInteger(nom$,p%)
  item_add 13,"Zone 1: "+str$(ReadBlockFromBinaryFileToInteger%)
  ' puis, lire la zone 2:
  ReadBlockFromBinaryFileToFloat(nom$,p%+4)
  item_add 13,"zone 2: "+str$(ReadBlockFromBinaryFileToFloat)
  ' enfin, lire la zone 3:
  ReadBlockFromBinaryFileToString(nom$,60,p%+12)
  item_add 13,"Zone 3: ["+ReadBlockFromBinaryFileToString$+"]"
  return

sortie:
  CloseBinaryFile(nom$)
  return


#INCLUDE "KGF_SUB.bas"

' test_definition_record.bas

label lire, modifier

dim nfld%, fld1%, fld2, fld3$
dim res%, base%, nrec%, lu%
dim nom$ : nom$ = "test_fichier_binaire.dat"
fld3$ = string$(60," ")

KGF_initialize("KGF.dll")

define_record(3)

add_integer_field(adr(fld1%))
add_float_field(adr(fld2))
add_string_field(adr(fld3$),60)

build_record()

alpha 10 : top 10,10 : left 10,10 : caption 10,"Enregistrement:"
edit 11 : top 11,10 : left 11,100 : width 11,40 : text 11,"0"
button 12 : top 12,10 : left 12,160 : caption 12,"Lire"
  on_click 12,lire
button 13 : top 13,10 : left 13,320 : caption 13,"Modifier"
  on_click 13,modifier

end

lire:
  nrec% = val(text$(11))
  ReadBinaryFileRecord(nom$,record$,nrec%)
  message "lu: fld1%="+str$(fld1%)+"  fld2="+str$(fld2)+"  fld3$="+fld3$
  lu% = 1
  return
 
modifier:
  if lu%=0 then return
  fld2 = 0 - fld2
  fld3$ = left$(trim$(fld3$)+" bis"+string$(60," "),60)
  WriteBinaryFileRecord(nom$,record$,nrec%)
  message "écrit: fld1%="+str$(fld1%)+"  fld2="+str$(fld2)+"  fld3$="+fld3$
  return


#INCLUDE "KGF_SUB.bas"