Coloramic

' ------------------------------------------------------------------------------
' DECLARATION DES VARIABLES
' ------------------------------------------------------------------------------
dim x%,M%,a$,file$,res%,H%,L%,IT%,Img$,ligne,col,S$,sep%,y%,ref$,batch$,F_bat$
dim R%,G%,B%,R1%,G1%,B1%
dim D$,DL$,DF$,ND$,DA$
dim Lang$,Donnee$(200),def$(200),multi,compteur%,result%
dim Dossier$,Racine$,b$
dim titre$,lign%,col%,haut%,large%,Nbre_lign%
' ------------------------------------------------------------------------------
' DECARATION DES LABELS
' ------------------------------------------------------------------------------
label Init,Create_Langues,Create_image,Init_Lang
label Menu,Ouvrir,Quitter,Langue,Valid_Langue,Select_Drap,APp,AIde
label Elim,Valid_List,Annul_List,Travail,Tailles,Avancement
label Color_From,Color_To,Lien_Site,Ferm_Aide
' ------------------------------------------------------------------------------
' FORM 0
' ------------------------------------------------------------------------------
application_title "Coloramic"
width 0,274:height 0,315:top 0,(screen_y-315)/2:left 0,(screen_x-274)/2
font_name 0,"Times new roman":font_size 0,10:caption 0,"Coloramic"

main_menu 1
 for x%=2 to 7:sub_menu x% :next x%
 for x%=2 to 5 :parent x%,1:next x%
 for x%=6 to 7 :parent x%,2:next x%
 for x%=3 to 7 :on_click x%,Menu:next x%

dlist 11 :' liste des adresses de fichiers langues
dlist 12 :' liste des adresses de drapeaux
dlist 13 :' liste des adresses des fichiers images à transformer avec leur tailles (HxL)
dlist 14 :' Contenu du fichier langue sélectionné
picture 18:height 18,256:width 18,256:color 18,240,240,240
Image 16
gosub Init
gosub Init_Lang
on_close 0,Quitter
end
' ------------------------------------------------------------------------------
Init:
  D$=dir_current$
  if dir_exists(D$+"\BE_Output")=0 then dir_make D$+"\BE_Output"
  if dir_exists(D$+"\Langues")=0 then dir_make D$+"\Langues"
  if dir_exists(D$+"\Flags")=0 then dir_make D$+"\Flags"
  if dir_exists(D$+"\Aide")=0 then dir_make D$+"\Aide"
  ND$=D$+"\BE_Output"
  DL$=D$+"\Langues"
  DF$=D$+"\Flags"
  DA$=D$+"\Aide"
  if file_exists(D$+"\Param.inf")=0
      gosub Create_Langues
      gosub Create_image
  end_if
  if file_exists(D$+"\param.inf")=0
      file_open_write 2000,D$+"\Param.inf"
      file_write 2000,"French"
      file_close 2000
      Lang$="French"
  else
      file_open_read 2000,D$+"\Param.inf"
      file_read 2000,Lang$
      file_close 2000
  end_if
if file_exists(D$+"\Fd.jpg")=1 then file_load 18,D$+"\Fd.jpg"
return
' ------------------------------------------------------------------------------
Init_Lang:
  clear 14
  file_load 14,DL$+"\"+Lang$+".txt"
  for x%=1 to count(14): def$(x%)=item_read$(14,x%):next x%
  for x%=1 to 6:caption x%+1,def$(x%):next x%
  for x%=102 to 104:if object_exists(x%)=1 then caption x%,def$(x%-95):next x%
  if object_exists(300)=1 then caption 300,def$(10)
  for x%=113 to 114:if object_exists(x%)=1 then caption x%,def$(x%-102):next x%
  if object_exists(400)=1 then caption 400,def$(2)
  if object_exists(403)=1 then caption 403,def$(8)
  if object_exists(500)=1 then caption 500,def$(3)
  if object_exists(600)=1 then caption 600,def$(4)
  for x%=501 to 507:if object_exists(x%)=1 then caption x%,def$(x%-488):next x%
  if object_exists(502)=1 then hint 502,def$(20)
  if object_exists(600)=1 then caption 600,def$(4)
  if object_exists(602)=1 then caption 602,def$(6)
return
' ------------------------------------------------------------------------------
Menu:
  for x%=3 to 7
      if clicked(x%)=1 then M%=x%
  next x%
  select M%
      case 3
        gosub Langue
      case 4
        gosub APp
      case 5
        gosub Aide
      case 6
        gosub Ouvrir
      case 7
        gosub Quitter
  end_select
return
' ------------------------------------------------------------------------------
Ouvrir:
  clear 13
  if object_exists(101)=1 then clear 101
  hide 0
  if object_exists(100)=1
      show 100
      active 103
  else
      form 100:height 100,350:width 100,550:top 100,(screen_y-350)/2:left 100,(screen_x-550)/2
      font_name 100,"Times new roman":font_size 100,10
      command_target_is 100
      list 101:parent 101,100:height 101,150:width 101,534:on_double_click 101,Elim
      cursor_point 101
      alpha 102: parent 102,100:top 102,155:left 102,20:font_color 102,0,0,255
      button 103:parent 103,100:top 103,280:left 103,370:on_click 103,Valid_List
      cursor_point 103
      button 104:parent 104,100:top 104,280:left 104,450:on_click 104,Annul_List
      cursor_point 104
      R%=0:G%=0:B%=0:R1%=0:G1%=0:B1%=1
      picture 105:height 105,50:width 105,50:top 105,230:left 105,100
      color 105,R%,G%,B%
      picture 106:height 106,50:width 106,50:top 106,230:left 106,250
      color 106,R1%,G1%,B1%
      y%=190
      for x%=107 to 109:y%=y%+25:spin x%:width x%,50:top x%,y%:left x%,30:min x%,0:max x%,255:on_change x%,Color_From:next x%
      font_color 107,255,0,0:font_color 108,0,255,0:font_color 109,0,0,255
      position 107,R% :position 108,G% :position 109,B%
      y%=190
      for x%=110 to 112:y%=y%+25:spin x%:width x%,50:top x%,y%:left x%,170:min x%,0:max x%,255:on_change x%,Color_To:next x%
      font_color 110,255,0,0:font_color 111,0,255,0:font_color 112,0,0,255
      position 110,R1% :position 111,G1% :position 112,B1%
      alpha 113:top 113,215:left 113,100
      alpha 114:top 114,215:left 114,250
  end_if
    gosub Init_Lang
    dll_on D$+"\KGF.dll"
    racine$ =D$
    dossier$ = string$(255," ")
    res% = DLL_call4("FolderSelect",adr(racine$),adr(dossier$),len(dossier$),1)
    dll_off
    if res%=0
      hide 100
      show 0
      return
    end_if
    a$=dossier$
    dir_change a$
    file$=file_find_first$
    if file_extract_extension$(file$)=".bmp" then item_add 101,trim$(a$)+"\"+file$
    file$=file_find_next$
    while file$<>"_"
    if file_extract_extension$(file$)=".bmp" then item_add 101,trim$(a$)+"\"+file$
    file$=file_find_next$
    end_while
    file_find_close
    gosub Tailles
return
' ------------------------------------------------------------------------------
Color_From:
R%=val(text$(107)):G%=val(text$(108)):B%=val(text$(109))
color 105,R%,G%,B%
return
' ------------------------------------------------------------------------------
Color_To:
R1%=val(text$(110)):G1%=val(text$(111)):B1%=val(text$(112))
color 106,R1%,G1%,B1%
return
' ------------------------------------------------------------------------------
Elim:
  item_delete 101,item_index(101)
return
' ------------------------------------------------------------------------------
Valid_List:
  if count(101)>0
    clear 101
    hide 100
    gosub Avancement
    gosub Travail
  else
    message "La liste est vide"
    inactive 103
  end_if
return
' ------------------------------------------------------------------------------
Annul_List:
  hide 100
  show 0
return
' ------------------------------------------------------------------------------
Tailles:
  if count(101)>0
      dll_on D$+"\KGF.dll"
      for x%=1 to count(101)
        file_load 16,item_read$(101,x%)
        clipboard_copy 16
        res% = dll_call0("GetClipboardPictureHeight")
        H%=res%
        res% = dll_call0("GetClipboardPictureWidth")
        L%=res%
        item_add 13,item_read$(101,x%)+";"+str$(H%)+";"+str$(L%)
        item_delete 101,x%
        item_insert 101,x%,item_read$(13,x%)
      next x%
      dll_off
  end_if
return
' ------------------------------------------------------------------------------
Avancement:
  if object_exists(300)=1
      show 300
  else
      Form 300:height 300,100:width 300,320:top 300,(screen_y-100)/2:left 300,(screen_x-320)/2
      font_name 300,"arial":font_size 300,8:font_color 300,255,0,0
      command_target_is 300
      progress_bar 301:width 301,200:top 301,20:left 301,20:position 301,0
      alpha 302 :top 302,20 :left 302,230
  end_if
  gosub Init_Lang
  multi=(100/count(13))
return
' ------------------------------------------------------------------------------
Travail:
  form 200:hide 200
  command_target_is 200
  picture 201: color 201,R%,G%,B% : 2D_target_is 201 :2D_pen_color R1%,G1%,B1%

  IT%=0
  For compteur% = 1 to count(13)
  cls
  IT%=compteur%
  S$=item_read$(13,compteur%)
  sep%=instr(S$,";")
  Img$=left$(S$,sep%-1)
  S$=right$(S$,len(S$)-sep%)
  sep%=instr(S$,";")
  H%=val(left$(S$,sep%-1))
  L%=val(right$(S$,len(S$)-sep%))
  height 201,H%+1 : width 201,L%+1
  file_load 201,Img$
  for ligne = 0 to H%
      for col = 0 to L%
        if color_pixel_red(201,col,ligne) = R%
            if color_pixel_green(201,col,ligne) = G%
              if color_pixel_blue(201,col,ligne) = B%
              ' message str$(col) + "," + str$(ligne)
              2D_point col,ligne
              end_if
            end_if
        end_if
      next col
  next ligne
  file_save 201,ND$+"\"+file_extract_name$(Img$)
  wait 100
  Position 301,int(IT%*multi)
  caption 302,str$(int(IT%*multi))+" %"
  Next compteur%

  command_target_is 0
  hide 300
  delete 200
  show 0
return
' ------------------------------------------------------------------------------
Langue:
  if object_exists(400)=1
      show 400
  else
      form 400:width 400,300:height 400,200:top 400,(screen_y-200)/2:left 400,(screen_x-300)/2
      font_name 400,"Times new roman":font_size 400,10
      command_target_is 400
      list 401:height 401,160:on_click 401,Select_Drap:cursor_point 401
      picture 402:height 402,80:width 402,120:top 402,20:left 402,130:stretch_on 402 :color 402,240,240,240
      button 403:top 403,135:left 403,205:cursor_point 403:on_click 403,Valid_Langue
  end_if
  inactive 403
  gosub Init_Lang
  dir_change DL$
  clear 401
  a$=file_find_first$
  item_add 401,left$(a$,len(a$)-4)
  a$=file_find_next$
  while a$<>"_"
  item_add 401,left$(a$,len(a$)-4)
  a$=file_find_next$
  end_while
  file_find_close
return
' ------------------------------------------------------------------------------
Select_Drap:
ref$=DF$+"\"+item_index$(401)+".bmp"
  if file_exists(ref$)=1
    file_load 402,ref$
  else
    color 402,240,240,240
  end_if
active 403
return
' ------------------------------------------------------------------------------
Valid_Langue:
  Lang$=item_index$(401)
  gosub Init_Lang
  file_open_write 2000,D$+"\Param.inf"
  file_write 2000,Lang$
  file_close 2000
  hide 400
return
' ------------------------------------------------------------------------------
APp:
  if object_exists(500)=1
      show 500
  else
      form 500:height 500,210:width 500,360:top 500,(screen_y-210)/2:left 500,(screen_x-360)/2
      font_name 500,"Times new roman":font_size 500,10
      command_target_is 500
      alpha 501:top 501,20:left 501,20
      alpha 502:top 502,50:left 502,20:font_size 502,12:font_color 502,0,0,255:on_click 502,Lien_Site
      cursor_point 502
      alpha 503:top 503,54:left 503,180:font_size 503,8
      alpha 504:top 504,80:left 504,20
      alpha 505:top 505,100:left 505,120
      alpha 506:top 506,120:left 506,10
      alpha 507:top 507,140:left 507,10:font_color 507,255,0,0
  end_if
  gosub Init_Lang
return
' ------------------------------------------------------------------------------
Lien_Site:
  execute "http://panoramic-language.pagesperso-orange.fr/French/index.html"
return
' ------------------------------------------------------------------------------
AIde:
  if object_exists(600)=1
    show 600
  else
    form 600:height 600,250:width 600,400:top 600,0:left 600,screen_x-400
    font_name 600,"Times new roman":font_size 600,10
    command_target_is 600
    memo 601:top 601,10:left 601,10:width 601,365:height 601,170
    bar_vertical 601
    Button 602:top 602,185:left 602,300:cursor_point 602
    on_click 602,Ferm_Aide
  end_if
  gosub Init_Lang
  if file_exists(DA$+"\Aide_"+lang$+".txt")=1
    file_load 601,DA$+"\Aide_"+lang$+".txt"
  else
    item_add 601,def$(21)
  end_if
return
' ------------------------------------------------------------------------------
Ferm_Aide:
  hide 600
  clear 601
return
' ------------------------------------------------------------------------------
' FICHIER LANGUE FRANCAIS
' ------------------------------------------------------------------------------
Create_Langues:
file_open_write 15,DL$+"\French.txt"
for x%=1 to 21:read donnee$(x%):file_writeln 15,donnee$(x%):next x%
file_close 15
data "Fichier"
data "Langue"
data "A Propos"
data "Aide"
data "Ouvrir"
data "Quitter"
data "Double cliquer pour effacer un item"
data "Valider"
data "Annuler"
data "Patienter pendant la conversion"
data "De"
data "Vers"
data "Cette application a été créée avec :"
data "PANORAMIC EDITOR"
data "Vs 0.9.23 du 19/07/2012"
data "Créé par :"
data "ygeronimi"
data "avec la collaboration de la communauté des panoramiciens"
data "Cette application est ''Freeware'' et ne peut donc être vendue"
data "Cliquez pour nous rejoindre..."
data "Fichier inexistant"
' ------------------------------------------------------------------------------
' FICHIER LANGUE ANGLAIS
' ------------------------------------------------------------------------------
file_open_write 15,DL$+"\English.txt"
for x%=1 to 21:read donnee$(x%):file_writeln 15,donnee$(x%):next x%
file_close 15
Data "Files"
Data "Langage"
Data "About"
Data "Help"
Data "Open"
Data "Exit"
Data "Double click to clear an item"
Data "Valid"
Data "Cancel"
Data "Wait please..."
Data "From"
Data "To"
Data "This application was created with :"
Data "PANORAMIC EDITOR"
Data "Vs 0.9.23 of 19/07/2012"
Data "Created by :"
Data "ygeronimi"
Data "with the collaboration of panoramiciens"
Data "This application is freeware and can not be sold"
Data "Click to join us..."
Data "Unknown file..."
' ------------------------------------------------------------------------------
' FICHIER LANGUE ALLEMAND
' ------------------------------------------------------------------------------
file_open_write 15,DL$+"\Deutsch.txt"
for x%=1 to 21:read donnee$(x%):file_writeln 15,donnee$(x%):next x%
file_close 15
data "Datei"
data "Sprache"
data "Über"
data "Die Beihilfen"
data "Öffnen"
data "Verlassen"
data "Doppelklick auf ein Element zul Löschen"
data "Bestätigen"
data "Kündigen"
data "Warten auf die Umwandlung"
data "von"
data "auf"
Data "Dieses Programm wurde erstellt mit :"
Data "PANORAMIC EDITOR"
Data "Vs 0.9.23 von 19/07/2012"
Data "Erstellt von :"
Data "ygeronimi"
Data "In Zusammenarbeit mit der Gemeinde der Panoramiker"
Data "Diese Anwendung ist Freeware und kann nicht verkauft werden"
Data "Klicken Sie, um sich uns anzuschließen ..."
Data "Vorhandene Datei..."
' ------------------------------------------------------------------------------
' FICHIER HELP FRENCH
' ------------------------------------------------------------------------------
file_open_write 15,DA$+"\Aide_French.txt"
for x%=1 to 64:read donnee$(x%):file_writeln 15,donnee$(x%):next x%
file_close 15
Data "Fonction de Coloramic ?"
Data "****************************"
Data ""
data "Coloramic a pour fonction de changer une couleur d'une image"
data "par une autre."
data "Lorsqu'une couleur est utilisée pour la transparence, il y  a des"
data "risques d'une altération de l'image à son affichage."
data "En changeant la couleur transparente par sa couleur voisine"
data "la plus proche l'oeil ne détecte pas ce changement mais"
data "l'affichage s'en trouve amélioré."
data ""
data "Comment installer Coloramic ?"
data "***********************************"
data ""
data "- ''Coloramic.exe'' et le fichier ''KGF.dll'' ainsi que ''Fd.jpg''"
data "sont à placer dans un même dossier."
data ""
data "- Lancer l'exécutable, il créée lui même les dossiers et fichiers"
data "indispensables à son bon fonctionnement."
data ""
data "- Vous pouvez ajouter les drapeaux des pays dont la langue"
data "est présente dans ''...Coloramic\Langue''"
data "dans le dossier ''...Coloramic\Flags''"
data ""
data ""
data "Comment utiliser Coloramic ?"
data "**********************************"
data ""
data "- Cliquer sur ''Fichier\Ouvrir'' une boite de dialogue apparait."
data ""
data "- Choisir le dossier à charger dans Coloramic, en le selectionnant"
data "le contenu apparait dans la liste de droite."
data ""
data "- Valider le choix du dossier, tous les fichiers portant l'extension"
data "*.bmp sont chargés dans Coloramic, la boite de dialogue disparait"
data "et laisse place à une fenêtre. Dans la liste apparaissent tous les fichiers"
data "chargés avec leurs dimensions ( H x L )."
data ""
data "- Pour effacer un fichier de la liste, double-cliquez sur celui ci dans"
data "la liste"
data ""
data "- Choisir la couleur à changer, une image  avec trois selecteurs de"
data "couleur ( en bas à gauche ) permettent de selectionner et visualiser"
data "la couleur à changer (0,0,0 par défaut)."
data ""
data "- Choisir la couleur de remplacement, une image  avec trois selecteurs"
data "de couleur ( en bas à droite ) permettent de selectionner et visualiser"
data "la couleur à obtenir (0,0,1 par défaut)."
data ""
data "- Valider et une barre d'état apparait et indique le pourcentage de"
data "conversion effectué. La barre disparait, tous les fichiers sont convertis"
data "et se trouvent dans le dossier ''...Coloramic\BE_OutPut''"
data ""
data "Avertissement !"
data "******************"
data ""
data "Si vous incorporez un fichier dans le dossier ''...\Coloramic\Langue''."
data "Le fichier doit être au format *.txt et se conformer aux lignes des fichiers"
data "existants tant par le nombre de celles-ci que par la traduction."
data "Tout autre formatage est à vos risques et périls."
data ""
data "Si vous insérez un fichier dans le dossier ''...\Coloramic\Flags''."
data "Il doit être au format *.bmp ( 24 couleurs )."
data "Tout autre formatage est à vos risques et périls."
' ------------------------------------------------------------------------------
' FICHIER HELP DEUTSCH
' ------------------------------------------------------------------------------
file_open_write 15,DA$+"\Aide_Deutsch.txt"
for x%=1 to 63:read donnee$(x%):file_writeln 15,donnee$(x%):next x%
file_close 15
Data "Funktion Coloramic?"
Data "****************************"
Data ""
Data "Coloramic kann verwendet werden, um eine Farbe eines Bildes"
Data "durch eine andere zu ersetzen."
Data "Wenn eine Farbe als Transparenz verwendet wird, besteht die"
Data "Gefahr einer Verschlechterung des angezeigten Bildes."
Data "Austausch der Transparenz Farbe gegen eine naheliegende Farbe"
Data "ist unmerklich für das Auge, verbessart aber dann due Anzeige."
Data ""
Data "Wie wird Coloramic installiert?"
Data "******************************"
Data ""
Data "-'' Coloramic.exe'' und'' Datei'' und'' KGF.dll Fd.jpg''"
Data "sollten im selben Ordner abgelegt werden."
Data ""
Data "- Starten Sie die ausführbare Datei - sie erzeugt sebsttätig"
Data "notwendige Ordner und Dateien für ordnungsgemäßen Betrieb."
Data ""
Data "- Sie können Flaggen der Länder, deren Sprache sich im"
Data "Ordner    Coloramic ...'' \'' Language  befindet, in dem"
data "Ordner ... Coloramic'' \'' Flags  ablegen."
Data ""
Data ""
Data "Wie wird Coloramic benutzt?"
Data "***************************"
Data ""
Data "- Wenn Sie auf '' File \ Open'' klicken, wird ein Dialogfeld angezeigt."
Data ""
Data "- Wählen Sie den in Coloramic zu ladenden Ordner."
Data "Der Inhalt erscheint in der Liste auf der rechten Seite."
Data ""
Data "- Bestätigen Sie die Auswahl des Ordners, alle Dateien mit der Erweiterung"
Data "*. Coloramic bmp werden geladen, das Dialogfeld geladen verschwindet"
Data "und weicht einem Fenster. In der Liste erscheinen alle Dateien"
Data "mit ihren Abmessungen (H x L)."
Data ""
Data "- Um eine Datei aus der Liste zu löschen, klicken Sie doppelt in die"
Data "Liste"
Data ""
Data "- Wählen Sie die auszutauschende Farbe. Ein Bild (unten links) mit drei"
Data " Knopfschaltern erlaubt, die Farbe auszuwählen und anzuzeigen"
Data " (0,0,0 Vorgabe)."
Data ""
Data "- Wählen Sie die Ersatzfarbe. Ein Bild (rechts unten) mit drei Knopfschaltern"
Data "erlaubt, die Farbe auszuwählen und anzuzeigen"
Data ", (0,0,1 Vorschlag)."
Data ""
Data "- Bestätigen Sie, und eine Statusleiste erscheint und zeigt den Prozentsatz der"
Data "Konvertierung an. Diese Leiste verschwindet, werden alle Dateien konvertiert sind."
Data "Diese befinden sich im Ordner ... Coloramic'' \'' BE_OutPut"
Data ""
Data "Warnung!"
Data "********"
Data ""
Data "Wenn Sie eine Datei in den Ordner'' ... \ Coloramic \'' Sprache einbetten:"
data "-diese Datei muss im *. txt Format sein muss die existierenden Zeilen beachten,"
Data "sowohl in Anbetracht der Anzahl als der Übersetzung.."
Data "Jedes andere Format ist auf eigene Gefahr."
Data ""
Data "Sollten Sie eine Datei in den Ordner'' ... \ Coloramic \'' Flags einfügen:"
Data "- diese Datei muss im Format *.bmp (24 Farben)."
Data "Jedes andere Format ist auf eigene Gefahr."
' ------------------------------------------------------------------------------
' FICHIER HELP ENGLISH
' ------------------------------------------------------------------------------
file_open_write 15,DA$+"\Aide_English.txt"
for x%=1 to 64:read donnee$(x%):file_writeln 15,donnee$(x%):next x%
file_close 15
Data "function Coloramic?"
Data "****************************"
Data ""
data "Coloramic operable to change a color of a picture"
data "by another."
data "When color is used for transparency, there are"
data "risk of a deterioration of the image being displayed."
data "Changing transparent color by color door"
data "nearest the eye does not detect the change, but"
data "display is improved."
data ""
data "Coloramic How to install?"
data "***********************************"
data ""
data "-'' Coloramic.exe'' and'' file'' and'' KGF.dll Fd.jpg''"
data "should be placed in the same folder."
data ""
data "- Run the executable, it created itself files and folders"
data "Essential for proper operation."
data ""
data "- You can add flags of countries whose language"
data "is present in Coloramic ...'' \'' Language"
data "folder ... Coloramic'' \'' Flags"
data ""
data ""
data "Coloramic How to use?"
data "**********************************"
data ""
data "- Click on'' File \ Open'' a dialog box will appear."
data ""
data "- Select the file to load into Coloramic, by selecting"
data "content appears in the list on the right."
data ""
data "- Confirm selection of the file, all files with the extension"
data "*. Coloramic bmp are loaded into the dialog box disappears"
data "and gives way to a window. list appears in all files"
data "loaded with their dimensions (H x L)."
data ""
data "- To delete a file from the list, double-click on it in"
data "list"
data ""
data "- Choose the color to change an image with three selector"
data "color (bottom left) can select and view"
data "to change the color (0,0,0 default)."
data ""
data "- Choose the replacement color, an image with three knob"
data "color (bottom right) can select and view"
data "to get the color (0,0,1 default)."
data ""
data "- Validate and a status bar appears and shows the percentage of"
data "conversion done. bar disappears, all the files are converted"
data "and is located in the folder ... Coloramic'' \'' BE_OutPut"
data ""
data "Warning!"
data "******************"
data ""
data "If you embed a file in the folder'' ... \ Coloramic \'' Language."
data "file must be in *. txt and comply with lines from files"
data "as existing by the number of those that will in the translation."
data "Any other format is at your own risk."
data ""
data "If you insert a file in the folder'' ... \ Coloramic \'' Flags."
data "must be in the format *. bmp (24 colors)."
data "Any other format is at your own risk."
return

Create_Image:
  read titre$
  read haut%
  read large%
  read Nbre_lign%
  if object_exists(800)=0
      form 800:hide 800
      command_target_is 800
      picture 801:width 801,large% :height 801,haut% :2d_target_is 801
      for x%=1 to Nbre_Lign%
        read col% :read lign% :read R% :read G% :read B%
        2d_pen_color R%,G%,B%
        2d_point col%,lign%
      next x%
  end_if
  file_save 801,DF$+"\"+titre$+".bmp"
  cls
  #include "Deutsch.bas"
  read titre$
  read haut%
  read large%
  read Nbre_lign%
  width 801,large% :height 801,haut%
      for x%=1 to Nbre_lign%
        read col% :read lign% :read R% :read G% :read B%
        2d_pen_color R%,G%,B%
        2d_point col%,lign%
      next x%
  file_save 801,DF$+"\"+titre$+".bmp"
  cls
  #include "French.bas"
  read titre$
  read haut%
  read large%
  read Nbre_lign%
  width 801,large% :height 801,haut%
      for x%=1 to Nbre_lign%
        read col% :read lign% :read R% :read G% :read B%
        2d_pen_color R%,G%,B%
        2d_point col%,lign%
      next x%
  file_save 801,DF$+"\"+titre$+".bmp"
  command_target_is 0
  delete 800
  #include "English.bas"
return

Quitter:
terminate